Nastavenie vlastných označení údajov v grafe

Nasledujúci postup jazyka VBA (Visual Basic for Applications) vám umožní používať hodnoty buniek ako označenia údajov v grafoch v Excel pre Mac. Ak chcete využiť postup, postupujte takto:

1. V Exceli kliknite na položku Nástroje > Makrá > Zaznamenať nové makro.

2. V rozbaľovacom poli Uložiť makro v : vyberte položku Zošit osobných makier.

   Poznámka: Uložením procedúry VBA v zošite osobných makier ho potom môžete použiť v ľubovoľnej inštancii Excelu. To znamená, že sa neobmedzuje len na použitie v jednom zošite.

3. Stlačte tlačidlo OK.

4. Prejdite na ponuku Nástroje > makrá > zastaviť zaznamenávanie.

5. Prejdite do časti Nástroje > makrá > Editor jazyka Visual Basic.

6. Visual Basic Editor (VBE) sa otvorí nad Excelom. Na navigačnej table vľavo rozbaľte projekt VBA (PERSONAL). XLSB) na zobrazenie modulu 1.

7. Dvojitým kliknutím na modul 1 zobrazte tablu Kód, ktorá sa otvorí na pravej strane okna VBE.

8. Kód VBA, ktorý bol vytvorený pri zaznamenaní nového makra, nie je potrebný, preto vyberte všetko a stlačte kláves Delete. 

9. Potom vyberte kód VBA v nižšie uvedenom textovom poli, stlačením kombinácie klávesov CMD + C ho skopírujte a potom ho prilepte späť na tablu Kód pomocou kombinácie klávesov CMD + V. Teraz môžete ukončiť program Visual Basic Editor a vrátiť sa do Excelu.

10. Makro otestujte vytvorením grafu s označeniami údajov. Potom vyberte ľubovoľné označenie údajov v grafe a spustite makro kliknutím na položku Nástroje > Makrá > makrá. Vyberte položku SetCustomDataLabels a potom stlačte kláves Run. Automaticky sa zobrazí výzva na výber rozsahu označení údajov, tak to urobte a potom stlačte tlačidlo OK.  

    Poznámka: Procedúry jazyka VBA nie je možné vrátiť späť, preto to skúste v kópii zošita. Ak spustíte kód a nechcete zachovať výsledky, zošit bude potrebné zavrieť bez uloženia.

11. Po ukončení Excelu sa uistite, že ste zmeny uložili v časti OSOBNÉ. XLSB, takže makro bude k dispozícii v budúcnosti.

12. Vždy, keď chcete pridať alebo odstrániť označenia údajov z grafu, vyberte označenia údajov a spustite makro.

13. Na pridanie tlačidla na spustenie makra z pása s nástrojmi alebo panela s nástrojmi môžete použiť excelové > predvoľby > páse s nástrojmi & panel s nástrojmi .

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub