Функция СУММ: формула суммы в Excel

Функция СУММ: формула суммы в Excel

Функция СУММ — одна из математических и тригонометрических функций, складывающая значения. Вы можете складывать отдельные значения, диапазоны ячеек, ссылки на ячейки или данные всех этих трех видов.

Пример

  • =СУММ(A2:A10)

  • =СУММ(A2:A10;C2:C10)

Браузер не поддерживает видео. Установите Microsoft Silverlight, Adobe Flash Player или Internet Explorer 9.

Это видео — часть учебного курса Сложение чисел в Excel 2013.

СУММ(число1;[число2];…)

Имя аргумента

Описание

число1    (обязательный)

Первое число для сложения. Это может быть число 4, ссылка на ячейку, например B6, или диапазон ячеек, например B2:B8.

число2–255    (необязательный)

Это второе число для сложения. Можно указать до 255 чисел.

Если вам нужно быстро получить сумму диапазона ячеек, вам достаточно просто выделить диапазон и посмотреть на правый нижний угол окна Excel.

Снимок экрана: выделение диапазона ячеек и просмотр строки состояния
Строка состояния


Информация в строке состояния зависит от текущего выделенного фрагмента, будь то одна ячейка или несколько. Если вы щелкнете правой кнопкой мыши строку состояния, появится всплывающее диалоговое окно со всеми доступными параметрами. Если выбрать какие-либо из них, в строке состояния появятся соответствующие значения для выбранного диапазона. Дополнительные сведения о строке состояния.

Формулу СУММ проще всего добавить на лист с помощью мастера автосуммирования. Выберите пустую ячейку непосредственно над или под диапазоном, который нужно суммировать, а затем откройте на ленте вкладку "Главная" или "Формула" и нажмите Автосумма > Сумма. Мастер автосуммирования автоматически определяет диапазон для суммирования и создает формулу. Он может работать и по горизонтали, если вы выберете ячейку справа или слева от суммируемого диапазона, но это буде рассматриваться в следующем разделе.

Используйте мастер автосуммирования для автоматического создания формулы СУММ.  Выделите диапазон сверху/снизу или справа/слева от суммируемого диапазона, затем на ленте откройте вкладку "Формула" и выберите "Автосумма" > "Сумма".
Быстрое сложение смежных диапазонов с помощью мастера автосуммирования


В диалоговом окне "Автосумма" можно также выбрать другие стандартные функции, например:

Автосуммирование по вертикали

В ячейке B6 показана формула автосуммирования =СУММ(B2:B5)

Мастер автосуммирования автоматически определяет ячейки B2:B5 в качестве диапазона для суммирования. Вам нужно только нажать клавишу ВВОД для подтверждения. Если вам нужно добавить или исключить несколько ячеек, удерживая нажатой клавишу SHIFT, нажимайте соответствующую клавишу со стрелкой, пока не выделите нужный диапазон, а затем нажмите клавишу ВВОД.

Подсказка Intellisense для функции. Плавающий тег СУММ(число1;[число2];…) под функцией — это подсказка Intellisense. Если вы щелкнете СУММ или название другой функции, оно примет вид синей гиперссылки, которая приведет вас к разделу справки для этой функции. Если щелкать отдельные элементы функции, будут выделяться соответствующие фрагменты в формуле. В данном случае будут выделены только ячейки B2:B5, поскольку в этой формуле только одна числовая ссылка. Тег Intellisense появляется для любой функции.

Автосуммирование по горизонтали

В ячейке D2 показана формула автосуммирования =СУММ(B2:C2)

Использовании функции СУММ с несмежными диапазонами.  Ячейка C8 содержит формулу =СУММ(C2:C3;C5:C6). При использовании именованных диапазонов формула примет вид =СУММ(Неделя1;Неделя2).

Мастер автосуммирования обычно работает только со смежными диапазонами, так что если ваш диапазон для суммирования содержит пустые строки или столбцы, Excel остановится на первом пропуске. В этом случае вам нужно использовать функцию СУММ по выделению, в которое вы последовательно добавляете отдельные диапазоны. В данном примере, если у вас есть данные в ячейке B4, Excel создаст формулу =СУММ(C2:C6), поскольку распознает смежный диапазон.

Чтобы быстро выделить несколько несмежных диапазонов, нажмите CTRL + щелчок левой кнопкой мыши. Сначала введите "=СУММ(", затем выбирайте разные диапазоны, а Excel будет автоматически добавлять между ними точку запятой в качестве разделителя. По завершении нажмите клавишу ВВОД.

СОВЕТ. Быстро добавить функцию СУММ в ячейку можно с помощью клавиш ALT + =. После этого вам останется только выбрать диапазоны.

