Diretrizes e exemplos de fórmulas de matriz

Diretrizes e exemplos de fórmulas de matriz

Para se tornar um usuário avançado do Excel, você precisa saber como usar fórmulas de matriz, que podem fazer cálculos impossíveis de serem feitos com fórmulas que não sejam de matriz. O artigo a seguir baseia-se em uma série de colunas Excel Power User escritas por Colin Wilcox e adaptadas dos capítulos 14 e 15 do livro Excel 2002 Formulas, escrito por John Walkenbach, MVP do Excel.

Aprender sobre fórmulas de matriz

As fórmulas de matriz costumam ser chamadas de fórmulas CSE (Ctrl+Shift+Enter) porque, em vez de apenas pressionar Enter, você deve pressionar Ctrl+Shift+Enter para concluir a fórmula.

Por que usar fórmulas de matriz?

Se tiver experiência no uso de fórmulas do Excel, você saberá que pode executar algumas operações bastante sofisticadas. Por exemplo, é possível calcular o custo total de um empréstimo ao longo de um dado número de anos. As fórmulas de matriz podem ser usadas para executar tarefas complexas, como, por exemplo:

  • Contar o número de caracteres contidos em um intervalo de células.

  • Somar apenas números que atendam a certas condições, como os valores mais baixos de um intervalo ou números que estejam entre um limite superior e inferior.

  • Somar todo n-ésimo valor em um intervalo de valores.

Rápida introdução a matrizes e fórmulas de matriz

Uma fórmula de matriz é aquela capaz de executar vários cálculos em um ou mais itens de uma matriz. Você pode considerar uma matriz como uma linha de valores, uma coluna de valores ou uma combinação de linhas e colunas de valores. As fórmulas de matriz podem retornar vários resultados ou um único resultado. Por exemplo, você pode criar uma fórmula de matriz em um intervalo de células e usá-la para calcular uma coluna ou linha de subtotais. Também pode colocar uma fórmula de matriz em uma única célula e calcular um único valor. As fórmulas de matriz que contêm várias células são denominadas fórmulas de várias células, enquanto as que contêm uma única célula são denominadas fórmulas de célula única.

Os exemplos da próxima seção mostram como criar fórmulas de matriz de várias células e de uma célula.

Experimente!

Este exercício mostra como usar fórmulas de matriz de várias células e de uma célula para calcular um conjunto de estatísticas de vendas. O primeiro conjunto de etapas usa uma fórmula de várias células para calcular um conjunto de subtotais. O segundo conjunto usa uma fórmula de uma célula para calcular um total geral.

Fórmula de matriz de várias células

Esta é uma pasta de trabalho inserida no navegador. Embora ela contenha dados de exemplo, não é possível criar nem alterar fórmulas de matriz em uma pasta de trabalho inserida; para isso, é necessário o programa Excel. Você pode ver as respostas na pasta de trabalho inserida e um texto que explica como funciona a fórmula de matriz. No entanto, para aproveitar realmente essas fórmulas, você precisará ver a pasta de trabalho no Excel.

Criar uma fórmula de matriz de várias células

  1. Copie toda a tabela abaixo e cole-a na célula A1 de uma planilha em branco no Excel.

    Vendedor

    Tipo de
    carro

    Número de
    vendas

    Preço
    unitário

    Total
    de vendas

    Oliveira

    Sedã

    5

    33000

    Cupê

    4

    37000

    Ingle

    Sedã

    6

    24000

    Cupê

    8

    21000

    Jordan

    Sedã

    3

    29000

    Cupê

    1

    31000

    Gonçalo

    Sedã

    9

    24000

    Cupê

    5

    37000

    Sanchez

    Sedã

    6

    33000

    Cupê

    8

    31000

    Total Geral

    Total Geral

    '=SOMA(C2:C11*D2:D11)

    =SOMA(C2:C11*D2:D11)

  2. Para ver o Total de Vendas de cupês e sedãs para cada vendedor, selecione E2:E11, insira a fórmula =C2:C11*D2:D11 e depois pressione Ctrl+Shift+Enter.

  3. Para ver o Total Geral de todas as vendas, selecione a célula F11, insira a fórmula =SOMA(C2:C11*D2:D11) e depois pressione Ctrl+Shift+Enter.

Para baixar a pasta de trabalho, clique no botão verde do Excel na barra preta na parte inferior da pasta de trabalho. Em seguida, você poderá abrir o arquivo no Excel, selecionar as células que contêm as fórmulas de matriz e pressionar Ctrl+Shift+Enter para executar a fórmula.

