Funkcja SUMA

Funkcja SUMA, jedna z funkcji matematycznych i trygonometrycznych, dodaje wartości. Możesz dodawać pojedyncze wartości, odwołania do komórek lub zakresów lub połączenie tych wszystkich trzech typów wyrażeń.

Na przykład:

  • =SUMA(A2:A10)

  • =SUMA(A2:A10;C2:C10)

Przeglądarka nie obsługuje klipu wideo. Instalowanie dodatku Microsoft Silverlight, Adobe Flash Player lub programu Internet Explorer 9.

Ten klip wideo jest częścią kursu szkoleniowego zatytułowanego Dodawanie liczb w programie Excel 2013.

SUMA(liczba1;[liczba2];...)

Nazwa argumentu

Opis

liczba1    (wymagany)

Pierwsza liczba, którą chcesz dodać. Liczbą może być na przykład 4, odwołanie do komórki, takie jak B6, lub zakres komórek, taki jak B2:B8.

liczba2–255    (opcjonalny)

Druga liczba, którą chcesz dodać. W ten sposób możesz określić do 255 liczb.

Jeśli chcesz szybko obliczyć sumę zakresu komórek, wystarczy zaznaczyć zakres i sprawdzić wartość w prawej dolnej części okna programu Excel.

Zrzut ekranu przedstawiający zaznaczanie zakresu komórek, a następnie sprawdzanie wartości na pasku stanu
Pasek stanu


To jest pasek stanu wyświetlający informacje dotyczące zaznaczenia, które może obejmować jedną lub wiele komórek. Kliknięcie prawym przyciskiem myszy na pasku stanu spowoduje wyświetlenie okna dialogowego funkcji zawierającego wszystkie opcje, które można wybrać. Pamiętaj, że wyświetlane są też wartości z zaznaczonego zakresu, jeśli te atrybuty są zaznaczone. Dowiedz się więcej o pasku stanu.

Najłatwiejszym sposobem dodania formuły SUMA do arkusza jest użycie kreatora autosumowania. Zaznacz pustą komórkę bezpośrednio powyżej lub poniżej zakresu, który chcesz zsumować, i na karcie Narzędzia główne lub Formuła na wstążce naciśnij pozycję Autosumowanie > Suma. Kreator autosumowania automatycznie wykrywa zakres, który ma zostać podsumowany, i tworzy formułę. Kreator działa również w poziomie, jeśli zaznaczysz komórkę po lewej lub prawej stronie zakresu, który ma zostać podsumowany. Pamiętaj, że rozwiązanie to nie będzie działać dla zakresów nieciągłych, ale jeszcze to omówimy w następnej sekcji.

Możesz użyć kreatora autosumowania, aby automatycznie tworzyć formuły sumy. Zaznacz zakres powyżej/poniżej lub po lewej/prawej stronie sumowanego zakresu, a następnie przejdź na kartę Formuła na wstążce i wybierz opcje Autosumowanie i SUMA.
Szybkie sumowanie ciągłych zakresów za pomocą kreatora autosumowania


Okno dialogowe Autosumowanie umożliwia również wybranie innych typowych funkcji, takich jak:

Korzystanie z funkcji Autosumowanie w pionie

Komórka B6 przedstawia formułę sumy autosumowania: =SUMA(B2:B5)

Kreator autosumowania wykrył automatycznie komórki B2:B5 jako zakres do podsumowania. Wszystko, co musisz zrobić, to nacisnąć klawisz Enter, aby potwierdzić wybór. Jeśli chcesz dodać/wykluczyć więcej komórek, przytrzymaj klawisz Shift i za pomocą klawiszy strzałek zaznacz odpowiedni zakres, a po zakończeniu naciśnij klawisz Enter.

Przewodnik funkcji IntelliSense: tag przestawny SUMA(liczba1;[liczba2];...) poniżej funkcji to przewodnik funkcji Intellisense. Jeśli klikniesz funkcję SUMA lub nazwę funkcji, element zmieni się w niebieski hiperlink prowadzący do tematu pomocy dla tej funkcji. Po kliknięciu poszczególnych elementów funkcji ich reprezentatywne części w formule zostaną wyróżnione. W tym przypadku wyróżniony będzie tylko zakres B2:B5, ponieważ w tej formule występuje tylko jedno odwołanie liczbowe. Tag funkcji IntelliSense zostanie wyświetlony dla dowolnej funkcji.

Korzystanie z funkcji Autosumowanie w poziomie

Komórka D2 przedstawia formułę sumy autosumowania: =SUMA(B2:C2)