Примечание.Возможно, вы заметили, что Excel выделяет цветом разные диапазоны данных функции и соответствующие фрагменты в формуле: ячейки C2:C3 выделены одним цветом, а ячейки C5:C6 — другим. Excel делает это для всех функций, если только диапазон, на который указывает ссылка, не находится на другом листе или в другой книге. Для более эффективного использования специальных возможностей вы можете создавать именованные диапазоны, например "Неделя1", "Неделя2" и т. д., а затем ссылаться на них в формуле:

=СУММ(Неделя1;Неделя2)

В Excel можно с легкостью выполнять математические операции — как по отдельности, так и в сочетании с функциями Excel, например СУММ. В таблице ниже перечислены операторы, которые могут вам пригодиться, а также связанные с ними функции. Операторы можно вводить как с помощью цифрового ряда на клавиатуре, так и с помощью цифровой клавиатуры, если она у вас есть. Например, с помощью клавиш Shift + 8 можно ввести знак звездочки (*) для умножения.

Оператор

Операция

Примеры

+

Сложение

=1+1

=A1+B1

=СУММ(A1:A10)+10

=СУММ(A1:A10)+B1

-

Вычитание

=1-1

=A1-B1

=СУММ(A1:A10)-10

=СУММ(A1:A10)-B1

*

Умножение

=1*1

=A1*B1

=СУММ(A1:A10)*10

=СУММ(A1:A10)*B1

=ПРОИЗВЕД(1;1) — функция ПРОИЗВЕД

/

Деление

=1/1

=A1/B1

=СУММ(A1:A10)/10

=СУММ(A1:A10)/B1

=ЧАСТНОЕ(1;1) — функция ЧАСТНОЕ

^

Возведение в степень

=1^1

=A1^B1

=СУММ(A1:A10)^10

=СУММ(A1:A10)^B1

=СТЕПЕНЬ(1;1) — функция СТЕПЕНЬ

Дополнительные сведения см. в статье Использование Microsoft Excel в качестве калькулятора.

Другие примеры

  1. Допустим, вам нужно применить процент скидки к суммируемому диапазону ячеек.

    Использование операторов с функцией СУММ.  Ячейка B16 содержит формулу =СУММ(A2:A14)*-25%.  В правильной конструкции формулы вместо -25 % должна быть указана ссылка на ячейку, например =СУММ(A2:A14)*E2
    • =СУММ(A2:A14)*-25%

    Вы получаете 25 % от суммируемого диапазона, но значение 25 % введено прямо в формуле, так что если позже вам потребуется его изменить, найти его будет непросто. Гораздо лучше будет поместить значение 25 % в ячейку (где его будет легко найти и изменить) и использовать ссылку на нее, например:

    • =СУММ(A2:A14)*E2

    Если нужно не умножить, а разделить, просто укажите вместо знака "*" знак "/": =СУММ(A2:A14)/E2

  2. Функция СУММ — сложение и вычитание

    а. Чтобы прибавить или вычесть значение из функции СУММ, используйте знаки "+" и "-", например:

    • =СУММ(A1:A10)+E2

    • =СУММ(A1:A10)-E2

Этот раздел содержит некоторые рекомендации по работе с функцией СУММ. Многие из этих рекомендаций можно применить и к другим функциям.