Se estiver trabalhando no Excel, verifique se a Planilha1 está ativa e depois selecione as células E2:E11. Pressione F2 e digite a fórmula =C2:C11*D2:D11 na célula atual E2. Se você pressionar Enter, a fórmula será inserida apenas na célula E2 e o valor 165000 será exibido. Após digitar a fórmula, em vez de pressionar apenas Enter, pressione Ctrl+Shift+Enter. Agora, você verá os resultados nas células E2:E11. Repare que na barra de fórmulas, a fórmula aparece como {=C2:C11*D2:D11}, o que indica que ela é uma fórmula de matriz, como mostra a tabela a seguir.

Quando você pressiona Ctrl+Shift+Enter, o Excel coloca a fórmula entre chaves ({ }) e insere uma instância da fórmula em cada célula do intervalo selecionado. Como isso acontece muito rápido, o que você vê na coluna E é o valor total das vendas de cada tipo de carro para cada vendedor. Se você selecionar E2, depois selecionar E3, E4 e assim por diante, a mesma fórmula será mostrada: {=C2:C11*D2:D11}

Os totais da coluna E são calculados por uma fórmula de matriz

Criar uma fórmula de matriz de uma célula

Na célula F10 da pasta de trabalho, digite a fórmula a seguir e pressione Ctrl+Shift+Enter:

=SOMA(C2:C11*D2:D11)

Neste caso, o Excel multiplica os valores da matriz (o intervalo de células C2 a D11) e usa a função SOMA para somar os totais. O resultado é um total geral de R$ 1.590.000,00 em vendas. Esse exemplo mostra como esse tipo de fórmula pode ser eficiente. Por exemplo, vamos supor que você tenha 1.000 linhas de dados. Você pode somar esses dados no todo ou em parte, criando uma fórmula de matriz em uma única célula, em vez de arrastar a fórmula pelas 1.000 linhas.

Além disso, observe que a fórmula de célula única (G11) é totalmente independente da fórmula de várias células (E2 a E11). Esta é outra vantagem de usar fórmulas de matriz : a flexibilidade. Você pode alterar as fórmulas na coluna E ou excluir toda essa coluna, sem afetar a fórmula contida na célula G11.

As fórmulas de matriz também oferecem estas vantagens:

  • Consistência    Se clicar em qualquer das células de E2 para baixo, você verá a mesma fórmula. Essa consistência pode ajudar a garantir mais precisão.

  • Segurança    Não é possível substituir um componente de uma fórmula de matriz de várias células. Por exemplo, clique na célula E3 e pressione Delete. Você precisará selecionar o intervalo de células inteiro (E2 a E11) e alterar a fórmula da matriz inteira ou então deixar a matriz como está. Como uma medida de segurança a mais, pressione Ctrl+Shift+Enter para confirmar a alteração na fórmula.

  • Arquivos menores    Você pode usar uma única fórmula de matriz em vez de várias fórmulas intermediárias. Por exemplo, a pasta de trabalho usa uma fórmula de matriz para calcular os resultados na coluna E. Se tivesse usado fórmulas padrão (como =C2*D2, C3*D3, C4*D4…), você teria usado 11 fórmulas diferentes para calcular os mesmos resultados.

Sintaxe da fórmula de matriz

Em geral, as fórmulas de matriz usam a sintaxe padrão de fórmulas. Todas elas começam com um sinal de igual (=), e a maioria das funções internas do Excel pode ser usada nessas fórmulas. A principal diferença é que, quando se usa uma fórmula de matriz, é necessário pressionar Ctrl+Shift+Enter para inserir a fórmula. Quando você faz isso, o Excel coloca a fórmula de matriz entre chaves — se você digitar as chaves manualmente, a fórmula será convertida em uma cadeia de texto e não funcionará.

As funções de matriz são uma forma realmente eficiente de criar uma fórmula complexa. A fórmula de matriz =SOMA(C2:C11*D2:D11) é igual a esta: =SOMA(C2*D2,C3*D3,C4*D4,C5*D5,C6*D6,C7*D7,C8*D8,C9*D9,C10*D10,C11*D11).

Inserir e alterar fórmulas de matriz

Importante    Pressione Ctrl+Shift+Enter sempre que precisar inserir ou editar uma fórmula de matriz. Isso se aplica tanto a fórmulas de célula única como de várias células.

Sempre que trabalhar com fórmulas de várias células, também lembre-se do seguinte:

  • Selecione o intervalo de células que receberá os resultados antes de inserir a fórmula. Você fez isso quando criou a fórmula de várias células selecionando as células E2 a E11.

  • Não é possível alterar o conteúdo de uma célula individual em uma fórmula de matriz. Para testar isso, selecione a célula E3 na pasta de trabalho e pressione Delete. O Excel exibirá uma mensagem informando que não é possível alterar parte de uma matriz.

  • Você pode mover ou excluir uma fórmula de matriz inteira, mas não pode mover nem excluir parte dela. Em outras palavras, para reduzir uma fórmula de matriz, primeiro exclua a fórmula existente e depois comece do zero.

  • Para excluir uma fórmula de matriz, selecione a fórmula inteira (por exemplo, =C2:C11*D2:D11), pressione Delete e, em seguida, pressione Ctrl+Shift+Enter.

  • Não é possível inserir células em branco ou excluir células de uma fórmula de matriz de várias células.

