WYSZUKAJ.PIONOWO, funkcja

Funkcja WYSZUKAJ.PIONOWO, jedna z funkcji wyszukiwania i odwołań, umożliwia znajdowanie danych w tabeli lub zakresie według wierszy. Funkcja ta pozwala na przykład wyszukać nazwisko pracownika przy użyciu jego numeru pracownika lub znaleźć numer telefonu przez wyszukanie odpowiedniego nazwiska (podobnie jak w książce telefonicznej).

Pomyślność działania funkcji WYSZUKAJ.PIONOWO zależy od prawidłowego uporządkowania danych: szukana wartość (nazwisko pracownika) musi znajdować się po lewej stronie zwracanej wartości, którą chcesz znaleźć (numer telefonu pracownika).

Składnia

WYSZUKAJ.PIONOWO(szukana_wartość; tabela_tablica; nr_kolumny; [przeszukiwany_zakres])

Na przykład:

  • =WYSZUKAJ.PIONOWO(105;A2:C7;2;PRAWDA)

  • =WYSZUKAJ.PIONOWO("Pawłowski";B2:E7;2;FAŁSZ)

Nazwa argumentu

Opis

szukana_wartość    (wymagany)

Wartość, która ma zostać znaleziona. Wartość, która ma zostać znaleziona, musi być w pierwszej kolumnie zakresu komórek określonego za pomocą argumentu tabela_tablica.

Jeśli na przykład wartość argumentu tabela_tablica obejmuje komórki B2:D7, szukana_wartość musi znajdować się w kolumnie B. Obejrzyj poniższy rysunek. Szukana_wartość może być wartością lub odwołaniem do komórki.

tabela_tablica    (wymagany)

Zakres komórek, w których funkcja WYSZUKAJ.PIONOWO szuka wartości szukana_wartość i wartości zwracanej.

Pierwsza kolumna w zakresie komórek musi zawierać wartość zdefiniowaną za pomocą argumentu szukana_wartość (na poniższej ilustracji jest to nazwisko). Zakres komórek musi również zawierać wartość zwracaną (na poniższej ilustracji jest to imię), którą chcesz znaleźć.

Dowiedz się, jak zaznaczać zakresy w arkuszu.

nr_kolumny    (wymagany)

Numer kolumny (począwszy od 1 dla pierwszej z lewej kolumny w ramach zakresu tabela_tablica) zawierającej wartość zwracaną.

przeszukiwany_zakres    (opcjonalny)

Wartość logiczna określająca, czy funkcja WYSZUKAJ.PIONOWO ma znaleźć dopasowanie dokładne, czy przybliżone:

  • PRAWDA — powoduje wyszukanie najbliższej wartości przy założeniu, że pierwsza kolumna w tabeli jest posortowana liczbowo lub alfabetycznie. Jeśli nie określisz metody, ta metoda jest stosowana domyślnie.

  • FAŁSZ — powoduje wyszukanie dokładnej wartości w pierwszej kolumnie.

Na poniższym obrazie przedstawiono, jak należy skonfigurować arkusz z formułą =VLOOKUP("Akers",B2:D5,2,FALSE), aby zwracał imię Dominika.

Przykładowa wartość i tablica potrzebne do utworzenia formuły WYSZUKAJ.PIONOWO w programie Excel

Przykłady

Aby skorzystać z tych przykładów w programie Excel, skopiuj dane z poniższej tabeli i wklej je w komórce A1 nowego arkusza.

Identyfikator

Nazwisko

Imię

Stanowisko

Data urodzenia

101

Duda

Aneta

Przedstawiciel handlowy

1968-12-08

102

Pawłowski

Marcin

Wiceprezes do spraw sprzedaży

1952-02-19

103

Sokołowska

Magdalena

Przedstawiciel handlowy

1963-08-30

104

Kalinowski

Jacek

Przedstawiciel handlowy

1958-09-19

105

Borkowski

Wojciech

Kierownik ds. sprzedaży

1955-03-04

106

Ostrowski

Roman

Przedstawiciel handlowy

