SUM (funcția SUM)

Funcția SUM, una dintre funcțiile matematice și trigonometrice, adună valori. Puteți aduna valori individuale, referințe de celule, zone sau o combinație a acestora.

De exemplu:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Browserul nu acceptă redarea video. Instalați Microsoft Silverlight, Adobe Flash Player sau Internet Explorer 9.

Acest videoclip face parte dintr-un curs de instruire numit Adunarea numerelor în Excel 2013.

SUM(număr1,[număr2],...)

Nume argument

Descriere

număr1    (Necesar)

Primul număr pe care doriți să-l adunați. Numărul poate fi 4, o referință de celulă ca B6 sau o interval de celule, cum ar fi B2:B8.

număr2-255    (Opțional)

Acesta este al doilea număr pe care doriți să-l adunați. Puteți specifica până la 255 de numere în acest fel.

Dacă doriți să faceți rapid suma unei zone de celule, tot trebuie să faceți este să selectați zona și să căutați în partea din dreapta jos a ferestrei Excel.

Captură de ecran cu selectarea unei zone de celule, apoi vizualizarea barei de stare
Bară de stare


Aceasta este bara de stare și afișează informații cu privire la elementele selectate, indiferent dacă este o singură celulă sau mai multe. Dacă faceți clic dreapta pe bara de stare, va apărea o casetă de dialog de caracteristică afișând toate opțiunile pe care le puteți selecta. Rețineți că aceasta afișează și valorile pentru zona selectată, dacă aveți aceste atribute selectate. Aflați mai multe despre Bara de stare.

Cea mai simplă modalitate de a adăuga o formulă SUM la foaia de lucru este să utilizați expertul Însumare automată. Selectați o celulă goală de deasupra sau dedesubtul zonei pe care doriți să o adunați și, pe filele Pornire sau Formulă din panglică, apăsați Însumare automată > Însumare. Expertul Însumare automată va depista automat zona de adunat și va crea formula pentru dvs. Acesta poate funcționa și pe orizontală dacă selectați o celulă la stânga sau la dreapta zonei de adunat. Rețineți că nu va funcționa pentru zone necontigue, însă vom discuta acest lucru în secțiunea următoare.

Puteți utiliza Expertul Însumare automată pentru a construi automat o formulă de sumă.  Selectați o zonă de deasupra/dedesubtul sau de la stânga/dreapta zonei care va fi însumată și mergeți la fila Formulă din panglică, apoi selectați Însumare automată și  Sumă.
Utilizarea expertului Însumare automată pentru a însuma rapid zone contigue


Caseta de dialog Însumare automată vă mai permite și să selectați alte funcții comune, cum ar fi:

Însumarea automată pe verticală

Celula B6 arată formula de sumă Însumare automată: =SUM(B2:B5)

Expertul Însumare automată a detectat automat celulele B2:B5 ca zonă de adunat. Tot ce trebuie să faceți este să apăsați pe Enter pentru a confirma. Dacă trebuie să adăugați/să excludeți mai multe celule, puteți să apăsați lung tasta Shift > tasta săgeată dorită până când selecția se potrivește cu ceea ce doriți și să apăsați pe Enter când terminați.

Ghidul IntelliSense al funcției: eticheta mobilă SUM (număr1, [număr2], ...) de sub funcția este ghidul său Intellisense. Dacă faceți clic pe SUM sau pe numele funcției, acesta se va transforma într-un hyperlink albastru, care vă va duce la subiectul de Ajutor pentru acea funcție. Dacă faceți clic pe elementele individuale ale funcției, părțile lor reprezentative din formulă vor fi evidențiate. În acest caz, doar B2:B5 ar fi evidențiat, deoarece există un singur număr de referință în această formulă. Eticheta Intellisense va apărea pentru orice funcție.

Însumarea automată pe orizontală

Celula D2 arată formula de sumă Însumare automată: =SUM(B2:C2)

Utilizarea SUM cu zone necontigue.  Formula celulei C8 este = SUM(C2:C3,C5:C6). Ați putea utiliza, de asemenea, zone denumite, astfel încât formula ar fi = SUM(Săptămâna1,Săptămâna2).

Expertul Însumare automată va funcționa în general doar pentru zone contigue, astfel încât dacă aveți rânduri sau coloane necompletate în cadrul zonei, Excel se va opri la primul spațiu liber. În acest caz, ar trebui să adunați după selecție, adăugând zonele individuale una câte una. În acest exemplu, dacă ați avea date în celula B4, Excel ar genera =SUM(C2:C6) , deoarece ar recunoaște o zonă contiguă.