Expandindo uma fórmula de matriz

Às vezes, poderá ser necessário expandir uma fórmula de matriz. O processo não é complicado, mas você deverá seguir as diretrizes fornecidas anteriormente.

Nesta planilha, adicionamos mais algumas linhas de vendas (linhas 12 a 17). Aqui, queremos atualizar as fórmulas de matriz para que incluam essas linhas adicionais.

Certifique-se de fazer isso no programa desktop do Excel (depois de ter baixado a pasta de trabalho para o seu computador).

Expandir uma fórmula de matriz

  1. Copie essa tabela inteira para a célula A1 em uma planilha do Excel.

    Vendedor

    Tipo de
    carro

    Número de
    vendas

    Preço
    unitário

    Total
    de vendas

    Oliveira

    Sedã

    5

    33000

    165000

    Cupê

    4

    37000

    148000

    Ingle

    Sedã

    6

    24000

    144000

    Cupê

    8

    21000

    168000

    Jordan

    Sedã

    3

    29000

    87000

    Cupê

    1

    31000

    31000

    Gonçalo

    Sedã

    9

    24000

    216000

    Cupê

    5

    37000

    185000

    Sanchez

    Sedã

    6

    33000

    198000

    Cupê

    8

    31000

    248000

    Toth

    Sedã

    2

    27000

    Cupê

    3

    30000

    Wang

    Sedã

    4

    22000

    Cupê

    1

    41000

    Young

    Sedã

    5

    32000

    Cupê

    3

    36000

    Total Geral

  2. Selecione a célula E18, insira a fórmula de Total Geral = SOMA(C2:C17*D2:D17) na célula A20 e pressione Ctrl+Shift+Enter.
    A resposta deverá ser 2.131.000.

  3. Selecione o intervalo de células que contém a fórmula de matriz atual (E2:E11), mais as células vazias (E12:E17) que vêm em seguida aos novos dados. Em outras palavras, selecione as células E2:E17.

  4. Pressione F2 para alternar para o modo de edição.

  5. Na barra de fórmulas, altere C11 para C17, altere D11 para D17 e pressione Ctrl+Shift+Enter.
    O Excel atualizará a fórmula nas células E2 a E11 e colocará uma instância da fórmula nas novas células, E12 a E17.

  6. Digite a fórmula de matriz = SOMA(C2:C17*D2*D17) na célula F17 para que faça referência às células da linha 2 à 17 e pressione Ctrl+Shift+Enter para inserir a fórmula.
    O novo total geral deverá ser 2.131.000.

Desvantagens de usar fórmulas de matriz

As fórmulas de matriz são excelentes, mas também têm algumas desvantagens:

  • Pode acontecer de você se esquecer de pressionar Ctrl+Shift+Enter. Isso pode acontecer com os usuários mais experientes do Excel. Lembre-se de pressionar essa combinação de teclas sempre que inserir ou editar uma fórmula de matriz.

  • É possível que outros usuários da pasta de trabalho não entendam suas fórmulas. Na prática, normalmente as fórmulas de matriz não são explicadas em uma planilha. Portanto, se outros usuários precisarem modificar suas pastas de trabalho, evite usar fórmulas de matriz ou verifique se esses usuários conhecem esse tipo de fórmula e saberão como alterá-las, caso seja necessário.

  • Dependendo da velocidade de processamento e da memória do computador, fórmulas de matriz grandes podem reduzir a velocidade dos cálculos.

Início da Página

Aprender sobre constantes de matriz

As constantes de matriz são um componente das fórmulas de matriz. Para criar essas constantes, insira uma lista de itens e coloque-a entre chaves ({ }) manualmente, da seguinte maneira:

={1,2,3,4,5}

Agora você já sabe que precisa pressionar Ctrl+Shift+Enter ao criar fórmulas de matriz. Como as constantes de matriz são um componente dessas fórmulas, coloque as constantes entre chaves manualmente digitando-as. Em seguida, use Ctrl+Shift+Enter para inserir a fórmula inteira.

Se você separar os itens com vírgulas, será criada uma matriz horizontal (uma linha). Se você separar os itens com ponto-e-vírgulas, será criada uma matriz vertical (uma coluna). Para criar uma matriz bidimensional, delimite os itens em cada linha usando vírgulas e delimite cada linha usando ponto-e-vírgulas.

Esta é uma matriz em uma única linha: {1,2,3,4}. Está é uma matriz em uma única coluna: {1;2;3;4}. E esta é uma matriz de duas linhas e quatro colunas: {1,2,3,4;5,6,7,8}. Na matriz de duas linhas, a primeira linha é 1, 2, 3 e 4, e a segunda é 5, 6, 7 e 8. Um ponto-e-vírgula separa as duas linhas, entre 4 e 5.

