Полные сведения о формулах в Excel

Полные сведения о формулах в Excel

Если вы раньше не работали с Excel, скоро вы узнаете, что это не просто таблица для ввода чисел. Конечно, в Excel можно просто считать суммы в строках и столбцах, но можно также вычислять платежи по ипотеке, решать математические и инженерные задачи и находить наиболее благоприятные варианты, зависящие от заданных переменных значений.

В Excel все это реализовано с помощью формул в ячейках. По этим формулам выполняются вычисления и другие действия с данными на листе. Формула всегда начинается со знака равенства (=), после которого можно вводить числа, математические операторы (например, знаки + и - для сложения и вычитания) и встроенные функции Excel, значительно расширяющие возможности формул.

Ниже приведен пример формулы, умножающей 2 на 3 и прибавляющей к результату 5, чтобы получить 11.

=2*3+5

Ниже приведены примеры формул, которые можно использовать на листах.

  • =A1+A2+A3   . Вычисляет сумму значений в ячейках A1, A2 и A3.

  • =СУММ(A1:A10)   . С помощью функции СУММ вычисляет сумму значений в ячейках от A1 до A10.

  • =СЕГОДНЯ()   . Возвращает текущую дату.

  • =ПРОПИСН("привет")   .  Преобразует текст "привет" в "ПРИВЕТ" с помощью функции ПРОПИСН.

  • ЕСЛИ(A1>0)   . С помощью функции ЕСЛИ проверяет, содержится ли в ячейке A1 значение, большее нуля.

Формула также может содержать один или несколько таких элементов, как функции, ссылки, операторы и константы.

Части формулы   

Части формулы

1. Функции. Функция ПИ() возвращает значение числа пи: 3,142...

2. Ссылки. A2 возвращает значение ячейки A2.

3. Константы. Числа или текстовые значения, введенные непосредственно в формулу, например 2.

4. Операторы. Оператор ^ (крышка) применяется для возведения числа в степень, а * (звездочка) — для умножения.

Константа представляет собой готовое (не вычисляемое) значение, которое всегда остается неизменным. Например, дата 09.10.2008, число 210 и текст "Прибыль за квартал" являются константами. Выражение или его значение константами не являются. Если формула в ячейке содержит константы, а не ссылки на другие ячейки (например, имеет вид =30+70+110), значение в такой ячейке изменяется только после редактирования формулы. Обычно лучше помещать такие константы в отдельные ячейки, где их можно будет легко изменить при необходимости, а в формулах использовать ссылки на эти ячейки.

Операторы задают тип вычислений, производимых над элементами формулы. В Excel соблюдается обычный порядок вычислений: скобки, экспоненты, умножение и деление и, наконец, прибавление и вычитание или, сокращенно, СЭУДПВ (смотрите, эти умельцы делают порхающий велосипед). С помощью скобок можно менять этот порядок вычислений.