1963-07-02

Formuła

Opis

=WYSZUKAJ.PIONOWO("Pawłowski";B2:E7;2;FAŁSZ)

Wyszukuje wartość Pawłowski w pierwszej kolumnie (B) tabeli tabela_tablica B2:E7 i zwraca wartość Marcin znalezioną w drugiej kolumnie (C) tabeli tabela_tablica. Argument przeszukiwany_zakres o wartości FAŁSZ zwraca dokładne dopasowanie.

=WYSZUKAJ.PIONOWO(102;A2:C7;2;FAŁSZ)

Wyszukuje dokładne dopasowanie nazwiska dla argumentu szukana_wartość102 w kolumnie A. Zwracana jest wartość Pawłowski. Jeśli szukana_wartość to 105, zwracane jest nazwisko Borkowski.

=JEŚLI(WYSZUKAJ.PIONOWO(103;A1:E7;2;FAŁSZ)="Ostrowski";"Znaleziono";"Nie znaleziono")

Sprawdza, czy nazwisko pracownika o identyfikatorze 103 to Ostrowski. Ponieważ identyfikatorowi 103 odpowiada nazwisko Sokołowska, zostaje zwrócony wynik Nie znaleziono. Jeśli zmienisz w formule "Ostrowski" na "Sokołowska", wynikiem funkcji będzie Znaleziono.

=ZAOKR.DO.CAŁK(CZĘŚĆ.ROKU(DATA(2014;6;30);WYSZUKAJ.PIONOWO(105;A2:E7;5;FAŁSZ);1))

Wyszukuje wiek pracownika o identyfikatorze 105 dla roku obrachunkowego 2014. Za pomocą funkcji CZĘŚĆ.ROKU odejmuje datę urodzenia od daty końcowej roku obrachunkowego i wyświetla wynik 59 jako liczbę całkowitą przy użyciu funkcji ZAOKR.DO.CAŁK.

=JEŻELI(CZY.BRAK(WYSZUKAJ.PIONOWO(105;A2:E7;2;FAŁSZ))=PRAWDA;"Nie znaleziono pracownika";WYSZUKAJ.PIONOWO(105;A2:E7;2;FAŁSZ))

Jeśli istnieje pracownik z identyfikatorem 105, zostanie wyświetlone jego nazwisko (Borkowski). W przeciwnym wypadku zostanie wyświetlony komunikat Nie znaleziono pracownika. Funkcja CZY.BRAK (zobacz CZY, funkcje) zwraca wartość PRAWDA, jeśli funkcja WYSZUKAJ.PIONOWO zwraca wartość błędu #N/D.

=WYSZUKAJ.PIONOWO(104;A2:E7;3;FAŁSZ)&" "&WYSZUKAJ.PIONOWO(104;A2:E7;2;FAŁSZ)&" pracuje na stanowisku "&WYSZUKAJ.PIONOWO(104;A2:E7;4;FAŁSZ)

Łączy wartości trzech komórek dotyczących pracownika o identyfikatorze 104, tworząc pełne zdanie Jacek Kalinowski pracuje na stanowisku Przedstawiciel handlowy.

Typowe problemy

Problem

Co się nie udało

Zwrócona nieprawidłowa wartość

Jeśli argument przeszukiwany_zakres ma wartość PRAWDA lub został pominięty, pierwsza kolumna musi być posortowana alfabetycznie lub liczbowo. Jeśli pierwsza kolumna nie jest posortowana, zwracana może być nieoczekiwana wartość. Posortuj pierwszą kolumnę lub użyj wartości FAŁSZ, aby uzyskać dokładne dopasowanie.

Wartość #N/D w komórce

  • Jeśli argument przeszukiwany_zakres ma wartość PRAWDA, a wartość argumentu szukana_wartość jest mniejsza od najmniejszej wartości w pierwszej kolumnie tabeli tabela_tablica, wówczas zwracana jest wartość błędu #N/D.

  • Jeśli argument przeszukiwany_zakres ma wartość FAŁSZ, wartość błędu #N/D oznacza, że nie znaleziono dokładnej liczby.