Como nas fórmulas de matriz, você pode usar constantes de matriz com a maioria das funções internas do Excel. As seções a seguir explicam como criar cada tipo de constante e como usá-las com funções no Excel.

Início da Página

Criar constantes unidimensionais e bidimensionais

Os procedimentos a seguir oferecem alguma prática na criação de constantes horizontais, verticais e bidimensionais.

Criar uma constante horizontal

  1. Use a pasta de trabalho dos exemplos anteriores ou crie uma nova pasta de trabalho.

  2. Selecione as células A1 a E1.

  3. Na barra de fórmulas, insira a seguinte fórmula e pressione Ctrl+Shift+Enter:

    ={1,2,3,4,5}

    Neste caso, você deve digitar as chaves de abertura e fechamento ({ }).

    O seguinte resultado será exibido:

    Constante de matriz horizontal em uma fórmula de matriz

Criar uma constante vertical

  1. Na pasta de trabalho, selecione uma coluna de cinco células.

  2. Insira a seguinte fórmula na barra de fórmulas e pressione Ctrl+Shift+Enter:

    ={1;2;3;4;5}

    O seguinte resultado será exibido:

    Constante de matriz vertical em uma fórmula de matriz

Criar uma constante bidimensional

  1. Na pasta de trabalho, selecione um bloco de células de quatro colunas de largura e três linhas de altura.

  2. Na barra de fórmulas, insira a seguinte fórmula e pressione Ctrl+Shift+Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}

    O seguinte resultado será exibido:

    Constante de matriz bidimensional em uma fórmula de matriz

Usar constantes em fórmulas

Este é um exemplo simples que usa constantes:

  1. Na pasta de trabalho de exemplo, crie uma nova planilha.

  2. Na célula A1, digite 3 e depois digite 4 em B1, 5 em C1, 6 em D1 e 7 em E1.

  3. Na célula A3, digite a seguinte fórmula e pressione Ctrl+Shift+Enter:

    =SOMA(A1:E1*{1,2,3,4,5})

    Observe que o Excel colocará a constante entre um segundo par de chaves, porque você a digitou como uma fórmula de matriz.

    Fórmula de matriz com constante de matriz

    O valor 85 será exibido na célula A3.

A próxima seção explica como a fórmula funciona.

Sintaxe da constante de matriz

A fórmula que você acabou de usar contém várias partes.

Sintaxe de fórmula de matriz com constante de matriz

1. Função

2. Matriz armazenada

3. Operador

4. Constante de matriz

O último elemento dentro dos parênteses é a constante de matriz: {1,2,3,4,5}. Lembre-se de que o Excel não coloca as constantes de matriz entre chaves; você deve digitá-las. Lembre-se também de que, após adicionar uma constante a uma fórmula de matriz, você pressiona Ctrl+Shift+Enter para inserir a fórmula.

Como o Excel executa as operações das expressões entre parênteses primeiro, os próximos dois elementos a serem processados são os valores armazenados na pasta de trabalho (A1:E1) e o operador. Neste ponto, a fórmula multiplica os valores da matriz armazenada pelos valores correspondentes da constante. Isso equivale a:

=SOMA(A1*1,B1*2,C1*3,D1*4,E1*5)

Por fim, a função SOMA somará os valores, e o resultado 85 será exibido na célula A3.

Para evitar usar a matriz armazenada e manter a operação inteiramente na memória, substitua a matriz armazenada por outra constante de matriz:

=SOMA({3,4,5,6,7}*{1,2,3,4,5})

Para testar isso, copie a função, selecione uma célula em branco na pasta de trabalho, cole a fórmula na barra de fórmulas e pressione Ctrl+Shift+Enter. Você verá o mesmo resultado do exercício anterior que usou a fórmula de matriz:

=SOMA(A1:E1*{1,2,3,4,5})

Elementos que podem ser usados em constantes

As constantes de matriz podem conter números, texto, valores lógicos (como VERDADEIRO e FALSO) e valores de erro (como #N/D). Você pode usar números nos formatos inteiro, decimal e científico. Se você incluir texto, será necessário colocá-lo entre aspas (").

As constantes de matriz não podem conter outras matrizes, fórmulas ou funções. Em outras palavras, elas só podem conter texto ou números separados por vírgula ou ponto-e-vírgula. O Excel exibirá uma mensagem de aviso quando você inserir uma fórmula como {1,2,A1:D4} ou {1,2,SOMA(Q2:Z8)}. Além disso, valores numéricos não podem conter sinais de percentual, cifrões, vírgulas ou parênteses.

Nomeando constantes de matriz

O melhor modo de usar constantes de matriz é nomeá-las. As constantes nomeadas podem ser mais fáceis de usar e ocultam um pouco da complexidade das fórmulas de matriz. Para nomear uma constante de matriz e usá-la em uma fórmula, siga este procedimento:

  1. Na guia Fórmulas, no grupo Nomes Definidos, clique em Definir Nome.
    A caixa de diálogo Definir Nome será exibida.

  2. Na caixa Nome, digiteTrimestre1.

  3. Na caixa Refere-se a, insira a seguinte constante (lembre-se de digitar as chaves manualmente):

    ={"Janeiro","Fevereiro","Março"}

    O conteúdo da caixa de diálogo agora tem esta aparência:

    Caixa de diálogo Editar Nome com fórmula

  4. Clique em OK e selecione uma linha de três células em branco.

  5. Digite a seguinte fórmula e pressione Ctrl+Shift+Enter:

    =Trimestre1

    O seguinte resultado será exibido:

    Constante de matriz nomeada inserida como fórmula

Quando você usar uma constante nomeada como uma fórmula de matriz, lembre-se de digitar o sinal de igual. Caso contrário, o Excel interpretará a matriz como uma cadeia de texto, e a fórmula não funcionará conforme esperado. Por fim, lembre-se de que você pode usar combinações de texto e números.

Solução de problemas de constantes de matriz

Procure os seguintes problemas quando suas constantes de matriz não funcionarem:

  • Talvez alguns elementos não estejam separados pelo caractere correto. Se vírgulas ou pontos-e-vírgulas forem omitidos ou colocados no lugar errado, a constante de matriz poderá não ser criada corretamente ou uma mensagem de aviso poderá ser exibida.

  • Talvez você tenha selecionado um intervalo de células que não corresponda ao número de elementos da constante. Por exemplo, se você selecionar uma coluna de seis células para ser usada com uma constante de cinco células, o valor de erro #N/D será exibido na célula vazia. De maneira inversa, se você selecionar células de menos, o Excel omitirá os valores que não tiverem uma célula correspondente.

Constantes de matriz em ação

Os exemplos a seguir demonstram algumas das formas pelas quais você pode colocar constantes de matriz para utilização em fórmulas de matriz. Alguns dos exemplos usam a função TRANSPOR para converter linhas em colunas e vice-versa.

Multiplicar cada item de uma matriz

  1. Crie uma nova planilha e depois selecione um bloco de células vazias com quatro colunas de largura e três linhas de altura.

  2. Digite a seguinte fórmula e pressione Ctrl+Shift+Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}*2

Elevar os itens de uma matriz ao quadrado

  1. Selecione um bloco de células vazias com quatro colunas de largura e três linhas de altura.

  2. Digite a seguinte fórmula de matriz e pressione Ctrl+Shift+Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}*{1,2,3,4;5,6,7,8;9,10,11,12}

    Como alternativa, digite esta fórmula de matriz, que utiliza o operador circunflexo (^):

    ={1,2,3,4;5,6,7,8;9,10,11,12}^2

Transpor uma linha unidimensional

  1. Selecione uma coluna de cinco células em branco.

  2. Digite a seguinte fórmula e pressione Ctrl+Shift+Enter:

    =TRANSPOR({1,2,3,4,5})

Embora você tenha inserido uma constante de matriz horizontal, a função TRANSPOR converterá a constante em uma coluna.

Transpor uma coluna unidimensional

  1. Selecione uma linha de cinco células em branco.

  2. Insira a seguinte fórmula e pressione Ctrl+Shift+Enter:

    =TRANSPOR({1;2;3;4;5})

Embora você tenha inserido uma constante de matriz vertical, a função TRANSPOR converterá a constante em uma linha.

Transpor uma constante bidimensional

  1. Selecione um bloco de células com três colunas de largura e quatro linhas de altura.

  2. Insira a seguinte constante e pressione Ctrl+Shift+Enter:

    =TRANSPOR({1,2,3,4;5,6,7,8;9,10,11,12})

A função TRANSPOR converterá cada linha em uma série de colunas.

Início da Página

Colocar fórmulas de matriz básicas para funcionar

Esta seção contém exemplos de fórmulas de matriz básicas.

Criar matrizes e constantes de matriz com base em valores existentes

O exemplo a seguir explica como usar fórmulas de matriz para criar vínculos entre intervalos de células em planilhas diferentes. Também mostra como criar uma constante de matriz com base no mesmo conjunto de valores.

Criar uma matriz com base em valores existentes

  1. Em uma planilha no Excel, selecione as células C8:E10 e insira esta fórmula:

    ={10,20,30;40,50,60;70,80,90}

    Não deixe de digitar { (chave de abertura) antes de digitar 10 e } (chave de fechamento) depois de digitar 90, pois você está criando uma matriz de números.

  2. Pressione Ctrl+Shift+Enter, o que insere essa matriz de números no intervalo de células C8:E10 usando uma fórmula de matriz.
    Em sua planilha, C8 a E10 deve ter a seguinte aparência:

    10

    20

    30

    40

    50

    60

    70

    80

    90

  3. Selecione o intervalo de células C1 a E3.

  4. Insira a seguinte fórmula na barra de fórmulas e pressione Ctrl+Shift+Enter:

    =C8:E10

    Uma matriz 3x3 de células aparece nas células C1 a E3. com os mesmos valores que você viu em C8 a E10.

Criar uma constante de matriz com base em valores existentes

  1. Com as células C1:C3 selecionadas, pressione F2 para alternar para o modo de edição.
    A fórmula de matriz ainda deve ser = C8:E10.

  2. Pressione F9 para converter as referências de célula em valores. O Excel converterá os valores em uma constante de matriz. A fórmula agora deve ser ={10,20,30;40,50,60;70,80,90}, como C8:E10.

  3. Pressione Ctrl+Shift+Enter para inserir a constante de matriz como uma fórmula de matriz.

Contar caracteres em um intervalo de células

O exemplo a seguir mostra como contar o número de caracteres, inclusive espaços, em um intervalo de células.

  1. Copie esta tabela inteira e cole-a em na célula A1 de uma planilha.

  2. Selecione a célula A9 e pressione Ctrl+Shift+Enter para ver o número total de caracteres em células A2:A6 (66).

  3. Selecione a célula A12 e pressione Ctrl+Shift+Enter para ver a maior célula em A2:A6 (célula A3).

Dados

Isto é um

monte de células que

se juntam

para formar uma

única sentença.

Total de caracteres em A2:A6

=SOMA(NÚM.CARACT(A2:A6))

Conteúdo da maior célula (A3)

=ÍNDICE(A6:A9,CORRESP(MÁX(NÚM.CARACT(A6:A9)),NÚM.CARACT(A6:A9),0),1)

A seguinte fórmula usada na célula A9 conta o número total de caracteres (66) nas células A2 a A6.

=SOMA(NÚM.CARACT(A2:A6))

Neste caso, a função NÚM.CARACT retornará o comprimento de cada cadeia de texto em cada uma das células do intervalo. Em seguida, a função SOMA somará esses valores e exibirá o resultado (66) na célula que contém a fórmula, A9.

Localizar os n menores valores de um intervalo

Este exemplo mostra como localizar os três menores valores de um intervalo de células.

  1. Selecione as células A16 a A18.
    Esse conjunto de células conterá os resultados retornados pela fórmula de matriz.

  2. Insira a seguinte fórmula na barra de fórmulas e pressione Ctrl+Shift+Enter:

    =MENOR(A5:A14,{1;2;3})

Os valores 400, 475 e 500 são exibidos nas células A16 a A18, respectivamente.

Essa fórmula usa uma constante de matriz para avaliar a função MENOR três vezes e retornar o menor (1), o segundo menor (2) e o terceiro menor (3) membro da matriz contido nas células A1:A10. Para localizar mais valores, adicione mais argumentos à constante e um número equivalente de células de resultado ao intervalo A12:A14. Você também pode usar funções adicionais com essa fórmula, como SOMA ou MÉDIA. Por exemplo:

=SOMA(MENOR(A 5 :A1 4 ,{1;2;3}))

=MÉDIA(MENOR(A 5 :A1 4 ,{1;2;3}))

Localizar os n maiores valores de um intervalo

Para localizar os maiores valores de um intervalo, você pode substituir a função MENOR pela função MAIOR. Além disso, o exemplo a seguir usa as funções LINHA e INDIRETO.

  1. Selecione as células A1 a A3.

  2. Insira a seguinte fórmula na barra de fórmulas e pressione Ctrl+Shift+Enter:

    =MAIOR(A5:A14,LINHA(INDIRETO("1:3")))

Os valores 3200, 2700 e 2000 são exibidos nas células A1 a A3, respectivamente.

Neste ponto, pode ser útil saber um pouco sobre as funções LINHA e INDIRETO. Você pode usar a função LINHA para criar uma matriz de números inteiros consecutivos. Por exemplo, selecione uma coluna vazia de 10 células na pasta de trabalho do exercício, insira esta fórmula de matriz nas células A5:A14 e pressione Ctrl+Shift+Enter:

=LINHA(1:10)

A fórmula cria uma coluna de 10 inteiros consecutivos. Para ver um possível problema, insira uma linha acima do intervalo que contém a fórmula de matriz (ou seja, acima da linha 1). O Excel ajustará as referências de linha e a fórmula irá gerar inteiros de 2 a 11. Para corrigir esse problema, adicione a função INDIRETO à fórmula:

=LINHA(INDIRETO("1:10"))