Типы операторов. Бывает четыре типа операторов: арифметические, операторы сравнения, операторы объединения текста и ссылки.

  • Арифметические операторы

    Арифметические операторы служат для выполнения базовых арифметических операций, таких как сложение, вычитание, умножение, деление или объединение чисел. Результатом операций являются числа. Арифметические операторы приведены ниже.

    Арифметический оператор

    Значение

    Пример

    + (знак "плюс")

    Сложение

    =3+3

    – (знак "минус")

    Вычитание
    Отрицание

    =3–3
    =-3

    * (звездочка)

    Умножение

    =3*3

    / (косая черта)

    Деление

    =3/3

    % (знак процента)

    Процент

    30%

    ^ (крышка)

    Возведение в степень

    =3^3

  • Операторы сравнения

    Операторы сравнения используются для сравнения двух значений. Результатом этой операции является логическое значение: ИСТИНА либо ЛОЖЬ.

    Оператор сравнения

    Значение

    Пример

    = (знак равенства)

    Равно

    =A1=B1

    > (знак "больше")

    Больше

    =A1>B1

    < (знак "меньше")

    Меньше

    =A1<B1

    >= (знак "больше или равно")

    Больше или равно

    =A1>=B1

    <= (знак "меньше или равно")

    Меньше или равно

    =A1<=B1

    <> (знак "не равно")

    Не равно

    =A1<>B1

  • Оператор объединения текста

    Амперсанд (&) используется для объединения (соединения) одной или нескольких текстовых строк в одну.

    Текстовый оператор

    Значение

    Пример

    & (амперсанд)

    Соединение или объединение последовательностей знаков в одну последовательность

    Результатом формулы ="Ветер"&"ок" будет "Ветерок".
    Если в ячейку A1 записать "Фамилия", а в B1 "Имя", формула =A1&", "&B1 вернет "Фамилия, Имя".

  • Операторы ссылок

    Для определения ссылок на диапазоны ячеек можно использовать операторы, указанные ниже.

    Оператор ссылки

    Значение

    Пример

    : (двоеточие)

    Оператор диапазона, который образует одну ссылку на все ячейки, находящиеся между первой и последней ячейками диапазона, включая эти ячейки.

    B5:B15

    ; (точка с запятой)

    Оператор объединения. Объединяет несколько ссылок в одну ссылку.

    =СУММ(B5:B15;D5:D15)

    (пробел)

    Оператор пересечения множеств, используется для ссылки на общие ячейки двух диапазонов.

    B7:D7 C6:C8

К началу страницы

В некоторых случаях порядок вычисления может повлиять на возвращаемое формулой значение, поэтому для получения нужных результатов важно понимать стандартный порядок вычислений и знать, как можно его изменить.

  • Порядок вычислений

    Значения обрабатываются формулой в определенном порядке. Формула в Microsoft Excel всегда начинается со знака равенства (=). Знак равенства свидетельствует о том, что следующие за ним знаки составляют формулу. Элементы, следующие за знаком равенства, являются используемыми в расчетах операндами (например, константами или ссылками на ячейки), которые разделяются операторами вычислений. Формула в Excel вычисляется слева направо в соответствии с порядком, определенным для каждого оператора в формуле.

  • Приоритет операторов в формулах Excel

    Если в одной формуле используется несколько операторов, Microsoft Excel выполняет операции в порядке, указанном в приведенной ниже таблице. Если формула содержит операторы с одинаковым приоритетом — например, операторы деления и умножения, — они выполняются слева направо.

    Оператор

    Описание

    : (двоеточие)

    (один пробел)

    , (запятая)

    Операторы ссылок

    Знак "минус"

    %

    Процент

    ^

    Возведение в степень

    * и /

    Умножение и деление

    + и -

    Сложение и вычитание

    &

    Объединение двух текстовых строк в одну

    =
    < >
    <=
    >=
    <>

    Сравнение

  • Использование скобок в формулах Excel

    Чтобы изменить порядок выполнения формулы, заключите ее часть, которая должна быть выполнена первой, в скобки. Например, результатом приведенной ниже формулы будет число 11, поскольку в Microsoft Excel умножение выполняется раньше сложения. В данной формуле число 2 умножается на 3, а затем к результату добавляется число 5.

    =5+2*3

    Если же с помощью скобок изменить синтаксис, Microsoft Excel сложит 5 и 2, а затем умножит результат на 3; результатом этих действий будет число 21.

    =(5+2)*3

    В приведенном ниже примере скобки, в которые заключена первая часть формулы, задают следующий порядок вычислений: определяется значение B4+25, после чего полученный результат делится на сумму значений в ячейках D5, E5 и F5.

    =(B4+25)/СУММ(D5:F5)

    К началу страницы

Функции представляют собой заранее определенные формулы, выполняющие вычисления над заданными величинами — аргументами — в определенном порядке или по определенной схеме. С помощью функций можно выполнять как простые, так и сложные вычисления. Все функции Excel можно увидеть на вкладке "Формулы".

