Prehľad vzorcov v Exceli

Prehľad vzorcov v Exceli

Ak ste doteraz Excel nepoužívali, onedlho zistíte, že je viac než len mriežkou, do ktorej vkladáte čísla do stĺpcov alebo riadkov. Áno, Excel môžete použiť na získanie súčtov čísel v stĺpci alebo riadku, ale môžete pomocou neho vypočítať aj splátky hypotéky, vyriešiť matematické alebo technické úlohy alebo nájsť scenár pre najlepší prípad na základe zadaných premenných.

Excel tieto výpočty vykoná pomocou vzorcov v bunkách. Vzorec vykoná výpočty alebo iné akcie na údajoch v hárku. Vzorec sa vždy začína znamienkom rovnosti (=), za ním môžu nasledovať čísla, matematické operátory (napríklad znamienko plus alebo mínus na sčítanie alebo odčítanie) a vstavané funkcie Excelu, ktoré môžu skutočne zvýšiť potenciál vzorca.

Nasledujúci vzorec napríklad vynásobí číslo 2 číslom 3, k výsledku priráta číslo 5 a zobrazí odpoveď 11.

=2*3+5

Tu sú uvedené niektoré ďalšie príklady vzorcov, ktoré možno zadať do hárka.

  • =A1+A2+A3    Vypočíta súčet hodnôt v bunkách A1, A2 a A3.

  • =SUM(A1:A10)    Pomocou funkcie SUM vráti súčet hodnôt v bunkách A1 až A10.

  • =TODAY()    Vráti aktuálny dátum.

  • =UPPER("ahoj")     Pomocou funkcie UPPER skonvertuje text „ahoj“ na text „AHOJ“.

  • =IF(A1>0)    Pomocou funkcie IF určí, či bunka A1 obsahuje väčšiu hodnotu ako 0.

Vzorec môže obsahovať tieto súčasti: funkcie, odkazy, operátory a konštanty.

Časti vzorca   

Časti vzorca

1. Funkcie: Funkcia PI() vráti hodnotu pí: 3,142...

2. Odkazy: Odkaz A2 vráti hodnotu bunky A2.

3. Konštanty: Číselné alebo textové hodnoty zadané priamo do vzorca, napríklad číslo 2.

4. Operátory: Operátor ^ (znak mocniny) umocní číslo na príslušnú mocninu a operátor * (hviezdička) vynásobí čísla.

Konštanta je hodnota, ktorá sa nevypočítava – vždy zostáva rovnaká. Napríklad dátum 9.10.2008, číslo 210 alebo text „Štvrťročné výnosy“ sú všetko konštanty. Konštantou nie je výraz ani hodnota, ktorá je výsledkom výrazu. Ak namiesto odkazov na bunky použijete vo vzorci konštanty (napríklad: =30+70+110), výsledok sa zmení, iba ak upravíte vzorec. Vo všeobecnosti je vhodné umiestniť konštanty do samostatných buniek, kde ich môžete podľa potreby zmeniť, a potom odkazovať na tieto bunky vo vzorci.

Operátory určujú typ výpočtu, ktorý chcete vykonať na prvkoch vo vzorci. Excel pri výpočtoch dodržiava všeobecné matematické pravidlá, ktoré zahŕňajú Zátvorky, Exponenty, Násobenie a delenie, Sčítanie a odčítanie alebo skratku pravidla poradia výpočtov PEMDAS (zátvorka, exponenty, násobenie, delenie, sčítanie, odčítanie). Použitím zátvoriek môžete toto poradie výpočtov zmeniť.