A função INDIRETO usa cadeias de texto como argumentos (é por isso que o intervalo 1:10 é colocado entre aspas duplas). O Excel não ajusta valores de texto quando você insere linhas ou move a fórmula de matriz de alguma outra maneira. Como resultado, a função LINHA sempre gera a matriz de inteiros desejada.

Vamos examinar a fórmula que você usou anteriormente — =MAIOR(A5:A14,LINHA(INDIRETO("1:3"))) — começando dos parênteses internos para os externos: a função INDIRETO retorna um conjunto de valores de texto, neste caso, os valores 1 a 3. A função LINHA, por sua vez, gera uma matriz colunar de três células. A função MAIOR usa os valores do intervalo de células A5:A14 e é avaliada três vezes, uma vez para cada referência retornada pela função LINHA. Os valores 3200, 2700 e 2000 são retornados para a matriz colunar de três células. Para localizar mais valores, adicione um intervalo de células maior à função INDIRETO.

Para concluir, você pode usar essa fórmula com outras funções, como SOMA e MÉDIA.

Localizar a cadeia de texto mais longa de um intervalo de células

Esta fórmula só funcionará quando um intervalo de dados contiver uma única coluna de células. Na Planilha3, insira a seguinte fórmula na célula A16 e pressione Ctrl+Shift+Enter:

=ÍNDICE(A6:A9,CORRESP(MÁX(NÚM.CARACT(A6:A9)),NÚM.CARACT(A6:A9),0),1)

O texto "várias células que" é exibido na célula A16.

Vamos examinar mais detalhadamente a fórmula, começando dos elementos internos para os externos. A função NÚM.CARACT retorna o comprimento de cada um dos itens do intervalo de células A6:A9. A função MÁX calcula o maior valor entre esses itens, que corresponde à cadeia de texto mais longa, que está na célula A7.

É neste ponto que as coisas ficam um pouco mais complexas. A função CORRESP calcula o deslocamento (a posição relativa) da célula que contém a cadeia de texto mais longa. Para fazer isso, são necessários três argumentos: um valor de pesquisa, uma matriz de pesquisa e um tipo de correspondência. A função CORRESP procura na matriz de pesquisa o valor de pesquisa especificado. Neste caso, o valor de pesquisa é a cadeia de texto mais longa:

