Função PROCV

Dica: Tente usar a nova função PROCV, uma versão aprimorada do PROCV que funciona em qualquer direção e retorna correspondências exatas por padrão, tornando-a mais fácil e conveniente de usar do que seu antecessor.

Utilize PROCV quando precisar encontrar itens em uma tabela ou um intervalo por linha. Por exemplo, procurar o preço de uma peça automotiva pelo número da peça ou encontrar o nome de um funcionário com base na ID do funcionário.

Em uma forma mais simples, a função PROCV descreve:

=PROCV(O que você deseja pesquisar, onde você deseja pesquisar, o número da coluna no intervalo que contém o valor a ser retornado, retorna uma correspondência Aproximada ou Exata – indicada como 1/TRUE ou 0/FALSE).

O navegador não dá suporte a vídeo. Instale o Microsoft Silverlight, o Adobe Flash Player ou o Internet Explorer 9.

Dica: O segredo do PROCV é organizar seus dados para que o valor que você procura (Fruta) fique à esquerda do valor de retorno (Quantidade) que você deseja localizar.

Use a função PROCV para pesquisar um valor em uma tabela.

Sintaxe

PROCV(valor_procurado; matriz_tabela; núm_índice_coluna; [intervalo_pesquisa])

Por exemplo:

=PROCV(A2,A10:C20,2,TRUE)
=PROCV("Monte";B2:E7;2;FALSO)
=PROCV(A2,’Client Details’!A:F,3,FALSE)

Nome do argumento	Descrição
valor_procurado (obrigatório)	O valor que você deseja procurar. O valor que você deseja pesquisar deve estar na primeira coluna do intervalo de células especificado no argumento *table_array. Por exemplo, se table-array* abrange as células B2:D7, então o seu lookup_value deve estar na coluna B. O *valor_procurado* pode ser um valor ou uma referência a uma célula.
matriz_tabela (obrigatório)	O intervalo de células em que PROCV procurará pelo *valor_procurado* e pelo valor de retorno. Você pode usar um intervalo nomeado ou uma tabela, e você pode utilizar nomes no argumento em vez de referências de célula. A primeira coluna no intervalo de células deve conter o *lookup_value*. O intervalo de células também precisa incluir o valor de retorno que você deseja localizar. Saiba como selecionar intervalos em uma planilha.
núm_índice_coluna (obrigatório)	O número da coluna (começando com 1 para a coluna mais à esquerda da *table_array*) que contém o valor de retorno.
intervalo_pesquisa (opcional)	Um valor lógico que especifica se você quer que a PROCV localize uma correspondência aproximada ou exata: Correspondência aproximada - 1/TRUE pressupõe que a primeira coluna da tabela seja classificada numericamente ou alfabeticamente, e então procurará o valor mais próximo. Esse será o método padrão, se você não especificar um. Por exemplo, =PROCV(90,A1:B100,2,TRUE). Correspondência exata - 0/FALSE pesquisa pelo valor exato na primeira coluna. Por exemplo, =PROCV("Smith",A1:B100,2,FALSE).

Introdução

Há quatro informações que serão necessárias para criar a sintaxe da função PROCV:

O valor que você deseja pesquisar, também chamado de valor de pesquisa.
O intervalo onde o valor de pesquisa está localizado. Lembre-se de que o valor de pesquisa deve estar sempre na primeira coluna no intervalo para que a função PROCV funcione corretamente. Por exemplo, se o valor de pesquisa estiver na célula C2, o intervalo deve começar com C.
O número da coluna no intervalo que contém o valor de retorno. Por exemplo, se você especificar B2:D11 como o intervalo, você deverá contar B como a primeira coluna, C como a segunda e assim por diante.
Se preferir, você pode especificar VERDADEIRO se quiser uma correspondência aproximada ou FALSO se quiser que uma correspondência exata do valor de retorno. Se você não especificar nada, o valor padrão será sempre VERDADEIRO ou correspondência aproximada.

Agora, reúna todos os itens acima da seguinte maneira:

=PROCV(valor da pesquisa, intervalo que contém o valor da pesquisa, o número da coluna no intervalo que contém o valor de retorno, Correspondência Aproximada (TRUE) ou Correspondência Exata (FALSE)).

Exemplos

Aqui estão alguns exemplos de PROCV:

Exemplo 1

=PROCV(B3,B2:E7,2,FALSE)