Метод =1+2 или =A+B. Вы можете ввести =1+2+3 или =A1+B1+C2 и получить абсолютно точные результаты, однако этот метод ненадежен по ряду причин.

  1. Опечатки. Допустим, вы пытаетесь ввести много больших значений такого вида:

    • =14598,93+65437,90+78496,23

    А теперь попробуйте проверить правильность записей. Гораздо проще поместить эти значения в отдельные ячейки и использовать их в формуле СУММ. Кроме того, значения в ячейках можно отформатировать, чтобы привести их к более наглядному виду, чем если бы они были в формуле.

    Используйте функцию СУММ, вместо того чтобы указывать значения прямо в формулах.  Ячейка D5 содержит формулу =СУММ(D2:D4)
  2. Ошибки #ЗНАЧ!, если ячейки по ссылкам содержат текст вместо чисел

    Допустим, вы используете формулу такого вида:

    • =A1+B1+C1 или =A1+A2+A3

    Пример неудачной формулы.  Ячейка D2 содержит формулу =A2+B2+C2

    Если ячейки, на которые указывают ссылки, содержат нечисловые (текстовые) значения, формула может вернуть ошибку #ЗНАЧ!. Функция СУММ пропускает текстовые значения и выдает сумму только числовых значений.

    Правильная формула.  Вместо выражения =A2+B2+C2 ячейка D2 содержит формулу =СУММ(A2:C2)
  3. Ошибка #ССЫЛКА! при удалении строк или столбцов

    Ошибка #ССЫЛКА! возникла из-за удаления столбца.  Формула приняла вид =A2+#ССЫЛКА!+B2

    При удалении строки или столбца формулы не обновляются: из них не исключаются удаленные значения, поэтому возвращается ошибка #ССЫЛКА!. Функция СУММ, в свою очередь, обновляется автоматически.

    Функция СУММ будет автоматически корректироваться при вставке и удалении строк и столбцов.
  4. Формулы не обновляют ссылки при вставке строк или столбцов

    Формулы =A+B+C не обновляются при добавлении строк

    При вставке строки или столбца формула не обновляется — в нее не включается добавленная строка, тогда как функция СУММ будет автоматически обновляться (пока вы не вышли за пределы диапазона, на который ссылается формула). Это особенно важно, когда вы рассчитываете, что формула обновится, но этого не происходит. В итоге ваши результаты остаются неполными, и этого можно не заметить.

    В примере показана формула СУММ, которая при добавлении столбца автоматически расширяется от =СУММ(A2:C2) до =СУММ(A2:D2)
  5. Функция СУММ — отдельные ячейки или диапазоны

    Используя формулу такого вида:

    • =СУММ(A1;A2;A3;B1;B2;B3)

    вы изначально закладываете в нее вероятность появления ошибок при вставке или удалении строк в указанном диапазоне по тем же причинам. Гораздо лучше использовать отдельные диапазоны, например:

    • =СУММ(A1:A3;B1:B3)

    Такая формула будет обновляться при добавлении и удалении строк.

  1. Функцию СУММ можно использовать вместе с другими функциями. Ниже приведен пример, в котором вычисляется среднее значение суммы за все указанные месяцы.

    Использование СУММ с другими функциями.  Ячейка M2 содержит формулу =СУММ(A2:L2)/СЧЁТЗ(A2:L2).  Примечание: для простоты столбцы с мая по ноябрь скрыты.
    • =СУММ(A2:L2)/СЧЁТЗ(A2:L2)

  2. Эта формула получает сумму ячеек A2:L2 и делит ее на количество непустых ячеек в диапазоне A2:L2 (ячейки с мая по декабрь пусты).

  1. Иногда требуется просуммировать определенную ячейку на нескольких листах. Казалось бы, можно просто щелкнуть нужную ячейку на каждом листе, используя знак "+" для сложения значений. Но это довольно утомительно, и при этом легко допустить ошибку.

    • =Лист1!A1+Лист2!A1+Лист3!A1

    С помощью трехмерной функции СУММ это можно сделать гораздо проще:

    Трехмерное суммирование — ячейка D2 содержит формулу =СУММ(Лист1:Лист3!A2)
    • =СУММ(Лист1:Лист3!A1)

    Эта формула будет суммировать ячейку A1 на всех листах с первого по третий.

    Это особенно пригодится в ситуации, когда для каждого месяца (с января по декабрь) используется отдельный лист, а вам нужно подвести общий итог на листе сводки.

    Трехмерное суммирование с использованием именованных листов.  Ячейка D2 содержит формулу =СУММ(Январь:Декабрь!A2)
    • =СУММ(Январь:Декабрь!A2)

    Эта формула будет суммировать ячейку A2 на каждом листе с января по декабрь.

    Примечания : Если названия листов содержат пробелы, например "Продажи января", необходимо использовать апострофы, указывая эти названия в формуле. Обратите внимание на апострофы ПЕРЕД названием первого листа и ПОСЛЕ названия последнего.

    • =СУММ('Продажи января:Продажи декабря'!A2)

    Метод 3D также можно использовать с другими функциями: СРЗНАЧ, МИН, МАКС и т. д.

    • =СРЗНАЧ(Лист1:Лист3!A1)

    • =МИН(Лист1:Лист3!A1)

    • =МАКС(Лист1:Лист3!A1)

Проблема

Возможная причина

Функция СУММ отображает символы ##### вместо результата.

Проверьте ширину столбцов. Как правило, символы ##### отображаются, если столбец слишком узкий для результата формулы.

Функция СУММ отображает саму формулу в виде текста, а не результат.

Проверьте, не выбран ли для ячейки текстовый формат. Выберите соответствующую ячейку или соответствующий диапазон и нажмите клавиши Ctrl + 1, чтобы открыть диалоговое окно Формат ячеек, затем щелкните вкладку Число и выберите нужный формат. Если для ячейки использовался текстовый формат и она не изменилась после выбора другого формата, нажмите клавиши F2 > Enter, чтобы принудительно изменить формат.

Функция СУММ не обновляется.

Проверьте, выбрано ли для вычисления значение Автоматически. На вкладке Формулы откройте Параметры вычислений. Вы также можете выполнить вычисление на листе принудительно, нажав клавишу F9.