Dowiedz się więcej na temat błędów w arkuszach, takich jak #N/D, #ADR i innych.

Wartość #ADR! w komórce

Jeśli wartość nr_kolumny jest większa niż liczba kolumn określona za pomocą wartości tabela_tablica, zostanie zwrócona wartość błędu #ADR!.

Wartość #ARG! w komórce

Jeśli wartość tabela_tablica jest mniejsza niż 1, zostanie zwrócona wartość błędu #ARG!.

Wartość #NAZWA? w komórce

Wartość błędu #NAZWA? zazwyczaj oznacza, że w formule brakuje cudzysłowu. Aby wyszukać nazwisko osoby, upewnij się, że w formule zostało ono ujęte w cudzysłów. Na przykład wprowadź nazwisko "Pawłowski" w formule =WYSZUKAJ.PIONOWO("Pawłowski";B2:E7;2;FAŁSZ).

Najważniejsze wskazówki

Czynność

Uzasadnienie

Używaj odwołań bezwzględnych dla argumentu przeszukiwany_zakres.

Dzięki odwołaniom bezwzględnym można wypełniać formułę tak, aby zawsze przeszukiwała ten sam zakres.

Dowiedz się, jak korzystać z bezwzględnych odwołań do komórek.

Nie przechowuj wartości liczbowych ani dat jako tekstu.

W przypadku wyszukiwania wartości liczbowych lub dat upewnij się, że dane w pierwszej kolumnie zdefiniowanej za pomocą argumentu tabela_tablica nie są przechowywane jako wartości tekstowe. W przeciwnym razie funkcja WYSZUKAJ.PIONOWO może zwrócić niepoprawną lub nieoczekiwaną wartość.

Posortuj pierwszą kolumnę.

Posortuj pierwszą kolumnę tabeli tabela_tablica przed użyciem funkcji WYSZUKAJ.PIONOWO, jeśli argument przeszukiwany_zakres ma wartość PRAWDA.

Używaj symboli wieloznacznych.

Jeśli argument przeszukiwany_zakres ma wartość FAŁSZ, a argument szukana_wartość ma wartość tekstową, przy określaniu argumentu szukana_wartość można używać symboli wieloznacznych — znaku zapytania (?) i gwiazdki (*). Znak zapytania odpowiada dowolnemu znakowi, a gwiazdka dowolnej sekwencji znaków. Aby wyszukać znak zapytania lub gwiazdkę, przed szukanym znakiem należy wpisać tyldę (~).

Na przykład formuła =WYSZUKAJ.PIONOWO("Pawłowsk?";B2:E7;2;FAŁSZ) spowoduje wyszukanie wszystkich wystąpień tekstu Pawłowsk, przy czym ostatnia litera może być różna.

Upewnij się, że dane nie zawierają błędnych znaków.

W przypadku wyszukiwania w pierwszej kolumnie wartości tekstowych upewnij się, że dane w tej kolumnie nie zawierają początkowych ani końcowych spacji, niespójnych cudzysłowów prostych (' lub ") ani drukarskich (‘ lub „”), znaków zapytania ani znaków niedrukowanych. Wystąpienie takich znaków może spowodować zwrócenie przez funkcję WYSZUKAJ.PIONOWO nieoczekiwanej wartości.

Spróbuj użyć funkcji OCZYŚĆ lub funkcji USUŃ.ZBĘDNE.ODSTĘPY, aby usunąć końcowe spacje za wartościami tabeli w komórce.

Powiązane

Dotyczy: Excel Starter, Excel for Mac 2011, Excel 2016 for Mac, Excel 2010, Excel 2013, Excel 2007, Excel Online



Czy te informacje były pomocne?

Tak Nie

Jak możemy to poprawić?

255 pozostało znaków

Aby chronić swoją prywatność, nie dołączaj do opinii informacji o kontakcie. Przejrzyj nasze zasady zachowania poufności informacji.

Dziękujemy za opinię!

Zasoby pomocy technicznej

Zmień język