INDEKS, funkcja

Funkcja INDEKS zwraca wartość lub odwołanie do wartości, która znajduje się w tabeli lub zakresie.

Przeglądarka nie obsługuje klipu wideo. Instalowanie dodatku Microsoft Silverlight, Adobe Flash Player lub programu Internet Explorer 9.

Funkcji INDEKS można używać na dwa sposoby:

  • Jeśli chcesz zwrócić wartość określonej komórki lub tablicy komórek, zobacz Forma tablicowa.

  • Jeśli chcesz zwrócić odwołanie do określonych komórek, zobacz Forma odwołaniowa.

Forma tablicowa

Opis

Zwraca wartość elementu w tabeli lub tablica, wybranego przez indeksy numerów kolumny i wiersza.

Jeśli pierwszy argument funkcji INDEKS jest stałą tablicową, należy używać formy tablicowej.

Składnia

INDEKS(tablica;nr_wiersza;[nr_kolumny])

Składnia funkcji INDEKS obejmuje następujące argumenty.

  • Tablica    Argument wymagany. Zakres komórek lub stała tablicowa.

    • Jeśli argument tablica zawiera tylko jeden wiersz lub jedną kolumnę, to odpowiednio argument nr_wiersza lub nr_kolumny jest argumentem opcjonalnym.

    • Jeśli tablica zawiera więcej niż jeden wiersz i więcej niż jedną kolumnę, a zostanie użyty tylko jeden argument, nr_wiersza lub nr_kolumny, funkcja INDEKS zwróci tablicę z całym wierszem lub z całą kolumną.

  • Nr_wiersza    Argument wymagany. Wskazuje wiersz tablicy, z którego zostanie zwrócona wartość. Jeśli argument nr_wiersza zostanie pominięty, będzie wymagany argument nr_kolumny.

  • Nr_kolumny    Argument opcjonalny. Wskazuje kolumnę tablicy, z której zostanie zwrócona wartość. Jeśli argument nr_kolumny zostanie pominięty, będzie wymagany argument nr_wiersza.

Spostrzeżenia

  • Jeśli zostaną użyte zarówno argumenty nr_wiersza, jak i nr_kolumny, funkcja INDEKS zwróci wartość w komórce na przecięciu zdefiniowanym przez argumenty nr_wiersza i nr_kolumny.

  • Jeśli argument nr_wiersza lub nr_kolumny będzie mieć wartość zero (0), funkcja INDEKS zwróci tablicę wartości odpowiednio dla całego wiersza lub dla całej kolumny. Aby użyć wartości zwracanych w postaci tablicy, funkcję INDEKS należy wprowadzać jako formuła tablicowa — w przypadku wiersza do poziomego zakresu komórek, a w przypadku kolumny do pionowego zakresu komórek. Aby wprowadzić formułę tablicową, należy nacisnąć klawisze CTRL+SHIFT+ENTER.

    Uwaga :  W aplikacji Excel Web App nie można tworzyć formuł tablicowych.

  • Argumenty nr_wiersza i nr_kolumny muszą wskazywać na komórki znajdujące się wewnątrz tablicy; w przeciwnym przypadku funkcja INDEKS zwraca wartość błędu #ADR!.

Przykłady

Przykład 1

W tych przykładach zastosowano funkcję INDEKS do znalezienia wartości w komórce na przecięciu wiersza i kolumny.

Skopiuj przykładowe dane z poniższej tabeli i wklej je w komórce A1 nowego arkusza programu Excel. Aby formuły wyświetlały wyniki, zaznacz je, naciśnij klawisz F2, a następnie naciśnij klawisz Enter. Jeśli to konieczne, możesz dostosować szerokości kolumn, aby wyświetlić pełne dane.

Dane

Dane

Jabłka

Cytryny

Banany

Gruszki

Formuła

Opis

Wynik

=INDEKS(A2:B3;2;2)

Wartość na przecięciu drugiego wiersza i drugiej kolumny w zakresie A2:B3.

Gruszki

=INDEKS(A2:B3;2;1)

Wartość na przecięciu drugiego wiersza i pierwszej kolumny w zakresie A2:B3.

Banany