PROCV procura por Fontana na primeira coluna (coluna B) na table_array B2:E7, e retorna Olivier da segunda coluna (coluna C) da table_array. False retorna uma correspondência exata.

Exemplo 2

=PROCV(102,A2:C7,2,FALSE)

PROCV procura uma correspondência exata (FALSE) do sobrenome para 102 (lookup_value) na segunda coluna (coluna B) no intervalo A2:C7 e retorna Fontana.

Exemplo 3

=SE(PROCV(103,A1:E7,2,FALSE)="Sousa","Encontrado","Não encontrado")

SE verifica para ver se o PROCV retorna Sousa como o sobrenome do funcionário correspondente para (lookup_value) 103 na (table_array) A1:E7. Como o sobrenome correspondente a 103 é Leal, a condição SE é false e Não Encontrado será exibido.

Exemplo 4

=INT(FRACÇÃOANO(DATA(2014,6,30),PROCV(105,A2:E7,5,FALSE),1))

PROCV procura a data de nascimento do funcionário correspondente a (lookup_value) 109 no intervalo da (table_array) A2:E7, e retorna 04/03/1955. Em seguida, FRACÇÃOANO subtrai essa data de nascimento de 30/06/2014 e retorna um valor, que é então convertido por INY para o número inteiro 59.

Exemplo 5

SE(É.NÃO.DISP(PROCV(105,A2:E7,2,FALSE))=TRUE,"Funcionário não encontrado",PROCV(105,A2:E7,2,FALSE))

SE verifica se PROCV retorna um valor para o sobrenome a partir a coluna B para (lookup_value) 105. Se PROCV encontrar um sobrenome, então SE exibirá o sobrenome, caso contrário SE retornará Funcionário não encontrado. É.NÃO.DISP garante que, se o PROCV retornar #N/D, o erro será substituído pelo Funcionário não encontrado, em vez de #N/D.

Neste exemplo, o valor de retorno é Burke, que é o sobrenome correspondente a 105.

Você pode utilizar PROCV para combinar várias tabelas em uma, desde que uma das tabelas tenha campos em comum com todas as outras. Isso pode ser especialmente útil se você precisar compartilhar uma pasta de trabalho com pessoas que têm versões mais antigas do Excel que não suportam recursos de dados com várias tabelas como fontes de dados - combinando as fontes em uma tabela e alterando a fonte de dados do recurso de dados para a nova tabela, o recurso de dados pode ser usado em versões mais antigas do Excel (desde que o próprio recurso de dados seja suportado pela versão antiga).

Uma planilha com colunas que usam PROCV para obter dados de outras tabelas

Aqui, as colunas A-F e H têm valores ou fórmulas que usam apenas valores na planilha, e as demais colunas usam PROCV e os valores da coluna A (Código do Cliente) e da coluna B (Advogado) para obter dados de outras tabelas.

Copie a tabela que tem os campos comuns em uma nova planilha e dê um nome a ela.
Clique em Dados > Ferramentas de Dados > Relacionamentos para abrir a caixa de diálogo Gerenciar Relacionamentos.
Para cada relacionamento listado, observe o seguinte:
- O campo que vincula as tabelas (listado entre parênteses na caixa de diálogo). Este é o lookup_value da sua fórmula PROCV.
- O nome da Tabela de Pesquisa Relacionada. Esta é a table_array na sua fórmula PROCV.
- O campo (coluna) na Tabela de Pesquisa Relacionada que possui os dados desejados na sua nova coluna. Essas informações não são mostradas na caixa de diálogo Gerenciar Relacionamentos - você precisará examinar a Tabela de Pesquisa Relacionada para ver qual campo deseja recuperar. Você deseja anotar o número da coluna (A=1) - este é o col_index_num na sua fórmula.
Para adicionar um campo à nova tabela, insira sua fórmula PROCV na primeira coluna vazia utilizando as informações coletadas na etapa 3.

No nosso exemplo, a coluna G utiliza Advogado (o lookup_value) para obter os dados da Taxa de Cobrança da quarta coluna (col_index_num = 4) da tabela da planilha Advogados, tblAttorneys (a table_array), com a fórmula =PROCV([@Attorney],tbl_Attorneys,4,FALSE).

