TEXTO (função TEXTO)

A função TEXTO permite-lhe alterar a forma como os números são apresentados ao aplicar formatação com os códigos de formatação. Esta função é útil em situações onde pretende apresentar números num formato mais legível ou pretende combinar números com texto ou símbolos.

Nota: A função TEXTO irá converter números em texto, o que poderá dificultar a referência de futuros cálculos. Aconselhamos a manter o valor original numa célula e, em seguida, utilizar a função TEXTO noutra célula. Assim, se precisar de criar outras fórmulas, pode sempre utilizar o valor original como referência e não o resultado da função TEXTO.

Sintaxe

TEXTO(valor; formato_texto)

A sintaxe da função TEXTO tem os seguintes argumentos:

Nome do Argumento

Descrição

valor

Um valor numérico que pretende converter em texto.

formato_texto

Uma cadeia de texto que define a formatação que pretende aplicar ao valor fornecido.

Descrição geral

De uma forma resumida, a função TEXTO diz:

  • =TEXTO(Valor que pretende formatar, "Código de formatação que pretende aplicar")

Eis alguns exemplos populares, que podem ser copiados diretamente para o Excel para que possa experimentar. Tenha em atenção que os códigos de formatação encontram-se entre aspas.

Fórmula

Descrição

=TEXTO(1234,567;"# ##0,00\ [$€-x-euro1]")

A moeda tem um separador nos milhares e dois decimais, como 1 234,57 €. Tenha em atenção que o Excel arredonda o valor para duas casas decimais.

=TEXTO(HOJE();"DD/MM/AA")

O dia de hoje no formato DD/MM/AA, como 14/03/12

=TEXTO(HOJE();"DDDD")

O dia da semana de hoje, como segunda-feira

=TEXTO(AGORA();"H:MM")

Hora atual, como 13:29

=TEXTO(0,285;"0,0%")

Percentagem, como 28,5%

=TEXTO(4,34 ;"#?/?")

Fração, como 4 1/3

=COMPACTAR(TEXTO(0,34;"#?/?"))

Fração, como 1/3 Tenha em atenção que este exemplo utiliza a função COMPACTAR para remover os espaços à esquerda do valor decimal.

=TEXTO(12200000;"0,00E+00")

Notação científica, como 1,22E+07

=TEXTO(123456789;"[<=999999999]###\ ###\ ###;(###) ###\ ###\ ###")

Especial (número de telefone), como (123) 123 456 789

=TEXTO(1234;"0000000")

Adiciona zeros à esquerda (0), como 0001234

=TEXTO(123456;"##0° 00' 00''")

Personalizado – Latitude/Longitude

Nota: Apesar de poder utilizar a função TEXTO para alterar a formatação, não é a única forma de o fazer. Pode alterar a formatação sem uma fórmula, ao premir Ctrl+1 (ou Imagem do ícone do botão Comando do MAC +1 no Mac) e, em seguida, selecionar o formato que pretende utilizar na caixa de diálogo Formatar Células > Número.

Transferir os nossos exemplos

Pode transferir um livro de exemplo com todos os exemplos da função TEXTO que encontrará neste artigo, com alguns exemplos extra. Pode acompanhar os exemplos no livro ou criar os seus códigos de formatação da função TEXTO.

Transferir os exemplos da função TEXTO do Excel

Estão disponíveis outros códigos de formatação

Pode utilizar a caixa de diálogo Formatar Células para localizar outros códigos de formatação disponíveis:

  1. Prima Ctrl+1 ( Imagem do ícone do botão Comando do MAC +1 no Mac) para apresentar na caixa de diálogo Formatar Células.

  2. Selecione o formato que pretende no separador Número.

  3. Selecione a opção Personalizado.

  4. O código de formatação que pretende é apresentado na caixa Tipo. Neste caso, selecione tudo da caixa Tipo, exceto o ponto e vírgula (;) e o símbolo @. No exemplo abaixo, selecionámos e copiámos só a secção dd/mm/aa.

  5. Prima Ctrl+C para copiar o código de formatação e, em seguida, prima Cancelar para dispensar a caixa de diálogo Formatar Células.

  6. Agora, só tem de premir Ctrl+V para colar o código de formatação na sua fórmula TEXTO, por exemplo: =TEXTO(B2;"dd/mm/aa"). Certifique-se de que cola o código de formatação entre aspas ("código de formatação"), caso contrário o Excel devolverá uma mensagem de erro.

Exemplo de utilização da caixa de diálogo Formatar Células > Número > Personalizado para fazer com que o Excel crie automaticamente cadeias de formato.

Códigos de formatação por categoria

Seguem-se alguns exemplos de como pode aplicar diferentes formatos de número aos seus valores, ao utilizar a caixa de diálogo Formatar Células e, em seguida, a opção Personalizado para copiar esses códigos de formatação para a sua função TEXTO.

Por que razão o Excel elimina os meus zeros (0) à esquerda?

