Observação: A função, método, objeto ou propriedade descrita neste tópico será desabilitada se o Serviço de Expressão de Jato da Microsoft estiver em execução no modo de área restrita, o que impede a avaliação de expressões potencialmente inseguras. Para obter mais informações sobre o modo de área restrita, procure por "modo de área restrita" na Ajuda.
Retorna uma referência a um objeto fornecido por um componente ActiveX.
Sintaxe
GetObject([pathname ] [, classe ] )
A sintaxe da função GetObject tem esses argumentos:
|
Argumento |
Descrição |
|
Caminho |
Opcional. Variant (String). O caminho completo e o nome do arquivo que contém o objeto a ser recuperado. Se pathname for omitido, a classe será necessária. |
|
classe |
Opcional. Variant (String). Uma cadeia de caracteres que representa o classe do objeto. |
A classeargumento usa o nome do aplicativo de sintaxe.objecttype e tem estas partes:
|
Parte |
Descrição |
|
Appname |
Obrigatório. Variant (String). O nome do aplicativo que fornece o objeto. |
|
Objecttype |
Obrigatório. Variant (String). O tipo ou classe de objeto a ser criado. |
Comentários
Observação: Exemplos a seguir demonstram o uso dessa função em um módulo VBA (Visual Basic for Applications). Para obter mais informações sobre como trabalhar com o VBA, selecione Referência do Desenvolvedor na lista suspensa ao lado de Pesquisar e insira um ou mais termos na caixa de pesquisa.
Use a função GetObject para acessar um objeto ActiveX de um arquivo e atribuir o objeto a um variável de objeto. Use a instrução Set para atribuir o objeto retornado por GetObject à variável de objeto. Por exemplo:
Dim CADObject As Object
Set CADObject = GetObject("C:\CAD\SCHEMA.CAD")
Quando esse código é executado, o aplicativo associado ao nome de caminho especificado é iniciado e o objeto no arquivo especificado é ativado.
Se pathname for uma cadeia de caracteres de comprimento zero (""), GetObject retornará uma nova instância de objeto do tipo especificado. Se o argumento pathname for omitido, GetObject retornará um objeto ativo atualmente do tipo especificado. Se nenhum objeto do tipo especificado existir, ocorrerá um erro.
Alguns aplicativos permitem ativar parte de um arquivo. Adicione um ponto de exclamação (!) ao final do nome do arquivo e siga-o com uma cadeia de caracteres que identifica a parte do arquivo que você deseja ativar. Para obter informações sobre como criar essa cadeia de caracteres, consulte a documentação do aplicativo que criou o objeto.
Por exemplo, em um aplicativo de desenho, você pode ter várias camadas para um desenho armazenado em um arquivo. Você pode usar o código a seguir para ativar uma camada dentro de um desenho chamado SCHEMA.CAD:
Set LayerObject = GetObject("C:\CAD\SCHEMA.CAD!Layer3")
Se você não especificar a classe do objeto, a Automação determinará o aplicativo a ser iniciado e o objeto a ser ativado, com base no nome do arquivo fornecido. Alguns arquivos, no entanto, podem dar suporte a mais de uma classe de objeto. Por exemplo, um desenho pode dar suporte a três tipos diferentes de objetos: um objeto Application , um objeto Drawing e um objeto Toolbar , todos eles fazem parte do mesmo arquivo. Para especificar qual objeto em um arquivo você deseja ativar, use o argumento de classe opcional. Por exemplo:
Dim MyObject As Object
Set MyObject = GetObject("C:\DRAWINGS\SAMPLE.DRW", _
"FIGMENT.DRAWING")
No exemplo, FIGMENT é o nome de um aplicativo de desenho e DRAWING é um dos tipos de objeto que ele dá suporte.
Depois que um objeto é ativado, você o referencia em código usando a variável de objeto que você definiu. No exemplo anterior, você acessa propriedades e métodos do novo objeto usando a variável de objeto MyObject. Por exemplo:
MyObject.Line 9, 90
MyObject.InsertText 9, 100, "Hello, world."
MyObject.SaveAs "C:\DRAWINGS\SAMPLE.DRW"
Observação: Use a função GetObject quando houver uma instância atual do objeto ou se você quiser criar o objeto com um arquivo já carregado. Se não houver nenhuma instância atual e você não quiser que o objeto seja iniciado com um arquivo carregado, use a função CreateObject .
Se um objeto tiver se registrado como um objeto de instância única, apenas uma instância do objeto será criada, não importa quantas vezes CreateObject seja executado. Com um objeto de instância única, GetObject sempre retorna a mesma instância quando chamado com a sintaxe de cadeia de caracteres de comprimento zero ("") e causa um erro se o argumento pathname for omitido. Você não pode usar GetObject para obter uma referência a uma classe criada com o Visual Basic.
Exemplo
Este exemplo usa a função GetObject para obter uma referência a uma planilha de Microsoft Office Excel 2007 específica (MyXL). Ele usa a propriedade Application da planilha para tornar o Excel visível, para fechá-la e assim por diante. Usando duas chamadas de API, o procedimento DetectExcel Sub procura o Excel e, se estiver em execução, insira-o na Tabela de Objetos em Execução. A primeira chamada para GetObject causará um erro se o Microsoft Excel ainda não estiver em execução. No exemplo, o erro faz com que o sinalizador ExcelWasNotRunning seja definido como True. A segunda chamada para GetObject especifica um arquivo a ser aberto. Se o Excel ainda não estiver em execução, a segunda chamada iniciará-a e retornará uma referência à planilha representada pelo arquivo especificado, mytest.xls. O arquivo deve existir no local especificado; caso contrário, o erro de automação de erro do Visual Basic é gerado. Em seguida, o código de exemplo torna o Excel e a janela que contém a planilha especificada visível. Por fim, se não houver nenhuma versão anterior do Excel em execução, o código usará o método Quit do objeto Aplicativo para fechar o Excel. Se o aplicativo já estivesse em execução, nenhuma tentativa será feita para fechá-lo. A referência em si é lançada definindo-a como Nothing.
' Declare necessary API routines:
Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName as String, _
ByVal lpWindowName As Long) As Long
Declare Function SendMessage Lib "user32" Alias _
"SendMessageA" (ByVal hWnd as Long,ByVal wMsg as Long, _
ByVal wParam as Long, _
ByVal lParam As Long) As Long
Sub GetExcel()
Dim MyXL As Object ' Variable to hold reference
' to Microsoft Excel.
Dim ExcelWasNotRunning As Boolean ' Flag for final release.
' Test to see if there is a copy of Microsoft Excel already running.
On Error Resume Next ' Defer error trapping.
' GetObject function called without the first argument returns a
' reference to an instance of the application. If the application isn't
' running, an error occurs.
Set MyXL = GetObject(, "Excel.Application")
If Err.Number <> 0 Then ExcelWasNotRunning = True
Err.Clear ' Clear Err object in case error occurred.
' Check for Microsoft Excel. If Microsoft Excel is running,
' enter it into the Running Object table.
DetectExcel
' Set the object variable to reference the file you want to see.
Set MyXL = GetObject("c:\vb4\MYTEST.XLS")
' Show Microsoft Excel through its Application property. Then
' show the actual window containing the file using the Windows
' collection of the MyXL object reference.
MyXL.Application.Visible = True
MyXL.Parent.Windows(1).Visible = True
Do manipulations of your file here.
' ...
' If this copy of Microsoft Excel was not running when you
' started, close it using the Application property's Quit method.
' Note that when you try to quit Microsoft Excel, the
' title bar blinks and a message is displayed asking if you
' want to save any loaded files.
If ExcelWasNotRunning = True Then
MyXL.Application.Quit
End IF
Set MyXL = Nothing ' Release reference to the
' application and spreadsheet.
End Sub
Sub DetectExcel()
' Procedure dectects a running Excel and registers it.
Const WM_USER = 1024
Dim hWnd As Long
' If Excel is running this API call returns its handle.
hWnd = FindWindow("XLMAIN", 0)
If hWnd = 0 Then ' 0 means Excel not running.
Exit Sub
Else
' Excel is running so use the SendMessage API
' function to enter it in the Running Object Table.
SendMessage hWnd, WM_USER + 18, 0, 0
End If
End Sub