Puteți selecta rapid mai multe zone necontigue, folosind Ctrl+clic stânga. Introduceți mai întâi, „=SUM(”, apoi selectați zonele, iar Excel va adăuga automat separatorul virgulă între zone pentru dvs. Apăsați pe Enter când ați terminat.

SFAT: puteți utiliza ALT+= pentru a adăuga rapid funcția SUM într-o celulă. Apoi tot ce trebuie să faceți este să selectați zonele.

Notă: este posibil să observați că Excel a evidențiat diferitele zone ale funcțiilor folosind culori, iar acestea corespund în cadrul formulei, astfel că C2:C3 are o culoare, iar C5:C6 are alta. Excel va face acest lucru pentru toate funcțiile, dacă zona la care faceți referire se află pe o altă foaie de lucru sau în alt registru de lucru. Pentru accesibilitate îmbunătățită cu tehnologia de asistare, puteți utiliza Zone denumite, cum ar fi „Săptămâna1”, „Săptămâna2” etc., apoi puteți face referire la acestea în formulă:

=SUM(Săptămâna1,Săptămâna2)

Puteți efectua cu ușurință operații matematice cu Excel, simple și împreună cu funcții Excel, cum ar fi SUM. Următorul tabel listează operatorii pe care îi puteți utiliza, împreună cu unele funcții asociate. Puteți introduce operatorii fie de pe șirul de numere pe tastatură, fie de pe minitastatura cu 10 taste, dacă aveți una. De exemplu, Shift+8 va introduce un asterisc (*) pentru înmulțire.

Operator

Operație

Exemple

+

Adunare

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Scădere

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Înmulțire

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - funcția PRODUCT

/

Împărțire

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - funcția QUOTIENT

^

Ridicare la putere

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - funcția POWER

Pentru mai multe informații, consultați Utilizarea Excel drept calculator.

Alte exemple
  1. Să presupunem că doriți să aplicați un discount procentual la o zonă de celule însumate.

    Utilizarea operatorilor cu SUM.  Formula din celula B16 este =SUM(A2:A14)*-25%.  Formula ar fi construită corespunzător dacă -25 % ar fi o referință la celulă, cum ar fi = SUM (A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Ar returna 25 % din zona însumată, însă acest lucru codifică cei 25% din formulă și îi poate face dificil de găsit mai târziu, dacă trebuie să modificați procentul. E mult mai bine să plasați reducerea de 25% într-o celulă și să faceți referire la aceasta, deoarece astfel valoarea poate fi modificată cu ușurință, astfel:

    • =SUM(A2:A14)*E2

    Pentru a împărți în loc să înmulțiți, înlocuiți „*” cu „/”: =SUM(A2:A14)/E2

  2. Adunarea sau scăderea dintr-o sumă

    i. Puteți să adunați sau să scădeți cu ușurință dintr-o sumă, utilizând + sau - după cum urmează:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Această secțiune va discuta câteva exemple de bună practică pentru lucrul cu funcția SUM. Multe dintre acestea pot fi aplicate și la lucrul cu alte funcții.

Metoda =1+2 sau =A+B - deși puteți să introduceți =1+2+3 sau =A1+B1+C2 și să obțineți rezultate corecte, aceste metode sunt predispuse la erori din mai multe motive:
  1. Greșelile de tastare - imaginați-vă că încercați să introduceți mai multe valori sau valori mai mari, ca în acest exemplu:

    • =14598,93+65437,90+78496,23

    Apoi încercați să verificați dacă acestea sunt corecte. Este mult mai ușor să plasați aceste valori în celule individuale și să utilizați o formulă SUM. În plus, puteți formata valorile atunci când se află în celule, făcându-le mult mai ușor de citit atunci când se află într-o formulă.

    Utilizați funcția SUM în locul valorilor cu codificare impusă în formule.  Formula din celula D5 este =SUM(D2:D4)
  2. Erorile #VALUE! determinate de utilizarea textului în loc de numere

    Dacă utilizați o formulă ca:

    • =A1+B1+C1 sau =A1+A2+A3

    Exemplu de construcție slabă a formulei.  Formula din celula D2 este =A2+B2+C2

    Formula poate să nu reușească dacă există valori nenumerice (text) în celulele la care faceți referire, returnând o eroare #VALUE!. SUM va ignora valorile text și vă va oferi suma valorilor numerice.

    Construirea corespunzătoare a formulei.  În loc de = A2 + B2 + C2, formula din celula D2 este =SUM(A2:C2)
  3. Eroarea #REF! determinată de ștergerea rândurilor sau a coloanelor

    Eroare #REF! cauzată de ștergerea unei coloane.  Formula s-a modificat în = A2 + #REF! + B2

    Dacă ștergeți un rând sau o coloană, formula nu se va actualiza pentru a exclude rândul șters și va returna o eroare #REF!, pe când o funcție SUM se va actualiza automat.

    Funcția SUM se va ajusta automat dacă sunt rânduri și coloane inserate sau șterse
  4. Formulele nu actualizează referințele la inserarea rândurilor sau a coloanelor

    Formulele = A + B + C nu se actualizează dacă adăugați rânduri

    Dacă inserați un rând sau o coloană, formula nu se va actualiza pentru a include rândul adăugat, pe când o funcție SUM se va actualiza automat (atât timp cât nu sunteți în afara zonei la care face referire formula). Acest lucru este important mai ales dacă vă așteptați ca formula să se actualizeze și nu este așa, deoarece veți obține rezultate incomplete fără a vă anunța acest lucru.

    Exemplul prezintă o formulă SUM care se extinde automat din =SUM(A2:C2) la =SUM(A2:D2) atunci când este inserată o coloană
  5. Funcția SUM cu referințe la celule individuale versus zone

    Utilizarea unei formule precum

    • =SUM(A1,A2,A3,B1,B2,B3)

    este la fel de predispusă la erori atunci când inserați sau ștergeți rânduri din zona la care faceți referire, din aceleași motive. Este mult mai bine să utilizați zone individuale, cum ar fi:

    • =SUM(A1:A3,B1:B3)

    Care se vor actualiza atunci când adăugați sau ștergeți rânduri.

  1. Puteți utiliza SUM împreună cu alte funcții. Iată un exemplu care creează un calcul al mediei lunare:

    Utilizarea SUM cu alte funcții.  Formula din celula M2 este =SUM(A2:L2)/COUNTA(A2:L2).  Notă: coloanele Mai-Noiembrie sunt ascunse pentru claritate.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Formula preia suma A2:L2 împărțită la numărul de celule nevide din A2:L2 (lunile mai - decembrie sunt vide).

  1. Uneori, trebuie să adunați o anumită celulă de pe mai multe foi de lucru. Poate fi tentant să faceți clic pe fiecare foaie și pe celula dorită și să utilizați „+” pentru a aduna valorile celulelor, dar acest lucru este plictisitor și poate da naștere la erori.

    • =Foaie1!A1+Foaie2!A1+Foaie3!A1

    Puteți realiza acest lucru mult mai ușor cu o sumă 3D sau tridimensională:

    Sumă terță - Formula din celula D2 este=SUM(Sheet1:Sheet3!A2)
    • =SUM(Foaie1:Foaie3!A1)

    Aceasta va însuma celula A1 de pe toate foile, de la Foaia 1 la Foaia 3.

    Acest lucru este util în special atunci când aveți o singură foaie pentru fiecare lună (ianuarie-decembrie) și trebuie să le adunați pe o foaie rezumat.

    Sumă terță pe toate foile denumite.  Formula din D2 este =SUM(Ianuarie:Decembrie!A2)
    • =SUM(Ianuarie:Decembrie!A2)

    Se va aduna celula A2 de pe fiecare foaie, din ianuarie până în decembrie.

    Note : Dacă foile de lucru au spații în cadrul numelui, cum ar fi „Vânzări ianuarie”, trebuie să utilizați un apostrof atunci când faceți referire la numele lor într-o formulă. Observați că apostroful se află ÎNAINTE de primul nume al unei foi de lucru și DUPĂ ultimul.

    • =SUM(‘Vânzări ianuarie:Vânzări decembrie’!A2)

    Metoda 3D va funcționa și cu alte funcții, cum ar fi AVERAGE, MIN, MAX etc:

    • =AVERAGE(Foaie1:Foaie3!A1)

    • =MIN(Foaie1:Foaie3!A1)

    • =MAX(Foaie1:Foaie3!A1)

Problemă

Ce nu a funcționat

Funcția SUM returnează ##### în locul rezultatului.

Verificați lățimile coloanelor. ##### înseamnă de obicei că respectiva coloană este prea îngustă pentru a afișa rezultatul formulei.

Funcția SUM afișează formula propriu-zisă ca text, nu rezultatul.

Verificați dacă nu cumva celula este formatată ca text. Selectați celula sau zona în cauză și utilizați Ctrl+1 pentru a afișa caseta de dialog Formatare celule, apoi faceți clic pe fila Număr și selectați formatul dorit. În cazul în care celula a fost formatată ca text și nu se modifică după ce schimbați formatul, trebuie să utilizați F2 > Enter pentru a impune modificarea formatului.

Funcția SUM nu se actualizează.

Asigurați-vă că valoarea Calcul este setată la Automat. Pe fila Formulă, accesați Opțiuni de calcul. De asemenea, puteți utiliza F9 pentru a impune ca foaia de lucru să realizeze calculul.

Asigurați-vă că este setat calculul pe Automat.  Din fila Formule mergeți la Opțiuni de calcul.

Unele valori nu sunt adunate.

Numai valorile numerice din referința sau din zona funcției pot fi adunate. Celulele goale, valorile logice ca TRUE sau valorile text sunt ignorate.

Apare eroarea #NAME? în locul rezultatului așteptat.

Acest lucru înseamnă de obicei că formula este scrisă greșit, cum ar fi =suma(A1:A10) în loc de =SUM(A1:A10).

Funcția SUM afișează un număr întreg, dar ar trebui să afișeze zecimale

Verificați formatarea celulelor pentru a vă asigura că vor fi afișate zecimale. Selectați celula sau zona în cauză și utilizați Ctrl+1 pentru a afișa caseta de dialog Formatare celule, apoi faceți clic pe fila Număr și selectați formatul dorit, asigurându-vă că indicați numărul de zecimale dorit.

  1. Vreau doar să adaug/să scad/să înmulțesc/să împart numere Vedeți această serie video despre Operații matematice de bază în Excel sau Utilizarea Excel drept calculator.

  2. Cum pot afișa mai multe/mai puține zecimale? Puteți modifica formatul de număr. Selectați celula sau zona în cauză și utilizați Ctrl+1 pentru a afișa caseta de dialog Formatare celule, apoi faceți clic pe fila Număr și selectați formatul dorit, asigurându-vă că indicați numărul de zecimale dorit.

  3. Cum adun sau scad valori de timp? Puteți aduna și scădea valori de timp în câteva modalități diferite. De exemplu, pentru a obține diferența între 8:00 - 00:00 pentru calcularea salariului, veți utiliza: = („00:00”-„8:00”)*24, scăzând din ora de terminare ora de început. Rețineți că Excel calculează orele ca fracțiune a unei zile, așa că trebuie să înmulțiți cu 24 pentru a obține numărul total de ore. În primul exemplu utilizăm =((B2-A2)+(D2-C2))*24 pentru a obține suma orelor de la început la sfârșit, mai puțin pauza de prânz (în total 8,50 de ore).

    Dacă adunați pur și simplu ore și minute și doriți să le afișați astfel, puteți face adunarea și nu este necesar să înmulțiți cu 24, deci în al doilea exemplu utilizăm =SUM(A6:C6), deoarece avem nevoie doar de numărul total de ore și minute pentru activitățile atribuite (5:36 sau 5 ore, 36 minute).

    Calcule de timp

    Pentru mai multe informații, consultați: Adunarea sau scăderea valorilor de timp.

  4. Cum calculez diferența dintre date? La fel ca în cazul orelor, puteți aduna și scădea și date. Iată un exemplu foarte obișnuit de contorizare a numărului de zile dintre două date calendaristice. Este simplu: = B2-A2. Esențial pentru lucrul cu date și ore este să începeți cu data/ora de sfârșit și să scădeți data/ora de început.

    Calculul diferențelor dintre date

    Pentru mai multe modalități de a lucra cu datele, consultați: Calcularea numărului de zile dintre două date.

  5. Cum adun doar celulele vizibile? Uneori, când ascundeți manual rânduri sau utilizați Filtrarea automată pentru a afișa doar anumite date, poate că doriți să adunați celulele vizibile. Puteți să utilizați funcția SUBTOTAL. Dacă utilizați un rând total într-un tabel Excel, orice funcție pe care o selectați din lista verticală Total va fi introdusă automat ca un subtotal. Aflați mai multe despre cum să calculați totalul datelor dintr-un tabel Excel.

Aveți o întrebare cu privire la funcții?

Postați o întrebare în forumul Comunității Excel

Ajutați-ne să îmbunătățim Excel

Aveți sugestii despre cum putem îmbunătăți următoarea versiune de Excel? Dacă aveți, consultați subiectele de la UserVoice pentru Excel.

Consultați și

Urmăriți un videoclip despre cum să utilizați funcția SUM

Funcția SUMIF adună doar valorile care îndeplinesc un criteriu unic

Funcția SUMIFS adună doar valorile care îndeplinesc mai multe criterii

Funcția COUNTIF numără numai valorile care îndeplinesc un criteriu unic

Funcția COUNTIFS numără numai valorile care îndeplinesc mai multe criterii

Prezentare generală a formulelor din Excel

Cum să evitați formulele eronate

Găsirea și corectarea erorilor din formule

Comenzi rapide de la tastatură în Excel pentru Windows

Comenzi rapide de la tastatură în Excel pentru Mac

Funcțiile matematice și trigonometrice

Funcțiile Excel (în ordine alfabetică)

Funcțiile Excel (după categorie)

Partajare Facebook Facebook Twitter Twitter E-mail E-mail

Au fost utile aceste informații?

Minunat! Alt feedback?

Cum putem îmbunătăți?

Vă mulțumim pentru feedback!

×