Проверьте, выбрано ли для вычисления значение "Автоматически".  На вкладке "Формулы" откройте "Параметры вычислений".

Некоторые значения не добавляются.

В ссылке на функцию или диапазоне суммируются только числовые значения. Пустые ячейки, логические величины (например, ИСТИНА) и текст игнорируются.

Вместо ожидаемого результата отображается значение ошибки #ИМЯ?.

Обычно это означает, что в формуле содержится ошибка: например, вместо =СУММ(A1:A10) введено =сума(A1:A10).

Функция СУММ отображает целое число, хотя должно отображать десятичное.

Проверьте, выбрано ли отображение десятичных чисел в формате ячейки. Выберите соответствующую ячейку или соответствующий диапазон и нажмите клавиши Ctrl + 1, чтобы открыть диалоговое окно Формат ячеек, затем щелкните вкладку Число и выберите нужный формат, указав при этом нужное количество десятичных знаков.

  1. Мне нужно добавить, вычесть, умножить или поделить числа. Просмотрите серию учебных видео: Основные математические операции в Excel или Использование Microsoft Excel в качестве калькулятора.

  2. Как уменьшить или увеличить число отображаемых десятичных знаков? Можно изменить числовой формат. Выберите соответствующую ячейку или соответствующий диапазон и нажмите клавиши Ctrl + 1, чтобы открыть диалоговое окно Формат ячеек, затем щелкните вкладку Число и выберите нужный формат, указав при этом нужное количество десятичных знаков.

  3. Как добавить или вычесть значения времени? Есть несколько способов добавить или вычесть значения времени. Например, чтобы получить разницу между 8:00 и 12:00 для вычисления заработной платы, можно воспользоваться формулой =("12:00"-"8:00")*24, т. е. отнять время начала от времени окончания. Обратите внимание, что Excel вычисляет значения времени как часть дня, поэтому чтобы получить суммарное количество часов, необходимо умножить результат на 24. В первом примере используется формула =((B2-A2)+(D2-C2))*24 для вычисления количества часов от начала до окончания работы с учетом обеденного перерыва (всего 8,5 часов).

    Если вам нужно просто добавить часы и минуты, вы можете просто вычислить сумму, не умножая ее на 24. Во втором примере используется формула =СУММ(A6:C6), так как здесь нужно просто посчитать общее количество часов и минут, затраченных на задания (5:36, т. е. 5 часов 36 минут).

    Расчет времени

    Дополнительные сведения см. в статье Сложение и вычитание значений времени

  4. Как получить разницу между датами? Как и значения времени, значения дат можно добавить или вычесть. Вот распространенный пример вычисления количества дней между датами. Для этого используется простая формула =B2-A2. При работе со значениями дат и времени важно помнить, что дата или время начала вычитается из даты или времени окончания.

    Вычисление разницы между датами

    Другие способы работы с датами описаны в статье Определение количества дней между двумя датами.

  5. Как вычислить сумму только видимых ячеек? Иногда когда вы вручную скрываете строки или используете автофильтр, чтобы отображались только определенные данные, может понадобиться вычислить сумму только видимых ячеек. Для этого можно воспользоваться функцией ПРОМЕЖУТОЧНЫЕ.ИТОГИ. Если вы используете строку итогов в таблице Excel, любая функция, выбранная из раскрывающегося списка "Итог", автоматически вводится как промежуточный итог. Дополнительные сведения см. в статье Данные итогов в таблице Excel.

Дополнительные сведения

Вы всегда можете задать вопрос специалисту Excel Tech Community, попросить помощи в сообществе Answers community, а также предложить новую функцию или улучшение на веб-сайте Excel User Voice.

См. также

Видео об использовании функции СУММ

Функция СУММЕСЛИ (суммирует только значения, соответствующие одному условию)

Функция СУММЕСЛИМН (суммирует только значения, соответствующие нескольким условиям)

Функция СЧЁТЕСЛИ (подсчитывает только значения, соответствующие одному условию)

Функция СЧЁТЕСЛИМН (подсчитывает только значения, соответствующие нескольким условиям)

Общие сведения о формулах в Excel

Рекомендации, позволяющие избежать появления неработающих формул

Поиск и исправление ошибок в формулах

Сочетания клавиш в Excel для Windows

Сочетания клавиш в Excel для Mac

Математические и тригонометрические функции

Функции Excel (по алфавиту)

Функции Excel (по категориям)

Добавление формул и функций (бесплатное ознакомительное видео)

Совершенствование навыков
Перейти к обучению
Первоочередный доступ к новым возможностям
Присоединиться к программе предварительной оценки Office

Были ли сведения полезными?

Спасибо за ваш отзыв!

Благодарим за отзыв! Возможно, будет полезно связать вас с одним из наших специалистов службы поддержки Office.

×