LICZ.JEŻELI, funkcja

Funkcja LICZ.JEŻELI, jedna z funkcji statystycznych, umożliwia policzenie liczby komórek, które spełniają dane kryteria. Można na przykład policzyć, ile razy konkretna nazwa miasta występuje na liście klientów.

Mówiąc najprościej, działanie funkcji LICZ.JEŻELI jest następujące:

  • =LICZ.JEŻELI(Gdzie chcesz szukać?; Co chcesz znaleźć?)

Na przykład:

  • =LICZ.JEŻELI(A2:A5;"Londyn")

  • =LICZ.JEŻELI(A2:A5;A4)

Przeglądarka nie obsługuje klipu wideo. Instalowanie dodatku Microsoft Silverlight, Adobe Flash Player lub programu Internet Explorer 9.

LICZ.JEŻELI(zakres;kryteria)

Nazwa argumentu

Opis

zakres    (wymagany)

Grupa komórek, które mają zostać zliczone. Zakres może zawierać liczby, tablice, nazwany zakres lub odwołania zawierające liczby. Wartości puste i tekst są ignorowane.

Dowiedz się, jak zaznaczać zakresy w arkuszu.

kryteria    (wymagany)

Liczba, wyrażenie, odwołanie do komórki lub ciąg tekstowy określające, które komórki będą zliczane.

Można użyć liczby, np. 32, porównania, np. ">32", komórki, np. B4 lub wyrazu, np. "jabłka".

Funkcja LICZ.JEŻELI używa tylko pojedynczego kryterium. Aby użyć wielu kryteriów, należy skorzystać z funkcji LICZ.WARUNKI.

Przykłady

Aby skorzystać z tych przykładów w programie Excel, skopiuj dane z poniższej tabeli i wklej je w komórce A1 nowego arkusza.

Dane

Dane

jabłka

32

pomarańcze

54

brzoskwinie

75

jabłka

86

Formuła

Opis

=LICZ.JEŻELI(A2:A5;"jabłka")

Zwraca liczbę komórek zawierających wyraz „jabłka” w komórkach z zakresu od A2 do A5. Wynik to 2.

=LICZ.JEŻELI(A2:A5;A4)

Zlicza komórki zawierające wyraz „brzoskwinie” (wartość komórki A4) w komórkach z zakresu od A2 do A5. Wynik to 1.

=LICZ.JEŻELI(A2:A5;A2)+LICZ.JEŻELI(A2:A5;A3)

Zlicza komórki zawierające wyraz „jabłka” (wartość komórki A2) i wyraz „pomarańcze” (wartość komórki A3) w komórkach z zakresu od A2 do A5. Wynik to 3. Ta formuła używa funkcji LICZ.JEŻELI dwa razy do określenia wielu kryteriów (jedno kryterium na wyrażenie). Można też użyć funkcji LICZ.WARUNKI.

=LICZ.JEŻELI(B2:B5;">55")

Zwraca liczbę komórek z zakresu od B2 do B5, które zawierają wartość większą niż 55. Wynik to 2.

=LICZ.JEŻELI(B2:B5;"<>"&B4)

Zwraca liczbę komórek z zakresu od B2 do B5, które zawierają wartość różną od 75. Użycie znaku handlowego „i” (&) powoduje scalenie operatora porównania „nierówne” (<>) i wartości w komórce B4, co może być odczytane jako =LICZ.JEŻELI(B2:B5;"<>75"). Wynik to 3.

=LICZ.JEŻELI(B2:B5;">=32")-LICZ.JEŻELI(B2:B5;">85")

Zwraca liczbę komórek z zakresu od B2 do B5, które zawierają wartość większą niż (>) lub równą (=) 32 i mniejszą niż (<) lub równą (=) 85. Wynik to 3.

=LICZ.JEŻELI(A2:A5;"*")

Zwraca liczbę komórek z zakresu od A2 do A5, które zawierają jakikolwiek tekst. Gwiazdka (*) jest używana jako symbol wieloznaczny odpowiadający dowolnemu znakowi. Wynik to 4.

= LICZ.JEŻELI(A2:A5;"????ka")

Zwraca liczbę komórek z zakresu od A2 do A5, które zawierają tekst o długości dokładnie 6 znaków kończący się literami „ka”. Znak zapytania (?) jest używany jako symbol wieloznaczny odpowiadający pojedynczemu znakowi. Wynik to 2.

Typowe problemy

Problem

Co się nie udało

Dla długich ciągów jest zwracana nieprawidłowa wartość.

Funkcja LICZ.JEŻELI zwraca niepoprawne wyniki w razie użycia jej do dopasowania ciągów mających więcej niż 255 znaków.

Do dopasowania ciągów mających więcej niż 255 znaków należy użyć funkcji ZŁĄCZ.TEKSTY lub operatora łączenia (&). Na przykład: =LICZ.JEŻELI(A2:A5;"długi ciąg"&"inny długi ciąg").

Wartość nie jest zwracana, mimo że jest oczekiwana.

Należy się upewnić, że argument kryteria został ujęty w cudzysłów.

Formuła LICZ.JEŻELI powoduje zwrócenie błędu #ARG! w przypadku odwoływania się do innego arkusza.

Ten błąd występuje, gdy formuła zawierająca funkcję odwołuje się do komórek lub zakresu w zamkniętym skoroszycie, a komórki są obliczane. Aby ta funkcja działała, musi być otwarty drugi skoroszyt.

Najważniejsze wskazówki

Czynność

Uzasadnienie

Należy pamiętać, że funkcja LICZ.JEŻELI ignoruje wielkość liter w ciągach tekstowych.

W kryteriach nie jest uwzględniana wielkość liter. Innymi słowy ciąg „jabłka” i ciąg „JABŁKA” spowodują wyszukanie tych samych komórek.

Używaj symboli wieloznacznych.

W kryteriach można stosować znaki wieloznaczne — znak zapytania (?) i gwiazdkę (*). Znak zapytania odpowiada dowolnemu pojedynczemu znakowi, a gwiazdka odpowiada dowolnej sekwencji znaków. Aby wyszukać rzeczywisty znak zapytania lub gwiazdkę, należy przed takim znakiem wpisać tyldę (~).

Na przykład funkcja =LICZ.JEŻELI(A2:A5;"jabłk?") policzy wszystkie wystąpienia ciągu „jabłk” z dodaną jeszcze jedną literą, która może być różna.

Upewnij się, że dane nie zawierają błędnych znaków.

W przypadku zliczania wartości tekstowych należy się upewnić, że dane nie zawierają początkowych ani końcowych spacji, niespójnych cudzysłowów prostych ani drukarskich, znaków zapytania ani znaków niedrukowanych. Wystąpienie takich znaków może spowodować zwrócenie przez funkcję LICZ.JEŻELI nieoczekiwanej wartości.

Spróbuj użyć funkcji OCZYŚĆ lub funkcji USUŃ.ZBĘDNE.ODSTĘPY.

Ze względów praktycznych używaj nazwanych zakresów.

Funkcja LICZ.JEŻELI obsługuje nazwane zakresy w formule (np. =LICZ.JEŻELI(owoce;">=32")-LICZ.JEŻELI(owoce;">85"). Nazwany zakres może znajdować się w bieżącym arkuszu, innym arkuszu w tym samym skoroszycie lub w innym skoroszycie. Aby można było odwołać się z innego skoroszytu, drugi skoroszyt także musi być otwarty.

Uwaga : Funkcja LICZ.JEŻELI nie będzie zliczać komórek na podstawie koloru czcionki lub tła komórki. Program Excel obsługuje jednak funkcje zdefiniowane przez użytkownika (UDF) przy użyciu operacji języka Microsoft Visual Basic for Applications (VBA) na komórkach na podstawie koloru tła lub czcionki. Oto przykład, jak można ustalić liczbę komórek z określonym kolorem komórki przy użyciu języka VBA.

Potrzebujesz dodatkowej pomocy?

Zawsze możesz zadać pytanie ekspertowi w społeczności technicznej programu Excel, uzyskać pomoc techniczną w społeczności witryny Answers bądź zasugerować nową funkcję lub ulepszenie w witrynie UserVoice dotyczącej programu Excel.

Zobacz też

Do zliczania niepustych komórek użyj funkcji ILE.NIEPUSTYCH

Do zliczania komórek spełniających wiele kryteriów użyj funkcji LICZ.WARUNKI

Zobacz klip wideo na temat sposobu korzystania z funkcji LICZ.WARUNKI

Funkcja SUMA.JEŻELI sumuje tylko wartości spełniające pojedyncze kryterium

Funkcja SUMA.WARUNKÓW sumuje tylko wartości spełniające wiele kryteriów

Funkcja WARUNKI (usługa Office 365, program Excel 2016 lub nowszy)

Funkcja USUŃ.ZBĘDNE.ODSTĘPY służy do usuwania z komórek spacji początkowych i końcowych

Funkcja OCZYŚĆ służy do usuwania z komórek znaków niedrukowalnych

Omówienie formuł w programie Excel

Jak unikać niepoprawnych formuł

Wykrywanie błędów w formułach

Funkcje statystyczne

Funkcje programu Excel (lista alfabetyczna)

Funkcje programu Excel (według kategorii)

Używanie funkcji SUMA.JEŻELI i LICZ.JEŻELI oraz funkcji pokrewnych do szybkiego analizowania danych (bezpłatny podgląd)

Rozwijaj swoje umiejętności
Poznaj szkolenia
Uzyskuj nowe funkcje w pierwszej kolejności
Dołącz do niejawnych testerów pakietu Office

Czy te informacje były pomocne?

Dziękujemy za opinię!

Dziękujemy za opinię! Wygląda na to, że połączenie Cię z jednym z naszych agentów pomocy technicznej pakietu Office może być pomocne.

×