Вычисление разности двух дат

С помощью функции РАЗНДАТ можно вычислить разность между двумя датами. Поместите начальную дату в одну ячейку, а конечную — в другую. Затем введите формулу (см. одну из формул ниже).

Разность в днях

=РАЗНДАТ(D9;E9;"d") и результат: 856

В этом примере начальная дата находится в ячейке D9, а конечная — в ячейке E9. Формула помещена в ячейку F9. Параметр "d" возвращает количество полных дней между двумя датами.

Разность в неделях

=(РАЗНДАТ(D13;E13;"d")/7) и результат: 122,29

В этом примере начальная дата находится в ячейке D13, а конечная — в ячейке E13. Параметр "d" возвращает количество дней. Но в конце формулы указано выражение /7. Это выражение делит количество дней на 7, поскольку в неделе 7 дней. Учтите, что этот результат также должен иметь числовой формат. Нажмите клавиши CTRL+1. Затем выберите Числовой > Число десятичных знаков: 2.

Разность в месяцах

=РАЗНДАТ(D5;E5;"m") и результат: 28

В этом примере начальная дата находится в ячейке D5, а конечная — в ячейке E5. Параметр "m" в формуле возвращает количество полных месяцев между двумя датами.

Разность в годах

=РАЗНДАТ(D2;E2;"y") и результат: 2

В этом примере начальная дата находится в ячейке D2, а конечная — в ячейке E2. Параметр "y" возвращает количество полных лет между двумя датами.

Вычисление возраста в годах, месяцах и днях

Можно также вычислить возраст или срок службы. Результат при этом будет иметь следующий вид: "2 года, 4 месяца, 5 дней".

1. Используйте функцию РАЗНДАТ для вычисления суммарного количества лет.

=РАЗНДАТ(D17;E17;"y") и результат: 2

В этом примере начальная дата находится в ячейке D17, а конечная — в ячейке E17. Параметр "y" в формуле возвращает количество полных лет между двумя датами.

2. Используйте функцию РАЗНДАТ с параметром "ym" для вычисления количества месяцев.

=РАЗНДАТ(D17;E17;"ym") и результат: 4

В еще одну ячейку поместите формулу РАЗНДАТ с параметром "ym". Параметр "ym" возвращает количество месяцев, остающихся после последнего полного года.

3. Используйте другую формулу, чтобы найти дни.

=РАЗНДАТ(D17;E17;"md") и результат: 5

Теперь нужно определить количество оставшихся дней. Мы сделаем это, написав другую формулу, чем приведенная выше. Эта формула вычитает первый день конечного месяца (01.05.2016) из исходной даты окончания в ячейке E17 (06.05.2016). Ниже описано, как это делается. Сначала, функция ДАТА создает дату, 01.05.2016. Она делает это на основе года и месяца в ячейке E17 (число 1 означает первый день месяца). Функция ДАТА отображает 01.05.2016. Затем мы вычитаем эту дату из исходной конечной даты в ячейке E17, т. е. 06.05.2016. "06.05.2016" минус "01.05.2016" равняется 5 дням.

Примечание : Не рекомендуется использовать аргумент "md" функции РАЗНДАТ, так как это может привести к неправильным результатам вычисления.

4. Необязательно: объедините три формулы в одну.

=РАЗНДАТ(D17;E17;"y")&" лет, "&РАЗНДАТ(D17;E17;"ym")&" месяцев, "&РАЗНДАТ(D17;E17;"md")&" дней" и результат: 2 лет, 4 месяцев, 5 дней

Все три вычисления можно поместить в одну ячейку, как в этом примере. Можно использовать амперсанды, кавычки и текст. Такую формулу дольше вводить, но зато здесь все вычисления в одном месте. Совет. Чтобы добавить в формулу разрыв строки, нажмите клавиши ALT+ВВОД. Это упростит чтение. Если не видно всю формулу целиком, нажмите клавиши CTRL+SHIFT+U.

Скачивание образцов

Вы можете скачать образец книги со всеми примерами из этой статьи и использовать как готовые, так и свои собственные формулы.

Скачать примеры вычисления даты

Другие вычисления даты и времени

Как было показано выше, функция РАЗНДАТ вычисляет разность между начальной и конечной датами. Но вместо ввода конкретной даты можно использовать в формуле функцию СЕГОДНЯ(). При этом Excel в качестве даты берет текущую дату компьютера. Помните, что она изменится, когда файл будет снова открыт в другой день.

=РАЗНДАТ(СЕГОДНЯ();D28;"y") и результат: 984

Заметьте, что во время создания записи дата была 6 октября 2016 г.

Вычислить количество рабочих дней между двумя датами можно с помощью функции ЧИСТРАБДНИ.МЕЖД. При этом можно также исключить выходные и праздничные дни.

Перед началом. Решите, нужно ли исключить праздничные даты. Если да, введите список праздничных дней в отдельной области или на отдельном листе. Поместите каждую праздничную дату в отдельную ячейку. Затем выделите эти ячейки, выберите Формулы > Присвоить имя. Присвойте диапазону имя МоиПраздники и нажмите кнопку ОК. Затем создайте формулу, выполнив указанные ниже действия.

1. Введите начальную и конечную даты.

В ячейке D53 начальная дата 01.01.2016, в ячейке E53 конечная дата 12.31.2016

В этом примере начальная дата находится в ячейке D53, а конечная — в ячейке E53.

2. Еще в одной ячейке введите формулу такого вида:

=ЧИСТРАБДНИ.МЕЖД(D53;E53;1) и результат: 261

