ÍNDICE (Função ÍNDICE)

A função ÍNDICE retorna um valor ou a referência a um valor de dentro de uma tabela ou intervalo.

Seu navegador não oferece suporte a vídeo. Instale o Microsoft Silverlight, o Adobe Flash Player ou o Internet Explorer 9.

Há duas maneiras de usar a função ÍNDICE:

  • Se você deseja retornar o valor de uma célula especificada ou uma matriz de células, consulte Forma matricial.

  • Se você deseja retornar uma referência a células especificadas, consulte o Formulário de referência.

Forma matricial

Descrição

Retorna o valor de um elemento em uma tabela ou matriz selecionado pelos índices de número de linha e coluna.

Use a forma de matriz se o primeiro argumento de ÍNDICE for uma constante de matriz.

Sintaxe

ÍNDICE(matriz; núm_linha; [núm_coluna])

A sintaxe da função ÍNDICE tem os seguintes argumentos.

  • Matriz    Obrigatório. Um intervalo de células ou uma constante de matriz.

    • Se a matriz contiver apenas uma linha ou coluna, o argumento Núm_linha ou Núm_coluna correspondente é opcional.

    • Se a matriz tiver mais de uma linha e mais de uma coluna e apenas Núm_linha ou Núm_coluna for usado, ÍNDICE retornará uma matriz referente à linha ou coluna inteira da matriz.

  • Núm_linha    Obrigatório. Seleciona a linha na matriz a partir da qual um valor deverá ser retornado. Se Núm_linha for omitido, Núm_coluna é obrigatório.

  • Núm_coluna    Opcional. Seleciona a coluna na matriz a partir da qual um valor deverá ser retornado. Se Núm_coluna for omitido, Núm_linha é obrigatório.

Comentários

  • Se os argumentos Núm_linha e Núm_coluna forem usados, ÍNDICE retornará o valor contido na célula que estiver no ponto de interseção entre Núm_linha e Núm_coluna.

  • Se você definir Núm_linha ou Núm_coluna como 0 (zero), ÍNDICE retornará a matriz de valores referente à coluna ou linha inteira, respectivamente. Para usar valores retornados como uma matriz, insira a função ÍNDICE como uma fórmula de matriz em um intervalo horizontal de células para uma linha e em um intervalo vertical de células para uma coluna. Para inserir uma fórmula de matriz, pressione Ctrl+Shift+Enter.

    Observação : No Excel Web App, não é possível criar fórmulas de matriz.

  • Núm_linha e Núm_coluna devem fazer referência a uma célula dentro de uma matriz, caso contrário, ÍNDICE retornará o valor de erro #REF!.

Exemplos

Exemplo 1

Esses exemplos usam a função ÍNDICE para localizar o valor em uma célula em interseção onde a linha e a coluna se encontram.

Copie os dados de exemplo da tabela a seguir e cole-os na célula A1 de uma nova planilha do Excel. Para as fórmulas mostrarem resultados, selecione-as, pressione F2 e pressione Enter. Se precisar, você poderá ajustar as larguras das colunas para ver todos os dados.

Dados

Dados

Maçãs

Limões

Bananas

Peras

Fórmula

Descrição

Resultado

=ÍNDICE(A2:B3;2;2)

O valor na interseção da segunda linha com a segunda coluna no intervalo A2:B3.

Peras

=ÍNDICE(A2:B3;2;1)

O valor na interseção da segunda linha com a primeira coluna no intervalo A2:B3.

Bananas

Exemplo 2

Esse exemplo usa a função ÍNDICE em uma fórmula matriz para localizar os valores em duas células especificadas em uma matriz 2x2.

Nesse caso, escolha duas células verticalmente, como A1:A2, cole a fórmula =ÍNDICE({1,2;3,4};0,2) na primeira célula e pressione Ctrl+Shift+Enter. Se for inserida como uma fórmula de matriz, o Excel colará a fórmula automaticamente na segunda célula.

Fórmula

Descrição

Resultado

=ÍNDICE({1,2;3,4};0,2)

Valor encontrado na primeira linha, segunda coluna da matriz. A matriz contém 1 e 2 na primeira linha e 3 e 4 na segunda linha.

2

Valor encontrado na segunda linha, segunda coluna da matriz (mesma matriz do exemplo acima).

4

Observação : Esta é uma fórmula de matriz e deve ser inserida por meio do comando Ctrl+Shift+Enter. O Excel encapsulará a fórmula automaticamente entre chaves {}. Se você tentar inseri-las por conta própria, o Excel exibirá a fórmula como texto. Se você não usar o comando Ctrl+Shift+Enter, a fórmula retornará o erro #VALOR!.

Início da página

Forma de referência

Descrição