(MÁX(NÚM.CARACT( A6 : A9 ))

e essa cadeia de caracteres reside nesta matriz:

NÚM.CARACT( A6:A9 )

O argumento tipo de correspondência é 0. O tipo de correspondência pode consistir em um valor 1, 0 ou -1. Se você especificar 1, CORRESP retornará o maior valor que seja menor ou igual ao valor de pesquisa. Se você especificar 0, CORRESP retornará o primeiro valor que seja exatamente igual ao valor de pesquisa. Se você especificar -1, CORRESP localizará o menor valor que seja maior ou igual ao valor de pesquisa especificado. Se você omitir um tipo de correspondência, o Excel adotará o valor 1.

Por fim, a função ÍNDICE opera com estes argumentos: uma matriz e um número de linha e de coluna nessa matriz. O intervalo de células A6:A9 fornece a matriz, a função CORRESP fornece o endereço das células e o argumento final (1) especifica que o valor vem da primeira coluna da matriz.

Início da Página

Colocar fórmulas de matriz avançadas para funcionar

Esta seção contém exemplos de fórmulas de matriz avançadas.

Somar um intervalo que contém valores de erro

A função SOMA do Excel não funciona quando você tenta somar um intervalo que contém um valor de erro, como #N/D. Este exemplo mostra como somar os valores em um intervalo chamado Dados que contém erros.

=SOMA(SE(ÉERROS(Dados),"",Dados))

A fórmula cria uma nova matriz contendo os valores originais menos quaisquer valores de erro. Das funções internas para as externas, a função ÉERROS pesquisa o intervalo de células (Dados) em busca de erros. A função SE retornará um valor específico se uma condição especificada for avaliada como VERDADEIRO e outro valor se ela for avaliada como FALSO. Neste caso, ela retorna cadeias de caracteres vazias ("") para todos os valores de erro, pois eles são avaliados como VERDADEIRO, e retorna os valores restantes do intervalo (Dados), pois eles são avaliados como FALSO, o que significa que eles não contêm valores de erro. Em seguida, a função SOMA calcula o total da matriz filtrada.

Contar o número de valores de erro em um intervalo

Este exemplo é semelhante à fórmula anterior, mas retorna o número de valores de erro em um intervalo chamado Dados em vez de filtrá-los:

=SOMA(SE(ÉERROS(Dados),1,0))

Essa fórmula cria uma matriz contendo o valor 1 para as células que contêm erros e o valor 0 para as que não contêm erros. Você pode simplificar a fórmula e obter o mesmo resultado removendo o terceiro argumento da função SE, da seguinte maneira:

SOMA(SE(ÉERROS(Dados),1))

Se você não especificar o argumento, a função SE retornará FALSO se uma célula não contiver um valor de erro. Você pode simplificar a fórmula ainda mais:

=SOMA(SE(ÉERROS(Dados)*1))

Essa versão funciona porque VERDADEIRO*1=1 e FALSO*1=0.

Somar valores com base em condições

Talvez seja necessário somar valores com base em condições. Por exemplo, esta fórmula de matriz soma apenas os inteiros positivos em um intervalo chamado Vendas:

=SOMA(SE(Vendas>0,Vendas))

A função SE cria uma matriz de valores positivos e falsos. A função SOMA essencialmente ignora os falsos valores, pois 0+0=0. O intervalo de células que você usa nessa fórmula pode consistir em qualquer número de linhas e colunas.

Você também pode somar valores que atendam a mais de uma condição. Por exemplo, esta fórmula de matriz calcula valores maiores que 0 e menores ou iguais a 5:

=SOMA((Vendas>0)*(Vendas<=5)*(Vendas))

Lembre-se de que essa fórmula retornará um erro se o intervalo contiver uma ou mais células não numéricas.

Você também pode criar fórmulas de matriz que usem um tipo de condição OU. Por exemplo, você pode somar valores que sejam menores que 5 e maiores que 15:

=SOMA(SE((Vendas<5)+(Vendas>15),Vendas))

A função SE localiza todos os valores menores que 5 e maiores que 15 e passa esses valores para a função SOMA.

Não é possível usar as funções E e OU diretamente em fórmulas de matriz, pois essas funções retornam um único resultado, VERDADEIRO ou FALSO, e as funções de matriz exigem matrizes de resultados. Você pode contornar o problema usando a lógica mostrada na fórmula anterior. Em outras palavras, execute operações matemáticas, como adição ou multiplicação, em valores que atendam à condição OU ou E.

Calcular uma média que exclua zeros

Este exemplo mostra como remover zeros de um intervalo quando você precisar calcular a média dos valores desse intervalo. A fórmula usa um intervalo de dados chamado Vendas:

=MÉDIA(SE(Vendas<>0,Vendas))

A função SE cria uma matriz de valores que não são iguais a 0 e passa esses valores para a função MÉDIA.

Contar o número de diferenças entre dois intervalos de células

Esta fórmula de matriz compara os valores de dois intervalos de células chamados MeusDados e SeusDados e retorna o número de diferenças entre os dois. Se o conteúdo dos dois intervalos for idêntico, a fórmula retornará 0. Para usar esta fórmula, os intervalos de células devem ter o mesmo tamanho e a mesma dimensão (por exemplo, se MeusDados for um intervalo de 3 linhas por 5 colunas, o intervalo SeusDados deverá ter o mesmo tamanho):

=SOMA(SE( MeusDados =SeusDados,0,1))

A fórmula criará uma nova matriz do mesmo tamanho dos intervalos que você está comparando. A função SE preencherá a matriz com o valor 0 e o valor 1 (0 para células que não correspondam e 1 para células idênticas). Em seguida, a função SOMA retornará a soma dos valores da matriz.

Você pode simplificar a fórmula deste modo:

=SOMA(1*( MeusDados <> SeusDados ))

Como a fórmula que conta valores de erro em um intervalo, essa fórmula funciona porque VERDADEIRO*1=1 e FALSO*1=0.

Localizar o valor máximo em um intervalo

Esta fórmula de matriz retorna o número de linha do valor máximo em um intervalo de uma única coluna chamado Dados:

=MÍN(SE(Dados=MÁX(Dados),LINHA(Dados),""))

A função SE cria uma nova matriz que corresponde ao intervalo chamado Dados. Se uma célula correspondente contiver o valor máximo no intervalo, a matriz conterá o número da linha. Caso contrário, a matriz conterá uma cadeia de caracteres vazia (""). A função MÍN usa a nova matriz como segundo argumento e retorna o menor valor, que corresponde ao número da linha do valor máximo em Dados. Se o intervalo chamado Dados contiver valores máximos idênticos, a fórmula retornará a linha do primeiro valor.

Para retornar o endereço de célula real de um valor máximo, use esta fórmula:

=ENDEREÇO(MÍN(SE(Dados=MÁX(Dados),LINHA(Dados),"")),COLUNA(Dados))

Início da Página

Precisa de mais ajuda?

Você pode sempre consultar um especialista na Excel Tech Community, obter suporte na Comunidade de respostas ou sugerir um novo recurso ou melhoria no User Voice do Excel.

Consulte Também

Visão geral das fórmulas

Expanda suas habilidades
Explore o treinamento
Obtenha novos recursos primeiro
Ingressar no Office Insider

Essas informações foram úteis?

Obrigado por seus comentários!

Agradecemos pelos seus comentários! Parece que pode ser útil conectar você a um de nossos agentes de suporte do Office.

×