Вкладка "Формулы" на ленте Excel
  • Синтаксис функций Excel

    Приведенный ниже пример функции ОКРУГЛ, округляющий число в ячейке A10, демонстрирует синтаксис функции.

    Структура функции

    1. Структура. Структура функции начинается со знака равенства (=), за которым следуют имя функции, открывающая скобка, список аргументов, разделенных точками с запятой, и закрывающая скобка.

    2. Имя функции. Чтобы просмотреть весь список доступных функций, щелкните по ячейке и нажмите сочетание клавиш SHIFT + F3. После этого откроется диалоговое окно Вставка функции.

    Формулы Excel: диалоговое окно для вставки функции

    3. Аргументы. Существуют различные типы аргументов: числа, текст, логические значения (ИСТИНА и ЛОЖЬ), массивы, значения ошибок (например, #Н/Д) или ссылки на ячейки. Используемый аргумент должен возвращать допустимое для него значение. В качестве аргументов также могут выступать константы, формулы и другие функции.

    4. Всплывающая подсказка аргумента. При вводе функции появляется всплывающая подсказка с синтаксисом и аргументами. Например, всплывающая подсказка появляется, если ввести выражение =ОКРУГЛ(. Всплывающие подсказки отображаются только для встроенных функций.

    Примечание : Имена функций необязательно вводить заглавными буквами, например =ОКРУГЛ. Excel автоматически применит нужный регистр, как только вы нажмете клавишу ВВОД. Имя функции, написанное с ошибкой, например =СУММА(A1:A10) вместо =СУММ(A1:A10), вернет ошибку #ИМЯ?.

  • Ввод функций Excel

    Диалоговое окно Вставка функции облегчает ввод формул, содержащих функцию. При выборе функции в окне Вставка функции Excel запускает мастер функций. В нем перечислены имя функции, все ее аргументы, описание функции и каждого аргумента, текущее значение функции и текущий результат всей формулы.

    Мастер функций Excel

    С помощью автозаполнения можно упростить создание и редактирование формул, уменьшив количество опечаток и синтаксических ошибок. Как только вы вводите знак равенства (=) и начинаете писать имя функции, Excel отображает динамический раскрывающийся список доступных функций, аргументов и имен, совпадающий с введенными символами. Просто выберите подходящий элемент, и Excel сам введет его за вас.

    Автозаполнение формулы Excel

  • Вложение функций Excel

    В некоторых случаях может потребоваться использовать функцию в качестве одного из аргументов другой функции. Например, в приведенной ниже формуле для сравнения результата со значением 50 используется вложенная функция СРЗНАЧ.

    Вложенные функции

    1. Функции СРЗНАЧ и СУММ вложены в функцию ЕСЛИ.

    Допустимые типы вычисляемых значений   . Вложенная функция, используемая в качестве аргумента, должна возвращать соответствующий этому аргументу тип данных. Например, если аргумент должен быть логическим, т. е. иметь значение ИСТИНА либо ЛОЖЬ, вложенная функция также должна возвращать логическое значение (ИСТИНА или ЛОЖЬ). В противном случае Excel выдаст ошибку #ЗНАЧ!.

    Предельное количество уровней вложенности функций   . В формулах можно использовать до семи уровней вложенных функций. Если функция Б является аргументом функции А, функция Б находится на втором уровне вложенности. Например, в приведенном выше примере функции СРЗНАЧ и СУММ являются функциями второго уровня, поскольку обе они — аргументы функции ЕСЛИ. Функция, вложенная в качестве аргумента в функцию СРЗНАЧ, будет функцией третьего уровня, и т. д.

    К началу страницы

Ссылка указывает на ячейку или диапазон ячеек листа и сообщает Microsoft Excel, где находятся необходимые формуле значения или данные. С помощью ссылок можно использовать в одной формуле данные, находящиеся в разных частях листа, а также использовать значение одной ячейки в нескольких формулах. Кроме того, можно задавать ссылки на ячейки разных листов одной книги либо на ячейки из других книг. Ссылки на ячейки других книг называются связями или внешними ссылками.

  • Стиль ссылок A1

    По умолчанию Excel использует стиль ссылок A1, в котором столбцы обозначаются буквами (от A до XFD, не более 16 384 столбцов), а строки — номерами (от 1 до 1 048 576). Эти буквы и номера называются заголовками строк и столбцов. Чтобы добавить ссылку на ячейку, введите букву столбца, а затем — номер строки. Например, ссылка B2 указывает на ячейку, расположенную на пересечении столбца B и строки 2.

    Ячейка или диапазон

    Использование

    Ячейка на пересечении столбца A и строки 10

    A10

    Диапазон ячеек: столбец А, строки 10-20.

    A10:A20

    Диапазон ячеек: строка 15, столбцы B-E

    B15:E15

    Все ячейки в строке 5

    5:5

    Все ячейки в строках с 5 по 10

    5:10

    Все ячейки в столбце H

    H:H

    Все ячейки в столбцах с H по J

    H:J

    Диапазон ячеек: столбцы А-E, строки 10-20

    A10:E20

  • Создание ссылки на ячейку или диапазон ячеек с другого листа в той же книге

    В приведенном ниже примере функция СРЗНАЧ вычисляет среднее значение в диапазоне B1:B10 на листе "Маркетинг" в той же книге.

    Пример ссылки на лист

    1. Ссылка на лист "Маркетинг".

    2. Ссылка на диапазон ячеек от B1 до B10

    3. Восклицательный знак (!) отделяет ссылку на лист от ссылки на диапазон ячеек.

    Примечание : Если название упоминаемого листа содержит пробелы или цифры, его нужно заключить в апострофы ('), например так: '123'!A1 или ='Прибыль за январь'!A1.

  • Различия между абсолютными, относительными и смешанными ссылками

    1. Относительные ссылки   . Относительная ссылка в формуле, например A1, основана на относительной позиции ячейки, содержащей формулу, и ячейки, на которую указывает ссылка. При изменении позиции ячейки, содержащей формулу, изменяется и ссылка. При копировании или заполнении формулы вдоль строк и вдоль столбцов ссылка автоматически корректируется. По умолчанию в новых формулах используются относительные ссылки. Например, при копировании или заполнении относительной ссылки из ячейки B2 в ячейку B3 она автоматически изменяется с =A1 на =A2.

      Скопированная формула с относительной ссылкой   

      Скопированная формула с относительной ссылкой

    2. Абсолютные ссылки   . Абсолютная ссылка на ячейку в формуле, например $A$1, всегда ссылается на ячейку, расположенную в определенном месте. При изменении позиции ячейки, содержащей формулу, абсолютная ссылка не изменяется. При копировании или заполнении формулы по строкам и столбцам абсолютная ссылка не корректируется. По умолчанию в новых формулах используются относительные ссылки, а для использования абсолютных ссылок надо активировать соответствующий параметр. Например, при копировании или заполнении абсолютной ссылки из ячейки B2 в ячейку B3 она остается прежней в обеих ячейках: =$A$1.

      Скопированная формула с абсолютной ссылкой   

      Скопированная формула с абсолютной ссылкой
    3. Смешанные ссылки   . Смешанная ссылка содержит либо абсолютный столбец и относительную строку, либо абсолютную строку и относительный столбец. Абсолютная ссылка столбцов приобретает вид $A1, $B1 и т.д. Абсолютная ссылка строки приобретает вид A$1, B$1 и т.д. При изменении позиции ячейки, содержащей формулу, относительная ссылка изменяется, а абсолютная ссылка не изменяется. При копировании или заполнении формулы вдоль строк и вдоль столбцов относительная ссылка автоматически корректируется, а абсолютная ссылка не корректируется. Например, при копировании или заполнении смешанной ссылки из ячейки A2 в ячейку B3 она изменяется с =A$1 на =B$1.

      Скопированная формула со смешанной ссылкой   

      Скопированная формула со смешанной ссылкой

  • Стиль трехмерных ссылок

    Удобный способ для ссылки на несколько листов   . Трехмерные ссылки используются для анализа данных из одной и той же ячейки или диапазона ячеек на нескольких листах одной книги. Трехмерная ссылка содержит ссылку на ячейку или диапазон, перед которой указываются имена листов. В Microsoft Excel используются все листы, указанные между начальным и конечным именами в ссылке. Например, формула =СУММ(Лист2:Лист13!B5) суммирует все значения, содержащиеся в ячейке B5 на всех листах в диапазоне от Лист2 до Лист13 включительно.

    • При помощи трехмерных ссылок можно создавать ссылки на ячейки на других листах, определять имена и создавать формулы с использованием следующих функций: СУММ, СРЗНАЧ, СРЗНАЧА, СЧЁТ, СЧЁТЗ, МАКС, МАКСА, МИН, МИНА, ПРОИЗВЕД, СТАНДОТКЛОН.Г, СТАНДОТКЛОН.В, СТАНДОТКЛОНА, СТАНДОТКЛОНПА, ДИСПР, ДИСП.В, ДИСПА и ДИСППА.

    • Трехмерные ссылки нельзя использовать в формулах массива.

    • Трехмерные ссылки нельзя использовать вместе с оператор пересечения (один пробел), а также в формулах с неявное пересечение.

    Что происходит при перемещении, копировании, вставке или удалении листов   . Нижеследующие примеры поясняют, какие изменения происходят в трехмерных ссылках при перемещении, копировании, вставке и удалении листов, на которые такие ссылки указывают. В примерах используется формула =СУММ(Лист2:Лист6!A2:A5) для суммирования значений в ячейках с A2 по A5 на листах со второго по шестой.

    • Вставка или копирование.    Если вставить листы между листами 2 и 6, Microsoft Excel прибавит к сумме содержимое ячеек с A2 по A5 на новых листах.

    • Удаление   .  Если удалить листы между листами 2 и 6, Microsoft Excel не будет использовать их значения в вычислениях.

    • Перемещение   . Если листы, находящиеся между листом 2 и листом 6, переместить таким образом, чтобы они оказались перед листом 2 или после листа 6, Microsoft Excel вычтет из суммы содержимое ячеек с перемещенных листов.

    • Перемещение конечного листа   . Если переместить лист 2 или 6 в другое место книги, Microsoft Excel скорректирует сумму с учетом изменения диапазона листов.

    • Удаление конечного листа   . Если удалить лист 2 или 6, Microsoft Excel скорректирует сумму с учетом изменения диапазона листов.

  • Стиль ссылок R1C1

    Можно использовать такой стиль ссылок, при котором нумеруются и строки, и столбцы. Стиль ссылок R1C1 удобен для вычисления положения столбцов и строк в макросах. При использовании стиля R1C1 в Microsoft Excel положение ячейки обозначается буквой R, за которой следует номер строки, и буквой C, за которой следует номер столбца.

    Ссылка

    Значение

    R[-2]C

    относительная ссылка на ячейку, расположенную на две строки выше в том же столбце

    R[2]C[2]

    Относительная ссылка на ячейку, расположенную на две строки ниже и на два столбца правее

    R2C2

    Абсолютная ссылка на ячейку, расположенную во второй строке второго столбца

    R[-1]

    Относительная ссылка на строку, расположенную выше текущей ячейки

    R

    Абсолютная ссылка на текущую строку

    При записи макроса в Microsoft Excel для некоторых команд используется стиль ссылок R1C1. Например, если записывается команда щелчка элемента Автосумма для вставки формулы, суммирующей диапазон ячеек, в Microsoft Excel при записи формулы будет использован стиль ссылок R1C1, а не A1.

    Чтобы включить или отключить использование стиля ссылок R1C1, установите или снимите флажок Стиль ссылок R1C1 в разделе Работа с формулами категории Формулы в диалоговом окне Параметры. Чтобы открыть это окно, перейдите на вкладку Файл.

    К началу страницы

Для обозначения ячеек, диапазонов ячеек, формул, констант и таблиц Excel можно создавать определенные имена. Имя — это значимое краткое обозначение, поясняющее предназначение ссылки на ячейку, константы, формулы или таблицы, так как понять их суть с одного взгляда бывает непросто. Ниже приведены примеры имен и показано, как их использование упрощает понимание формул.

Пример 1

Тип примера

Пример использования диапазонов вместо имен

Пример с использованием имен

Ссылка

=СУММ(A16:A20)

=СУММ(Продажи)

Константа

=ПРОИЗВЕД(A12;9,5%)

=ПРОИЗВЕД(Цена;СтавкаНалога)

Формула

=ТЕКСТ(ВПР(MAX(A16,A20),A16:B20,2,FALSE),"дд.мм.гггг")

=ТЕКСТ(ВПР(МАКС(Продажи),ИнформацияОПродажах,2,ЛОЖЬ),"дд.мм.гггг")

Таблица

A22:B25

=ПРОИЗВЕД(Price,Table1[@Tax Rate])

Пример 2

Скопируйте образец данных из приведенной ниже таблицы и вставьте его в ячейку A1 нового листа Excel. Чтобы отобразить результаты формул, выделите их и нажмите клавишу F2, а затем — клавишу ВВОД. Кроме того, вы можете настроить ширину столбцов в соответствии с содержащимися в них данными.

Примечание :  В формулах в столбцах C и D определенное имя "Продажи" заменяется ссылкой на диапазон A9:A13, а имя "ИнформацияОПродажах" заменяется диапазоном A9:B13. Если же в книге не будет этих имен, формулы в D2:D3 вернут ошибку #ИМЯ?.

Тип примера

Пример, в котором не используются имена

Пример, в котором используются имена

Формула и результат с использованием имен

Ссылка

'=СУММ(A9:A13)

'=СУММ(Продажи)

=СУММ(Продажи)

Формула

'=ТЕКСТ(ВПР(МАКС(A9:13),A9:B13,2,ЛОЖЬ),"dd/mm/yyyy")

'=ТЕКСТ(ВПР(МАКС(Продажи),ИнформацияОПродажах,2,ЛОЖЬ),"дд.мм.гггг")

=ТЕКСТ(ВПР(МАКС(Продажи),ИнформацияОПродажах,2,ЛОЖЬ),"дд.мм.гггг")

Цена

995 

Продажи

Дата продажи

249 

17.03.2011

399 

02.04.2011

643 

23.04.2011

275 

30.04.2011

447 

04.05.2011

  • Типы имен

    Существует несколько типов имен, которые можно создавать и использовать.

    • Определенное имя   . Имя, используемое для представления ячейки, диапазона ячеек, формулы или константы. Можно создавать собственные определенные имена. Иногда (например, при настройке области печати) Excel самостоятельно создает определенное имя.

    • Имя таблицы   . Имя таблицы Excel, которая представляет собой набор данных по определенной теме. Эти данные хранятся в записях (строках) и полях (столбцах) таблицы. Каждый раз при вставке таблицы Excel по умолчанию присваивает ей имя "Таблица1", "Таблица2" и т. д. Это имя можно изменить, сделав его более понятным.

      Дополнительные сведения о таблицах Excel см. в статье Использование структурированных ссылок в таблицах Excel.

  • Создание и ввод имен

    Имена можно создавать, используя указанные ниже средства.

    • Поле имени в строке формул   . Этот способ лучше всего использовать для создания имени для выделенного диапазона на уровне книги.

    • Создание имени по выделению   .  Можно удобно создавать имена из существующих имен строк и столбцов с помощью выделения ячеек на листе.

    • Диалоговое окно "Создание имени".    Это лучше всего использовать, если нужна большая гибкость при создании имен, например, задание области определения на локальном уровне листа или создание примечания к имени.

    Примечание : По умолчанию в именах используются абсолютные ссылки на ячейки.

    Имя можно ввести указанными ниже способами.

    • Ввод   . Введите имя, например, в качестве аргумента формулы.

    • Автозавершение формул   . Используйте раскрывающийся список автозавершения формул, в котором автоматически выводятся допустимые имена.

    • Выбором из команды "Использовать в формуле"   . Выберите определенное имя из списка, доступного в команде Использовать в формуле в группе Определенные имена на вкладке Формула.

Дополнительные сведения см. в статье Определение и использование имен в формулах.

К началу страницы

Формула массива может выполнить несколько вычислений, а затем вернуть одно значение или группу значений. Формула массива обрабатывает несколько наборов значений, называемых аргументами массива. Каждый аргумент массива должен включать одинаковое число строк и столбцов. Формула массива создается так же, как и другие формулы, с той разницей, что для ввода такой формулы используются клавиши CTRL+SHIFT+ВВОД. Некоторые встроенные функции являются формулами массива, и для получения правильных результатов их следует вводить как массивы.

Константы массива могут использоваться вместо ссылок, если не требуется вводить каждую постоянную величину в отдельную ячейку на листе.

Использование формулы массива для вычисления одного или нескольких значений

Примечание : При вводе формулы массива Excel автоматически заключает ее в фигурные скобки { и }. При попытке вручную ввести фигурные скобки Excel отобразит формулу как текст.

  • Формула массива, вычисляющая одно значение   . С ее помощью можно упростить модель листа, заменив несколько отдельных формул одной формулой массива.

    Например, далее вычисляется итоговое значение цен на акции; строки ячеек не используются при вычислении и отображении отдельных значений для каждой акции.

    Формула массива, вычисляющая одно значение

    При вводе формулы ={СУММ(B2:D2*B3:D3)} в качестве формулы массива сначала вычисляется значение "Акции" и "Цена" для каждой биржи, а затем — сумма всех результатов.

  • Формула массива, вычисляющая несколько значений   . Некоторые функции возвращают массивы значений или требуют массив значений в качестве аргумента. Для вычисления нескольких значений с помощью формулы массива необходимо ввести массив в диапазон ячеек, состоящий из того же числа строк или столбцов, что и аргументы, которые принимают этот массив.

    Например, по заданному ряду из трех значений продаж (в столбце B) для трех месяцев (в столбце A) функция ТЕНДЕНЦИЯ определяет продолжение линейного ряда объемов продаж. Чтобы можно было отобразить все результаты формулы, она вводится в три ячейки столбца C (C1:C3).

    Формула массива, вычисляющая несколько значений

    Формула =ТЕНДЕНЦИЯ(B1:B3;A1:A3), введенная как формула массива, возвращает три значения (22 196, 17 079 и 11 962), вычисленные по трем объемам продаж за три месяца.

Использование констант массива

В обычную формулу можно ввести ссылку на ячейку со значением или на само значение, также называемое константой. Подобным образом в формулу массива можно ввести ссылку на массив либо массив значений, содержащихся в ячейках (его иногда называют константой массива). Формулы массива принимают константы так же, как и другие формулы, однако константы массива необходимо вводить в определенном формате.

Константы массива могут содержать числа, текст, логические значения, например ИСТИНА или ЛОЖЬ, либо значения ошибок, такие как #Н/Д. В одной константе массива могут присутствовать значения различных типов, например {1,3,4;ИСТИНА,ЛОЖЬ,ИСТИНА}. Числа в константах массива могут быть целыми, десятичными или иметь экспоненциальный формат. Текст должен быть заключен в двойные кавычки, например "Вторник".

Константы массива не могут содержать ссылки на ячейку, столбцы или строки разной длины, формулы и специальные знаки: $ (знак доллара), круглые скобки или % (знак процента).

При форматировании констант массива убедитесь, что выполняются указанные ниже требования.

  • Константы заключены в фигурные скобки ({ }).

  • Столбцы разделены запятыми (,). Например, чтобы представить значения 10, 20, 30 и 40, введите {10,20,30,40}. Эта константа массива является матрицей размерности 1 на 4 и соответствует ссылке на одну строку и четыре столбца.

  • Значения ячеек из разных строк разделены точками с запятой (;). Например, чтобы представить значения 10, 20, 30, 40 и 50, 60, 70, 80, находящиеся в расположенных друг под другом ячейках, можно создать константу массива с размерностью 2 на 4: {10,20,30,40;50,60,70,80}.

К началу страницы

Вместе с формулой удаляются и результаты ее вычисления. Тем не менее, можно удалить саму формулу, оставив при этом результат ее вычисления в виде значения в ячейке.

  • Ниже описано, как удалить формулы вместе с их значениями.

    1. Выделите ячейку или диапазон ячеек с формулой.

    2. Нажмите клавишу DELETE.

  • Чтобы удалить формулы, но оставить их значения, выполните указанные ниже действия.

    1. Выделите ячейку или диапазон ячеек с формулой.

      Если формула является формулой массива, выделите диапазон ячеек, содержащих эту формулу.

      Выделение диапазона ячеек, содержащих формулу массива

      1. Щелкните любую ячейку в формуле массива.

      2. На вкладке Главная в группе Редактирование нажмите кнопку Найти и выделить и выберите команду Перейти.

      3. Нажмите кнопку Выделить.

      4. Установите флажок Текущий массив.

    2. На вкладке Главная в группе Буфер обмена нажмите кнопку Копировать Изображение кнопки .
      Изображение ленты Excel

      Сочетание клавиш    Можно также нажать клавиши CTRL+C.

    3. На вкладке Главная в группе Буфер обмена щелкните стрелку под кнопкой Вставить Изображение кнопки и выберите пункт Вставить значения.

К началу страницы

Ниже перечислены некоторые из наиболее распространенных ошибок, допускаемых при вводе формул, а также способы их избежания.

Убедитесь, что…

Дополнительные сведения

Все открывающие и закрывающие скобки в формуле согласованы   

Убедитесь, что каждой скобке соответствует открывающая или закрывающая скобка. При создании формулы Excel выделяет вводимые скобки цветом.

Для указания диапазонов используется двоеточие   

С помощью двоеточия (:) разделяются ссылки на первую и последнюю ячейки в диапазоне. Например: A1:A5.

Указаны обязательные аргументы    

У функции могут быть обязательные и необязательные аргументы (последние обозначаются в синтаксисе квадратными скобками). Необходимо ввести все обязательные аргументы. Старайтесь также не вводить слишком много аргументов.

В формуле не больше 64 уровней вложенности функций   

Уровней вложенности не может быть более 64.

Имена книг и листов заключены в одинарные кавычки    

Если имена листов или книг, на ячейки или значения в которых вы ссылаетесь, содержат небуквенные символы, их нужно заключить в одинарные кавычки (').

Указан путь к внешним книгам    

Внешние ссылки должны содержать имя книги и путь к ней.

Числа введены без форматирования    

При вводе чисел в формулу нельзя указывать знаки долларов, так как они используются для обозначения абсолютных ссылок. Например, вместо значения $1000 нужно ввести 1000.

К началу страницы

Важно : Вычисляемые результаты формул и некоторые функции листа Excel могут несколько отличаться на компьютерах под управлением Windows с архитектурой x86 или x86-64 и компьютерах под управлением Windows RT с архитектурой ARM. Подробнее об этих различиях.

У вас есть вопрос об определенной функции?

Задать вопрос на форуме сообщества, посвященного Excel

Помогите нам улучшить Excel

У вас есть предложения по улучшению следующей версии Excel? Если да, ознакомьтесь с темами на портале пользовательских предложений для Excel.

Дополнительные сведения

Полные сведения о формулах в Excel

Рекомендации, позволяющие избежать появления неработающих формул

Поиск ошибок в формулах

Сочетания клавиш и горячие клавиши в Excel

Функции Excel (по алфавиту)

Функции Excel (по категориям)

Совершенствование навыков
Перейти к обучению
Первоочередный доступ к новым возможностям
Присоединиться к программе предварительной оценки Office

Были ли сведения полезными?

Спасибо за ваш отзыв!

Благодарим за отзыв! Возможно, будет полезно связать вас с одним из наших специалистов службы поддержки Office.

×