Retorna a referência da célula na interseção de linha e coluna específicas. Se a referência for formada por seleções não adjacentes, você pode escolher a seleção que deseja observar.

Sintaxe

ÍNDICE (referência, núm_linha, [núm_coluna], [núm_área])

A sintaxe da função ÍNDICE tem os seguintes argumentos.

  • Referência    Obrigatório. Uma referência a um ou mais intervalos de célula.

    • Se você estiver inserindo um intervalo não adjacente para a ref, coloque ref entre parênteses.

    • Se cada área na referência contiver apenas uma linha ou coluna, o argumento Núm_linha ou Núm_coluna, respectivamente, será opcional. Por exemplo, para uma referência de linha única, use ÍNDICE(ref;;núm_coluna).

  • Núm_linha    Obrigatório. É o número da linha em ref de onde será fornecida uma referência.

  • Núm_coluna    Opcional. É o número da coluna em ref de onde será fornecida uma referência.

  • Núm_área    Opcional. Seleciona um intervalo em ref do qual deve ser retornada a interseção de Núm_linha com Núm_coluna. A primeira área selecionada ou inserida recebe o número 1, a segunda recebe o número 2, e assim por diante. Se Núm_área for omitido, ÍNDICE usará a área 1.

Por exemplo, se Ref descrever as células (A1:B4;D1:E4;G1:H4), Núm_área 1 representará o intervalo A1:B4, Núm_área 2 representará o intervalo D1:E4 e Núm_área 3 representará o intervalo G1:H4.

Comentários

  • Depois que Ref e Núm_área tiverem selecionado um intervalo específico, Núm_linha e Núm_coluna selecionam uma célula específica: Núm_linha 1 é a primeira linha do intervalo, Núm_coluna 1 é a primeira coluna, e assim por diante. A referência que ÍNDICE retorna é a interseção entre Núm_linha e Núm_coluna.

  • Se você definiu Núm_linha ou Núm_coluna como 0, ÍNDICE retorna a referência para a coluna ou linha inteira, respectivamente.

  • Núm_linha, Núm_coluna e Núm_área devem apontar para uma célula na referência; senão, ÍNDICE retornará o valor de erro #REF!. Se Núm_linha e Núm_coluna forem omitidos, ÍNDICE retornará a área em referência especificada por Núm_área.

  • O resultado da função ÍNDICE é uma referência e é interpretado como tal por outras fórmulas. Dependendo da fórmula, o valor retornado por ÍNDICE pode ser usado como uma referência ou como um valor. Por exemplo, a fórmula de macro CÉL("largura";ÍNDICE(A1:B2;1;2)) é equivalente a CÉL("largura";B1). A função CÉL usa o valor retornado por ÍNDICE como uma referência de célula. Por outro lado, uma fórmula tal como 2*ÍNDICE(A1:B2;1;2) traduz o valor retornado por ÍNDICE no número da célula B1.

Observação : A função CÉL não está disponível no Excel Web App.

Exemplos

Copie os dados de exemplo da tabela a seguir e cole-os na célula A1 de uma nova planilha do Excel. Para as fórmulas mostrarem resultados, selecione-as, pressione F2 e pressione Enter. Se precisar, você poderá ajustar as larguras das colunas para ver todos os dados.

Fruta

Andrade

Contagem

Maçãs

$0,69

40

Bananas

$0,34

38

Limões

$0,55

15

Laranjas

$0,25

25

Peras

$0,59

40

Amêndoas

$2,80

10

Cajus

$3,55

16

Amendoins

$1,25

20

Nozes

$1,75

12

Fórmula

Descrição

Resultado

=ÍNDICE(A2:C6;2;3)

A interseção da segunda linha com a terceira coluna no intervalo A2:C6, que é o conteúdo da célula C3.

38

=ÍNDICE((A1:C6;A8:C11);2;2;2)

A interseção da segunda linha com a segunda coluna na segunda área de A8:C11, que é o conteúdo da célula B9.

1,25

=SOMA(ÍNDICE(A1:C11;0;3;1))

A soma da terceira coluna na primeira área do intervalo A1:C11, que é a soma de C1:C11.

216

=SOMA(B2:ÍNDICE(A2:C6;5;2))

A soma do intervalo que começa em B2 e termina na interseção da quinta linha com a segunda coluna no intervalo A2:A6, que é a soma de B2:B6.

2,42

Início da página

Consulte Também

Função PROCV

Função CORRESP

Função INDIRETO

Diretrizes e exemplos de fórmulas de matriz

Funções de pesquisa e referência (referência)

Compartilhar Facebook Facebook Twitter Twitter Email Email

Essas informações foram úteis?

Ótimo! Outros comentários?

Como podemos melhorá-lo?

Obrigado por seus comentários!

×