Typy operátorov. Existujú štyri rôzne typy výpočtových operátorov: aritmetické, porovnávacie, textové reťazce a odkazové.

  • Aritmetické operátory

    Ak chcete vykonať základné matematické operácie, ako je napríklad sčítanie, odčítanie, násobenie alebo delenie, kombinovať čísla a získavať číselné výsledky, použite nasledujúce aritmetické operátory.

    Aritmetický operátor

    Význam

    Príklad

    + (znak plus)

    Sčítanie

    =3+3

    – (znamienko mínus)

    Odčítanie
    Záporná hodnota

    =3–3
    =-3

    * (hviezdička)

    Násobenie

    =3*3

    / (lomka)

    Delenie

    =3/3

    % (znak percenta)

    Percento

    30%

    ^ (znak ^)

    Umocnenie

    =3^3

  • Operátory porovnávania

    Pomocou nasledujúcich operátorov môžete porovnať dve hodnoty. Ak sú dve hodnoty porovnávané pomocou týchto operátorov, výsledkom je logická hodnota – TRUE alebo FALSE.

    Operátor porovnania

    Význam

    Príklad

    = (znak rovnosti)

    Rovná sa

    =A1=B1

    > (znamienko väčšie)

    Väčšie

    =A1>B1

    < (znamienko menšie)

    Menšie

    =A1<B1

    >= (znamienko väčšie alebo rovné)

    Väčšie alebo rovné

    =A1>=B1

    <= (znamienko menšie alebo rovné)

    Menšie alebo rovné

    =A1<=B1

    <> (znamienko nerovnosti)

    Nerovná sa

    =A1<>B1

  • Operátor reťazenia textu

    Pomocou znaku & môžete zlučovať (alebo spájať) viaceré textové reťazce do jedného bloku textu.

    Textový operátor

    Význam

    Príklad

    Znak „&“

    Pripája alebo spája dve hodnoty a vytvára jednu súvislú textovú hodnotu.

    Výsledkom dvoch výrazov ="North"&"wind" je jeden výraz "Northwind".
    V bunke A1 sa nachádza výraz "Priezvisko" a v bunke B1 výraz "Meno", výsledkom reťazenia =A1&", "&B1 je výraz "Priezvisko, Meno".

  • Odkazové operátory

    Použitím nasledujúcich operátorov pre výpočty je možné spájať rozsahy buniek.

    Odkazový operátor

    Význam

    Príklad

    : (dvojbodka)

    Operátor rozsahu, ktorý vytvára odkaz na všetky bunky medzi dvoma odkazmi vrátane týchto dvoch odkazov.

    B5:B15

    ; (bodkočiarka)

    Operátor zjednotenia, ktorý spája viac odkazov do jedného odkazu.

    =SUM(B5:B15;D5:D15)

    (medzera)

    Operátor prieniku, ktorý vytvára jeden odkaz na spoločné bunky dvoch odkazov.

    B7:D7 C6:C8

Na začiatok stránky

V niektorých prípadoch môže poradie vykonaného výpočtu ovplyvniť vrátenú hodnotu vzorca. Ak chcete získať požadované výsledky, je dôležité vedieť spôsob určenia poradia a ako ho možno zmeniť.

  • Poradie výpočtu

    Vzorce vypočítavajú hodnoty v určitom poradí. Vzorec programu Excel vždy začína znamienkom rovnosti (=). Program Excel interpretuje znaky, ktoré nasledujú za znamienkom rovnosti, ako vzorec. Za znamienkom rovnosti nasledujú vypočítavané prvky (operandy), ako sú napríklad konštanty alebo odkazy na bunky. Tieto prvky sú oddelené výpočtovými operátormi. Program Excel vypočítava vzorec zľava doprava, pričom zachováva poradie operátorov vzorca.

  • Priorita operátorov vo vzorcoch Excelu

    Ak v jednom vzorci skombinujete niekoľko operátorov, Excel vykoná operácie v poradí zobrazenom v nasledujúcej tabuľke. Ak vzorec obsahuje operátory s rovnakou prioritou – napríklad operátor násobenia spolu s operátorom delenia – Excel tieto operátory vyhodnotí zľava doprava.

    Operátor

    Popis

    : (dvojbodka)

    (jednoduchá medzera)

    ; (bodkočiarka)

    Odkazové operátory

    Záporná hodnota (napríklad –1)

    %

    Percento

    ^

    Umocňovanie

    * a /

    Násobenie a delenie

    + a –

    Sčítanie a odčítanie

    &

    Spája dva textové reťazce (reťazenie)

    =
    < >
    <=
    >=
    <>

    Porovnanie

  • Použitie zátvoriek vo vzorcoch Excelu

    Ak chcete zmeniť poradie operácií, vložte časť vzorca, ktorá sa má vypočítať ako prvá, do zátvoriek. Nasledujúci vzorec napríklad dáva výsledok 11, pretože program Excel vykonáva násobenie pred sčítaním. Vzorec vynásobí číslo 2 číslom 3 a potom k výsledku pripočíta číslo 5.

    =5+2*3

    Ak však zmeníte syntax použitím zátvoriek, program Excel najskôr sčíta čísla 5 a 2 a potom vynásobí výsledok číslom 3, čo dáva výslednú hodnotu 21.

    =(5+2)*3

    Zátvorky v prvej časti vzorca v nasledujúcom príklade zabezpečujú, že sa najskôr vypočíta súčet B4+25 a výsledok sa potom vydelí súčtom hodnôt v bunkách D5, E5 a F5.

    =(B4+25)/SUM(D5:F5)

    Na začiatok stránky

Funkcie sú preddefinované vzorce, ktoré vykonávajú výpočty pomocou konkrétnych hodnôt, ktoré sa nazývajú argumenty, v určitom poradí alebo štruktúre. Funkcie sa používajú pri jednoduchých a zložitých výpočtoch. Všetky funkcie Excelu nájdete na páse s nástrojmi na karte Vzorce:

Karta Vzorce na páse s nástrojmi v Exceli
  • Syntax funkcie Excelu

    Nasledujúci príklad, v ktorom funkcia ROUND zaokrúhli číslo v bunke A10, ilustruje syntax tejto funkcie.

    Štruktúra funkcie

    1. Štruktúra. Štruktúra funkcie sa začína znamienkom rovnosti (=), za ktorým nasleduje názov funkcie, ľavá zátvorka, argumenty funkcie oddelené bodkočiarkami a nakoniec pravá zátvorka.

    2. Názov funkcie. Ak chcete zobraziť zoznam dostupných funkcií, kliknite na bunku a stlačte kombináciu klávesov SHIFT + F3. Spustí sa tak dialógové okno Vloženie funkcie.

    Vzorce programu Excel – dialógové okno na vloženie funkcie

    3. Argumenty. Argumenty môžu byť čísla, text, logické hodnoty, napríklad TRUE alebo FALSE, polia, chybové hodnoty typu #N/A alebo odkazy na bunku. Vybraté argumenty musia nadobúdať platné hodnoty. Argumentmi môžu byť tiež konštanty, vzorce alebo iné funkcie

    4. Popis argumentu. Po zadaní funkcie sa zobrazí popis so syntaxou a argumentmi. Tento popis sa zobrazí napríklad po zadaní reťazca =ROUND(. Popisy sa zobrazujú len pre vstavané funkcie.

    Poznámka: Funkcie, ako je napríklad =ROUND, nie je potrebné zadávať veľkými písmenami. Excel automaticky po stlačení klávesu Enter vytvorí názov funkcie z veľkých písmen. Ak zadáte názov funkcie nesprávne, napríklad =SUME(A1:A10) namiesto =SUM(A1:A10), Excel vráti chybu #NÁZOV?.

  • Zadávanie funkcií Excelu

    Pri vytváraní vzorca obsahujúceho funkciu môžete použiť dialógové okno Vloženie funkcie, ktoré umožňuje vkladať funkcie hárka. Po výbere funkcie z dialógového okna Vloženie funkcie spustí Excel sprievodcu funkciami, prostredníctvom ktorého sa zobrazí názov funkcie, všetky argumenty, popis funkcie a každého argumentu, aktuálny výsledok funkcie a aktuálny výsledok celého vzorca.

    Sprievodca funkciami v Exceli

    Ak chcete vytvoriť alebo upraviť vzorce a obmedziť chyby zadávania alebo syntaxe, použite Automatické dokončovanie vzorca. Po zadaní znamienka rovnosti (=) a začiatočných písmen funkcie Excel zobrazí dynamický rozbaľovací zoznam s platnými funkciami, argumentmi a názvami, ktoré zodpovedajú písmenám. Potom môžete v rozbaľovacom zozname vybrať, čo potrebujete, a Excel vykoná zadanie za vás.

    Automatické dokončovanie vzorca v Exceli

  • Vnorenie funkcií Excelu

    V niektorých prípadoch je potrebné použiť funkciu ako jeden z argumentov inej funkcie. Nasledujúci vzorec napríklad používa vnorenú funkciu AVERAGE a výsledok porovnáva s hodnotou 50.

    Vnorené funkcie

    1. Funkcie AVERAGE a SUM sú vnorené v rámci funkcie IF.

    Platné výsledky.    Ak sa vnorená funkcia použije ako argument, musí vrátiť rovnaký typ hodnôt, aký používa argument. Ak napríklad argument vracia hodnotu TRUE alebo FALSE, vnorená funkcia musí vrátiť hodnotu TRUE alebo FALSE. V opačnom prípade program Excel zobrazí hlásenie o chybovej hodnote #HODNOTA!.

    Obmedzenia úrovní vnorenia.    Vzorec môže obsahovať najviac sedem úrovní vnorených funkcií. Ak sa jedna funkcia (označme ju ako funkcia B) použije ako argument v inej funkcii (označme ju ako funkcia A), funkcia B bude funkciou druhej úrovne. Napríklad funkcia AVERAGE a funkcia SUM budú funkciami druhej úrovne, ak sa použijú ako argumenty funkcie IF. Funkcia vnorená vo vnorenej funkcii AVERAGE bude funkciou tretej úrovne, a tak ďalej.

    Na začiatok stránky

Odkaz definuje bunku alebo rozsah buniek v hárku a oznamuje Excelu, kde má hľadať hodnoty alebo údaje, ktoré chcete vo vzorci použiť. Pomocou odkazov možno v jednom vzorci použiť údaje uložené v rôznych častiach hárka, alebo možno hodnotu jednej bunky použiť vo viacerých vzorcoch. Odkazovať sa môže aj na bunky v iných hárkoch jedného zošita a na iné zošity. Odkazy na bunky v iných zošitoch sa nazývajú prepojenia alebo externé odkazy.

  • Štýl odkazu A1

    Excel predvolene používa štýl odkazu A1, ktorý odkazuje na stĺpce označené písmenami (od A po XDF, celkovo 16 384 stĺpcov) a na riadky označené číslami (od 1 do 1 048 576). Písmená sa nazývajú nadpisy stĺpcov a čísla nadpisy riadkov. Ak chcete odkazovať na bunku, zadajte písmeno stĺpca a číslo riadka. Napríklad B2 odkazuje na bunku, ktorá sa nachádza v stĺpci B a riadku 2.

    Odkaz na

    Použite

    Bunku v stĺpci A a v riadku 10

    A10

    Rozsah buniek v stĺpci A a v riadkoch od čísla 10 po číslo 20

    A10:A20

    Rozsah buniek v riadku číslo 15 a v stĺpcoch od písmena B po písmeno E

    B15:E15

    Všetky bunky v riadku číslo 5

    5:5

    Všetky bunky od riadka číslo 5 po riadok číslo 10

    05:10:00

    Všetky bunky v stĺpci H

    H:H

    Všetky bunky od stĺpca H po stĺpec J

    H:J

    Rozsah buniek od stĺpca A po stĺpec E a od riadka číslo 10 po riadok číslo 20

    A10:E20

  • Vytvorenie odkazu na bunku alebo rozsah buniek v inom hárku toho istého zošita

    V nasledujúcom príklade funkcia AVERAGE vypočíta priemernú hodnotu z rozsahu buniek B1:B10 v hárku s názvom Marketing v tom istom zošite.

    Príklad odkazu na hárok

    1. Odkazuje sa na hárok s názvom Marketing

    2. Odkazuje sa na rozsah buniek od B1 až po B10

    3. Výkričník (!) oddeľuje odkaz na hárok od odkazu na rozsah buniek

    Poznámka: Ak sa v hárku, na ktorý sa odkazuje, nachádzajú medzery alebo čísla, pred a za názov hárka budete musieť pridať apostrof ('), napríklad ='123'!A1 alebo ='Tržby za január'!A1.

  • Rozdiel medzi absolútnymi, relatívnymi a zmiešanými odkazmi

    1. Relatívne odkazy.     Relatívny odkaz vo vzorci, napríklad A1, je založený na relatívnej pozícii bunky obsahujúcej vzorec a bunky, na ktorú odkaz odkazuje. Ak sa zmení pozícia bunky obsahujúcej vzorec, zmení sa aj príslušný odkaz. V prípade skopírovania alebo vyplnenia vzorca do viacerých riadkov alebo stĺpcov sa odkaz automaticky upraví. Podľa predvoleného nastavenia sa v nových vzorcoch používajú relatívne odkazy. Ak napríklad skopírujete alebo vyplníte relatívny odkaz z bunky B2 do bunky B3, odkaz =A1 sa automaticky upraví na =A2.

      Skopírovaný vzorec s relatívnym odkazom   

      Skopírovaný vzorec s relatívnym odkazom

    2. Absolútne odkazy.    Absolútny odkaz vo vzorci, napríklad $A$1, vždy odkazuje na bunku na určitom mieste. Ak sa zmení pozícia bunky obsahujúcej vzorec, absolútny odkaz zostane rovnaký. V prípade skopírovania alebo vyplnenia vzorca do viacerých riadkov alebo stĺpcov sa absolútny odkaz neupraví. V predvolenom nastavení sa v nových vzorcoch používajú relatívne odkazy, takže ich môže byť potrebné prepnúť na absolútne odkazy. Ak napríklad skopírujete alebo vyplníte absolútny odkaz z bunky B2 do bunky B3, odkaz zostane v oboch bunkách rovnaký: =$A$1.

      Skopírovaný vzorec s absolútnym odkazom   

      Skopírovaný vzorec s absolútnym odkazom
    3. Zmiešané odkazy.     Zmiešaný odkaz má buď absolútny stĺpec a relatívny riadok alebo absolútny riadok a relatívny stĺpec. Absolútny odkaz na stĺpec má tvar $A1, $B1, atď. Absolútny odkaz na riadok má tvar A$1, B$1, atď. Ak sa zmení pozícia bunky obsahujúcej vzorec, relatívny odkaz sa zmení a absolútny odkaz zostane rovnaký. V prípade skopírovania alebo vyplnenia vzorca do viacerých riadkov alebo stĺpcov, sa relatívny odkaz automaticky upraví, absolútny odkaz sa neupraví. Ak napríklad skopírujete alebo vyplníte zmiešaný odkaz z bunky A2 do bunky B3, odkaz =A$1 sa upraví na =B$1.

      Skopírovaný vzorec so zmiešaným odkazom   

      Skopírovaný vzorec so zmiešaným odkazom

  • Priestorový štýl odkazu

    Jednoduchšie odkazovanie viacerých hárkov    Ak chcete analyzovať údaje v tej istej bunke alebo rozsahu buniek na viacerých hárkoch zošita, použite priestorový odkaz. Priestorový odkaz zahŕňa odkaz na bunku alebo rozsah, pred ktorým je rozsah názvov hárkov. Program Excel použije všetky hárky uložené medzi prvým a posledným názvom v odkaze. Napríklad pomocou vzorca =SUM(Hárok2:Hárok13!B5) sčíta všetky hodnoty v bunke B5 vo všetkých hárkoch v rozsahu Hárok2 až Hárok13.

    • Priestorové odkazy je možné použiť na odkazovanie na bunky v iných hárkoch, na definovanie názvov a vytváranie vzorcov pomocou nasledujúcich funkcií: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA a VARPA.

    • Priestorové odkazy nie je možné použiť vo vzorcoch poľa.

    • Priestorové odkazy nie je možné použiť s operátor prieniku (medzera), ani vo vzorcoch používajúcich implicitný prienik.

    Čo sa stane pri presúvaní, kopírovaní, vkladaní alebo odstraňovaní hárkov    Nasledujúce príklady vysvetľujú, čo sa stane pri presunutí, skopírovaní, vložení alebo odstránení hárkov, ktoré sú zahrnuté do priestorového odkazu. Pri príkladoch je použitý vzorec =SUM(Hárok2:Hárok6!A2:A5), ktorý počíta súčet buniek A2 až A5 v hárkoch 2 až 6.

    • Vloženie alebo skopírovanie.    Ak medzi hárky 2 a 6 (v našom príklade krajné hárky) vložíte alebo skopírujete iné hárky, program Excel zahrnie do výpočtov všetky hodnoty v bunkách A2 až A5 v pridaných hárkoch.

    • Odstránenie.     Ak odstránite hárky, ktoré sa nachádzajú medzi hárkami 2 a 6, program Excel odstráni z výpočtu príslušné hodnoty.

    • Presunutie.    Ak hárky, ktoré sa nachádzajú medzi hárkami 2 a 6, premiestnite mimo daného rozsahu hárkov, program Excel odstráni z výpočtu príslušné hodnoty.

    • Presunutie koncového bodu.    Ak hárok 2 alebo 6 premiestnite na iné miesto v tom istom zošite, program Excel upraví výpočet tak, aby sa prispôsobil novému rozsahu hárkov medzi nimi.

    • Odstránenie koncového bodu.    Ak odstránite hárky 2 a 6, program Excel upraví výpočet tak, aby sa prispôsobil rozsahu hárkov medzi nimi.

  • Štýl odkazu R1C1

    V tomto štýle odkazu sú riadky aj stĺpce zošita číslované. Štýl odkazu R1C1 sa používa hlavne pri výpočtoch umiestnenia riadkov a stĺpcov v makrách. Pri štýle R1C1 udáva Excel umiestnenie bunky číslom riadka za písmenom R a číslom stĺpca za písmenom C.

    Odkaz

    Význam

    R[-2]C

    relatívny odkaz na bunku v tom istom stĺpci a o dva riadky vyššie

    R[2]C[2]

    Relatívny odkaz na bunku o dva riadky nižšie a o dva stĺpce doprava

    R2C2

    Absolútny odkaz na bunku v druhom riadku a druhom stĺpci

    R[-1]

    Relatívny odkaz na celý riadok nad aktívnou bunkou

    Polomer

    Absolútny odkaz na aktuálny riadok

    Pri zaznamenávaní makra program Excel zaznamená niektoré príkazy použitím štýlu odkazu R1C1. Ak napríklad zaznamenávate príkaz, napríklad ak kliknutím na tlačidlo Automatický súčet vložíte vzorec na sčítanie rozsahu buniek, program Excel zaznamená daný vzorec použitím štýlu odkazu R1C1, a nie štýlu A1.

    Štýl odkazu R1C1 môžete zapnúť alebo vypnúť začiarknutím alebo zrušením začiarknutia políčka Štýl odkazu R1C1 v sekcii Práca so vzorcami v kategórii Vzorce v dialógovom okne Možnosti. Ak chcete zobraziť toto dialógové okno, kliknite na kartu Súbor.

    Na začiatok stránky

Môžete vytvoriť definované názvy, ktoré budú predstavovať bunky, rozsahy buniek, vzorce, konštanty alebo tabuľky Excelu. Názov je zmysluplná skratka, ktorá zjednodušuje pochopenie účelu odkazu na bunku, konštanty, vzorca alebo tabuľky, ktoré by inak boli na prvý pohľad ťažko pochopiteľné. V nasledujúcej časti sú uvedené bežné príklady názvov a zároveň poskytujeme vysvetlenie, ako môže použitie názvov vo vzorcoch zlepšiť prehľadnosť a zjednodušiť pochopenie vzorcov.

Príklad 1

Typ príkladu

Príklad, v ktorom sú použité namiesto názvov rozsahy

Príklad, v ktorom sú použité názvy

Odkaz

=SUM(A16:A20)

=SUM(Predaj)

Konštanta

=PRODUCT(A12;9,5%)

=PRODUCT(Cena;SadzbaDane)

Vzorec

=TEXT(VLOOKUP(MAX(A16;A20);A16:B20;2;FALSE);"m/dd/rrrr")

=TEXT(VLOOKUP(MAX(Predaj);Informácie o predaji;2;FALSE);"m/dd/rrrr")

Tabuľka

A22:B25

=PRODUCT(Cena;Tabuľka1[@Sadzba dane])

Príklad 2

Vzorové údaje skopírujte do nasledujúcej tabuľky a prilepte ich do bunky A1 nového excelového hárka. Ak chcete, aby vzorce zobrazovali výsledky, označte ich, stlačte kláves F2 a potom stlačte kláves Enter. V prípade potreby môžete upraviť šírku stĺpcov, aby sa údaje zobrazovali celé.

Poznámka:  Vo vzorcoch v stĺpcoch C a D definovaný názov Predaj pre odkaz nahrádza rozsah A9:A13 a názov Informácie o predaji nahrádza rozsah A9:B13. Ak v skúšobnom zošite tieto názvy nevytvoríte, vzorce v rozsahu buniek D2:D3 vrátia chybu #NÁZOV?.

Typ príkladu

Príklad bez použitia názvu

Príklad s použitím názvu

Vzorec a výsledok s použitím názvu

Referencia

'=SUM(A9:A13)

'=SUM(Predaj)

=SUM(Predaj)

Vzorec

'=TEXT(VLOOKUP(MAX(A9:B13);A9:B13;2;FALSE);"dd/mm/yyyy")

'=TEXT(VLOOKUP(MAX(Predaj);Informácie o predaji;2;FALSE);"dd/mm/yyyy")

=TEXT(VLOOKUP(MAX(Predaj);Informácie o predaji;2;FALSE);"dd/mm/yyyy")

Cena

995 EUR

Predaj

Termín predaja

249 EUR

17.3.2011

399 EUR

2.4.2011

643 EUR

23.4.2011

275 EUR

30.4.2011

447 EUR

4.5.2011

  • Typy názvov

    Existujú niekoľko typov názvov, ktoré môžete vytvoriť a použiť.

    • Definovaný názov    Názov, ktorý predstavuje bunku, rozsah buniek, vzorec alebo konštantu. Môžete vytvoriť vlastné definované názvy. Niekedy vytvorí definované názvy aj program Excel, napríklad pri nastavovaní oblasti tlače.

    • Názov tabuľky    Názov pre tabuľku programu Excel, ktorá je kolekciou údajov o konkrétnom predmete, ktorý je uložený v záznamoch (riadkoch) alebo poliach (stĺpcoch). Program Excel vytvára predvolené názvy tabuliek programu Excel – „Tabuľka1“, „Tabuľka2“, a tak ďalej – vždy, keď vložíte tabuľku programu Excel. Tieto názvy však môžete zmeniť tak, aby boli zrozumiteľnejšie.

      Ďalšie informácie o excelových tabuľkách nájdete v téme Používanie štruktúrovaných odkazov v tabuľkách programu Excel.

  • Vytváranie a zadávanie názvov

    Názov vytvoríte pomocou nasledujúcich možností:

    • Pole názvov v riadku vzorcov    V tomto poli môžete najlepšie vytvoriť názov úrovne zošita pre vybratý rozsah.

    • Vytvorenie názvu z výberu    Názvy môžete vytvoriť aj jednoduchým výberom bunky v hárku z existujúcich menoviek riadkov alebo stĺpcov.

    • Dialógové okno Nový názov    V tomto okne môžete flexibilnejšie vytvárať názvy, napríklad určením rozsahu lokálnej úrovne hárka alebo vytvorením komentára k názvu.

    Poznámka: Predvolene sa pri názvoch používajú absolútne odkazy na bunky.

    Možnosti tvorby názvu:

    • Zadanie    Zadajte názov, napríklad ako keď do vzorca zadávate argument.

    • Používanie funkcie Automatické dokončovanie vzorca    V rozbaľovacom zozname Automatické dokončovanie vzorca sú automaticky uvedené platné názvy.

    • Výber z príkazu Použiť vo vzorci    Vyberte názov zo zoznamu, ktorý je dostupný v príkaze Použiť vo vzorci v časti Definované názvy na karte Vzorce.

Ďalšie informácie nájdete v téme Definovanie a používanie názvov vo vzorcoch.

Na začiatok stránky

Vzorec poľa môže vykonať viacero výpočtov a vrátiť jeden alebo viacero výsledkov. Vzorce poľa pracujú s dvoma alebo viacerými množinami hodnôt, ktoré sa označujú ako argumenty poľa. Všetky argumenty poľa musia mať rovnaký počet riadkov a stĺpcov. Vzorce poľa sa vytvárajú rovnako ako ostatné vzorce, zadávajú sa však stlačením kombinácie klávesov CTRL+SHIFT+ENTER. Niektoré vstavané funkcie predstavujú vzorce poľa a na získanie správnych výsledkov je nutné ich zadať ako polia.

Konštanty poľa je možné použiť namiesto odkazov v prípade, keď jednotlivé hodnoty konštánt nechcete zadať do samostatných buniek v hárku.

Použitie vzorca poľa na vypočítanie jedného alebo viacerých výsledkov

Poznámka: Keď vložíte vzorec poľa, Excel tento vzorec automaticky uzavrie do zložených zátvoriek { }. Ak sa pokúsite zadať tieto zložené zátvorky sami, Excel zobrazí vzorec ako text.

  • Vzorec poľa, ktorý vytvára jeden výsledok    Tento typ vzorca poľa môže zjednodušiť model hárka tým, že nahradí niekoľko rôznych vzorcov jedným vzorcom poľa.

    Nasledujúci vzorec napríklad vypočíta celkovú hodnotu poľa cien akcií a podielov bez použitia riadka buniek na výpočet a zobrazenie jednotlivých hodnôt pre každú akciu.

    Vzorec poľa, ktorý vypočíta jednoduchý výsledok

    Ak zadáte vzorec ={SUM(B2:D2*B3:D3)} ako vzorec poľa, vzorec vynásobí podiely a cenu pre každú akciu a spočíta výsledky týchto výpočtov.

  • Vzorec poľa, ktorý vytvára viacero výsledkov    Niektoré funkcie hárka vrátia polia hodnôt alebo požadujú pole hodnôt ako argument. Ak chcete vzorec poľa použiť na výpočet viacerých výsledkov, musíte pole zadať do rozsahu buniek s rovnakým počtom riadkov a stĺpcov ako majú argumenty poľa.

    Ak máte napríklad súbor troch údajov o predaji (v stĺpci B) počas troch mesiacov (v stĺpci A), funkcia TREND určí lineárne hodnoty údajov o odbytoch. Aby sa zobrazili všetky výsledky vzorca, vloží sa do troch buniek v stĺpci C (C1:C3).

    Vzorec poľa, ktorý vypočíta viacero výsledkov

    Ak zadáte vzorec =TREND(B1:B3;A1:A3) ako vzorec poľa, vypočíta na základe troch údajov o predaji a troch mesiacov tri nezávislé výsledky (22196, 17079 a 11962).

Použitie konštánt poľa

V obyčajnom vzorci je možné zadať odkaz na bunku obsahujúcu hodnotu, alebo samotnú hodnotu nazývanú konštanta. Podobne je možné zadať vo vzorci poľa odkaz na pole, alebo je možné zadať pole hodnôt obsiahnutých v bunkách, ktoré sa tiež nazýva konštanta poľa. Vzorce poľa pracujú s konštantami rovnako ako obyčajné vzorce. Konštanty poľa je však potrebné zadať v určitom formáte.

Konštanty poľa môžu obsahovať čísla, text, logické hodnoty, napríklad TRUE alebo FALSE alebo chybové hodnoty, napríklad #NEDOSTUPNÝ. Jedna konštanta poľa môže obsahovať rôzne typy hodnôt – napríklad {1;3;4|TRUE;FALSE;TRUE}. Čísla v konštantách poľa môžu byť v celočíselnom, desatinnom alebo komplexnom tvare. Text musí byť zadaný v úvodzovkách, napríklad "Utorok".

Konštanty poľa nemôžu obsahovať odkazy na bunky, stĺpce alebo riadky nerovnakej dĺžky, vzorce alebo špeciálne znaky $ (znak dolára), zátvorky alebo % (znak percenta).

Pri formátovaní konštánt poľa skontrolujte, či ste:

  • Konštanty uzavreli v zložených zátvorkách ({ } ).

  • Hodnoty v odlišných stĺpcoch oddelili bodkočiarkami (;). Napríklad hodnoty 10, 20, 30 a 40 možno vyjadriť ako {10;20;30;40}. Táto konštanta poľa je poľom 1 krát 4 a je ekvivalentná odkazu na rozsah 1 riadok krát 4 stĺpce.

  • Hodnoty v odlišných riadkoch oddelili zvislými čiarami (|). Napríklad hodnoty 10, 20, 30, 40 v jednom riadku a hodnoty 50, 60, 70, 80 v riadku bezprostredne pod ním možno vyjadriť konštantou poľa 2 krát 4: {10;20;30;40|50;60;70;80}.

Na začiatok stránky

Keď odstránite vzorec, odstránia sa aj výsledné hodnoty vzorca. Môžete však odstrániť iba vzorec a ponechať výslednú hodnotu vzorca, ktorá sa zobrazí v bunke.

  • Ak chcete odstrániť vzorce spolu s ich výslednými hodnotami, postupujte takto:

    1. Vyberte bunku alebo rozsah buniek, ktorý obsahuje požadovaný vzorec.

    2. Stlačte kláves DELETE.

  • Ak chcete odstrániť vzorce bez odstránenia ich výsledných hodnôt, postupujte takto:

    1. Vyberte bunku alebo rozsah buniek, ktorý obsahuje požadovaný vzorec.

      Ak je vzorec vzorcom poľa, vyberte rozsah buniek, ktorý ho obsahuje.

      Výber rozsahu buniek, ktorý obsahuje vzorec poľa

      1. Kliknite na bunku vo vzorci poľa.

      2. Na karte Domov kliknite v skupine Úpravy na možnosť Nájsť a vybrať a potom kliknite na položku Prejsť na.

      3. Kliknite na položku Špeciálne.

      4. Kliknite na položku Aktuálne pole.

    2. Na karte Domov kliknite v skupine Schránka na položku Kopírovať Vzhľad tlačidla .
      Pás s nástrojmi v programe Excel

      Klávesová skratka    Môžete stlačiť aj kombináciu klávesov CTRL + C.

    3. Na karte Domov kliknite v skupine Schránka na šípku pod tlačidlom Prilepiť Obrázok tlačidla a potom kliknite na položku Prilepiť hodnoty.

Na začiatok stránky

V nasledujúcej tabuľke sú zhrnuté niektoré najbežnejšie chyby, ktoré sa stávajú pri zadávaní vzorca, a pravidlá, ako sa vyhnúť chybám vo vzorcoch:

Skontrolujte, či ste vykonali nasledujúce kroky

Ďalšie informácie

Spárovanie všetkých otvorených a zatvorených zátvoriek vo vzorci   

Všetky zátvorky vo vzorcoch sú súčasťou zhodujúceho sa páru. Pri vytváraní vzorca zobrazí Excel zátvorky vo farbe počas zadávania.

Označenie rozsahu zadaného do vzorca pomocou dvojbodky   

Dvojbodky (:) sa používajú na oddelenie odkazu na prvú a poslednú bunku v rozsahu. Napríklad A1:A5.

Zadanie všetkých požadovaných argumentov    

Funkcie môžu obsahovať povinné a voliteľné argumenty (v syntaxi sa označujú hranatými zátvorkami). Všetky povinné argumenty by sa mali zadať. Skontrolujte tiež, či ste nezadali príliš veľa argumentov.

Do vzorca nevnárajte viac ako 64 funkcií   

Vnorenie funkcií do vzorca je obmedzené na 64 úrovní.

Uzavretie názvov pracovných zošitov a pracovných hárkov do jednoduchých úvodzoviek    

Keď odkazujete na hodnoty alebo bunky v iných pracovných zošitoch alebo hárkoch, ktoré obsahujú v názve iné ako abecedné znaky, názvy musia byť uzatvorené v jednoduchých úvodzovkách ( ' ).

Zahrnutie cesty do externých zošitov    

Externé odkazy musia obsahovať názov zošita a cestu k zošitu.

Zadanie čísel bez formátovania    

Čísla, ktoré zadáte do vzorca, by sa nemali formátovať pomocou desatinnej čiarky alebo znaku dolára ($), pretože čiarky sa už používajú na oddeľovanie argumentov vo vzorcoch a znaky dolára sa používajú na označenie absolútnych odkazov. Namiesto toho, aby ste do vzorca zadali napríklad $1,000, zadajte 1000.

Na začiatok stránky

Dôležité: Vypočítané výsledky vzorcov a niektoré funkcie excelových hárkov sa v počítačoch s Windowsom používajúcich architektúru x86 alebo x86-64 a počítačoch s Windowsom RT používajúcich architektúru ARM môžu mierne líšiť. Ďalšie informácie o odlišnostiach.

Máte otázku ku konkrétnej funkcii?

Uverejnite otázku vo fóre komunity používateľov Excelu

Pomôžte nám pri zlepšovaní Excelu

Máte nápady, ako by sme mohli zlepšiť nasledujúcu verziu Excelu? Ak áno, pozrite sa na témy v časti Excel User Voice.

Pozrite tiež

Prehľad vzorcov v Exceli

Zabránenie vzniku nefunkčných vzorcov

Vyhľadanie a oprava chýb vo vzorcoch

Excelové klávesové skratky a funkčné klávesy

Zoznam funkcií Excelu (podľa abecedy)

Zoznam funkcií Excelu (podľa kategórie)

Rozšírte svoje zručnosti
Preskúmať školenie
Buďte medzi prvými, ktorí získajú nové funkcie
Pridajte sa k insiderom pre Office

Boli tieto informácie užitočné?

Ďakujeme za vaše pripomienky!

Ďakujeme vám za pripomienky. Pravdepodobne vám pomôže, ak vás spojíme s pracovníkom podpory pre Office.

×