Entrar com a conta da Microsoft
Entrar ou criar uma conta.
Olá,
Selecionar uma conta diferente.
Você tem várias contas
Escolha a conta com a qual você deseja entrar.

A função TEXTO permite que você altere a maneira de exibir um número aplicando formatação a ele com códigos de formatação. Isso é útil quando você deseja exibir números em um formato mais legível ou deseja combinar números com texto ou símbolos.

Observação: A função TEXT converte números em texto, o que pode dificultar a referência em cálculos posteriores. É melhor manter seu valor original em uma célula e, em seguida, usar a função TEXT em outra célula. Assim, se você precisar criar outras fórmulas, referencie sempre o valor original e não o resultado da função TEXTO.

Sintaxe

TEXTO(valor;formato_texto)

A sintaxe da função TEXTO tem os seguintes argumentos:

Nome do argumento

Descrição

valor

Um valor numérico que você deseja ver convertido em texto.

formato_texto

Uma cadeia de texto que define a formatação a ser aplicada ao valor fornecido.

Visão geral

Em sua forma mais simples, a função TEXTO diz:

  • =TEXTO(valor que você deseja formatar; "Código de formatação que deseja aplicar")

Aqui estão alguns exemplos comuns que você pode copiar diretamente no Excel para testar por conta própria. Observe os códigos de formatação entre aspas.

Fórmula

Descrição

=TEXTO(1234,567;"$#;##0,00")

Moeda com separador de milhares e duas casas decimais, como R$ 1.234,57. Observe que o Excel arredonda o valor para duas casas decimais.

=TEXTO(HOJE();"DD/MM/AA")

Data de hoje no formato DD/MM/AA, como 14/03/12

=TEXTO(HOJE();"DDDD")

Dia da semana hoje, como segunda-feira

=TEXTO(AGORA();"HH:MM")

Hora atual, como 13:29

=TEXTO(0,285;"0,0%")

Porcentagem, como 28,5%

=TEXTO(4,34 ,"# ?/?")

Fração, como 4 1/3

=ARRUMAR(TEXTO(0,34;"#? /?" ))

Fração, como 1/3. Observe que a função ARRUMAR é usada para remover os espaços à esquerda em um valor decimal.

=TEXTO(12200000;"0,00E+00")

Notação científica, como 1,22E+07