O Excel está preparado para os números que são introduzidos nas células, não para os números que se assemelham a texto, como números de peça ou SKUs. Para reter os zeros à esquerda, formate o intervalo de entrada como Texto antes de colar ou introduzir valores. Selecione a coluna ou o intervalo onde irá colocar os valores, utilize o atalho Ctrl+1 para apresentar a caixa de diálogo Formatar Células e, no separador Número, selecione Texto. Com esta opção, o Excel manterá os seus zeros (0) à esquerda.

Se já introduziu os dados e o Excel removeu os seus zeros (0) à esquerda, pode utilizar a função TEXTO para voltar a adicioná-los. Pode fazer referência à célula superior com os valores e utilizar =TEXTO(valor;"00000") (onde o número de zeros na fórmula representa o total de carateres pretendido) e, em seguida, copiar e colar o resto do seu intervalo.

Exemplos de utilização da fórmula TEXTO para formatar zeros à esquerda. =TEXTO(A2;"00000")

Se, por alguma razão, precisar de converter os valores do texto novamente em números, pode multiplicar por 1, por exemplo =D4*1 ou utilizar o operador unário duplo (--), como =--D4.

O Excel separa os milhares com espaços se o formato contiver um espaço ( ) entre sinais de cardinal (#) ou zeros. Por exemplo, se o formato da cadeia for "# ###" o Excel apresentará o número 12200000 como 12 200 000.

Um ponto existente a seguir a um marcador de posição de dígitos dimensiona o número por 1000. Por exemplo, se o formato da cadeia for "# ##0,00", o Excel apresenta o número 12200000 como 12 200 000,00.

Exemplos da função TEXTO com o separador de milhares

Notas: 

  • O separador de milhares é definido consoante as suas definições regionais. Nos EUA utiliza-se uma vírgula, mas noutras regiões poderá ser utilizado um ponto final (.).

  • O separador dos milhares está disponível para os formatos de número, moeda e contabilidade.

Os seguintes exemplos referem-se aos formatos de número (apenas o separador dos milhares e das décimas), moeda e contabilidade padrão. O formato de moeda permite-lhe inserir o símbolo de moeda que preferir e alinha-o junto ao seu valor, enquanto o formato de contabilidade alinha o símbolo de moeda à esquerda da célula e o valor à direita. Tenha atenção à diferença entre os códigos de formatação de moeda e de contabilidade abaixo, uma vez que o formato de contabilidade utiliza um asterisco (*) para criar uma separação entre o símbolo e o valor.

Exemplos da função TEXTO com formatos de número, moeda e contabilidade

Para localizar o código de formatação de um símbolo de moeda, primeiro deve premir Ctrl+1 (ou Imagem do ícone do botão Comando do MAC +1 no Mac), selecionar o formato que pretende e, em seguida, selecionar o símbolo a partir o menu pendente Símbolo:

Seleção de Símbolo de Moeda da caixa de diálogo Formatar Células

Em seguida, prima Personalizado à esquerda, na secção Categoria, e copie o código de formatação, incluindo o símbolo de moeda.

Função TEXTO – moeda personalizada com símbolo

Nota: A função TEXTO não suporta a formatação por cores, pelo que, se copiar um código de formatação de número a partir da caixa de diálogo Formatar Células que inclua uma cor, por exemplo: # ##0,00\ [$€-x-euro1];[Vermelho](# ##0,00\ [$€-x-euro1]), a função TEXTO aceitará o código de formatação, mas não apresentará a cor.

Pode alterar a forma como uma data é apresentada ao utilizar uma combinação de "D" para dias, "M" para mês e "A" para anos.

Códigos de formatação Mês, Dia e Ano

Os códigos de formatação na função TEXTO não são sensíveis às maiúsculas e minúsculas, pelo que pode utilizar "D" ou "d", "M" ou "m" e "A" ou "a".

MVP do Excel, Mynda Treacy

A Mynda Recomenda...

Se partilhar ficheiros e relatórios do Excel com utilizadores de outros países/regiões, é aconselhável entregar o relatório no respetivo idioma. A MVP do Excel, Mynda Treacy, apresenta uma excelente solução neste artigo intitulado Excel Dates Displayed in Different Languages (Datas do Excel Apresentadas Noutros Idiomas). Também inclui um livro de exemplo que pode transferir.

Pode alterar a forma como a hora é apresentada ao utilizar uma combinação de "H" para horas, "M" para minutos e "S" para segundos. Também pode utilizar o "AM/PM" para o relógio de 12 horas.

Formatos de hora para horas, minutos e segundos

Se não escrever "AM/PM" ou "A/P", a hora será apresentada com base no relógio de 24 horas.

Os códigos de formatação na função TEXTO não são sensíveis às maiúsculas e minúsculas, pelo que pode utilizar "H" ou "h", "M" ou "m", "S" ou "s" e "AM/PM" ou "am/pm".

Pode alterar a forma como os valores decimais são apresentados com os formatos de percentagem (%).

Códigos de formatação para percentagem

Pode alterar a forma como os valores decimais são apresentados com os formatos de fração (?/?).

Códigos de formatação para frações

A notação científica é uma forma de apresentar os números em termos decimais entre 1 e 10, multiplicado por uma potência de 10. É frequentemente utilizada para encurtar a apresentação de grandes números.

Códigos de formatação para notação científica

O Excel fornece quatro formatos especiais:

  • Código Postal – "0000"

  • Código Postal +3 – "0000-000"

  • Número de Telefone – "[<=999999999]###\ ###\ ###;(###) ###\ ###\ ###"

  • Número da Segurança Social – "00000000000"

Formatos especiais para a função TEXTO

Os formatos na categoria Especial serão diferentes consoante a região. No entanto, se não existirem formatos especiais para a sua região ou se estes formatos não corresponderem às suas necessidades, pode criar o seu próprio formato na caixa de diálogo Formatar Células > Personalizado.

Cenário comum

A função TEXTO é raramente utilizada sozinha – na maioria das vezes é utilizada em conjunto com outras funções ou formatos. Digamos que pretende combinar texto e um valor numérico, como "Relatório Impresso a: 14/03/12" ou "Receita Semanal: 66 348,72 €". Poderia escrever essas informações manualmente no Excel, mas isso anula o objetivo de ter o Excel a efetuar automaticamente essa ação. Infelizmente, quando combina texto com números formatados, como datas, horas, moeda, entre outros, o Excel não sabe como os pretende apresentar, pelo que remove a formatação de número. É aqui que a função TEXTO se torna indispensável, pois permite-lhe forçar o Excel a formatar os valores da forma pretendida ao utilizar um código de formatação, como "DD/MM/AA" para o formato de data.

No seguinte exemplo, verá o que acontece se tentar juntar texto e números sem utilizar a função TEXTO. Neste caso, estamos a utilizar o E comercial (&) para concatenar uma cadeia de texto, um espaço (" ") e um valor com =A2&" "&B2.

Exemplo de união de texto sem a função TEXTO

Como pode verificar, o Excel removeu a formatação da data na célula B2. No exemplo seguinte, verá como a função TEXTO lhe permite aplicar o formato que pretende.

Exemplo de união de texto com a função TEXTO

A nossa fórmula atualizada é:

  • Célula C2:=A2&" "&TEXTO(B2;"dd/mm/aa") – Formato de data

Perguntas Mais Frequentes

Infelizmente, não é possível fazê-lo como a função TEXTO, terá de utilizar o código Visual Basic for Applications (VBA). A seguinte ligação tem um método: Como converter um valor numérico em palavras portuguesas no Excel

Sim, pode utilizar as funções MAIÚSCULAS, MINÚSCULAS e INICIAL.MAIÚSCULA. Por exemplo, =MAIÚSCULAS("olá") devolve "OLÁ".

Sim, mas essa ação requer alguns passos. Primeiro, selecione a célula ou as células onde pretende que isto aconteça e utilize o atalho Ctrl+1 para abrir a caixa de diálogo Formatar Células > Alinhamento > Controlo do texto. Selecione a opção Moldar Texto. Em seguida, ajuste a sua função TEXTO completa para incluir a função ASCII CARÁT(10) onde pretende colocar a quebra de linha. Poderá ter de ajustar a largura da coluna consoante o alinhamento do resultado final.

Exemplo da utilização da fórmula TEXTO com CARÁT(10) para inserir uma quebra de linha. ="Hoje é: "&CARÁT(10))&TEXTO(HOJE();"DD/MM/AA")

