Aplica-se a
Objeto Application |
Devolve um objeto FileDialog que representa uma só ocorrência de uma caixa de diálogo de ficheiro.
expressão.FileDialog (dialogType)
expressão Obrigatório. Uma expressão que devolve um dos objetos na lista Aplica-se a.
dialogType Obrigatório MsoFileDialogType. O tipo da caixa de diálogo de ficheiro.
O MsoFileDialogType pode ser uma destas constantes de MsoFileDialogType. |
msoFileDialogFilePicker |
msoFileDialogFolderPicker |
msoFileDialogOpen Não suportado no Microsoft Access. |
msoFileDialogSaveAs Não suportado no Microsoft Access. |
Observações
As constantes msoFileDialogOpen e msoFileDialogSaveAs não são suportadas no Microsoft Office Access 2007.
Exemplo
Este exemplo ilustra como utilizar o objeto FileDialog para apresentar uma caixa de diálogo que permite ao utilizador selecionar um ou mais ficheiros. Os ficheiros selecionados são depois adicionados a uma caixa de listagem denominada ListaDeFicheiros.
Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub