SZUKAJ.TEKST, SZUKAJ.TEKST.B, funkcje

SZUKAJ.TEKST, SZUKAJ.TEKST.B, funkcje

Ten artykuł zawiera opis składni formuł i zastosowania funkcji SZUKAJ.TEKST i SZUKAJ.TEKST.B w programie Microsoft Excel.

Opis

Funkcje SZUKAJ.TEKST i SZUKAJ.TEKST.B służą do odnajdywania jednego ciągu tekstowego wewnątrz innego ciągu tekstowego i zwracania pozycji początkowej szukanego tekstu liczonej od pierwszego znaku tekstu przeszukiwanego. Aby na przykład stwierdzić, na której pozycji w wyrazie „drukarka” znajduje się litera „u”, można użyć następującej funkcji:

=SZUKAJ.TEKST("u";"drukarka")

Ta funkcja zwraca wartość 3, ponieważ „u” to trzecia litera w wyrazie „drukarka”.

Za pomocą tej funkcji można również wyszukiwać wyrazy w innych wyrazach. Na przykład funkcja

=SZUKAJ.TEKST("wizja";"telewizja")

zwraca wartość 5, ponieważ wyraz „wizja” rozpoczyna się od piątego znaku wyrazu „telewizja”. Do określenia położenia znaku lub tekstu w ramach innego ciągu tekstowego służą funkcje SZUKAJ.TEKST i SZUKAJ.TEKST.B, natomiast funkcje FRAGMENT.TEKSTU i FRAGMENT.TEKSTU.B zwracają taki tekst. Tekst można zamienić przy użyciu funkcji ZASTĄP i ZASTĄP.B. Te funkcje przedstawia przykład 1 w niniejszym artykule.

Ważne : 

  • Te funkcje mogą nie być dostępne w niektórych językach.

  • Funkcja SZUKAJ.TEKST.B zlicza dwa bajty na znak, tylko jeśli jako domyślny jest ustawiony język obsługujący zestaw znaków DBCS. W innym przypadku funkcja SZUKAJ.TEKST.B działa tak samo jak funkcja SZUKAJ.TEKST i zlicza jeden bajt na znak.

Zestaw znaków DBCS jest obsługiwany między innymi przez następujące języki: japoński, chiński (uproszczony), chiński (tradycyjny) i koreański.

Składnia

SZUKAJ.TEKST(tekst_szukany;w_tekście;[nr_poz_pocz])

SZUKAJ.TEKST.B(tekst_szukany;w_tekście;[nr_poz_pocz])

W składni funkcji SZUKAJ.TEKST i SZUKAJ.TEKST.B występują następujące argumenty:

  • Tekst_szukany    Argument wymagany. Jest to tekst, który ma zostać znaleziony.

  • W_tekście    Argument wymagany. Jest to tekst, w którym ma zostać znaleziony tekst_szukany.

  • Nr_poz_pocz    Argument opcjonalny. Jest to numer znaku w argumencie w_tekście, od którego ma zostać rozpoczęte przeszukiwanie.

Spostrzeżenie

  • W funkcjach SZUKAJ.TEKST i SZUKAJ.TEKST.B nie jest uwzględniana wielkość liter. Jeśli w wyszukiwaniu powinna zostać uwzględniona wielkość liter, należy użyć funkcji ZNAJDŹ i ZNAJDŹ.B.

  • Przy określaniu argumentu tekst_szukany można używać znaków wieloznacznych: znaku zapytania (?) i gwiazdki (*). Znak zapytania odpowiada dowolnemu znakowi, a gwiazdka dowolnej sekwencji znaków. Aby znaleźć znak zapytania lub gwiazdkę, przed szukanym znakiem należy wpisać tyldę (~).  

  • Jeśli argument tekst_szukany nie zostanie znaleziony, funkcja zwróci błąd #ARG!

  • Jeśli argument nr_poz_pocz zostanie pominięty, przyjmuje się, że jest równy 1.

  • Jeśli argument nr_poz_pocz nie jest większy od 0 lub jest większy niż długość argumentu w_tekście, funkcja zwraca błąd #ARG!

  • Dzięki argumentowi nr_poz_pocz można pomijać określoną liczbę znaków. Załóżmy na przykład, że jest przetwarzany następujący tekst: „AUM0093.UbraniaMęskieMłodzieżowe”. Aby odnaleźć pozycję pierwszego znaku „U” w opisowej części tekstu przy użyciu funkcji SZUKAJ.TEKST, należy nadać argumentowi nr_poz_pocz wartość 8, tak aby nie była przeszukiwana część tekstu będąca numerem seryjnym (w tym przypadku „AUM0093”). Funkcja SZUKAJ.TEKST rozpoczyna wyszukiwanie od znaku na pozycji 8, odnajduje argument tekst_szukany przy następnym znaku i zwraca liczbę 9. Funkcja SZUKAJ.TEKST zawsze zwraca liczbę znaków względem początku argumentu w_tekście, łącznie ze znakami pominiętymi w przypadku, gdy argument nr_poz_pocz jest większy niż 1.

Przykłady

Skopiuj przykładowe dane z poniższej tabeli i wklej je w komórce A1 nowego arkusza programu Excel. Aby formuły wyświetlały wyniki, zaznacz je, naciśnij klawisz F2, a następnie naciśnij klawisz Enter. Jeśli to konieczne, możesz dostosować szerokości kolumn, aby wyświetlić pełne dane.

Dane

Zestawienia

Marża zysku

marża

Dziś "szef" jest w firmie.

Formuła

Opis

Wynik

=SZUKAJ.TEKST("e";A2;6)

Pozycja pierwszej litery „e” w ciągu zawartym w komórce A2, zaczynając od szóstego znaku.

7

=SZUKAJ.TEKST(A4;A3)

Pozycja wyrazu „marża” (wyszukiwany ciąg umieszczony w komórce A4) w ciągu „Marża zysku” (komórka A3, w której znajduje się ciąg do przeszukania).

8

=ZASTĄP(A3;SZUKAJ.TEKST(A4;A3);5;"Kwota")

Zamienia ciąg „Marża” na ciąg „Kwota”, najpierw szukając pozycji ciągu „Marża” w komórce A3, a następnie zamieniając pierwszy znak i kolejne cztery znaki ciągiem „Kwota”.

Kwota zysku

=FRAGMENT.TEKSTU(A3;SZUKAJ.TEKST(" ";A3)+1;4)

Zwraca cztery pierwsze znaki występujące po pierwszej spacji w ciągu „Marża zysku” (komórka A3).

zysk

=SZUKAJ.TEKST("""";A5)

Pozycja pierwszego podwójnego znaku cudzysłowu ('') w komórce A5.

5

=FRAGMENT.TEKSTU(A5;SZUKAJ.TEKST("""";A5)+1;SZUKAJ.TEKST("""";A5;SZUKAJ.TEKST("""";A5)+1)-SZUKAJ.TEKST("""";A5)-1)

Zwraca tylko tekst ujęty w podwójne cudzysłowy, znajdujący się w komórce A5.

szef

Rozwijaj swoje umiejętności
Poznaj szkolenia
Uzyskuj nowe funkcje w pierwszej kolejności
Dołącz do niejawnych testerów pakietu Office

Czy te informacje były pomocne?

Dziękujemy za opinię!

Dziękujemy za opinię! Wygląda na to, że połączenie Cię z jednym z naszych agentów pomocy technicznej pakietu Office może być pomocne.

×