Używanie funkcji SUMA w zakresach nieciągłych. Formuła w komórce C8 to =SUMA(C2:C3;C5:C6). Możesz również użyć nazwanych zakresów, więc formuła miałaby postać =SUMA(Tydzień1;Tydzień2).

Kreator autosumowania zazwyczaj działa tylko dla zakresów ciągłych, więc jeśli w zakresie sumy istnieją puste wiersze lub kolumny, program Excel zatrzyma się na pierwszym odstępie. W takim przypadku konieczne jest sumowanie według zaznaczenia, przez dodawanie po kolei poszczególnych zakresów. W tym przykładzie, jeśli dane znajdują się w komórce B4, program Excel wygeneruje formułę =SUMA(C2:C6), ponieważ rozpozna ciągły zakres.

Możesz szybko zaznaczyć wiele zakresów nieciągłych, trzymając naciśnięty klawisz Ctrl i klikając lewym przyciskiem myszy. Najpierw wpisz „=SUMA(”, następnie zaznacz różne zakresy, a program Excel automatycznie doda separator w formie średnika między zakresami. Po zakończeniu naciśnij klawisz Enter.

PORADA: Naciskając klawisze ALT+ =, możesz szybko dodać funkcję SUMA do komórki. Następnie wystarczy wybrać zakres(y).

Uwaga: można zauważyć, jak program Excel wyróżnia poszczególne zakresy funkcji różnymi kolorami, które są również używane w formule, więc zakres C2:C3 jest oznaczony jednym kolorem, a zakres C5:C6 — drugim. Program Excel wykona to dla wszystkich funkcji, chyba że zakres odwołania znajduje się w innym arkuszu lub w innym skoroszycie. W celu zapewnienia lepszego dostępu za pomocą technologii pomocniczej można użyć nazwanych zakresów, takich jak „Tydzień1”, „Tydzień2” itd., a następnie odwoływać się do nich w formule:

=SUMA(Tydzień1;Tydzień2)

W programie Excel można łatwo wykonywać operacje matematyczne — osobno oraz w połączeniu z funkcjami programu Excel, takimi jak SUMA. W poniższej tabeli wymieniono operatory, których można używać, oraz niektóre funkcje pokrewne. Operatory można wprowadzać przy użyciu wiersza klawiszy numerycznych na klawiaturze lub 10-klawiszowej klawiatury numerycznej (jeśli ją posiadasz). Na przykład naciskając klawisze Shift+8, wprowadzisz gwiazdkę (*) na potrzeby mnożenia.

Operator

Operacja

Przykłady

+

Dodawanie

=1+1

=A1+B1

=SUMA(A1:A10)+10

=SUMA(A1:A10)+B1

-

Odejmowanie

=1-1

=A1-B1

=SUMA(A1:A10)-10

=SUMA(A1:A10)-B1

*

Mnożenie

=1*1

=A1*B1

=SUMA(A1:A10)*10

=SUMA(A1:A10)*B1

=ILOCZYN(1;1) — funkcja ILOCZYN

/

Dzielenie

=1/1

=A1/B1

=SUMA(A1:A10)/10

=SUMA(A1:A10)/B1

=CZ.CAŁK.DZIELENIA(1;1) — funkcja CZ.CAŁK.DZIELENIA

^

Potęgowanie

=1^1

=A1^B1

=SUMA(A1:A10)^10

=SUMA(A1:A10)^B1

=POTĘGA(1;1) — funkcja POTĘGA

Aby uzyskać więcej informacji, zobacz Używanie programu Excel jako kalkulatora.

Inne przykłady

  1. Załóżmy, że chcemy zastosować rabat procentowy dla zakresu komórek, które zostały podsumowane.

    Używanie operatorów z funkcją SUMA. Formuła w komórce B16 to =SUMA(A2:A14)*-25%. Formuła zostałaby utworzona poprawnie, jeśli wartość -25% byłaby odwołaniem do komórki, takim jak np. =SUMA(A2:A14)*E2
    • = SUMA(A2:A14)*-25%

    Pozwoli to odliczyć 25% podsumowanego zakresu, jednak formuła używa stałej wartości 25%, która może być trudna do znalezienia później, jeśli zajdzie potrzeba jej zmiany. Dużo lepiej jest umieścić wartość 25% w komórce i odwoływać się do niej, gdzie jest lepiej widoczna i łatwo ją zmienić. Na przykład:

    • =SUMA(A2:A14)*E2

    Aby podzielić zamiast pomnożyć, wystarczy zastąpić znak „*” znakiem „/”: =SUMA(A2:A14)/E2

  2. Dodawanie do funkcji SUMA lub odejmowanie od niej

    i. Możesz łatwo dodać lub odjąć wartość od funkcji SUMA, używając operatora + lub - w następujący sposób:

    • =SUMA(A1:A10)+E2

    • =SUMA(A1:A10)-E2

W tej sekcji przedstawimy najważniejsze wskazówki dotyczące pracy z funkcją SUMA. Dużą część tych wskazówek można również stosować do pracy z innymi funkcjami.

Metoda =1+2 lub =A+B — mimo że można wprowadzić formułę =1+2+3 lub =A1+B1+C2 i uzyskać całkowicie dokładne wyniki, takie metody są podatne na błędy z kilku powodów:

  1. Literówki — załóżmy, że wprowadzasz znacznie więcej i/lub większe wartości, takie jak w następującym przykładzie:

    • =14598,93+65437,90+78496,23

    Następnie próbujesz sprawdzić, czy wprowadzone dane są poprawne. Znacznie łatwiej jest umieścić te wartości w osobnych komórkach i użyć formuły SUMA. Ponadto można sformatować wartości, gdy znajdują się w komórkach, aby były bardziej czytelne, niż gdy są częścią formuły.

    Zamiast używania ustalonych wartości w formułach użyj funkcji SUMA. Formuła w komórce D5 to =SUMA(D2:D4)
  2. Błędy #ARG! spowodowane odwołaniem do tekstu zamiast do liczb

    Jeśli korzystasz z formuły tego typu:

    • =A1+B1+C1 lub =A1+A2+A3

    Przykład nieprawidłowego konstruowania formuły. Formuła w komórce D2 to =A2+B2+C2

    Formuła może wygenerować błąd, jeśli w komórkach istnieją wartości nieliczbowe (tekst), które zwrócą błąd #ARG! Funkcja SUMA zignoruje wartości tekstowe i zwróci sumę tylko wartości liczbowych.

    Prawidłowa budowa formuły. Zamiast =A2+B2+C2 formuła w komórce D2 to =SUMA(A2:C2)
  3. Błąd #ADR! spowodowany usunięciem wierszy lub kolumn

    Błąd #ADR! spowodowany przez usunięcie kolumny. Formuła zmieniła się na =A2+#ADR!+B2

    Jeśli usuniesz wiersz lub kolumnę, formuła nie zostanie zaktualizowana w celu wykluczenia usuniętego wiersza i zwróci błąd #ADR!, gdy funkcja SUMA zostałaby automatycznie zaktualizowana.

    Funkcja SUMA jest automatycznie dopasowywana dla wstawionych lub usuniętych wierszy i kolumn
  4. Formuły nie spowodują zaktualizowania odwołań podczas wstawiania wierszy lub kolumn

    Formuły =A+B+C nie zostaną zaktualizowane, gdy dodasz wiersze

    Jeśli wstawisz wiersz lub kolumnę, formuła nie zostanie zaktualizowana w celu uwzględnienia dodanego wiersza, podczas gdy funkcja SUMA jest automatycznie aktualizowana (o ile nie został przekroczony zakres odwołania formuły). Jest to szczególnie ważne, jeśli oczekiwane jest aktualizowanie formuły, a tak się nie stanie i spowoduje to powstanie niepełnych wyników, czego użytkownik może nie zauważyć.

    Przykład przedstawia automatyczne rozszerzanie formuły z =SUMA(A2:C2) na =SUMA(A2:D2) po wstawieniu kolumny
  5. Funkcja SUMA z odwołaniami do poszczególnych komórek w porównaniu do zakresów

    Użycie formuły typu:

    • =SUMA(A1;A2;A3;B1;B2;B3)

    jest równie podatne na błędy podczas wstawiania lub usuwania wierszy w zakresie objętym odwołaniem z tych samych powodów. Dużo lepiej użyć pojedynczych zakresów, takich jak:

    • =SUMA(A1:A3;B1:B3),

    które będą aktualizowane podczas dodawania lub usuwania wierszy.

  1. Funkcji SUMA można oczywiście używać z innymi funkcjami. Oto przykład obliczenia miesięcznej średniej:

    Używanie funkcji SUMA z innymi funkcjami. Formuła w komórce M2 to =SUMA(A2:L2)/ILE.NIEPUSTYCH(A2:L2). Uwaga: kolumny maj–listopad są ukryte w celu zwiększenia przejrzystości.
    • =SUMA(A2:L2)/ILE.NIEPUSTYCH(A2:L2),

  2. co bierze sumę zakresu A2:L2 podzieloną przez liczbę niepustych komórek w zakresie A2:L2 (komórki maj–grudzień są puste).

  1. Czasami trzeba zsumować określoną komórkę w wielu arkuszach. Kuszące może być klikanie poszczególnych arkuszy i komórek i używanie po prostu operatora „+” w celu dodania wartości komórek, ale jest to pracochłonne i może być podatne na błędy.

    • =Arkusz1!A1+Arkusz2!A1+Arkusz3!A1

    Można to zrobić znacznie łatwiej za pomocą trójwymiarowej (3D) funkcji SUMA:

    Formuła sumy 3D w komórce D2 to = SUMA(Arkusz1:Arkusz3!A2)
    • =SUMA(Arkusz1:Arkusz3!A1),

    co spowoduje podsumowanie komórek A1 we wszystkich arkuszach od Arkusz1 do Arkusz3.

    Jest to szczególnie pomocne w sytuacji, gdy dla każdego miesiąca (styczeń–grudzień) używany jest jeden arkusz i trzeba je zsumować w arkuszu podsumowania.

    Suma 3D w nazwanych arkuszach. Formuła w komórce D2 to =SUMA(styczeń:grudzień!A2)
    • = SUMA(styczeń:grudzień!A2),

    co spowoduje podsumowanie komórek A2 w każdym arkuszu od stycznia do grudnia.

    Uwagi : Jeśli arkusze zawierają spacje w nazwach, jak np. „Sprzedaż styczeń”, to należy używać apostrofu przy odwoływaniu się do nazw arkuszy w formule: Zwróć uwagę na apostrof PRZED nazwą pierwszego arkusza oraz ZA nazwą ostatniego.

    • = SUMA('Sprzedaż styczeń:Sprzedaż grudzień'!A2)

    Metoda 3D działa również w przypadku innych funkcji, takich jak ŚREDNIA, MINIMUM, MAKSIMUM itp.:

    • =ŚREDNIA(Arkusz1:Arkusz3!A1)

    • =MIN(Arkusz1:Arkusz3!A1)

    • =MAX(Arkusz1:Arkusz3!A1)

Problem

Co się nie udało

Funkcja SUMA pokazuje ciąg ##### zamiast wyniku.

Sprawdź szerokość kolumn. Ciąg ##### oznacza zwykle, że kolumna jest za wąska, aby wyświetlić wynik.

Funkcja SUMA pokazuje samą formułę jako tekst, a nie wynik.

Sprawdź, czy komórka nie jest sformatowana jako tekst. Zaznacz odpowiednią komórkę lub zakres i użyj klawiszy Ctrl+1, aby wyświetlić okno dialogowe Formatowanie komórek, a następnie kliknij kartę Liczby i wybierz odpowiedni format. Jeśli komórka została sformatowana jako tekst i nie zmienia się po zmianie formatu, może być konieczne użycie klawiszy F2 > Enter w celu wymuszenia zmiany formatu.

Funkcja SUMA nie powoduje aktualizacji danych.

Upewnij się, że ustawienie Obliczanie ma wartość Automatyczne. Na karcie Formuły przejdź do pozycji Opcje obliczania. Możesz także za pomocą klawisza F9 wymusić obliczenia w arkuszu.

Upewnij się, że ustawienie Obliczanie ma wartość Automatyczne. Na karcie Formuły przejdź do pozycji Opcje obliczania.

Niektóre wartości nie są dodawane.

Do funkcji można dodać tylko wartości liczbowe z odwołania lub zakresu. Puste komórki, wartości logiczne, takie jak PRAWDA, lub tekst są ignorowane.

Zamiast oczekiwanego wyniku jest wyświetlany błąd #NAZWA?

Zazwyczaj oznacza to, że formuła jest błędnie wpisana. np. =sumy(A1:A10) zamiast =SUMA(A1:A10).

Funkcja SUMA pokazuje liczbę całkowitą, a powinna pokazywać miejsca dziesiętne

Sprawdź formatowanie komórek i upewnij się, że opcja wyświetlania miejsc dziesiętnych jest włączona. Zaznacz odpowiednią komórkę lub zakres i użyj klawiszy Ctrl+1, aby wyświetlić okno dialogowe Formatowanie komórek, a następnie kliknij kartę Liczby i wybierz odpowiedni format, pamiętając o określeniu liczby wyświetlanych miejsc dziesiętnych.

  1. Chcę tylko dodać/odjąć/pomnożyć/podzielić liczby Obejrzyj tę serię klipów wideo: Podstawowe obliczenia w programie Excel lub Używanie programu Excel jako kalkulatora.

  2. Jak wyświetlić więcej/mniej miejsc dziesiętnych? Możesz zmienić format liczb. Zaznacz odpowiednią komórkę lub zakres i użyj klawiszy Ctrl+1, aby wyświetlić okno dialogowe Formatowanie komórek, a następnie kliknij kartę Liczby i wybierz odpowiedni format, pamiętając o określeniu liczby wyświetlanych miejsc dziesiętnych.

  3. Jak dodawać lub odejmować godziny? Możesz dodawać i odejmować godziny na kilka różnych sposobów. Aby na przykład otrzymać różnicę między godzinami 8:00 i 12:00 na potrzeby obliczania płac, należy od godziny zakończenia odjąć godzinę rozpoczęcia przy użyciu formuły =("12:00"-"8:00")*24. Program Excel oblicza godziny w postaci ułamków dnia, więc należy pamiętać o pomnożeniu przez 24, aby uzyskać całkowitą liczbę godzin. W pierwszym przykładzie za pomocą formuły =((B2-A2)+(D2-C2))*24 obliczyliśmy liczbę godzin od początku do końca pomniejszoną o przerwę obiadową (łącznie 8,5 godziny).

    Jeśli chcesz po prostu dodać godziny i minuty i wyświetlić je w ten sposób, możesz je zsumować bez mnożenia przez 24. Dlatego w drugim przykładzie użyliśmy formuły =SUMA(A6:C6), ponieważ potrzebna jest tylko łączna liczba godzin i minut na przydzielone zadania (5:36, czyli 5 godzin i 36 minut).

    Obliczanie godzin

    Aby uzyskać więcej informacji, zobacz: Dodawanie lub odejmowanie godzin

  4. Jak obliczyć różnicę między datami? Daty można dodawać i odejmować (podobnie jak godziny). Oto typowy przykład obliczania liczby dni między dwiema datami. To bardzo proste: =B2-A2. Podstawową zasadą obowiązującą podczas pracy z datami i godzinami jest rozpoczęcie od daty/godziny zakończenia, a następnie odjęcie daty/godziny rozpoczęcia.

    Obliczanie różnic między datami

    Aby uzyskać więcej sposobów pracy z datami, zobacz: Obliczanie liczby dni między dwiema datami

  5. Jak zsumować tylko widoczne komórki? Czasami, gdy wiersze zostały ukryte ręcznie lub użyto Autofiltru do wyświetlania tylko określonych danych, chcemy zsumować tylko widoczne komórki. Można wtedy użyć funkcji SUMY.CZĘŚCIOWE. Jeśli używasz wiersza sumy w tabeli programu Excel, dowolna funkcja wybrana z listy rozwijanej wiersza Suma zostanie automatycznie wprowadzona jako suma częściowa. Więcej informacji na temat sumowania danych w tabeli programu Excel.

Potrzebujesz dodatkowej pomocy?

Zawsze możesz zadać pytanie ekspertowi w społeczności technicznej programu Excel, uzyskać pomoc techniczną w społeczności witryny Answers bądź zasugerować nową funkcję lub ulepszenie w witrynie UserVoice dotyczącej programu Excel.

Zobacz też

Zobacz klip wideo dotyczący korzystania z funkcji SUMA

Funkcja SUMA.JEŻELI dodaje tylko wartości spełniające pojedyncze kryterium

Funkcja SUMA.WARUNKÓW dodaje tylko wartości spełniające wiele kryteriów

Funkcja SUMA.JEŻELI zlicza tylko wartości spełniające pojedyncze kryterium

Funkcja LICZ.WARUNKI zlicza tylko wartości, które spełniają wiele kryteriów

Omówienie formuł w programie Excel

Jak unikać niepoprawnych formuł

Znajdowanie i poprawianie błędów w formułach

Skróty klawiaturowe w programie Excel dla systemu Windows

Skróty klawiaturowe w programie Excel dla komputerów Mac

Funkcje matematyczne i trygonometryczne

Funkcje programu Excel (lista alfabetyczna)

Funkcje programu Excel (według kategorii)

Rozwijaj swoje umiejętności
Poznaj szkolenia
Uzyskuj nowe funkcje w pierwszej kolejności
Dołącz do niejawnych testerów pakietu Office

Czy te informacje były pomocne?

Dziękujemy za opinię!

Dziękujemy za opinię! Wygląda na to, że połączenie Cię z jednym z naszych agentów pomocy technicznej pakietu Office może być pomocne.

×