A fórmula também pode utilizar uma referência de célula e uma referência de intervalo. No nosso exemplo, seria =PROCV(A2,'Advogados'!A:D,4,FALSO).
Continue adicionando campos até que você tenha todos os campos necessários. Se você estiver tentando preparar uma pasta de trabalho contendo recursos de dados que utilizam várias tabelas, altere a fonte de dados do recurso de dados para a nova tabela.

Problema	O que deu errado
Valor errado retornado	Se *intervalo_pesquisa* for VERDADEIRO ou for omitido, a primeira coluna precisará ser classificada em ordem alfabética ou numericamente. Se a primeira coluna não for classificada, o valor retornado poderá ser algo inesperado. Classifique a primeira coluna ou use FALSO para ter uma correspondência exata.
#N/D na célula	Se *intervalo_pesquisa* for VERDADEIRO, então, se o valor em *valor_procurado* for menor que o menor valor na primeira coluna da *matriz_coluna, você receberá o valor de erro #N/D. Se o intervalo_pesquisa* for FALSO, o valor de erro #N/D indicará que o número exato não foi encontrado. Para saber mais sobre como resolver erros #N/D na PROCV, confira Como corrigir um erro #N/D na função PROCV.
#REF! na célula	Se *col_index_num* for maior que o número de colunas na *table-array*, você receberá o #REF! valor de erro. Para obter mais informações sobre como resolver o #REF! erros no PROCV, consulte Como corrigir um erro #REF!.
#VALOR! na célula	Se a *table_array* for menor que 1, você receberá o VALOR#! valor de erro. Para saber mais sobre como resolver erros #VALOR! na PROCV, confira Como corrigir um erro #VALOR! na função PROCV.
#NOME? na célula	O valor de erro #NOME? geralmente significa que faltam as aspas da fórmula. Para procurar o nome de uma pessoa, certifique-se de usar o nome entre aspas na fórmula. Por exemplo, insira o nome como "Monte" na =PROCV("Monte";B2:E7;2;FALSO). Para obter mais informações, confira Como corrigir um erro #NOME!.
Erros #DESPEJAR! na célula	Este erro #DESPEJAR! específico geralmente significa que sua fórmula está se baseando em uma interseção implícita para o valor de pesquisa e utilizando uma coluna inteira como referência. Por exemplo, =PROCV(A:A,A:C,2,FALSE). Você pode resolver o problema ancorando a referência de pesquisa com o operador @ assim: =PROCV(@A:A,A:C,2,FALSE). Alternativamente, você pode utilizar o método PROCV tradicional e se referir a uma única célula em vez de uma coluna inteira: =PROCV(A2,A:C,2,FALSE).

Faça isto	Por quê?
Use referências absolutas para intervalo_pesquisa	Usar referências absolutas permite o preenchimento de uma fórmula de forma que ela sempre veja o mesmo intervalo de pesquisa exato. Saiba como usar as referências absolutas da célula.
Não armazene valores numéricos ou de data como texto.	Ao procurar valores de número ou data, verifique se os dados na primeira coluna da *matriz_tabela* não estão armazenados como valores de texto. Do contrário, PROCV poderá retornar um valor incorreto ou inesperado.
Classifique a primeira coluna	Classifique a primeira coluna da *matriz_tabela* antes de usar PROCV quando o intervalo_procurado for VERDADEIRO.
Use caracteres curinga	Se *intervalo_procurado* for FALSO e o *valor_procurado* for texto, você poderá usar os caracteres curinga—ponto de interrogação (?) e asterisco ()— em valor_procurado. Um ponto de interrogação corresponde a qualquer caractere único. Um asterisco determina qualquer sequência de caracteres. Se você quiser localizar um ponto de interrogação ou asterisco real, digite um til (~) antes do caractere. Por exemplo, =PROCV("Fontan?",B2:E7,2,FALSE) pesquisará todas as instâncias do Fontana* com uma última letra que pode variar.
Verifique se seus dados não contêm caracteres equivocados.	Ao procurar valores de texto na primeira coluna, verifique se os dados na primeira coluna não contêm espaços à esquerda, à direita, usam de modo inconsistente as aspas retas ( ' ou " ) e as curvas ( ‘ ou “ ) ou têm caracteres não imprimíveis. Nesses casos, a função PROCV poderá retornar um valor inesperado. Para obter resultados precisos, tente usar a função LIMPAR ou a função APARAR para remover espaços à direita em uma célula depois dos valores da tabela.