Przykład 2

W tym przykładzie zastosowano funkcję INDEKS w formule tablicowej do znalezienia wartości w dwóch komórkach określonych w tablicy 2x2.

W takim przypadku zaznacz dwie komórki pionowe, takie jak A1:A2, wklej następującą formułę =INDEKS({1;2\3;4};0;2) do pierwszej komórki, a następnie naciśnij klawisze CTRL+SHIFT+ENTER. Gdy formuła zostanie wprowadzona jako formuła tablicowa, program Excel automatycznie wklei ją do drugiej komórki.

Formuła

Opis

Wynik

=INDEKS({1;2\3;4};0;2)

Wartość znaleziona w pierwszym wierszu, drugiej kolumnie w tablicy. Tablica zawiera wartości 1 i 2 w pierwszym wierszu oraz wartości 3 i 4 w drugim wierszu.

2

Wartość znaleziona w drugim wierszu, drugiej kolumnie w tablicy (tej samej tablicy co powyżej).

4

Uwaga : Jest to formuła tablicowa, którą należy wprowadzić za pomocą klawiszy CTRL+SHIFT+ENTER. Program Excel automatycznie otoczy formułę nawiasami klamrowymi {}. Jeśli spróbujesz je wprowadzić samodzielnie, program Excel wyświetli formułę jako tekst. Jeśli nie naciśniesz klawiszy CTRL+SHIFT+ENTER, formuła zwróci błąd #ARG!.

Początek strony

Forma odwołaniowa

Opis

Zwraca odwołanie do komórki lezącej na przecięciu określonego wiersza i kolumny. Jeśli odwołanie zawiera nieprzylegające obszary, można wybrać obszar, który ma zostać uwzględniony.

Składnia

INDEKS(odwołanie;nr_wiersza;[nr_kolumny];[nr_obszaru])

Składnia funkcji INDEKS obejmuje następujące argumenty.

  • Odwołanie    Argument wymagany. Odwołanie do co najmniej jednego zakresu komórek.

    • Jeśli odwołanie dotyczy nieprzylegających zakresów, należy je ująć w nawiasy.

    • Jeśli każdy obszar w argumencie odwołanie zawiera tylko jeden wiersz lub kolumnę, to odpowiednio argument nr_wiersza lub nr_kolumny jest opcjonalny. Na przykład w przypadku odwołania do jednego wiersza należy zastosować funkcję INDEKS(odwołanie; nr_kolumny).

  • Nr_wiersza    Argument wymagany. Numer wiersza w odwołaniu, z którego zostanie zwrócony wynik w postaci odwołania.

  • Nr_kolumny    Argument opcjonalny. Numer kolumny w odwołaniu, z której zostanie zwrócony wynik w postaci odwołania.

  • Nr_obszaru    Argument opcjonalny. Określa zakres w odwołaniu, z którego zostanie zwrócone przecięcie wiersza o numerze nr_wiersza z kolumną o numerze nr_kolumny. Pierwszy zaznaczony lub wprowadzony obszar ma numer 1, drugi obszar ma numer 2 itd. Jeśli argument nr_obszaru zostanie pominięty, funkcja INDEKS użyje obszaru 1.  Obszary wymienione w tym miejscu muszą znajdować się w jednym arkuszu.  Jeśli określisz obszary, które nie znajdują się w tym samym arkuszu, spowoduje to wystąpienie błędu #ARG!.  Jeśli musisz użyć zakresów znajdujących się w różnych arkuszach, zalecamy użycie formy tablicowej funkcji INDEKS i obliczenie zakresu tworzącego tablicę za pomocą innej funkcji.  W celu obliczenia zakresu, który będzie używany, możesz na przykład użyć funkcji WYBIERZ.

Na przykład jeśli argument odwołanie opisuje komórki (A1:B4;D1:E4;G1:H4), argument nr_obszaru 1 to zakres A1:B4, argument nr_obszaru 2 to zakres D1:E4, a argument nr_obszaru 3 to zakres G1:H4.

