Prezentarea generală a formulelor din Excel

Prezentarea generală a formulelor din Excel

Dacă sunteți utilizator începător al programului Excel, veți descoperi în curând că acesta este ceva mai mult decât o simplă grilă în care puteți introduce numere în coloane sau rânduri. Sigur, Excel se poate utiliza pentru a găsi totalurile pentru o coloană sau un rând de numere, dar, de asemenea, mai poate calcula ratele unui împrumut, poate rezolva probleme de matematică sau de inginerie sau poate găsi un scenariu cu cel mai favorabil caz pe baza diverselor numere introduse.

Excel face acest lucru utilizând formule în celule. O formulă efectuează calcule sau alte acțiuni cu datele din foaia de lucru. O formulă începe întotdeauna cu semnul egal (=), care poate fi urmat de numere, operatori matematici (cum ar fi un semn + sau - pentru adunare sau pentru scădere) și funcții Excel încorporate, care pot extinde cu adevărat puterea unei formule.

De exemplu, următoarea formulă înmulțește 2 cu 3, apoi adună 5 la rezultat pentru a ajunge la răspuns, 11.

=2*3+5

Iată câteva exemple suplimentare de formule care se pot introduce într-o foaie de lucru.

  • =A1+A2+A3    Adună valorile din celulele A1, A2 și A3.

  • =SUM(A1:A10)    Utilizează funcția SUM pentru a returna suma valorilor din zona A1-A10.

  • =TODAY()    Returnează data curentă.

  • =UPPER("salut")     Efectuează conversia textului „salut” în „SALUT” utilizând funcția UPPER.

  • =IF(A1>0)    Utilizează funcția IF pentru a testa celula A1 și a determina dacă aceasta conține o valoare mai mare ca 0.

O formulă mai poate conține una sau toate dintre următoarele: funcții, referințe, operatori și constante.

Părți ale unei formule   

Părți ale unei formule

1. Funcții: funcția PI() returnează valoarea lui pi: 3,142...

2. Referințe: A2 returnează valoarea din celula A2.

3. Constante: numere sau valori text introduse direct într-o formulă, cum ar fi 2.

4. Operatori: operatorul ^ (accent circumflex) ridică un număr la putere, iar operatorul * (asterisc) înmulțește numere.

O constantă este o valoare care nu se calculează. Ea rămâne permanent aceeași. De exemplu, data 9.10.2008, numărul 210 și textul „Venituri trimestriale“ sunt toate constante. O expresie sau o valoare care rezultă dintr-o expresie nu este o constantă. Dacă utilizați valori constante în formule în loc de referințe la celule (de exemplu, =30+70+110), rezultatul se modifică numai dacă modificați formula. În general, este bine să plasați constantele în celule individuale, de unde pot fi modificate cu ușurință dacă este nevoie, apoi să faceți referire la celulele respective în formule.

Operatorii specifică tipul de calcul pe care doriți să-l efectuați cu elementele dintr-o formulă. Excel urmează reguli matematice generale pentru calcule, adică Paranteze, Exponenți, Înmulțire și împărțire și Adunare și scădere, traduse prin acronimul PEMDAS (paranteze, exponenți, înmulțire, împărțire, adunare, scădere). Utilizarea parantezelor vă permite să modificați ordinea de calcul.

