Funkcja TEKST umożliwia zmianę sposobu wyświetlania liczby przez zastosowanie do niej formatowania za pomocą kodów formatów. Jest to przydatne w sytuacjach, w których chcesz wyświetlić liczby w bardziej czytelnym formacie lub połączyć liczby z tekstem lub symbolami.
Uwaga: Funkcja TEKST konwertuje liczby na tekst, co może utrudniać odwoływanie się do nich w późniejszych obliczeniach. Najlepiej zachować oryginalną wartość w jednej komórce, a następnie użyć funkcji TEKST w innej komórce. Jeśli później zajdzie konieczność utworzenia innych formuł, odwołuj się zawsze do oryginalnej wartości, a nie do wyniku funkcji TEKST.
Składnia
TEKST(wartość;format_tekst)
W składni funkcji TEKST występują następujące argumenty:
|
Nazwa argumentu |
Opis |
|
wartość |
Wartość liczbowa, która ma zostać przekonwertowana na tekst. |
|
format_tekst |
Ciąg tekstowy definiujący formatowanie, które ma zostać zastosowane do podanej wartości. |
Omówienie
Mówiąc najprościej, działanie funkcji TEKST jest następujące:
-
=TEKST(wartość, którą chcesz sformatować; "Kod formatu, który chcesz zastosować")
Poniżej przedstawiono kilka popularnych przykładów, które można skopiować bezpośrednio do programu Excel, aby je samodzielnie wypróbować. Zwróć uwagę na kody formatów w cudzysłowie.
|
Formuła |
Opis |
|---|---|
|
=TEKST(1234,567;"# ##0,00 zł") |
Zapis walutowy z separatorem tysięcy w postaci spacji i dwoma miejscami dziesiętnymi, na przykład 1 234,57 zł. Zwróć uwagę, że program Excel zaokrągla wartość do dwóch miejsc dziesiętnych. |
|
=TEKST(DZIŚ();"RR-MM-DD") |
Dzisiejsza data w formacie RR-MM-DD, na przykład 12-03-14 |
|
=TEKST(DZIŚ();"DDDD") |
Dzisiejszy dzień tygodnia, na przykład poniedziałek |
|
=TEKST(TERAZ();"G:MM AM/PM") |
Bieżący czas, na przykład 1:29 PM |
|
=TEKST(0,285;"0,0%") |
Zapis procentowy, na przykład 28,5% |
|
=TEXT(4,34 ,"# ?/?") |
Wartość ułamkowa, na przykład 4 1/3 |
|
=USUŃ.ZBĘDNE.ODSTĘPY(TEKST(0,34;"# ?/?")) |
Wartość ułamkowa, na przykład 1/3 Zauważ, że ta funkcja korzysta z funkcji USUŃ.ZBĘDNE.ODSTĘPY w celu usunięcia spacji wiodącej w wartości dziesiętnej. |
|
=TEKST(12200000;"0,00E+00") |
Wartość w notacji wykładniczej, na przykład 1,22E+07 |
|
=TEKST(1234567898;"[<=9999999]###-####;(###) ###-####") |
Format specjalny (numer telefonu), na przykład (123) 456-7898 |
|
=TEKST(1234;"0000000") |
Dodawanie zer wiodących (0), na przykład 0001234 |
|
=TEKST(123456;"##0° 00' 00''") |
Format niestandardowy — szerokość/długość geograficzna |
Uwaga: Zastosowanie funkcji TEKST nie jest jedynym sposobem zmiany formatowania. Format można zmienić bez użycia formuły, naciskając klawisze CTRL+1 (lub 
Pobierz nasze przykłady
Możesz pobrać przykładowy skoroszyt ze wszystkimi przykładami zastosowania funkcji TEKST opisanymi w tym artykule i dodatkowymi zasobami. Możesz skorzystać z gotowych przykładów lub utworzyć własne kody formatów dla funkcji TEKST.
Pobierz przykłady zastosowania funkcji TEKST programu Excel
Inne dostępne kody formatów
W oknie dialogowym Formatowanie komórek można znaleźć inne dostępne kody formatów:
-
Naciśnij klawisze Ctrl+1 (
-
Na karcie Liczby wybierz żądany format.
-
Wybierz opcję Niestandardowe .
-
Żądany kod formatu jest teraz wyświetlany w polu Typ. W tym przypadku zaznacz wszystkie elementy znajdujące się w polu Typ z wyjątkiem średnika (;) i symbolu @. W poniższym przykładzie zaznaczono i skopiowano tylko ciąg rr-mm-dd.
-
Naciśnij klawisze Ctrl+C , aby skopiować kod formatu, a następnie naciśnij klawisz Anuluj , aby zamknąć okno dialogowe Formatowanie komórek .
-
Teraz wystarczy nacisnąć klawisze Ctrl+V, aby wkleić kod formatu do formuły TEKST, na przykład: =TEKST(B2;"rr-mm-dd"). Upewnij się, że kod formatu został wklejony w cudzysłowie ("kod formatu"), w przeciwnym razie w programie Excel zostanie wyświetlony komunikat o błędzie.
Kody formatów według kategorii
Poniżej przedstawiono kilka przykładów zastosowania różnych formatów liczb do wartości przy użyciu okna dialogowego Formatowanie komórek, a następnie skopiowania tych kodów formatów do funkcji TEKST przy użyciu opcji Niestandardowe.
Dlaczego program Excel usuwa zera wiodące?
Program Excel wyszukuje w komórkach wprowadzone liczby, a nie liczby wyglądające jak tekst, numery katalogowe czy kody SKU. Aby zachować zera wiodące, sformatuj zakres wejściowy jako tekst przed wklejeniem lub wprowadzeniem wartości. Zaznacz kolumnę lub zakres, w którym będą wprowadzane wartości, a następnie użyj klawiszy CTRL+1, aby wyświetlić okno dialogowe Format > Komórki i na karcie Liczby wybierz kategorię Tekstowe. Teraz program Excel pozostawi zera wiodące.
Jeśli dane zostały już wprowadzone, a zera wiodące zostały usunięte w programie Excel, możesz użyć funkcji TEKST, aby dodać je ponownie. Odwołując się do wartości w górnej komórce, użyj formuły =TEKST(wartość;"00000"), gdzie liczba cyfr 0 w formule odpowiada całkowitej liczbie potrzebnych znaków, a następnie skopiuj i wklej do pozostałej części zakresu.
Jeśli z jakiejś przyczyny chcesz przekonwertować wartości tekstowe z powrotem na liczby, możesz pomnożyć je przez 1, na przykład =D4*1, lub użyć podwójnego operatora jednoargumentowego (--), na przykład =--D4.
W programie Excel tysiące są oddzielane znakami spacji, jeśli format zawiera znak spacji między znakami liczb (#) lub zerami. Jeśli na przykład ciąg formatu ma postać "# ###", program Excel wyświetli liczbę 12200000 w postaci 12 200 000.
Znak spacji występujący po symbolu zastępczym cyfry powoduje przeskalowanie liczby przez wielokrotność jednego tysiąca. Jeśli na przykład ciąg formatu ma postać "# ###,0 ", program Excel wyświetli liczbę 12200000 w postaci 12 200,0.
Uwagi:
-
Symbol będący separatorem tysięcy zależy od ustawień regionalnych. W Polsce jest to spacja, ale w innych ustawieniach regionalnych może to być kropka (.).
-
Separator tysięcy jest dostępny w formacie liczbowym, walutowym i księgowym.
Poniżej przedstawiono przykłady standardowych formatów liczbowych (tylko separator tysięcy i liczba miejsc dziesiętnych), walutowych i księgowych. Format walutowy pozwala na wstawienie wybranego symbolu waluty i wyrównanie go obok wartości, natomiast w formacie księgowym symbol waluty będzie wyrównany do lewej strony komórki, a wartość do prawej. Zauważ różnicę w znajdujących się poniżej kodach formatów walutowych i księgowych. W formacie księgowym do wstawienia odstępu między symbolem waluty i wartością jest stosowany znak gwiazdki (*).
Aby znaleźć kod formatu odpowiadający symbolowi waluty, naciśnij najpierw klawisze Ctrl+1 (lub
Następnie kliknij pozycję Niestandardowe w sekcji Kategoria po lewej stronie i skopiuj kod formatu razem z symbolem waluty.
Uwaga: Funkcja TEKST nie obsługuje formatowania kolorów, dlatego po skopiowaniu z okna dialogowego Formatowanie komórek kodu formatu liczbowego zawierającego kolor, na przykład: # ##0,00 zł;[Czerwony]-# ##0,00 zł, funkcja TEKST zaakceptuje kod formatu, ale nie wyświetli odpowiedniego koloru.
Można zmienić sposób wyświetlania daty za pomocą kombinacji liter M (miesiąc), D (dzień) i R (rok).
W kodach formatów funkcji TEKST nie jest uwzględniana wielkość liter, więc można używać liter M lub m, D lub d, R lub r.
|
|
Mynda poleca... Jeśli udostępniasz pliki programu Excel oraz raporty użytkownikom z różnych krajów, możesz zadbać o to, aby otrzymywali raporty w swoich językach. Mynda Treacy, specjalista MVP w dziedzinie programu Excel, podaje doskonałe rozwiązanie w tym artykule: Daty programu Excel wyświetlane w różnych językach. Dostępny jest tam też przykładowy skoroszyt do pobrania. |
Można zmienić sposób wyświetlania czasu za pomocą kombinacji liter G (godzina), M (minuta) lub S (sekunda) oraz skrótu AM/PM dla formatu 12-godzinnego.
Jeśli nie zostanie użyty skrót AM/PM (lub A/P), czas będzie wyświetlany w formacie 24-godzinnym.
W kodach formatów funkcji TEKST nie jest rozróżniana wielkość liter, dlatego można używać liter G lub g, M lub m, S lub s oraz skrótu AM/PM lub am/pm.
Można zmienić sposób wyświetlania wartości dziesiętnych za pomocą kodów formatów ze znakiem procenta (%).
Można zmienić sposób wyświetlania wartości dziesiętnych za pomocą formatów kodów ze znakiem ułamka (?/?).
Notacja wykładnicza to sposób wyświetlania liczb jako liczb z zakresu od 1 do 10 pomnożonych przez potęgę liczby 10. Jest to często używany sposób skróconego wyświetlania dużych liczb.
Program Excel udostępnia 4 specjalne formaty:
-
Kod pocztowy — "00-000"
-
Numer telefonu — 6 cyfr — "[<=999999]###-###;(###) ###-###"
-
Numer telefonu — 7 cyfr — "[<=9999999]###-##-##;(###) ###-##-##"
-
Numer PESEL — "00000000000"
Formaty specjalne będą się różnić w zależności od ustawień regionalnych, ale jeśli dla konkretnych ustawień regionalnych nie ma żadnych formatów specjalnych lub jeśli nie spełniają one Twoich potrzeb, możesz utworzyć własne, korzystając z okna dialogowego Formatowanie komórek > Niestandardowe.
Typowy scenariusz
Funkcja TEKST najczęściej jest stosowana w połączeniu z dodatkowymi elementami. Załóżmy, że chcesz połączyć tekst i wartość liczbową, na przykład „Raport wydrukowano w dniu: 14-03-12” lub „Przychód tygodniowy: 66 348,72 zł”. Możesz wpisać to ręcznie w programie Excel, ale przecież program Excel ma Cię właśnie w tym wyręczyć. Niestety podczas łączenia tekstu i sformatowanych liczb (na przykład dat, godziny, walut itd.) program Excel nie może ustalić sposobu, w jaki chcesz wyświetlić wynik, dlatego usuwa formatowanie liczb. W tej sytuacji funkcja TEKST jest nieoceniona, ponieważ umożliwia wymuszanie na programie Excel formatowania wartości w odpowiedni sposób przy użyciu kodu formatu, na przykład "DD-MM-RR" dla formatu daty.
W poniższym przykładzie zobaczysz, co się stanie, jeśli spróbujesz połączyć tekst i liczbę bez używania funkcji TEKST. W tym przypadku jest używany operator „handlowego i” (&) do łączenia ciągu tekstowego, znaku spacji (" ") i wartości =A2&" "&B2.
Jak widać, program Excel usunął formatowanie z daty w komórce B2. W następnym przykładzie zobaczysz, jak funkcja TEKST umożliwia zastosowanie odpowiedniego formatu.
Nasza zaktualizowana formuła wygląda następująco:
-
Komórka C2:=A2&" "&TEKST(B2;"dd-mm-rr") — format daty
Często zadawane pytania
Niestety, nie można tego zrobić za pomocą funkcji TEKST; musisz użyć kodu Visual Basic for Applications (VBA). Poniższy link zawiera metodę: Jak przekonwertować wartość liczbową na wyrazy w języku angielskim w programie Excel.
Tak, możesz użyć funkcji LITERY.WIELKIE, LITERY.MAŁE i Z.WIELKIEJ.LITERY. Na przykład zastosowanie funkcji =LITERY.WIELKIE("witaj") zwróci w wyniku tekst „WITAJ”.
Tak, ale wymaga to wykonania kilku czynności. Najpierw zaznacz komórkę lub komórki, w których chcesz to zrobić, i użyj klawiszy Ctrl+1 , aby wyświetlić okno dialogowe Formatowanie > komórki , a następnie wyrównanie > kontrolkę tekst > zaznacz opcję Zawijaj tekst . Następnie dostosuj zakończoną funkcję TEKST, tak aby uwzględniała funkcję ASCII ZNAK(10) w miejscu, w którym chcesz wstawić podział wiersza. Być może trzeba będzie dostosować szerokość kolumn w zależności od tego, jak będzie wyglądał końcowy efekt.
W tym przypadku użyto zapisu: ="Dzisiaj jest: "&ZNAK(10)&TEKST(DZIŚ();"dd-mm-rr")
Jest to nazywane notacją naukową, a program Excel automatycznie konwertuje liczby dłuższe niż 12 cyfr, jeśli komórki są sformatowane jako ogólne, oraz 15 cyfr, jeśli komórki są sformatowane jako liczby. Jeśli musisz wprowadzić długie ciągi liczbowe, ale nie chcesz ich konwertować, sformatuj odpowiednie komórki jako tekstowe przed wprowadzeniem lub wklejeniem wartości do programu Excel.
|
|
Mynda poleca... Jeśli udostępniasz pliki programu Excel oraz raporty użytkownikom z różnych krajów, możesz zadbać o to, aby otrzymywali raporty w swoich językach. Mynda Treacy, specjalista MVP w dziedzinie programu Excel, podaje doskonałe rozwiązanie w tym artykule: Daty programu Excel wyświetlane w różnych językach. Dostępny jest tam też przykładowy skoroszyt do pobrania. |
Zobacz też
Tworzenie lub usuwanie niestandardowego formatu liczb
