Descrição geral de fórmulas no Excel

Descrição geral de fórmulas no Excel

Se estiver agora a começar a trabalhar com o Excel, irá perceber rapidamente que é mais do que uma grelha onde pode introduzir números em colunas ou linhas. Pode utilizar o Excel para descobrir totais de uma coluna ou de uma linha de números, mas também pode calcular o pagamento de um empréstimo, resolver problemas matemáticos ou de engenharia ou até encontrar o melhor cenário para uma questão baseada em números variáveis que insira.

O Excel fá-lo ao utilizar fórmulas em células. As fórmulas efetuam cálculos ou outras ações aos dados na sua folha de cálculo. As fórmulas começam sempre com um sinal de igual (=) que pode ser seguido por números, operadores matemáticos (como os sinais de adição ou subtração + e -) e funções do Excel incorporadas, que podem expandir significativamente a utilidade de uma fórmula.

Por exemplo, a fórmula seguinte multiplica 2 por 3 e adiciona 5 a esse resultado para obter a resposta 11.

=2*3+5

Seguem-se mais alguns exemplos de fórmulas que podem ser introduzidas numa folha de cálculo.

  • =A1+A2+A3    Adiciona os valores nas células A1, A2 e A3.

  • =SOMA(A1:A10)    Utiliza a função SOMA para devolver a soma dos valores do intervalo A1 a A10.

  • =HOJE()    Devolve a data atual.

  • =MAIÚSCULAS("olá")     Converte o texto "olá" em "OLÁ" utilizando a função MAIÚSCULAS.

  • =SE(A1>0)    Utiliza a função SE para testar a célula A1 de modo a determinar se a mesma contém um valor maior que 0.

Uma fórmula também pode conter um ou todos dos seguintes elementos: funções, referências, operadores e constantes.

Partes de uma fórmula   

Elementos de uma fórmula

1. Funções: a função PI() devolve o valor de pi: 3,142…

2. Referências: A2 devolve o valor na célula A2.

3. Constantes: números ou valores de texto introduzidos diretamente numa fórmula, como 2, por exemplo.

4. Operadores: o operador ^ (acento circunflexo) eleva um número a uma potência e o operador * (asterisco) multiplica números.

Uma constante é um valor que não é calculado; permanece sempre igual. Por exemplo, a data 09/10/2008, o número 210 e o texto "Lucros Trimestrais" são todos constantes. Uma expressão ou um valor resultante de uma expressão não é uma constante. Se utilizar constantes numa fórmula em vez de referências a células (por exemplo, =30+70+110), o resultado só é alterado se modificar a fórmula. Normalmente, o melhor é colocar as constantes em células individuais onde estas possam ser alteradas facilmente se necessário e, em seguida, referir as respetivas células na fórmula.

Os operadores especificam o tipo de cálculo que pretende efetuar nos elementos de uma fórmula. O Excel segue regras matemáticas gerais aplicadas a cálculos, nomeadamente Parênteses, Expoentes, Multiplicação e Divisão e Adição e Subtração ou, utilizando um acrónimo, regras PEMDAS (Para Evitar Múltiplas Dívidas À Segurança (Social). A utilização de parênteses permite-lhe alterar a ordem desse cálculo.

Tipos de operadores. Existem quatro tipos diferentes de operadores de cálculo: aritméticos, comparação, concatenação de texto e referência.

  • Operadores aritméticos

    Para executar operações matemáticas básicas como, por exemplo, adição, subtração, multiplicação ou divisão; combinar números e produzir resultados numéricos, utilize os seguintes operadores aritméticos.

    Operador aritmético

    Significado

    Exemplo

    + (sinal de adição)

    Soma

    =3+3

    - (sinal de subtração)

    Subtração
    Negação

    =3–3
    =-3

    * (asterisco)

    Multiplicação

    =3*3

    / (barra)

    Divisão

    =3/3

    % (símbolo de percentagem)

    Percentagem

    30%

    ^ (acento circunflexo)

    Exponenciação

    =3^3

  • Operadores de comparação

    Pode comparar dois valores com os operadores seguintes. Quando dois valores são comparados utilizando estes operadores, o resultado é um valor lógico — VERDADEIRO ou FALSO.

    Operador de comparação

    Significado

    Exemplo

    = (sinal de igual)

    Igual a

    =A1=B1

    > (sinal de maior)

    Maior que

    =A1>B1

    < (sinal de menor)

    Menor que

    =A1<B1

    >= (sinal de maior ou igual)

    Maior ou igual a

    =A1>=B1

    <= (sinal de menor ou igual)

    Menor ou igual a

    =A1<=B1

    <> (sinal de diferente)

    Diferente de

    =A1<>B1

  • Operador de concatenação de texto

    Utilize o E comercial (&) para concatenar (associar) uma ou mais cadeias de texto, de modo a formar um único bloco de texto.

    Operador de texto

    Significado

    Exemplo

    & ("E" comercial)

    Liga ou concatena dois valores e produz um valor de texto contínuo

    A fórmula ="North"&"wind" devolve o resultado "Northwind".
    Se a célula A1 contiver "Apelido" e a célula B1 contiver "Nome próprio", a fórmula =A1&";"&B1 devolve o resultado "Apelido, Nome próprio".

  • Operadores de referência

    Combinam intervalos de células para cálculos com os seguintes operadores.

    Operador de referência

    Significado

    Exemplo

    : (dois pontos)

    Operador de intervalo, que produz uma referência a todas as células entre duas referências, incluindo as duas referências.

    B5:B15

    ; (ponto e vírgula)

    Operador de união que combina várias referências numa só

    =SOMA(B5:B15;D5:D15)

    (espaço)

    Operador de interseção, que produz uma referência a células comuns às duas referências.

    B7:D7 C6:C8

Início da Página

Em alguns casos a ordem pela qual um cálculo é efetuado poderá afetar o valor devolvido pela fórmula, pelo que é importante compreender a forma como é determinada a ordem e como é possível alterar a ordem para obter os resultados pretendidos.

  • Ordem de cálculo

    As fórmulas calculam valores por uma ordem específica. Uma fórmula no Excel começa sempre com um sinal de igual (=). O Excel interpreta os carateres a seguir ao sinal de igual como uma fórmula. A seguir ao sinal de igual estão os elementos a calcular (os operandos), tais como constantes ou referências de células. Estes encontram-se separados por operadores de cálculo. O Excel calcula a fórmula da esquerda para a direita, de acordo com uma ordem específica para cada operador da fórmula.

  • Precedência de operadores em fórmulas do Excel

    Se combinar vários operadores numa única fórmula, o Excel executará as operações pela ordem apresentada na tabela que se segue. Se uma fórmula contiver operadores com a mesma precedência, por exemplo, se uma fórmula possuir um operador de multiplicação e outro de divisão, o Excel avaliará os operadores da esquerda para a direita.

    Operador

    Descrição

    : (dois pontos)

    (espaço simples)

    , (vírgula)

    Operadores de referência

    Negação (como –1)

    %

    Percentagem

    ^

    Potência

    * e /

    Multiplicação e divisão

    + e -

    Adição e subtração

    &

    Liga duas cadeias de texto (concatenação)

    =
    <>
    <=
    >=
    <>

    Comparação

  • Utilizar parênteses em fórmulas do Excel

    Para alterar a ordem de avaliação, escreva a parte da fórmula que pretende calcular primeiro entre parênteses. Por exemplo, a fórmula que se segue tem como resultado 11 porque o Excel efetua a multiplicação antes da adição. A fórmula multiplica 2 por 3 e, em seguida, adiciona 5 ao resultado.

    =5+2*3

    Por outro lado, se utilizar parênteses para alterar a sintaxe, o Excel adiciona 5 e 2 e depois multiplica o resultado por 3, obtendo 21.

    =(5+2)*3

    No exemplo que se segue, os parênteses colocados na primeira parte da fórmula forçam o Excel a calcular B4+25 em primeiro lugar e, em seguida, a dividir o resultado pela soma dos valores nas células D5, E5 e F5.

    =(B4+25)/SOMA(D5:F5)

    Início da Página

As funções são fórmulas predefinidas que efetuam cálculos através de valores específicos denominados argumentos, com uma determinada ordem ou estrutura. As funções podem ser utilizadas para efetuar cálculos simples ou complexos. Pode encontrar todas as funções do Excel no separador Fórmulas no Friso:

O separador Fórmulas do Excel no Friso
  • Sintaxe de funções do Excel

    O exemplo seguinte de uma função ARRED a arredondar um número na célula A10 ilustra a sintaxe de uma função.

    Estrutura de uma função

    1. Estrutura. A estrutura de uma função começa com um sinal de igual (=), seguido do nome da função, um parêntese de abertura, os argumentos da função separados por vírgulas e um parêntese de fecho.

    2. Nome da função. Para obter uma lista de funções disponíveis, clique numa célula e prima Shift+F3 de formar a abrir a caixa de diálogo Inserir Função.

    Fórmulas do Excel – caixa de diálogo Inserir Função

    3. Argumentos. Os argumentos podem ser números, texto, valores lógicos como VERDADEIRO ou FALSO, matrizes, valores de erro do tipo #N/D ou referências de célula. O argumento que indicar deve produzir um valor válido para esse argumento. Os argumentos também podem ser constantes, fórmulas ou outras funções.

    4. Descrição do argumento. É apresentada uma descrição com a sintaxe e os argumentos à medida que for escrevendo a função. Por exemplo, escreva =ARRED( para que a descrição seja apresentada. As descrições só são apresentadas para funções incorporadas.

    Nota : Não precisa de escrever as funções em maiúsculas, como =ARRED, uma vez que o Excel irá alterar automaticamente o nome da função para maiúsculas ao premir a tecla Enter. Se escrever incorretamente o nome de uma função, por exemplo =SUMA(A1:A10) em vez de =SOMA(A1:A10), o Excel irá devolver o erro #NOME?

  • Introduzir funções do Excel

    Quando cria uma fórmula que contém uma função, pode utilizar a caixa de diálogo Inserir Função para ajudá-lo a introduzir funções de folha de cálculo. Após selecionar uma função na caixa de diálogo Inserir Função, o Excel irá iniciar o assistente de funções, que apresenta o nome da função, cada um dos respetivos argumentos, uma descrição da função e de cada argumento, o resultado atual da função e o resultado atual de toda a fórmula.

    Assistente de Funções do Excel

    Para facilitar a criação e edição de fórmulas e reduzir a quantidade de erros de escrita e de sintaxe, utilize a Conclusão Automática de Fórmulas. Depois de escrever um = (sinal de igual) e as primeiras letras de uma função, o Excel apresenta uma lista pendente dinâmica de funções, argumentos e nomes válidos que correspondem a essas letras. Em seguida, pode selecionar uma das opções na lista pendente e o Excel irá introduzi-la automaticamente.

    Conclusão Automática de Fórmulas do Excel

  • Aninhar funções do Excel

    Em certos casos, poderá ter de utilizar uma função como um dos argumentos de outra função. Por exemplo, a fórmula que se segue utiliza uma função MÉDIA aninhada e compara o resultado com o valor 50.

    Funções aninhadas

    1. As funções MÉDIA e SOMA estão aninhadas na função SE.

    Devoluções válidas    Quando uma função aninhada é utilizada como um argumento, a função aninhada tem de devolver o mesmo tipo de valor utilizado pelo argumento. Por exemplo, se o argumento devolver um valor do tipo VERDADEIRO ou FALSO, a função aninhada terá de devolver um valor VERDADEIRO ou FALSO. Se a função não o fizer, o Excel apresentará um valor de erro #VALOR!.

    Aninhamento dos limites dos níveis    Uma fórmula pode conter até sete níveis de funções aninhadas. Quando uma função (que iremos designar por Função B) é utilizada como um argumento noutra função (a que iremos chamar Função A), a Função B atua como uma função de segundo nível. Por exemplo, a função MÉDIA e a função SOMA são ambas funções de segundo nível se forem utilizadas como argumentos da função SE. Uma função aninhada dentro da função MÉDIA aninhada seria uma função de terceiro nível e assim sucessivamente.

    Início da Página

Uma referência identifica uma célula ou um intervalo de células numa folha de cálculo, além de indicar ao Excel onde procurar os valores ou dados que pretende utilizar numa fórmula. Pode utilizar referências para utilizar os dados contidos em diferentes partes de uma folha de cálculo numa fórmula ou utilizar o valor de uma célula em várias fórmulas. Também pode fazer referência a células contidas noutras folhas do mesmo livro e a outros livros. Às referências a células contidas noutros livros dá-se o nome de ligações ou referências externas.

  • O estilo de referência A1

    Por predefinição, o Excel utiliza o estilo de referência A1, que se refere a colunas com letras (de A a XFD, num total de 16 384 colunas) e a linhas com números (de 1 até 1 048 576). Estas letras e números são denominados cabeçalhos de linha e coluna. Para fazer referência a uma célula, introduza a letra da coluna, seguida do número da linha. Por exemplo, B2 refere-se à célula na interseção da coluna B e da linha 2.

    Para fazer referência a

    Utilize

    A célula na coluna A e na linha 10

    A10

    O intervalo de células na coluna A e nas linhas de 10 a 20

    A10:A20

    O intervalo de células na linha 15 e nas colunas de B a E

    B15:E15

    Todas as células na linha 5

    5:5

    Todas as células nas linhas de 5 a 10

    5:10

    Todas as células na coluna H

    H:H

    Todas as células nas colunas de H a J

    H:J

    O intervalo de células nas colunas de A a E e nas linhas de 10 a 20

    A10:E20

  • Fazer referência a uma célula ou a um intervalo de células noutra folha de cálculo do mesmo livro

    No seguinte exemplo, a função MÉDIA calcula o valor médio do intervalo B1:B10 na folha de cálculo com o nome Marketing contida no mesmo livro.

    Exemplo de referência de folha

    1. Refere-se à folha de cálculo Marketing

    2. Refere-se ao intervalo de células de B1 a B10

    3. O ponto de exclamação (!) separa a referência à folha de cálculo da referência ao intervalo de células

    Nota : Se a folha de cálculo referida tiver espaços ou números, então terá de adicionar apóstrofos (') antes e depois do nome da folha de cálculo, por exemplo ='123'!A1 ou ='Receitas Janeiro'!A1.

  • Diferença entre referências absolutas, relativas e mistas

    1. Referências relativas    Uma referência de célula relativa numa fórmula, como, por exemplo, A1, com base na posição relativa da célula que contém a fórmula e da célula a que a referência se refere. Se a posição da célula que contém a fórmula for alterada, a referência será alterada. Se copiar ou preencher a fórmula para o lado nas linhas e para baixo nas colunas, a referência ajustar-se-á automaticamente. Por predefinição, as fórmulas novas utilizam referências relativas. Por exemplo, se copiar ou preencher uma referência relativa da célula B2 para a célula B3, esta ajustar-se-á automaticamente de =A1 para =A2.

      Fórmula copiada com referência relativa   

      Fórmula copiada com referência relativa

    2. Referências absolutas    Uma referência de célula absoluta numa fórmula como, por exemplo, $A$1, faz sempre referência a uma célula numa localização específica. Se a posição da célula que contém a fórmula for alterada, a referência absoluta permanecerá igual. Se copiar ou preencher a fórmula para o lado nas linhas e para baixo nas colunas, a referência absoluta não se ajustará. Por predefinição, as fórmulas novas utilizam referências relativas, pelo que poderá necessitar de as alterar para referências absolutas. Por exemplo, se copiar ou preencher uma referência absoluta da célula B2 para a célula B3, esta permanecerá igual em ambas as células: =$A$1.

      Fórmula copiada com referência absoluta   

      Fórmula copiada com referência absoluta
    3. Referências mistas    Uma referência mista tem uma coluna absoluta e uma linha relativa ou uma linha absoluta e uma coluna relativa. Uma referência de coluna absoluta fica com o formato $A1, $B1 e assim sucessivamente. Uma referência de linha absoluta fica com o formato A$1, B$1 e assim sucessivamente. Se a posição da célula que contém a fórmula for alterada, a referência relativa será alterada e a referência absoluta permanecerá. Se copiar ou preencher a fórmula para o lado nas linhas e para baixo nas colunas, a referência relativa ajustar-se-á automaticamente e a referência absoluta não se ajustará. Por exemplo, se copiar ou preencher uma referência mista da célula A2 para B3, esta ajustar-se-á de =A$1 para =B$1.

      Fórmula copiada com referência mista   

      Fórmula copiada com referência mista

  • Estilo de referência 3D

    Referir convenientemente múltiplas folhas de cálculo    Se pretender analisar dados contidos na mesma célula ou intervalo de células em várias folhas de cálculo de um livro, utilize uma referência 3D. Uma referência 3D inclui a referência da célula ou do intervalo, antecedida por um intervalo de nomes de folhas de cálculo. O Excel utiliza quaisquer folhas de cálculo guardadas entre os nomes iniciais e finais da referência. Por exemplo, =SOMA(Folha2:Folha13!B5) adiciona todos os valores contidos na célula B5 a todas as folhas de cálculo entre a Folha 2 e a Folha 13, inclusive.

    • Pode utilizar referências 3D para fazer referência a células noutras folhas de cálculo, para definir nomes e para criar fórmulas utilizando as seguintes funções: SOMA, MÉDIA, MÉDIAA, CONTAR, CONTAR.VAL, MÁXIMO, MÁXIMOA, MÍNIMO, MÍNIMOA, PRODUTO, DESVPAD.P, DESVPAD.S, DESVPADA, DESVPADPA, VAR.P, VAR.S, VARA e VARPA.

    • As referências 3D não podem ser utilizadas em fórmulas de matriz.

    • As referências 3D não podem ser utilizadas com o operador de interseção (um espaço) ou em fórmulas que utilizem interseção implícita.

    O que acontece quando move, copia, insere ou elimina folhas de cálculo    Os exemplos que se seguem explicam o que sucede quando move, copia, insere ou elimina folhas de cálculo que façam parte de uma referência 3D. Os exemplos utilizam a fórmula =SOMA(Folha2:Folha6!A2:A5) para adicionar as células A2 a A5 nas folhas de cálculo 2 a 6.

    • Inserir ou copiar    Se inserir ou copiar folhas entre a Folha2 e a Folha6 (os pontos opostos deste exemplo), o Excel incluirá nos cálculos todos os valores das células A2 a A5 das folhas adicionadas.

    • Eliminar     Se eliminar folhas entre a Folha2 e a Folha6, o Excel retirará os respetivos valores dos cálculos.

    • Mover    Se mover folhas entre a Folha2 e a Folha6 para outro local fora da referência do intervalo das folhas, o Excel removerá os respetivos valores dos cálculos.

    • Mover um extremo    Se mover a Folha2 ou a Folha6 para outro local no mesmo livro, o Excel ajustará os cálculos para acomodar o novo intervalo de folhas entre eles.

    • Eliminar um extremo    Se eliminar a Folha2 ou a Folha6, o Excel ajustará os cálculos para acomodar o intervalo de folhas entre eles.

  • O estilo de referência L1C1

    Também poderá utilizar um estilo de referência em que tanto as linhas como as colunas da folha de cálculo são numeradas. O estilo de referência L1C1 é útil para avaliar a posição das linhas e das colunas nas macros. No estilo L1C1, o Excel indica a localização de uma célula com um "L" seguido de um número de linha e um "C" seguido de um número de coluna.

    Referência

    Significado

    L[-2]C

    Uma referência relativa à célula duas linhas acima e na mesma coluna

    L[2]C[2]

    Uma referência relativa à célula duas linhas abaixo e duas colunas para a direita

    L2C2

    Uma referência absoluta à célula na segunda linha e na segunda coluna

    L[-1]

    Uma referência relativa à linha completa acima da célula ativa

    L

    Uma referência absoluta à linha atual

    Quando grava uma macro, o Excel grava alguns dos comandos utilizando o estilo de referência L1C1. Por exemplo, se gravar um comando, tal como clicar no botão Soma Automática para inserir uma fórmula que adiciona um intervalo de células, o Excel gravará a fórmula utilizando referências do estilo L1C1 e não do estilo A1.

    É possível ativar ou desativar o estilo de referência L1C1 selecionando ou desmarcando a caixa de verificação Estilo de referência L1C1 na secção Trabalhar com fórmulas na categoria Fórmulas da caixa de diálogo Opções. Para apresentar esta caixa de diálogo, clique no separador Ficheiro.

    Início da Página

Pode criar nomes definidos para representar células, intervalos de células, fórmulas, constantes ou tabelas do Excel. Um nome é uma abreviatura com significado que facilita a compreensão do objetivo de uma referência de célula, constante, fórmula ou tabela, já que cada uma poderá ser de difícil compreensão à primeira vista. As informações que se seguem mostram exemplos comuns de nomes e de como a sua utilização em fórmulas poderá melhorar a compreensão das mesmas.

Exemplo 1

Tipo de exemplo

Exemplo, utilizando intervalos em vez de nomes

Exemplo, utilizando nomes

Referência

=SOMA(A16:A20)

=SOMA(Vendas)

Constante

=PRODUTO(A12,9,5%)

=PRODUTO(Preço,TaxadeImposto)

Fórmula

=TEXTO(PROCV(MÁX(A16,A20),A16:B20,2,FALSO),"dd/mm/aaaa")

=TEXTO(PROCV(MÁX(Vendas),InfoVendas,2,FALSO),"dd/mm/aaaa")

Tabela

A22:B25

=PRODUTO(Preço,Tabela1[@Taxa do Imposto])

Exemplo 2

Copie os dados de exemplo que se encontram na seguinte tabela e cole-os na célula A1 de uma nova folha de cálculo do Excel. Para que as fórmulas mostrem os resultados, selecione-as, prima F2 e, em seguida, prima Enter. Caso seja necessário, pode ajustar as larguras das colunas para ver todos os dados.

Nota :  Nas fórmulas nas colunas C e D, o nome definido "Vendas" é substituído pela referência ao (intervalo) A9:A13 e o nome "InformaçõesDeVendas" é substituído pelo intervalo A9:B13. Se não criar estes nomes no seu livro de teste, as fórmulas no intervalo D2:D3 irão devolver o erro #NOME?

Tipo de exemplo

Exemplo, sem nome

Exemplo, com nome

Fórmula e resultado, com nome

Referência

'=SOMA(A9:A13)

'=SOMA(Vendas)

=SOMA(Vendas)

Fórmula

'=TEXTO(PROCV(MÁX(A9:13),A9:B13,2,FALSO),"dd-mm-aaaa")

'=TEXTO(PROCV(MÁX(Vendas),Informações de Vendas,2,FALSO),"dd-mm-aaaa")

=PROCV(MÁX(Vendas),Informações de Vendas,2,FALSO),"dd-mm-aaaa")

Preço

995 €

Vendas

Data da Venda

249 €

17/03/2011

399 €

02/04/2011

643 €

23/04/2011

275 €

30/04/2011

447 €

04/05/2011

  • Tipos de nomes

    Existem vários tipos de nomes que pode criar e utilizar.

    • Nome definido    Um nome que representa uma célula, intervalo de células, fórmula ou valor constante. Pode criar o seu próprio nome definido. Além disso, o Excel cria, por vezes, um nome definido automaticamente, como, por exemplo, quando define uma área de impressão.

    • Nome da tabela    Um nome para uma tabela do Excel, que consiste numa coleção de dados sobre um assunto específico armazenado em registos (linhas) e campos (colunas). O Excel cria um nome predefinido de tabela do Excel, "Tabela1", "Tabela2" e assim sucessivamente, sempre que insere uma tabela do Excel, mas poderá alterar estes nomes para lhe conferir um significado mais claro.

      Para obter mais informações sobre tabelas do Excel, consulte Utilizar referências estruturadas com tabelas do Excel.

  • Criar e introduzir nomes

    Pode criar nomes utilizando:

    • Caixa de nome na barra de fórmulas    É utilizada para criar um nome ao nível do livro para um intervalo selecionado.

    • Criar um nome a partir da seleção    Pode criar nomes facilmente a partir das etiquetas de linhas e colunas existentes, utilizando uma seleção de células na folha de cálculo.

    • Caixa de diálogo Novo Nome    Isto é mais adequado para quando pretende mais flexibilidade na criação de nomes, tal como a especificação de um âmbito ao nível da folha de cálculo local ou criação de um comentário do nome.

    Nota :  Por predefinição, os nomes utilizam referências de célula absolutas.

    Para escrever um nome, pode:

    • Escrever    Escrever o nome, por exemplo, como um argumento numa fórmula.

    • Utilizar a Conclusão Automática de Fórmulas    Utilizar a lista pendente Conclusão Automática de Fórmulas, na qual os nomes válidos são listados automaticamente.

    • Selecionar a partir do comando Utilizar na Fórmula    Selecionar um nome definido numa lista disponibilizada pelo comando Utilizar na Fórmula no grupo Nomes Definidos no separador Fórmula.

Para obter mais informações, consulte Definir e utilizar nomes em fórmulas.

Início da Página

Uma fórmula de matriz pode efetuar cálculos múltiplos e, em seguida, devolver um resultado único ou múltiplos resultados. As fórmulas de matriz atuam de acordo com dois ou mais conjuntos de valores conhecidos como argumentos de matriz. Cada argumento de matriz tem de ter o mesmo número de linhas e de colunas. As fórmulas de matriz são criadas do mesmo modo que se criam outras fórmulas, exceto que tem de premir Ctrl+Shift+Enter para introduzir a fórmula. Algumas das funções incorporadas são fórmulas de matriz e têm que ser introduzidas como matrizes para obter os resultados corretos.

As constantes de matriz podem ser utilizadas para substituir as referências quando não quiser introduzir cada valor da constante numa célula separada da folha de cálculo.

Utilizar uma fórmula de matriz para calcular resultados únicos ou múltiplos

Nota : Quando introduzir uma fórmula de matriz, o Excel insere automaticamente a fórmula entre { } (chavetas). Se tentar introduzir os parênteses manualmente, o Excel irá apresentar a fórmula como texto.

  • Fórmula de matriz que gera um único resultado    Este tipo de fórmula de matriz pode simplificar um modelo de folha de cálculo ao substituir várias fórmulas diferentes por uma única fórmula de matriz.

    Por exemplo, em seguida calcula-se o valor total de uma matriz de cotações de mercado e ações, sem utilizar uma linha de células para calcular e mostrar os valores individuais de cada ação.

    fórmula de matriz que gera um único resultado

    Quando introduz a fórmula ={SOMA(B2:D2*B3:D3)} como fórmula de matriz, multiplica as Ações e o Preço por cada ação e, em seguida, adiciona os resultados desse cálculo.

  • Fórmula de matriz que gera múltiplos resultados    Algumas funções da folha de cálculo devolvem matrizes de valores ou requerem uma matriz de valores como argumento. Para calcular múltiplos resultados com uma fórmula de matriz, terá de introduzir a matriz num intervalo de células que tenha o mesmo número de linhas e colunas que os argumentos da matriz.

    Por exemplo, para uma série de três valores de vendas (na coluna B) referente a uma série de três meses (na coluna A), a função TENDÊNCIA determina os valores lineares dos valores de vendas. Para apresentar todos os resultados da fórmula, tem de a introduzir em três células na coluna C (C1:C3).

    Fórmula de matriz que gera múltiplos resultados

    Quando introduz a fórmula =TENDÊNCIA(B1:B3;A1:A3) como fórmula de matriz, gera três resultados separados (22196, 17079 e 11962), com base em três valores de vendas e em três meses.

Utilizar constantes de matriz

Numa fórmula normal, pode introduzir uma referência a uma célula que contém um valor ou o valor propriamente dito, também designada por constante. Do mesmo modo, numa fórmula de matriz, pode introduzir uma referência a uma matriz ou introduzir a matriz de valores contida nas células, também denominada constante de matriz. As fórmulas de matriz aceitam constantes da mesma forma que as fórmulas sem matriz, mas tem de introduzir as constantes num determinado formato.

As constantes de matriz podem conter números, texto, valores lógicos como, por exemplo, VERDADEIRO ou FALSO ou valores de erro como #N/D. A mesma constante de matriz pode conter diferentes tipos de valores, por exemplo, {1,3,4;VERDADEIRO,FALSO,VERDADEIRO}. Os números nas constantes de matriz podem ser do tipo: número inteiro, decimal ou de formato científico. O texto tem de estar entre aspas, por exemplo, "Terça-feira".

As constantes de matriz não podem conter referências de células, colunas ou linhas com comprimentos diferentes, fórmulas ou carateres especiais $ (cifrão), parênteses ou % (símbolo de percentagem).

Ao formatar constantes de matriz, certifique-se de:

  • As incluir entre chavetas ( { } ).

  • Separar os valores em colunas diferentes por vírgulas (,). Por exemplo, para representar os valores 10, 20, 30 e 40, escreva {10,20,30,40}. Esta constante de matriz é conhecida como sendo uma matriz de 1 por 4 e equivale à referência de 1 linha por 4 colunas.

  • Separar os valores em linhas diferentes por ponto e vírgula (;). Por exemplo, para representar os valores 10, 20, 30 e 40 numa só linha e os valores 50, 60, 70 e 80 na linha imediatamente abaixo, teria de introduzir uma constante de matriz 2 por 4: {10,20,30,40;50,60,70,80}.

Início da Página

Quando elimina uma fórmula, os valores resultantes da mesma também são eliminados. No entanto, pode remover apenas a fórmula e manter o valor resultante da fórmula na célula.

  • Para eliminar fórmulas e os respetivos valores resultantes, faça o seguinte:

    1. Selecione a célula ou intervalo de células que contêm a fórmula.

    2. Prima Delete.

  • Para eliminar fórmulas sem remover os respetivos valores resultantes, faça o seguinte:

    1. Selecione a célula ou intervalo de células que contêm a fórmula.

      Se a fórmula for uma fórmula de matriz, selecione o intervalo de células que contém a fórmula de matriz.

      Como selecionar um intervalo de células que contém uma fórmula de matriz

      1. Clique numa célula na fórmula de matriz.

      2. No separador Base, no grupo Edição, clique em Localizar e Selecionar e, em seguida, clique em Ir Para.

      3. Clique em Especial.

      4. Clique em Matriz atual.

    2. No separador Base, no grupo Área de Transferência, clique em Copiar Imagem de botão .
      Imagem do Friso do Excel

      Atalho de teclado    Também pode premir Ctrl+C.

    3. No separador Base, no grupo Área de Transferência, clique na seta abaixo de Colar Imagem de botão e, em seguida, clique em Colar Valores.

Início da Página

A seguinte tabela resume alguns dos erros mais comuns que poderá cometer ao introduzir uma fórmula e como pode evitar erros de fórmulas:

Certifique-se de que…

Mais informações

Faz corresponder todos os parênteses iniciais e finais na fórmula   

Todos os parênteses pertencem a um par correspondente em fórmulas. Ao criar uma fórmula, o Excel apresenta os parênteses a cores à medida que são introduzidos.

Utiliza dois pontos para indicar os intervalos que introduzir na fórmula   

O sinal de dois pontos (:) é utilizado para separar a referência à primeira e à última célula do intervalo. Por exemplo, A1:A5.

Introduz todos os argumentos necessários    

As funções podem conter argumentos obrigatórios e opcionais (que são indicados entre parênteses retos na sintaxe). Devem ser introduzidos todos os argumentos obrigatórios. Certifique-se também de que não introduziu demasiados argumentos.

Não aninha mais do que 64 funções numa fórmula   

As funções de aninhamento numa fórmula estão limitadas a 64 níveis.

Inclui os nomes de livros ou de folhas de cálculo entre plicas    

Ao fazer referências a valores ou a células em outras folhas de cálculo ou livros que contêm carateres não alfabéticos nos respetivos nomes, estes têm de ser incluídos entre plicas ( ' ).

Inclui o caminho para livros externos    

As referências externas têm de conter o nome de um livro e o caminho para o mesmo.

Introduz números sem formatação    

Os números que introduzir numa fórmula não devem estar formatados com separadores decimais ou cifrões ($), uma vez que o ponto e vírgula já faz o papel de separador de argumento em fórmulas e os cifrões são utilizados para marcar referências absolutas. Por exemplo, em vez de introduzir $1000, introduza 1000 na fórmula.

Início da Página

Importante : Os resultados calculados de fórmulas e algumas funções de folha de cálculo do Excel poderão ser algo diferentes entre um PC com arquitetura de 86 bits ou de 86-64 bits e um PC com Windows RT com arquitetura ARM. Saiba mais sobre as diferenças.

Tem uma pergunta específica sobre funções?

Publicar uma pergunta no fórum da comunidade do Excel

Ajude-nos a melhorar o Excel

Tem alguma sugestão acerca de como podemos melhorar a próxima versão do Excel? Se tiver, consulte os tópicos no User Voice do Excel

Consulte também

Descrição geral de fórmulas no Excel

Como evitar fórmulas quebradas

Localizar e corrigir erros em fórmulas

Atalhos de teclado e teclas de função do Excel

Funções do Excel (por ordem alfabética)

Funções do Excel (por categoria)

Aumente os seus conhecimentos
Explore as formações
Seja o primeiro a obter novas funcionalidades
Adira ao Office Insider

As informações foram úteis?

Obrigado pelos seus comentários!

Obrigado pelo seu feedback! Parece que poderá ser benéfico reencaminhá-lo para um dos nossos agentes de suporte do Office.

×