Propriedade FileDialog

Aplicável a

Objeto Application

Retorna um objeto FileDialog que representa uma única instância de uma caixa de diálogo de arquivo.

expressão. FileDialog(dialogType)

expressão Obrigatória. Uma expressão que retorna um dos objetos na lista Aplica-se a.

dialogType    Obrigatório MsoFileDialogType. O tipo de caixa de diálogo do arquivo.

MsoFileDialogType pode ser uma dessas constantes de MsoFileDialogType.

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen Incompatível com o Microsoft Access.

msoFileDialogSaveAs Incompatível com o Microsoft Access.

Comentários

As constantes msoFileDialogOpen e msoFileDialogSaveAs não são compatíveis com o Microsoft Office Access 2007.

Exemplo

Este exemplo mostra como usar o objeto FileDialog para exibir uma caixa de diálogo que permite ao usuário escolher um ou mais arquivos. Os arquivos selecionados são adicionados a uma caixa de listagem chamada FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Expanda suas habilidades no Office
Explore o treinamento
Obtenha novos recursos primeiro
Ingressar no Office Insider

Essas informações foram úteis?

Obrigado por seus comentários!

Agradecemos pelos seus comentários! Parece que pode ser útil conectar você a um de nossos agentes de suporte do Office.

×