JEŻELI, funkcja

Funkcja JEŻELI jest jedną z najbardziej popularnych funkcji programu Excel, która umożliwia tworzenie logicznych porównań wartości z oczekiwanymi wynikami. Mówiąc najprościej, działanie funkcji JEŻELI jest następujące:

  • JEŻELI (jakieś wyrażenie jest prawdziwe, to wykonaj określone działanie, a w przeciwnym razie wykonaj inne działanie)

Instrukcja JEŻELI może zatem generować dwa wyniki. Pierwszy wynik otrzymamy, jeśli porównanie jest prawdziwe, a drugi — jeśli porównanie jest fałszywe.

Jeśli chcesz przejść od razu do pracy z wieloma instrukcjami JEŻELI, zobacz: Zaawansowane funkcje JEŻELI — praca z formułami zagnieżdżonymi i unikanie problemów.

Użyj funkcji JEŻELI, jednej z funkcji logicznych, aby zwrócić jedną wartość, jeśli warunek jest prawdziwy, lub inną wartość, jeśli jest fałszywy.

Składnia

JEŻELI(test_logiczny;wartość_jeżeli_prawda;[wartość_jeżeli_fałsz])

Na przykład:

  • =JEŻELI(A2>B2;"Budżet przekroczony";"OK")

  • =JEŻELI(A2=B2;B4-A4;"")

Nazwa argumentu

Opis

test_logiczny    (wymagane)

Warunek, który ma zostać sprawdzony.

wartość_jeżeli_prawda    (wymagane)

Wartość, która ma zostać zwrócona, jeśli wynik argumentu test_logiczny ma wartość PRAWDA.

wartość_jeżeli_fałsz    (opcjonalne)

Wartość, która ma zostać zwrócona, jeśli wynik argumentu test_logiczny ma wartość FAŁSZ.

Proste przykłady działania funkcji JEŻELI

Komórka D2 zawiera formułę =JEŻELI(C2="Tak";1;2)
  • =JEŻELI(C2="Tak";1;2)

W powyższym przykładzie działanie formuły w komórce D2 jest następujące: JEŻELI(C2 = Tak, to zwróć wartość 1, a w przeciwnym razie zwróć wartość 2)

Komórka D2 zawiera formułę =JEŻELI(C2=1;"Tak";"Nie")
  • =JEŻELI(C2=1;"Tak";"Nie")

W tym przykładzie działanie formuły w komórce D2 jest następujące: JEŻELI(C2 = 1, to zwróć wartość Tak, a w przeciwnym razie zwróć wartość Nie)

Jak widać, funkcja JEŻELI może służyć do oceny zarówno wartości, jak i ciągów tekstowych. Można jej również używać do oceny błędów. Oprócz porównywania wyrażeń i zwracania pojedynczych wyników można również używać operatorów matematycznych i wykonywać dodatkowe obliczenia w zależności od używanych kryteriów. Można również zagnieżdżać szereg funkcji JEŻELI w celu wykonywania wielokrotnych porównań.

Uwaga : Jeśli chcesz używać ciągów tekstowych w formułach, musisz ująć je w cudzysłów (np. "Tekst"). Jedynym wyjątkiem od tej reguły jest używanie wartości PRAWDA lub FAŁSZ, które są automatycznie rozpoznawane przez program Excel.

Jak zacząć

Najlepszy sposób na rozpoczęcie tworzenia instrukcji JEŻELI polega na określeniu, co zamierzasz osiągnąć. Jakiego porównania chcesz dokonać? Napisanie instrukcji JEŻELI jest często bardzo proste — wystarczy logicznie pomyśleć w ten sposób: „co powinno się zdarzyć, jeśli warunek będzie spełniony, a co, jeśli nie będzie spełniony”. Zawsze należy upewnić się, że instrukcje odpowiadają logicznemu ciągowi zdarzeń. W przeciwnym razie działanie formuły nie będzie zgodne z oczekiwaniami. Jest to szczególnie ważne w przypadku tworzenia złożonych (zagnieżdżonych) instrukcji JEŻELI.

Więcej przykładów działania funkcji JEŻELI

Formuła w komórce D2: =JEŻELI(C2>B2;”Budżet przekroczony”;”W ramach budżetu”)
  • =JEŻELI(C2>B2;”Budżet przekroczony”;”W ramach budżetu”)

W powyższym przykładzie działanie funkcji JEŻELI w komórce D2 jest następujące: JEŻELI(wartość w komórce C2 jest większa niż wartość w komórce B2, to zwróć „Budżet przekroczony”, a w przeciwnym razie zwróć „W ramach budżetu”)

Formuła w komórce E2: =JEŻELI(C2>B2;C2-B2;"")
  • =JEŻELI(C2>B2;C2-B2;0)

Na powyższej ilustracji zamiast wyniku tekstowego zostanie zwrócone wyrażenie matematyczne. Działanie formuły w komórce E2 jest następujące: JEŻELI(wartość rzeczywista przekracza koszty według budżetu, to odejmij koszty według budżetu od wartości rzeczywistej, a w przeciwnym razie nic nie zwracaj).

Formuła w komórce F7: JEŻELI(E7="Tak";F5*0,0825;0)
  • =JEŻELI(E7="Tak";F5*0,0825;0)

W tym przykładzie działanie formuły w komórce F7 jest następujące: JEŻELI(E7 = "Tak", to przemnóż wartość łącznej kwoty w komórce F5 przez 8,25%, a w przeciwnym razie zwróć wartość 0, ponieważ podatek od sprzedaży nie jest naliczany)

Najważniejsze wskazówki dotyczące stałych

W ostatnim przykładzie widać, że do formuły wprowadzono zarówno wartość "Tak", jak i stawkę podatku od sprzedaży (0,0825). Zwykle nie zaleca się używania stałych dosłownych (które mogą się zmieniać co jakiś czas) bezpośrednio w formułach, ponieważ w przyszłości ich znalezienie i zmodyfikowanie może okazać się trudne. Znacznie lepszą praktyką jest umieszczenie ich w osobnych komórkach, dzięki czemu można je łatwo znaleźć i zmienić. W tym przykładzie umieszczenie stałej w formule nie powoduje problemów, ponieważ mamy tylko jedną funkcję JEŻELI, a stawka podatku od sprzedaży jest rzadko zmieniana. W razie potrzeby można łatwo zmienić stawkę w formule.

Operatory arytmetyczne

Aby dowiedzieć się więcej o różnych operatorach arytmetycznych, jakich można używać w formułach (< mniejsze niż, > większe niż, = równe, <> nie równe itp.), zobacz ten artykuł: Operatory arytmetyczne i ich pierwszeństwo.

Korzystanie z funkcji JEŻELI w celu sprawdzenia, czy komórka jest pusta

Czasami może być konieczne sprawdzenie, czy komórka jest pusta — na ogół wówczas, gdy nie chcesz, by formuła zwracała wynik bez określonych wartości wejściowych.

Formuła w komórce E2: =JEŻELI(D2=1;"Tak";JEŻELI(D2=2;"Nie";"Możliwe"))

W takim przypadku można zastosować funkcję JEŻELI w połączeniu z funkcją CZY.PUSTA:

  • =JEŻELI(CZY.PUSTA(D2);"Pusta";"Niepusta")

Działanie formuły jest następujące: JEŻELI(komórka D2 jest pusta, to zwróć tekst „Pusta”, a w przeciwnym razie zwróć tekst „Niepusta”). Możesz również łatwo użyć własnej formuły dla warunku "Niepusta". W kolejnym przykładzie zastosujemy cudzysłowy ("") zamiast funkcji CZY.PUSTA. Ciąg "" oznacza po prostu „nic”.

Sprawdzanie, czy komórka jest pusta — formuła w komórce E2: =JEŻELI(CZY.PUSTA(D2);"Pusta";"Niepusta")
  • =JEŻELI(D3="";"Pusta";"Niepusta")

Działanie formuły jest następujące: JEŻELI(komórka D3 nie zawiera nic, to zwróć tekst „Pusta”, a w przeciwnym razie zwróć tekst „Niepusta”). Poniżej przedstawiono typowy przykład użycia ciągu "" w celu uniemożliwienia wykonania obliczeń w przypadku, gdy komórka zależna jest pusta:

  • =JEŻELI(D3="";"";twoja_formuła())

    JEŻELI(komórka D3 nie zawiera nic, to nic nie zwracaj, a w przeciwnym razie oblicz formułę).

Przykład zagnieżdżonej instrukcji JEŻELI

Prosta funkcja JEŻELI może generować tylko dwa wyniki (Prawda lub Fałsz), natomiast zagnieżdżenie tych funkcji pozwala uzyskać od 3 do 64 wyników.

Używanie cudzysłowów ("") w celu sprawdzenia, czy komórka jest pusta — formuła w komórce E3: =JEŻELI(D3="";"Pusta";"Niepusta")
  • =JEŻELI(D2=1;”Tak”;JEŻELI(D2=2;”Nie”;”Możliwe”))

Na powyższej ilustracji działanie formuły w komórce E2 jest następujące: JEŻELI(D2 ma wartość 1, to zwróć wartość „Tak”, a w przeciwnym razie JEŻELI(D2 ma wartość 2, to zwróć wartość „Nie”, a w przeciwnym razie zwróć wartość „Możliwe”)). Zwróć uwagę na to, że na końcu formuły znajdują się dwa nawiasy zamykające. Są one wymagane do zamknięcia obu funkcji JEŻELI. Próba wprowadzenia formuły bez obu tych nawiasów zamykających spowoduje, że program Excel spróbuje to poprawić.

Przestroga

Program Excel pozwala zagnieżdżać maksymalnie 64 funkcje JEŻELI, ale zdecydowanie nie zaleca się korzystania z tej możliwości. Dlaczego?

  • Poprawne skonstruowanie wielu instrukcji JEŻELI wymaga poświęcenia dużej ilości uwagi i dokładnego przeanalizowania logicznego działania wszystkich warunków. Jeśli nie uda Ci się w pełni dokładnie zagnieździć instrukcji JEŻELI, to formuła może działać w 75% przypadków, ale dla pozostałej części danych może zwracać nieoczekiwane wyniki. Niestety szanse na znalezienie tych 25% problematycznych przypadków są małe.

  • Zarządzanie wieloma instrukcjami JEŻELI może okazać się bardzo trudne, zwłaszcza, gdy od ich napisania upłynie trochę czasu lub — co gorsza — wystąpi konieczność przeanalizowania instrukcji utworzonych przez inną osobę.

  • Wiele instrukcji JEŻELI wymaga wielu nawiasów otwierających i zamykających (). Zarządzanie nimi może sprawiać trudności — w zależności od tego, jak złożona jest formuła.

Typowe problemy

Problem

Przyczyna

0 (zero) w komórce

Brak argumentu wartość_jeżeli_prawda lub wartość_jeżeli_fałsz. Aby była wyświetlana prawidłowa wartość, dodaj tekst argumentu do obu argumentów lub dodaj wartość PRAWDA lub FAŁSZ do argumentu.

#NAZWA? w komórce

Zazwyczaj oznacza to, że formuła jest błędnie wpisana.

Masz pytanie dotyczące konkretnej funkcji?

Zadaj pytanie na forum społeczności programu Excel

Pomoc w ulepszaniu programu Excel

Masz sugestie dotyczące możliwości ulepszenia następnej wersji programu Excel? Jeśli tak, zapoznaj się z tematami w witrynie UserVoice dotyczącej programu Excel.

Zobacz też

Zobacz klip wideo dotyczący korzystania z funkcji JEŻELI

Funkcja JEŻELI (usługa Office 365, program Excel 2016 i nowsze wersje programu Excel)

Zaawansowane funkcje JEŻELI — praca z formułami zagnieżdżonymi i unikanie problemów

Szkoleniowe klipy wideo: zaawansowane funkcje JEŻELI

Funkcja LICZ.JEŻELI będzie zliczać wartości na podstawie pojedynczego kryterium

Funkcja LICZ.WARUNKI będzie zliczać wartości na podstawie wielu kryteriów

Funkcja SUMA.JEŻELI będzie sumować wartości na podstawie pojedynczego kryterium

Funkcja SUMA.WARUNKÓW będzie sumować wartości na podstawie wielu kryteriów

ORAZ, funkcja

LUB, funkcja

WYSZUKAJ.PIONOWO, funkcja

Omówienie formuł w programie Excel

Jak unikać niepoprawnych formuł

Poprawianie typowych błędów w formułach przy użyciu funkcji sprawdzania błędów

Funkcje logiczne

Funkcje programu Excel (lista alfabetyczna)

Funkcje programu Excel (według kategorii)

Czy te informacje były pomocne?

Doskonale! Czy chcesz przesłać inne opinie?

Jak możemy to poprawić?

Dziękujemy za opinię!

×