Spostrzeżenia

  • Po określeniu przez argumenty odwołanie i nr_obszaru określonego zakresu, argumenty nr_wiersza i nr_kolumny wskazują na określoną komórkę: argument nr_wiersza 1 to pierwszy wiersz w zakresie, argument nr_kolumny 1 to pierwsza kolumna itd. Odwołanie zwrócone przez funkcję INDEKS to przecięcie wiersza nr_wiersza z kolumną nr_kolumny.

  • Jeśli argument nr_wiersza lub nr_kolumny jest równy zero (0), funkcja INDEKS zwraca odwołanie odpowiednio do całego wiersza lub do całej kolumny.

  • Argumenty nr_wiersza, nr_kolumny i nr_obszaru muszą wskazywać na komórkę znajdującą się wewnątrz odwołania; w przeciwnym przypadku funkcja INDEKS zwraca wartość błędu #ADR!. Jeśli argumenty nr_wiersza i nr_kolumny zostaną pominięte, funkcja INDEKS zwróci obszar w odwołaniu określonym przez argument nr_obszaru.

  • W wyniku działania funkcji INDEKS jest uzyskiwane odwołanie, które jest interpretowane jako takie przez inne formuły. W zależności od formuły, wynik zwracany przez funkcję INDEKS może być używany jako odwołanie lub jako wartość. Na przykład formuła KOMÓRKA("szerokość";INDEKS(A1:B2;1;2)) jest równoznaczna z formułą KOMÓRKA("szerokość";B1). Funkcja KOMÓRKA używa wartości zwróconej przez funkcję INDEKS, traktując ją jako odwołanie do komórki. Z drugiej strony, formuły, takie jak 2*INDEKS(A1:B2;1;2), przekształcają wartość zwracaną przez funkcję INDEKS na liczbę zawartą w komórce B1.

Uwaga :  Funkcja KOMÓRKA jest niedostępna w aplikacji Excel Web App.

Przykłady

Skopiuj przykładowe dane z poniższej tabeli i wklej je w komórce A1 nowego arkusza programu Excel. Aby formuły wyświetlały wyniki, zaznacz je, naciśnij klawisz F2, a następnie naciśnij klawisz Enter. Jeśli to konieczne, możesz dostosować szerokości kolumn, aby wyświetlić pełne dane.

Owoce

Cena

Liczba

Jabłka

0,69 zł

40

Banany

0,34 zł

38

Cytryny

0,55 zł

15

Pomarańcze

0,25 zł

25

Gruszki

0,59 zł

40

Migdały

2,80 zł

10

Nerkowce

3,55 zł

16

Orzechy ziemne

1,25 zł

20

Orzechy włoskie

1,75 zł

12

Formuła

Opis

Wynik

=INDEKS(A2:C6;2;3)

Przecięcie drugiego wiersza i trzeciej kolumny w zakresie A2:C6, czyli zawartość komórki C3.

38

=INDEKS((A1:C6;A8:C11);2;2;2)

Przecięcie drugiego wiersza i drugiej kolumny w drugim obszarze zakresu A8:C11, czyli zawartość komórki B9.

1,25

=SUMA(INDEKS(A1:C11;0;3;1))

Suma trzeciej kolumny w pierwszym obszarze zakresu A1:C11, czyli suma wartości w zakresie C1:C11.

216

=SUMA(B2:INDEKS(A2:C6;5;2))

Suma zakresu zaczynającego się w komórce B2 i kończącego się na przecięciu piątego wiersza i drugiej kolumny zakresu A2:A6, czyli suma wartości w zakresie B2:B6.

2,42

Początek strony

Zobacz też

WYSZUKAJ.PIONOWO, funkcja

PODAJ.POZYCJĘ, funkcja

ADR.POŚR, funkcja

Wskazówki i przykłady dotyczące formuł tablicowych

Funkcje wyszukiwania i odwołań (informacje)

Rozwijaj swoje umiejętności
Poznaj szkolenia
Uzyskuj nowe funkcje w pierwszej kolejności
Dołącz do niejawnych testerów pakietu Office

Czy te informacje były pomocne?

Dziękujemy za opinię!

Dziękujemy za opinię! Wygląda na to, że połączenie Cię z jednym z naszych agentów pomocy technicznej pakietu Office może być pomocne.

×