CONT.SES (Função CONT.SES)

Este artigo descreve a sintaxe da fórmula e o uso da funçãoCONT.SES no Microsoft Excel.

Descrição

Aplica critérios a células em vários intervalos e conta o número de vezes que todos os critérios são atendidos.

Sintaxe

CONT.SES(intervalo_critérios1, critérios1, [intervalo_critérios2, critérios2]…)

A sintaxe da função CONT.SES tem os seguintes argumentos:

  • intervalo_critérios1    Obrigatório. O primeiro intervalo no qual avaliar os critérios associados.

  • critérios1    Obrigatório. Os critérios no formato de um número, uma expressão, uma referência de célula ou um texto que define quais células serão contadas. Por exemplo, os critérios podem ser expressos como 32, ">32", B4, "maçãs" ou "32".

  • intervalo_critérios2, critérios2, ...    Opcional. Intervalos adicionais e seus critérios associados. Até 127 intervalo/critérios pares são permitidos.

Importante   Cada intervalo adicional deve ter o mesmo número de linhas e colunas que o argumento intervalo_critérios1. Os intervalos não precisam ser adjacentes entre si.

Comentários

  • Os critérios de cada intervalo são aplicados a uma célula de cada vez. Se todas as primeiras células atenderem aos seus critérios associados, a contagem aumentará em 1. Se todas as segundas células atenderem aos seus critérios associados, a contagem aumentará em 1 novamente e assim por diante até que todas as células sejam avaliadas.

  • Se o argumento de critérios for uma referência a uma célula vazia, a função CONT.SES tratará essa célula vazia como um valor 0.

  • Você pode usar os caracteres curinga — o ponto de interrogação (?) e o asterisco (*)  — nos critérios. Um ponto de interrogação corresponde a qualquer caractere simples, enquanto um asterisco corresponde a qualquer cadeia de caracteres. Se você quiser encontrar um ponto de interrogação ou asterisco real, digite um til (~) antes do caractere.

Exemplos

Copie os dados de exemplo da tabela a seguir e cole-os na célula A1 de uma nova planilha do Excel. Para as fórmulas mostrarem resultados, selecione-as, pressione F2 e pressione Enter. Se precisar, você poderá ajustar as larguras das colunas para ver todos os dados.

Vendedor

Cota de T1 excedida

Cota de T2 excedida

Cota de T3 excedida

Andrade

Sim

Não

Não

Barreto

Sim

Sim

Não

Gambaro

Sim

Sim

Sim

Nuno

Não

Sim

Sim

Fórmula

Descrição

Resultado

=CONT.SES(B2:D2,"=Sim")

Conta quantas vezes Andrade excedeu uma cota de vendas para os períodos T1, T2 e T3 (somente em T1).

1

=CONT.SES(B2:B5,"=Sim",C2:C5,"=Sim")

Conta quantos vendedores excederam suas cotas em T1 e T2 (Barreto e Gambaro).

2

=CONT.SES(B5:D5,"=Sim",B3:D3,"=Sim")

Conta quantas vezes Nuno e Barreto excederam a mesma cota para os períodos T1, T2 e T3 (somente em T2).

1

Exemplo 2

Dados

 

1

01.05.11

2

02.05.11

3

03.05.11

4

04.05.11

5

05.05.11

6

06.05.11

Fórmula

Descrição

Resultado

=CONT.SES(A2:A7,"<6",A2:A7,">1")

Conta quantos números entre 1 e 6 (sem incluir 1 e 6) estão contidos nas células entre A2 e A7.

4

=CONT.SES(A2:A7, "<5",B2:B7,"<5/3/2011")

Conta quantas linhas têm números menores que 5 nas células entre A2 a A7 e também têm datas anteriores a 5/3/2011 nas células entre B2 e B7.

0

=CONT.SES(A2:A7, "<" & A6,B2:B7,"<" & B4)

Mesma descrição que o exemplo anterior, mas usando referências de célula no lugar de constantes nos critérios.

2

Aplicável a: Excel 2016 Preview, Excel 2010, Excel Starter, Excel 2013, Excel Online, Excel 2016 for Mac, Excel for Mac 2011, Excel 2007



Essas informações foram úteis?

Sim Não

Como podemos melhorá-lo?

255 caracteres restantes

Para proteger sua privacidade, não inclua informações de contato em seus comentários. Avalie nosso política de privacidade.

Obrigado por seus comentários!

Recursos de suporte

Alterar idioma