Neste caso, utilizámos: ="Hoje é: "&CARÁT(10)&TEXTO(HOJE();"dd/mm/aa")

Isto é denominado Notação Científica, onde o Excel converte automaticamente os números que sejam superiores a 12 dígitos, se as células estiverem com a formatação Geral, e superiores a 15 dígitos se as células estiverem com a formatação Número. Se precisar de introduzir grandes cadeias numéricas, mas não as quiser converter, então terá de formatar as células em questão como Texto antes de introduzir ou colar os seus valores no Excel.

MVP do Excel, Mynda Treacy

A Mynda Recomenda...

Se partilhar ficheiros e relatórios do Excel com utilizadores de outros países/regiões, é aconselhável entregar o relatório no respetivo idioma. A MVP do Excel, Mynda Treacy, apresenta uma excelente solução neste artigo intitulado Excel Dates Displayed in Different Languages (Datas do Excel Apresentadas Noutros Idiomas). Também inclui um livro de exemplo que pode transferir.

Consulte Também

Criar ou eliminar um formato de número personalizado

Converter texto em números

Todas as funções do Excel (por categoria)

Aumente os seus conhecimentos do Office
Explore as formações
Seja o primeiro a obter novas funcionalidades
Adira ao Office Insider

As informações foram úteis?

Obrigado pelos seus comentários!

Obrigado pelo seu feedback! Parece que poderá ser benéfico reencaminhá-lo para um dos nossos agentes de suporte do Office.

×