Введите формулу, как в приведенном выше примере. Параметр "1" в формуле назначает субботы и воскресенья выходными днями и исключает их из общей суммы.

Примечание. В Excel 2007 нет функции ЧИСТРАБДНИ.МЕЖД. Но есть функция ЧИСТРАБДНИ. Функция из примера выше в Excel 2007 имела бы такой вид: =ЧИСТРАБДНИ(D53;E53). Не нужно указывать 1, потому что функция ЧИСТРАБДНИ по умолчанию считает субботу и воскресенье выходными днями.

3. При необходимости измените параметр "1".

Список Intellisense со значениями "2 - Воскресенье, понедельник"; "3 - Понедельник, вторник" и т. д.

Если у вас выходные дни не в субботу и воскресенье, укажите вместо "1" другое число из списка IntelliSense. Например, "2" назначает выходными днями воскресенья и понедельники.

Если у вас Excel 2007, пропустите это действие. Функция ЧИСТРАБДНИ в Excel 2007 всегда считает выходными днями субботу и воскресенье.

4. Введите имя диапазона праздничных дней.

=ЧИСТРАБДНИ.МЕЖД(D53;E53;1;МоиПраздники) и результат: 252

Если вы присвоили имя диапазону праздничных дней в соответствии с инструкциями раздела "Перед началом", введите в конце это имя, как здесь. Если у вас нет праздничных дней, можно оставить точку с запятой и не указывать МоиПраздники. В Excel 2007 формула из примера выше примет вид: =ЧИСТРАБДНИ(D53;E53;МоиПраздники).

Совет. Если вы не хотите ссылаться на имя диапазона праздничных дней, можете вместо него указать диапазон D35:E:39. Можно также ввести в формулу каждый праздничный день. Например, если праздничные дни приходятся на 1 и 2 января 2016 г., введите их следующим образом: =ЧИСТРАБДНИ.МЕЖД(D53;E53;1;{"01.01.2016";"02.01.2016"}). В Excel 2007 нужно ввести: =ЧИСТРАБДНИ(D53;E53;{"01.01.2016";"02.01.2016"})

Чтобы вычислить затраченное время, нужно из одного значения времени вычесть другое. Поместите начальное время в одну ячейку, а конечное — в другую. Обязательно указывайте полное значение времени, включая часы и минуты. Ниже это описано более подробно.

1. Введите начальное и конечное время.

Начальная дата/время 07:15, конечная дата/время 16:30

В этом примере начальное время находится в ячейке D80, а конечное — в ячейке E80. Обязательно укажите полное значение времени, включая часы и минуты.

2. Задайте формат чч:мм.

Диалоговое окно "Формат ячеек", формат "(все форматы)", тип "ч:мм"

Выберите обе даты и нажмите клавиши CTRL+1 (или Изображение значка кнопки команд в Mac +1 на компьютере с Mac OS). Выберите формат (все форматы) > чч:мм, если он еще не задан.

3. Вычислите разность двух значений времени.

=E80-D80 и результат: 09:15

В еще одной ячейке вычтите значение ячейки начального времени из значения ячейки конечного времени.

4. Задайте формат чч:мм.

Диалоговое окно "Формат ячеек", формат "(все форматы)", тип "ч:мм"

Нажмите клавиши CTRL+1 (или Изображение значка кнопки команд в Mac +1 на компьютере с Mac OS). Выберите (все форматы) > чч:мм.

Чтобы вычислить время между двумя датами и значениями времени, можно просто вычесть одного из другого. Но к каждой ячейке необходимо применить форматирование, чтобы приложение Excel вернуло нужный результат.

1. Введите два полных значения даты и времени.

Начальная дата 01.01.16 13:00; конечная дата 02.01.16 14:00

В одной ячейке введите полное значение начальной даты и времени. В другой — полное значение конечной даты и времени. В каждой ячейке необходимо указать месяц, день, год, час и минуту.

2. Задайте формат 14.03.12 13:30.

Диалоговое окно "Формат ячеек", формат "Дата", типа "14.03.12 13:30"

Выберите обе ячейки и нажмите клавиши CTRL+1 (или Изображение значка кнопки команд в Mac +1 на компьютере с Mac OS). Затем выберите Дата > 14.03.12 13:30. Этот образец даты приведен для примера, чтобы просто показать, как выглядит формат. Учитывайте, что в версиях, предшествующих Excel 2016, образец даты может выглядеть иначе, например 14.03.01 13:30.

3. Найдите разность двух значений.

=E84-D84 и результат 1,041666667

В еще одной ячейке вычтите начальные дату и время из конечных даты и времени. Результат будет выглядеть как десятичное число со знаками после запятой. Это будет исправлено в следующем действии.

4. Задайте формат [ч]:мм.

Диалоговое окно "Формат ячеек", формат "(все форматы)", тип "[ч]:мм"

Нажмите клавиши CTRL+1 (или Изображение значка кнопки команд в Mac +1 на компьютере с Mac OS). Выберите (все форматы). В поле Тип введите [ч]:мм.

См. также

Функция РАЗНДАТ

Функция ЧИСТРАБДНИ.МЕЖД

Функция ЧИСТРАБДНИ

Другие функции даты и времени

Вычисление разности между двумя значениями времени

Совершенствование навыков
Перейти к обучению
Первоочередный доступ к новым возможностям
Присоединиться к программе предварительной оценки Office

Были ли сведения полезными?

Спасибо за ваш отзыв!

Благодарим за отзыв! Возможно, будет полезно связать вас с одним из наших специалистов службы поддержки Office.

×