Tipuri de operatori. Există patru tipuri diferite de operatori de calcul: aritmetici, de comparare, de concatenare a textului și de referință.

  • Operatori aritmetici

    Pentru a efectua operații matematice de bază, cum sunt adunarea, scăderea, înmulțirea sau împărțirea, combinări de numere sau producerea de rezultate numerice, utilizați următorii operatori aritmetici.

    Operator aritmetic

    Semnificație

    Exemplu

    + (semnul plus)

    Adunare

    =3+3

    – (semnul minus)

    Scădere
    Negație

    =3–3
    =-3

    * (asterisc)

    Înmulțire

    =3*3

    / (linie oblică)

    Împărțire

    =3/3

    % (semnul procent)

    Procent

    30%

    ^ (accent circumflex)

    Ridicare la putere

    =3^3

  • Operatori de comparare

    Aveți posibilitatea să comparați două valori cu operatori următorii. Când două valori sunt comparate utilizând acești operatori, rezultatul este o valoare logică: fie TRUE, fie FALSE.

    Operator de comparare

    Semnificație

    Exemplu

    = (semn egal)

    Egal cu

    =A1=B1

    > (semnul mai mare)

    Mai mare decât

    =A1>B1

    < (semnul mai mic)

    Mai mic decât

    =A1<B1

    >= (semnul mai mare sau egal)

    Mai mare sau egal cu

    =A1>=B1

    <= (semnul mai mic sau egal)

    Mai mic sau egal cu

    =A1<=B1

    <> (semnul nu este egal cu)

    Nu este egal cu

    =A1<>B1

  • Operator de concatenare text

    Utilizați caracterul ampersand (&) pentru a uni sau a concatena unul sau mai multe șiruri de text pentru a realiza un singur text.

    Operator text

    Semnificație

    Exemplu

    & (ampersand)

    Conectează sau concatenează două valori pentru a produce o valoare de text continuă

    =„North”&„wind” formează „Northwind”.
    Acolo unde A1 conține „Nume de familie” și B1 conține „Prenume”, =A1&","&B1 formează „Nume de familie, Prenume”.

  • Operatori de referință

    Combină zone de celule pentru calcule cu următorii operatori.

    Operator de referință

    Semnificație

    Exemplu

    : (două puncte)

    Operator de zonă care produce o referință către toate celulele dintre două referințe, inclusiv către respectivele referințe.

    B5:B15

    . (punct)

    Operator de uniune care combină referințele multiple într-o singură referință

    =SUM(B5:B15,D5:D15)

    (spațiu)

    Operator de intersecție, care produce o referință la celulele comune celor două referințe

    B7:D7 C6:C8

Începutul paginii

În anumite cazuri, ordinea în care se execută calculul poate afecta rezultatul unei formule, așadar este important să înțelegeți cum este stabilită ordinea și cum aveți posibilitatea să modificați ordinea pentru a obține rezultatele dorite.

  • Ordinea operațiilor

    Formulele calculează valori într-o anumită ordine. În Excel, o formulă începe întotdeauna cu un semn egal (=). Excel interpretează caracterele care urmează semnului egal ca o formulă. După semnul egal urmează elementele de calculat (operanzii), cum ar fi constantele sau referințele la celule. Acestea sunt separate de operatorii de calcul. Excel calculează formula de la stânga la dreapta, conform unei ordini specifice pentru fiecare operator din formulă.

  • Prioritatea operatorilor în formulele Excel

    Atunci când combinați mai mulți operatori într-o singură formulă, Excel efectuează operațiile în ordinea arătată în următorul tabel. Dacă formula conține operatori de același grad. De exemplu, dacă formula conține atât operatorul de înmulțire cât și operatorul de împărțire, Excel evaluează operatorii de la stânga la dreapta.

    Operator

    Descriere

    : (două puncte)

    (un spațiu)

    , (virgulă)

    Operatori de referință

    Negație (ca în –1)

    %

    Procent

    ^

    Ridicare la putere

    * și /

    Înmulțire și împărțire

    + și –

    Adunare și scădere

    &

    Unește două șiruri de text (concatenare)

    =
    < >
    <=
    >=
    <>

    Comparație

  • Utilizarea parantezelor în formulele Excel

    Pentru a modifica ordinea evaluării, încadrați în paranteze partea formulei care doriți să fie calculată prima. De exemplu, rezultatul formulei următoare este 11, deoarece Excel calculează înmulțirea înaintea adunării. Formula înmulțește 2 cu 3 și adună 5 la rezultat.

    =5+2*3

    În schimb, dacă utilizați paranteze pentru a modifica sintaxa, Excel adună 5 cu 2, apoi înmulțește rezultatul cu 3 pentru a rezulta 21.

    =(5+2)*3

    În exemplul următor, parantezele care încadrează prima parte a formulei forțează programul Excel să calculeze întâi B4+25 apoi să împartă rezultatul cu suma valorilor din celulele D5, E5 și F5.

    =(B4+25)/SUM(D5:F5)

    Începutul paginii

Funcțiile sunt formule predefinite care efectuează calcule utilizând anumite valori, numite argumente, într-o anumită ordine sau structură. Funcțiile pot fi utilizate pentru efectuarea unor calcule simple sau complexe. Puteți găsi toate funcțiile Excel pe fila Formule din Panglică:

Fila Formule Excel de pe panglică
  • Sintaxa funcțiilor Excel

    Următorul exemplu al funcției ROUND, care rotunjește un număr din celula A10, ilustrează sintaxa unei funcții.

    Structura unei funcții

    1. Structură. Structura unei funcții începe cu semnul egal (=), urmat de numele funcției, o paranteză deschisă, argumentele funcției separate prin virgule și o paranteză închisă.

    2. Numele funcției. Pentru o listă de funcții disponibile, faceți clic pe o celulă și apăsați SHIFT+F3, care va lansa caseta de dialog Inserare funcție.

    Formule Excel - caseta de dialog Inserare funcție

    3. Argumente. Argumentele pot fi numere, text, valori logice ca TRUE sau FALSE, matrice, valori de eroare, de ex. #N/A, sau referințe la celule. Argumentul precizat trebuie să producă o valoare corectă pentru acel argument. Argumentele pot fi și constante, formule sau alte funcții.

    4. Sfat ecran pentru argumente. La tastarea funcției apare un sfat ecran al sintaxei și al argumentelor. De exemplu, când tastați =ROUND( apare sfatul ecran al funcției. Sfaturile ecran apar numai pentru funcțiile predefinite.

    Notă : Nu trebuie să tastați funcțiile cu majuscule, cum ar fi =ROUND, deoarece Excel va scrie automat numele funcției cu litere mari după ce apăsați pe Enter. Dacă scrieți greșit numele unei funcții, cum ar fi =SUME(A1:A10) în loc de =SUM(A1:A10), Excel va returna eroarea #NAME?.

  • Introducerea funcțiilor Excel

    La crearea unei formule care conține o funcție, puteți utiliza caseta de dialog Inserare funcție pentru a introduce funcții în foaia de lucru. După ce selectați o funcție din caseta de dialog Inserare funcție, Excel va lansa un expert pentru funcții care afișează numele funcției, fiecare argument al acesteia, o descriere a funcției și a fiecărui argument, rezultatul curent al funcției și rezultatul curent al întregii formule.

    Expertul de funcții Excel

    Pentru a simplifica crearea și editarea formulelor și pentru a reduce la minimum erorile de tastare și erorile de sintaxă, utilizați Completare automată formulă. După ce tastați un semn egal (=) și literele de început ale unei funcții, Excel afișează o listă verticală dinamică de funcții valide, argumente și nume care se potrivesc cu literele respective. Apoi puteți selecta un element din lista verticală și Excel îl va introduce pentru dvs.

    Completarea automată a formulelor în Excel

  • Imbricarea funcțiilor Excel

    În anumite cazuri, poate fi necesar să utilizați o funcție drept unul dintre argumentele altei funcții. De exemplu, formula următoare utilizează o funcție AVERAGE imbricată și compară rezultatul cu valoarea 50.

    Funcții imbricate

    1. Funcțiile AVERAGE și SUM sunt imbricate în funcția IF.

    Returnări corecte    Când o funcție imbricată este utilizată drept argument, aceasta trebuie să returneze același tip de valoare utilizat de argument. De exemplu, dacă argumentul returnează o valoare TRUE sau FALSE, atunci și funcția imbricată este necesar să returneze TRUE sau FALSE. În caz contrar, Excel afișează o valoare de eroare #VALUE!.

    Limitele nivelului de imbricare    O formulă poate conține până la șapte niveluri de funcții imbricate. Atunci când o funcție (o vom denumi Funcția B) este utilizată ca un argument în altă funcție (o vom denumi Funcția A), funcția B se comportă ca o funcție de nivelul al doilea. De exemplu, funcția AVERAGE și funcția SUM sunt ambele de nivelul al doilea dacă sunt argumente ale funcției IF. O funcție imbricată în interiorul funcției AVERAGE ar fi o funcție de nivelul al treilea etc.

    Începutul paginii

O referință identifică o celulă sau o zonă de celule dintr-o foaie de lucru și notifică Excel unde să caute valorile sau datele pe care doriți să le utilizați într-o formulă. Puteți să utilizați referințe pentru a folosi date conținute în diferite părți ale unei foi de lucru sau să utilizați valoarea dintr-o celulă în mai multe formule. De asemenea, puteți face referire la celule din alte foi ale aceluiași registru de lucru și la alte registre de lucru. Referințele la celule din alte registre de lucru se numesc legături sau referințe externe.

  • Stilul de referință A1

     În mod implicit, Excel utilizează stilul A1 pentru referințe, care se referă la coloane cu litere (de la A la XFD, în total 16.384 coloane) și rânduri cu numere (de la 1 la 1.048.576). Aceste litere și numere se numesc titluri de rând și de coloană. Pentru a face referire la o celulă, introduceți litera coloanei urmată de numărul rândului. De exemplu, B2 se referă la celula de la intersecția coloanei B cu rândul 2.

    Pentru a face referire la

    Utilizați

    Celula din coloana A și rândul 10

    A10

    Zona de celule din coloana A și rândurile de la 10 până la 20

    A10:A20

    Zona de celule din rândul 15 și coloanele de la B la E

    B15:E15

    Toate celulele din rândul 5

    5:5

    Toate celulele din rândurile de la 5 până la 10

    5:10

    Toate celulele din coloana H

    H:H

    Toate celulele din coloanele de la H la J

    H:J

    Zona de celule din coloanele de la A la E și din rândurile de la 10 la 20

    A10:E20

  • Crearea unei referințe la o celulă sau o zonă de celule de pe altă foaie din același registru de lucru

    În următorul exemplu, funcția AVERAGE calculează valoarea medie pentru zona B1:B10 de pe foaia de lucru numită Marketing, din același registru de lucru.

    Exemplu de referință de foaia de lucru

    1. Se referă la foaia de lucru denumită Marketing

    2. Se referă la zona de celule de la B1 la B10

    3. Semnul exclamării (!) Separă referința la foaia de lucru de referința la zona de celule

    Notă : Dacă foaia de lucru la care faceți referire include spații sau numere, atunci trebuie să adăugați apostrofuri (') înainte și după numele foii de lucru, cum ar fi ='123'!A1 sau ='Venituri ianuarie'!A1.

  • Diferența dintre referințele absolute, referințele relative și referințele mixte

    1. Referințele relative    O referință relativă la o celulă dintr-o formulă, cum ar fi A1, se bazează pe poziția celulei care conține formula și pe celula la care se referă referința. Dacă se modifică poziția celulei care conține formula, se modifică și referința. Dacă veți copia sau veți umple formula pe mai multe rânduri sau coloane verticale, referința se reglează în mod automat. În mod implicit, formulele noi utilizează referințe relative. De exemplu, dacă veți copia sau umple o referință relativă în celulele B2 și B3, ea se reglează automat de la =A1 la =A2.

      Formulă copiată cu referință relativă   

      Formulă copiată cu referință relativă

    2. Referințele absolute    O referință absolută la o celulă dintr-o formulă, cum ar fi $A$1, se referă întotdeauna la o celulă dintr-o anumită locație. Dacă se modifică poziția celulei care conține formula, referința absolută nu se modifică. Dacă veți copia sau umple formula pe mai multe rânduri sau coloane verticale, referința absolută nu se reglează. În mod implicit, formulele noi utilizează referințe relative, deci poate fi necesar să le comutați în referințe absolute. De exemplu, dacă veți copia sau umple o referință absolută în celulele B2 și B3, ea va rămâne neschimbată în ambele celule =$A$1.

      Formulă copiată cu referință absolută   

      Formulă copiată cu referință absolută
    3. Referințele mixte    O referință mixtă are o coloană absolută și un rând relativ sau un rând absolut și o coloană relativă. Referința pe o coloană absolută are forma $A1, $B1 etc. Referința pe un rând absolut are forma A$1, B$1 etc. Dacă se modifică poziționarea celulei care conține formula, referința relativă se modifică, iar referința absolută rămâne neschimbată. Dacă veți copia sau umple formula pe mai multe rânduri sau coloane verticale, referința relativă se va regla automat, iar referința absolută nu se va regla. De exemplu, dacă veți copia sau umple o referință mixtă din celulele de la A2 la B3, se va regla de la =A$1 la =B$1.

      Formulă copiată cu referință mixtă   

      Formulă copiată cu referință mixtă

  • Stilul de referință 3D

    Referințe la mai multe foi de lucru    Dacă doriți să analizați datele din aceeași celulă sau o zonă de celule din mai multe foi de lucru din registrul de lucru, utilizați o referință 3-D. O referință 3-D include referința la o celulă sau la o zonă de celule, precedată de o zonă de nume de foi de lucru. Excel utilizează foile de lucru stocate între numele de început și numele de final din referință. De exemplu, =SUM(Foaie2:Foaie13!B5) adaugă toate valorile conținute în celula B5 pe toate foile de lucru dintre Foaie 2 și Foaie 13, inclusiv.

    • Aveți posibilitatea să utilizați referințe 3-D pentru a face referire la celulele din alte foi, pentru a defini nume și pentru a crea formule utilizând următoarele funcții: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA și VARPA.

    • În formule matrice nu se pot utiliza referințe 3-D.

    • Referințele 3-D nu se pot utiliza cu operator intersecție (un spațiu) sau în formule care utilizează intersecție implicită.

    Ce se întâmplă când mutați, copiați, inserați sau ștergeți foi de lucru    Următoarele exemple arată ce se întâmplă când mutați, copiați, inserați sau ștergeți foi de lucru care sunt incluse în referințe 3-D. Exemplele utilizează formula =SUM(Foaie2:Foaie6!A2:A5) pentru a adăuga celulele de la A2 la A5 pe foile de lucru de la 2 la 6.

    • Inserare sau copiere    Dacă inserați sau copiați foile dintre Foaie2 și Foaie6 (punctele finale din acest exemplu), Excel include toate valorile din celulele de la A2 la A5 din foile adăugate în calcul.

    • Ștergere     Dacă ștergeți foile de la Foaie2 la Foaie6, Excel elimină valorile din calcul.

    • Mutare    Dacă mutați foile dintre Foaie2 și Foaie6 într-o locație aflată în afara intervalului de foi la care se face referire, Excel elimină valorile acestora din calcul.

    • Mutarea unui punct de final    Dacă mutați Foaie2 sau Foaie6 într-o altă locație din același registru de lucru, Excel reglează calculul pentru a include intervalul nou de foi de lucru.

    • Ștergerea unui punct de final    Dacă ștergeți Foaie2 sau Foaie6, Excel reglează calculul pentru a include intervalul de foi de lucru dintre ele.

  • Stilul de referință R1C1

    De asemenea, puteți utiliza un stil de referință în care atât rândurile, cât și coloanele din foaia de lucru sunt numerotate. Stilul de referințe R1C1 este util pentru calculul poziționărilor rândurilor și coloanelor în macrocomenzi. În acest stil, Excel indică locația unei celule cu un „R” urmat de un număr de rând și un „C” urmat de un număr de coloană.

    Referință

    Semnificație

    R[-2]C

    O referință relativă la celula cu două rânduri mai sus în aceeași coloană

    R[2]C[2]

    O referință relativă la celula cu două rânduri mai jos și două coloane la dreapta

    R2C2

    O referință absolută la celula din rândul al doilea și coloana a doua

    R[-1]

    O referință relativă la întregul rând de deasupra celulei active

    R

    O referință absolută la rândul curent

    Când înregistrați o macrocomandă, Excel înregistrează unele comenzi utilizând stilul R1C1 pentru referințe. De exemplu, dacă înregistrați o comandă cum ar fi aceea să faceți clic pe butonul Însumare automată pentru a insera o formulă care adaugă o zonă de celule, Excel înregistrează formula utilizând referințe cu stilul R1C1, nu cu stilul A1.

    Aveți posibilitatea să activați sau să dezactivați stilul R1C1 pentru referințe prin bifarea sau debifarea casetei de selectare Stil referință R1C1 din secțiunea Lucrul cu formulele, din categoria Formule, din caseta de dialog Opțiuni. Pentru a afișa această casetă de dialog, faceți clic pe fila Fișier.

    Începutul paginii

Puteți crea nume definite pentru a reprezenta celule, zone de celule, formule, valori constante sau tabele Excel. Numele este un instrument semnificativ care facilitează înțelegerea scopului unei referințe de celulă, a unei constante, a unei formule sau a unui tabel, fiecare dintre acestea fiind destul de dificil de înțeles dintr-o singură privire. Următoarele informații arată exemple obișnuite de nume și cum utilizarea lor poate îmbunătăți claritatea și înțelegerea.

Exemplul 1

Tip de exemplu

Exemplu cu utilizarea zonelor în locul numelor

Exemplu cu utilizarea numelor

Referință

=SUM(A16:A20)

=SUM(Vânzări)

Constantă

=PRODUCT(A12;9,5%)

=PRODUCT(Preț,Taxe)

Formulă

=TEXT(VLOOKUP(MAX(A16;A20);A16:B20;2;FALSE),"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Vânzări);InfoVânzări;2;FALSE);"m/dd/yyyy")

Tabel

A22:B25

=PRODUCT(Preț;Tabel1[@Taxe])

Exemplul 2

Copiați datele din exemplele din următorul tabel și lipiți-le în celula A1 a noii foi de lucru Excel. Pentru ca formulele să afișeze rezultate, selectați-le, apăsați pe F2, apoi pe Enter. Dacă trebuie, puteți ajusta lățimea coloanei pentru a vedea toate datele.

Notă :  În formulele din coloanele C și D, numele definit „Vânzări” este înlocuit cu referința la (zona) A9:A13 și numele „InfoVânzări” este înlocuit cu zona A9:B13. Dacă nu creați aceste nume în registrul de lucru test, formulele din D2:D3 vor returna eroarea #NAME?.

Tip de exemplu

Exemplu, neutilizând un nume

Exemplu, utilizând un nume

Formulă și rezultat, utilizând un nume

Referință

'=SUM(A9:A13)

'=SUM(Vânzări)

=SUM(Vânzări)

Formulă

'=TEXT(VLOOKUP(MAX(A9:13),A9:B13,2,FALSE),"m/dd/yyyy")

'=TEXT(VLOOKUP(MAX(Vânzări);InfoVânzări;2;FALSE);"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Vânzări);InfoVânzări;2;FALSE);"m/dd/yyyy")

Preț

995 lei

Vânzări

Dată vânzare

249 lei

17.03.2011

399 lei

02.04.2011

643 lei

23.04.2011

275 lei

30.04.2011

447 lei

04.05.2011

  • Tipuri de nume

    Există mai multe tipuri de nume pe care aveți posibilitatea să le creați și să le utilizați.

    • Nume definit    Un nume care reprezintă o celulă, o zonă de celule, o formulă sau o valoare constantă. Aveți posibilitatea creați propriul nume definit. De asemenea, Excel creează uneori un nume definit, cum ar fi atunci când setați o zonă de imprimare.

    • Nume tabel    Numele unui tabel Excel, care este o colecție de date despre un anumit subiect care sunt stocate în înregistrări (rânduri) și câmpuri (coloane). Excel creează un nume de tabel implicit „Tabel1”, „Tabel2” etc., de fiecare dată când inserați un tabel Excel, dar aveți posibilitatea să modificați numele pentru a le face mai semnificative.

      Pentru mai multe informații despre tabelele Excel, consultați Utilizarea referințelor structurate în tabelele Excel.

  • Crearea și introducerea numelor

    Aveți posibilitatea să creați un nume dacă utilizați:

    • Caseta Nume de pe bara de formule    Aceasta este cea mai potrivită pentru crearea unui nume al nivelului registrului de lucru pentru o zonă selectată.

    • Crearea unui nume din selecție    Aveți posibilitatea să creați cu ușurință nume din etichetele de coloană sau de rând existente, utilizând o selecție de celule din foaia de lucru.

    • Caseta de dialog Nume nou    Aceasta se utilizează îndeosebi atunci când doriți mai multă flexibilitate la crearea numelor, cum ar fi să specificați un domeniu pentru nivelul local al unei foi de lucru sau să creați comentarii despre nume.

    Notă : În mod implicit, numele utilizează referințe absolute la celule.

    Un nume se poate introduce:

    • Tastând    De exemplu, numele se tastează ca argument la o formulă.

    • Utilizând Completare automată formulă    Utilizați lista verticală Completare automată formulă, în care se listează automat nume valide.

    • Selectând din comanda Utilizare în formulă    Selectați un nume definit dintr-o listă disponibilă din comanda Utilizare în formulă, din grupul Nume definite, de pe fila Formule.

Pentru mai multe informații, consultați Definirea și utilizarea numelor în formule.

Începutul paginii

O formulă matrice poate efectua mai multe calcule și poate returna un singur rezultat sau mai multe rezultate. Formulele matrice acționează pe două sau mai multe seturi de valori cunoscute ca argumente matrice. Fiecare argument matrice trebuie să aibă același număr de rânduri și coloane. Creați formule matrice în același fel în care creați alte formule, cu excepția faptului că apăsați pe CTRL+SHIFT+ENTER pentru a introduce formula. Anumite funcții predefinite sunt formule matrice și trebuie introduse ca matrice pentru a obține rezultate corecte.

Constantele matrice se pot utiliza în locul referințelor când nu doriți să introduceți fiecare valoare constantă într-o celulă separată pe foaia de lucru.

Utilizarea unei formule matrice pentru a calcula rezultate unice și rezultate multiple

Notă : Când introduceți o formulă matrice, Excel inserează automat formula între acolade { }. Dacă încercați să introduceți singur acoladele, Excel va afișa formula ca text.

  • Formulă matrice care produce un rezultat unic    Acest tip de formulă matrice poate simplifica un model de foaie de lucru prin înlocuirea câtorva formule diferite cu o singură formulă matrice.

    De exemplu, următoarele calculează valoarea totală a unei matrice de acțiuni și cotații, fără a utiliza un rând de celule pentru a calcula și afișa valorile individuale pentru fiecare cotație.

    Formulă matrice care produce un rezultat unic

    Când introduceți formula ={SUM(B2:D2*B3:D3)} ca formulă matrice, aceasta înmulțește Acțiunile și Cotațiile, apoi însumează rezultatele pentru acele calcule.

  • Formulă matrice care produce mai multe rezultate    Unele funcții ale foii de lucru returnează matrice de valori sau necesită o matrice de valori ca argument. Pentru a calcula mai multe rezultate cu o formulă matrice, trebuie să introduceți matricea într-o zonă de celule care are același număr de rânduri și coloane ca argumentele matricei.

    De exemplu, dacă se dă o serie de trei cifre de vânzări (în coloana B) pentru o serie de trei luni (în coloana A), funcția TREND determină valorile în linie dreaptă pentru cifrele de vânzări. Pentru a afișa toate rezultatele formulei, introduceți matricea în trei celule din coloana C (C1:C3).

    Formula matrice care produce mai multe rezultate

    Când introduceți formula =TREND(B1:B3;A1:A3) ca formulă matrice, aceasta produce trei rezultate separate (22196, 17079 și 11962), bazate pe cele trei cifre de vânzări și pe cele trei luni.

Utilizarea constantelor matrice

Într-o formulă obișnuită, aveți posibilitatea să introduceți o referință la o celulă care conține o valoare sau valoarea în sine, denumită și constantă. În mod asemănător, într-o formulă matrice aveți posibilitatea să introduceți o referință la o matrice sau să introduceți o matrice de valori conținute în celulele, denumită și constantă matrice. Formulele matrice acceptă constante în același fel ca și formulele care nu sunt matrice, dar trebuie să introduceți constantele matrice într-un anumit format.

Constantele matrice pot conține numere, text, valori logice ca TRUE sau FALSE, sau valori de eroare ca #N/A. Tipuri diferite de valori se pot utiliza în aceeași constantă matrice , cum ar fi {1,3,4;TRUE,FALSE,TRUE}. Numerele dintr-o constantă matrice pot fi numere întregi, zecimale sau în format științific. Textul trebuie închis între ghilimele, cum ar fi „marți”.

Constantele matrice nu pot conține referințe la celule, coloane sau rânduri de lungimi inegale, formule sau caractere speciale $ (dolar), paranteze sau % (procent).

Când formatați constante matrice, asigurați-vă că:

  • Le includeți între acolade ( { }).

  • Separați valorile din coloane diferite cu ajutorul virgulelor (,). De exemplu, pentru a reprezenta valorile 10, 20, 30 și 40, introduceți {10,20,30,40}. Această constantă matrice este cunoscută ca matrice 1-pe-4 și este echivalentă cu o referință 1-rând-pe-4-coloane.

  • Separați valorile pe rânduri diferite, prin punct și virgulă (;). De exemplu, pentru a reprezenta valorile 10, 20, 30 și 40 pe un rând și 50, 60, 70 și 80 pe rândul de dedesubt, introduceți o constantă matrice 2-pe-4: {10,20,30,40;50,60,70,80}.

Începutul paginii

Atunci când ștergeți o formulă, valorile rezultate sunt șterse, de asemenea. Cu toate acestea, puteți să eliminați doar formula și să lăsați valoarea rezultată a formulei afișată în celulă.

  • Pentru a șterge formulele și valorile rezultate, procedați astfel:

    1. Selectați celula sau zona de celule care conține formula.

    2. Apăsați DELETE.

  • Pentru a șterge formulele fără a elimina valorile rezultate, procedați astfel:

    1. Selectați celula sau zona de celule care conține formula.

      Dacă formula este o formulă matrice, selectați zona care conține formula matrice.

      Cum se selectează o zonă de celule care conține formula matrice

      1. Faceți clic pe o celulă din formula matrice.

      2. În fila Pornire, în grupul Editare, faceți clic pe Găsire și selectare, apoi faceți clic pe Salt la.

      3. Faceți clic pe Special.

      4. Faceți clic pe Matrice curentă.

    2. Pe fila Pornire, în grupul Clipboard, faceți clic pe Copiere Buton WordArt .
      Imagine Panglică Excel

      Comandă rapidă de la tastatură    Alternativ, puteți apăsa CTRL+C.

    3. În fila Pornire, în grupul Clipboard, faceți clic pe săgeata de sub Lipire, Buton WordArt , apoi pe Lipire valoare.

Începutul paginii

Tabelul următor prezintă pe scurt câteva dintre cele mai comune greșeli pe care le puteți face atunci când introduceți o formulă și cum să evitați erorile din formule:

Asigurați-vă că...

Mai multe informații

Închideți toate parantezele deschise din formulă   

În formule, toate parantezele formează perechi. Când creați o formulă, Excel afișează parantezele colorat pe măsură ce sunt introduse.

Utilizați două puncte pentru a indica o zonă introdusă în formulă   

Semnul două puncte (:) este utilizat pentru a separa referința la prima și ultima celulă din zonă. De exemplu, A1:A5.

Introduceți toate argumentele necesare    

Funcțiile pot avea argumente obligatorii și opționale (indicate prin paranteze drepte în sintaxă). Toate argumentele obligatorii trebuie introduse. De asemenea, asigurați-vă că nu ați introdus prea multe argumente.

Nu imbricați mai mult de 64 funcții într-o formulă   

Imbricarea funcțiilor dintr-o formulă este limitată la 64 de niveluri.

Închideți numele de registre sau foi de lucru în ghilimele simple   

Atunci când faceți referire la valori sau celule din alte foi de lucru sau registre de lucru care au caractere nealfabetice în numele lor, numele trebuie încadrate în ghilimele simple (').

Adăugați calea la registrele de lucru externe    

Referințele externe trebuie să conțină un nume de registru de lucru și calea la registrul de lucru.

Introduceți numerele fără formatare    

Numerele introduse într-o formulă nu trebuie formatate cu separatori zecimali sau semne dolar ($), deoarece virgulele sunt utilizate deja ca separatori de argumente în formule, iar semnul dolar se utilizează pentru a marca referințe absolute. De exemplu, în loc să introduceți $1.000, introduceți 1000 în formulă.

Începutul paginii

Important : Rezultatele calculate ale formulelor și ale unor funcții de foaie de lucru Excel pot diferi ușor între un PC Windows care utilizează o arhitectură x86 sau x86-64 și un PC Windows RT care utilizează arhitectură ARM. Aflați mai multe despre diferențe.

Aveți o întrebare cu privire la funcții?

Postați o întrebare în forumul Comunității Excel

Ajutați-ne să îmbunătățim Excel

Aveți sugestii despre cum putem îmbunătăți următoarea versiune de Excel? Dacă aveți, consultați subiectele de la UserVoice pentru Excel

Consultați și

Prezentarea generală a formulelor din Excel

Cum să evitați formulele eronate

Găsirea și corectarea erorilor din formule

Comenzi rapide de la tastatură și taste funcționale Excel

Funcții Excel (în ordine alfabetică)

Funcții Excel (după categorie)

Extindeți-vă competențele
Explorați instruirea
Fiți primul care obține noile caracteristici
Alăturați-vă utilizatorilor Office Insider

Au fost utile aceste informații?

Vă mulțumim pentru feedback!

Vă mulțumim pentru feedback! Se pare că ar fi util să luați legătura cu unul dintre agenții noștri de asistență Office.

×