=TEXTO(2125727898,"[<=9999999]####-####;(##)>)

Números especiais (número de telefone), como (21) 2572-7898

=TEXTO(1234;"0000000")

Adiciona zeros (0), como 0001234

=TEXTO(123456;"##0° 00' 00''")

Personalizado – Latitude/Longitude

Observação: Embora você possa usar a função TEXTO para alterar a formatação, essa não é a única maneira. Você pode alterar o formato sem uma fórmula pressionando CTRL+1 (ou Imagem do ícone do botão Command no MAC+1 no Mac) e escolha o formato desejado na caixa de diálogo Formatar Células > Número .

Baixar nossos exemplos

Você pode baixar uma pasta de trabalho de exemplos com todos os exemplos da função TEXTO que encontrará neste artigo, além de alguns extras. Você pode acompanhá-los ou criar seus próprios códigos de formatação da função TEXTO.

Baixar exemplos da função TEXTO do Excel

Outros códigos de formatação disponíveis

Você pode usar a caixa de diálogo Formatar Células para localizar os outros códigos de formato disponíveis:

  1. Pressione Ctrl+1 (Imagem do ícone do botão Command no MAC+1 no Mac) para criar a caixa de diálogo Células de Formato .

  2. Selecione o formato desejado na guia Número .

  3. Selecione a opção Personalizado .

  4. O código de formatação desejado agora aparece na caixa Tipo. Nesse caso, selecione tudo na caixa Tipo, exceto o ponto e vírgula (;) e o símbolo @. No exemplo abaixo, selecionamos e copiamos apenas dd/mm/aa.

  5. Pressione Ctrl+C para copiar o código de formato e pressione Cancelar para descartar a caixa de diálogo Formatar Células .

  6. Agora, basta apenas pressionar Ctrl+V para colar o código de formatação em sua fórmula TEXTO, como: =TEXTO(B2;"dd/mm/aa"). Certifique-se de colar o código de formato dentro de aspas ("código de formato"), caso contrário, o Excel lhe dará uma mensagem de erro.

Exemplo de como usar a caixa de diálogo Formatar > Células > Número > Personalizado para que o Excel crie cadeias de caracteres de formato para você.

Códigos de formatação por categoria

A seguir estão alguns exemplos de como você pode aplicar diferentes formatos de número aos seus valores usando a caixa de diálogo Formatar Células e, em seguida, usar a opção Personalizado para copiar esses códigos de formato para sua função TEXT .

Por que o Excel exclui meu zero à esquerda?

O Excel é treinado para procurar números que estejam sendo inseridos nas células, não números que se parecem com texto, como números de peças ou SKUs. Para manter os zeros à esquerda, formate o intervalo de entrada como Texto antes de colar ou inserir valores. Selecione a coluna ou intervalo em que você colocará os valores, use Ctrl+1 para exibir o diálogo Formato > Células e, na guia Número, selecione Texto. Agora, o Excel manterá seu zero à esquerda

Se você já inseriu dados e o Excel removeu os 0’s à esquerda, é possível usar a função TEXTO para adicioná-los novamente. Você pode fazer referência à célula superior com os valores e usar =TEXTO(valor;"00000"), em que o número de 0’s na fórmula representa o número total de caracteres desejado. Em seguida, copie e cole no restante do intervalo.

Exemplos do uso de TEXTO para formatar zeros à esquerda.  =TEXTO(A2;"00000")

Se por algum motivo você precisa reverter os valores de texto em números, multiplique por 1, como =D4*1, ou use o operador unário duplo (--), como =--D4.

O Excel fará a separação de milhar se o formato contiver um ponto delimitado por teclas de cerquilha (#) ou por zeros. Por exemplo, se a cadeia de caracteres de formatação for "#.###", o Excel exibirá o número 12200000 como 12.200.000.

O ponto que segue um espaço reservado para dígito escala o número por 1.000. Por exemplo, se a cadeia de caracteres de formatação é "#.###,0.", o Excel exibirá o número 12200000 como 12.200,0.

Exemplos da função TEXTO usando o separador Milhares

Observações: 

  • O separador de milhares depende das configurações regionais. No Brasil é um ponto, mas em outras localidades é uma vírgula (,).

  • O separador de milhares está disponível para os formatos número, moeda e contábil.

A seguir estão exemplos de formatos número (somente separador de milhares e decimais), moeda e contábil padrão. O formato moeda permite a você inserir o símbolo de moeda à sua escolha e o alinha ao lado de seu valor; já o formato contábil alinha o símbolo de moeda à esquerda da célula e o valor à direita. Observe a diferença entre os códigos de formatação moeda e contábil abaixo, em que contábil usa um asterisco (*) para criar separação entre o símbolo e o valor.

Exemplos da função TEXTO com os formatos Número, Moeda e Contábil

Para encontrar o código de formatação de um símbolo de moeda, primeiro pressioneCtrl+1 (ou Imagem do ícone do botão Command no MAC+1 no Mac), selecione o formato desejado e escolha um símbolo na lista suspensa Símbolo:

Seleção de Símbolo de Moeda no diálogo Formatar Células

Clique em Personalizado à esquerda da seção Categoria e copie o código de formatação, inclusive o símbolo da moeda.

Função TEXTO – Moeda personalizada com símbolo

Observação: A função TEXTO não dá suporte à formatação de cor e, portanto, se você copiar um código de formatação de número do diálogo Formatar Células que inclua uma cor, como este: R$#.## 0,00_); [Vermelho](R$#,##0,00), a função TEXTO aceitará o código do formato, mas não exibirá a cor.

Você pode alterar a forma de exibição de uma data usando uma combinação de "M" para mês, "D" para dias e "Y" para anos.

Códigos de formato Mês, Dia e Ano

Os códigos de formatação na função TEXTO não diferenciam maiúsculas e minúsculas e, portanto, você pode usar "D" ou "d", "M" ou "m", "A" ou "a".

Mynda Treacy, MVP em Excel

Recomendação da Mynda...

Se você compartilha arquivos e relatórios do Excel com usuários de diferentes países, convém oferecer a eles relatórios em seus idiomas nativos. O MVP do Excel, Mynda Treacy tem uma ótima solução neste artigo Datas do Excel exibidas em diferentes idiomas. Ele também inclui uma pasta de trabalho de exemplo para download.

Você pode alterar a forma de exibição da hora usando uma combinação de "H" para horas, "M" para minutos ou "S" para segundos e "AM/PM" para um relógio de 12 horas.

Formatos de hora para horas, minutos e segundos

Se você excluir "AM/PM" ou "A/P", a hora será exibida com base no relógio de 24 horas.

Os códigos de formatação na função TEXTO não diferenciam maiúsculas e minúsculas e, portanto, você pode usar "H" ou "h", "M" ou "m", "S" ou "s".

Você pode alterar o modo de exibição de valores decimais com formatos de porcentagem (%).

Códigos de formato para Porcentagem

Você pode alterar o modo de exibição de valores decimais com fração (?/?) formatos.

Códigos de formato para Frações

Notação científica é uma maneira de exibir números em decimal entre 1 e 10 elevado à décima potência. Ela é usada com frequência para encurtar a exibição de números grandes.

Códigos de formato para Científico

O Excel oferece 4 formatos especiais:

  • CEP – "00000"

  • CEP + 4 - "00000-0000"

  • Número de telefone – "[<=9999999]####-####;(##)">

  • CPF – "000.000.000-00"

Formatos especiais para a função TEXTO

Os formatos especiais serão diferentes dependendo da localidade, mas se não existirem formatos especiais na sua região ou se ele não atenderem às suas necessidades, crie seu próprio usando o diálogo Formatar Células > Personalizado.

Cenário comum

A função Texto raramente é usada sozinha. Ela normalmente é usada em conjunto com outra coisa. Digamos que você queira combinar texto e um valor numérico, como "Relatório impresso em: 14/03/12" ou "Receita semanal: R$ 66.348,72". Você pode inserir os dados manualmente no Excel, mas isso desvirtua a finalidade de deixar que o Excel se encarregue da tarefa. Infelizmente, quando você combina texto e números formatados, como datas, horas, moeda e outros, o Excel não sabe como você deseja exibi-los e ele descarta a formatação do número. É aqui que a função TEXTO é muito útil, pois permite que você force o Excel a formatar os valores como desejar usando um código de formatação para o formato de data, como "DD/MM/AA".

No exemplo a seguir, você verá o que acontece quando tenta unir texto e número sem usar a função TEXTO. Nesse caso, estamos usando o E comercial (&) para concatenar uma cadeia de caracteres de texto, um espaço (" ") e um valor com =A2&" "&B2.

Exemplo de união de texto sem a função TEXTO

Como você pode ver, o Excel removeu a formatação da data na célula B2. No próximo exemplo, você verá como a função TEXTO permite aplicar o formato desejado.

Exemplo de união de texto com a função TEXTO

Nossa fórmula atualizada é:

  • Célula C2: =A2&" "&TEXTO(B2;"dd/mm/aa") – formato de data

Perguntas frequentes

Infelizmente, você não pode fazer isso com a função TEXT; você precisa usar o código VBA (Visual Basic for Applications). O link a seguir tem um método: como converter um valor numérico em palavras em inglês no Excel.

Sim, você pode usar as funções MAIÚSCULA, MINÚSCULA e PRI.MAIÚSCULA. Por exemplo, =MAIÚSCULA("olá") retornaria "OLÁ".

Sim, mas são necessárias algumas etapas. Primeiro, selecione a célula ou as células em que você deseja que isso aconteça e use Ctrl+1 para criar a caixa de diálogo Formatar células > e, em seguida, Alinhar > controle Texto > marcar a opção Texto de Encapsulamento. Em seguida, ajuste a função TEXTO concluída para incluir a função ASCII CARACT(10) onde deseja incluir a quebra de linha. Talvez seja necessário ajustar a largura da coluna, dependendo do alinhamento do resultado final.

Exemplo do uso de texto com CARACT(10) para inserir uma quebra de linha. ="Hoje é: "&CARACT(10))&TEXTO(HOJE();"DD/MM/AA")

Nesse caso, usamos: ="Hoje é: "&CARACT(10)&TEXTO(HOJE();"dd/mm/aa")

Isso é chamado notação científica, e o Excel converte automaticamente números com mais de 12 dígitos se uma célula for formatada como Geral e 15 dígitos se uma célula for formatada como um Número. Se você precisar inserir cadeias de caracteres numéricas longas, mas não quiser convertê-las, formate as células em questão como Texto antes de inserir ou colar seus valores no Excel.

Mynda Treacy, MVP em Excel

Recomendação da Mynda...

Se você compartilha arquivos e relatórios do Excel com usuários de diferentes países, convém oferecer a eles relatórios em seus idiomas nativos. O MVP do Excel, Mynda Treacy tem uma ótima solução neste artigo Datas do Excel exibidas em diferentes idiomas. Ele também inclui uma pasta de trabalho de exemplo para download.

Confira Também

Criar ou excluir um formato de número personalizado

Converter números armazenados como texto em números

Todas as funções do Excel (por categoria)

Precisa de mais ajuda?

Quer mais opções

Explore os benefícios da assinatura, procure cursos de treinamento, saiba como proteger seu dispositivo e muito mais.

As comunidades ajudam você a fazer e responder perguntas, fazer comentários e ouvir especialistas com conhecimento avançado.

Essas informações foram úteis?

Qual é o seu grau de satisfação com a qualidade do idioma?
O que afetou sua experiência?
Ao pressionar enviar, seus comentários serão usados para aprimorar os produtos e serviços da Microsoft. Seu administrador de TI poderá coletar esses dados. Política de Privacidade.

Agradecemos seus comentários!

×