Dzielenie tekstu na różne kolumny za pomocą funkcji

Dzielenie tekstu na różne kolumny za pomocą funkcji

Za pomocą funkcji tekstowych LEWY, FRAGMENT.TEKSTU, PRAWY, SZUKAJ.TEKST i DŁ można wykonywać operacje na ciągach tekstu w danych. Można na przykład rozłożyć imię, drugie imię i nazwisko z jednej komórki do trzech oddzielnych kolumn.

Kluczem do rozłożenia imienia, drugiego imienia i nazwiska przy użyciu funkcji tekstowych jest pozycja każdego znaku w ciągu tekstowym. Pozycje odstępów w ciągu tekstowym są również ważne, ponieważ wskazują początek lub koniec imienia, drugiego imienia i nazwiska w ciągu.

Na przykład w komórce zawierającej tylko imię i nazwisko nazwisko zaczyna się po pierwszym wystąpieniu odstępu. Niektóre nazwiska na liście mogą zawierać drugie imię. W takim przypadku nazwisko zaczyna się po drugim wystąpieniu odstępu.

W tym artykule pokazano, jak wyodrębnić różne składniki z rozmaitych zapisów imion i nazwisk, korzystając z tych przydatnych funkcji. Możesz również podzielić tekst i umieścić go w różnych kolumnach przy użyciu Kreatora konwersji tekstu na kolumny.

Przykładowe imię i nazwisko

Opis

Imię

Drugie imię

Nazwisko

Sufiks

1

Jacek Kalinowski

Brak drugiego imienia

Jacek

Kalinowski

2

Jakub S. Zawadzki

Inicjał drugiego imienia

Jakub

S.

Zawadzki

3

Ewa B. G. Ciesielska

Inicjały drugiego i trzeciego imienia

Ewa

B. G.

Ciesielska

4

Olecka, Aneta Magda

Nazwisko na początku z przecinkiem

Aneta

Magda

Olecka

5

Joanna Maria D. Rybka

Imię dwuczęściowe

Joanna Maria

D.

Rybka

6

Beata Sapieżyńska de Mattos

Nazwisko trzyczęściowe

Beata

Sapieżyńska de Mattos

7

Michał van Eaton

Nazwisko dwuczęściowe

Michał

van Eaton

8

Czernek Jun., Paweł K.

Nazwisko i sufiks na początku z przecinkiem

Paweł

K.

Czernek

Jun.

9

Wojciech Czupta III

Z sufiksem

Wojciech

Czupta

III

10

P. Maciej Czarnecki

Z prefiksem

Maciej

Czarnecki

11

Aneta Wiśniewska-Szypuła

Nazwisko pisane z łącznikiem

Aneta

Wiśniewska-Szypuła

Uwaga: Na ilustracjach w poniższych przykładach wyróżnienie w pełnym imieniu i nazwisku pokazuje znak, który jest wyszukiwany przez odpowiednią formułę SZUKAJ.TEKST.

W tym przykładzie są tylko dwa składniki: imię i nazwisko. Oba składniki oddziela jeden odstęp.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Jacek Kalinowski

Brak drugiego imienia

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

  1. Imię

    Imię zaczyna się od pierwszego znaku w ciągu (J) i kończy się szóstym znakiem (odstęp). Formuła zwraca 6 znaków w komórce A2, rozpoczynając od lewej.

    Formuła wyodrębniająca imię

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od lewej.

  2. Nazwisko

    Nazwisko zaczyna się od odstępu, dziewięć znaków od prawej, i kończy się ostatnim znakiem po prawej (i). Formuła wyodrębnia dziewięć znaków w komórce A2, rozpoczynając od prawej.

    Formuła wyodrębniająca nazwisko

    Użyj funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od lewej. (6)

  3. Oblicz całkowitą długość ciągu tekstowego, a następnie odejmij liczbę znaków od lewej do pierwszego odstępu, który został znaleziony w kroku 1.

W tym przykładzie jest użyte imię, inicjał drugiego imienia i nazwisko. Składniki nazwiska są oddzielone odstępem.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Jakub S. Zawadzki

Inicjał drugiego imienia

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (inicjał drugiego imienia)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-SZUKAJ.TEKST(" ";A2;1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik na żywo (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

  1. Imię

    Imię zaczyna się od pierwszego znaku z lewej (J) i kończy się szóstym znakiem (pierwszy odstęp). Formuła wyodrębnia pierwszych sześć znaków w komórce A2, rozpoczynając od lewej.

    Formuła wyodrębniająca imię i nazwisko oraz inicjał drugiego imienia

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od lewej. (6)

  2. Drugie imię

    Drugie imię zaczyna się na pozycji siódmego znaku (S) i kończy na dziewiątej pozycji (drugi odstęp). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia drugiego wystąpienia odstępu.

    Ta formuła wyodrębnia trzy znaki, rozpoczynając od siódmej pozycji.

    Szczegóły dotyczące formuły wyodrębniającej imię, drugie imię i nazwisko

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (7).

  3. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (S). Ta pozycja numeryczna jest pozycją początkową drugiego imienia. (6 + 1 = 7)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (6).

  4. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (S). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego wystąpienia odstępu. (6 + 1 = 7)

  5. Wyszukaj drugie wystąpienie odstępu w komórce A2, rozpoczynając od siódmej pozycji (S), która została znaleziona w kroku 4. Ten numer znaku jest pozycją końcową drugiego imienia. (9)

  6. Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (6)

  7. Użyj numeru znaku drugiego odstępu, który został znaleziony w kroku 5, i odejmij numer znaku pierwszego odstępu, który został znaleziony w kroku 6. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od siódmej pozycji, która została znaleziona w kroku 2. (9 - 7 = 2)

  8. Nazwisko

    Nazwisko zaczyna się dziewięć znaków od prawej (Z) i kończy pierwszym znakiem od prawej (i). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia drugiego i trzeciego wystąpienia odstępu (które są na siódmej i dziewiątej pozycji od lewej).

    Formuła wyodrębnia osiem znaków w komórce A2, rozpoczynając od prawej.

    Druga funkcja wyszukiwania w formule, służąca do wyodrębniania imienia, drugiego imienia i nazwiska
  9. Użyj funkcji DŁ i zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (6)

  10. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (S). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego wystąpienia odstępu. (7 + 1 = 8)

  11. Wyszukaj drugie wystąpienie odstępu w komórce A2, rozpoczynając od ósmej pozycji (S), która została znaleziona w kroku 2. Ten numer znaku jest końcową pozycją drugiego imienia. (10)

  12. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do drugiego wystąpienia odstępu, które zostało znalezione w kroku 3. Wynikiem jest liczba znaków pełnego imienia i nazwiska do wyodrębnienia od prawej. (15 – 10 = 5)

Poniżej przedstawiono przykład wyodrębniania inicjałów drugiego i trzeciego imienia. Składniki oddziela pierwsze i trzecie wystąpienie odstępu.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Ewa B. G. Ciesielska

Inicjały drugiego i trzeciego imienia

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (inicjały dodatkowych imion)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-SZUKAJ.TEKST(" ";A2;1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik na żywo (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

  1. Imię

    Imię zaczyna się od pierwszego znaku z lewej (E) i kończy się czwartym znakiem (pierwszy odstęp). Formuła wyodrębnia pierwsze cztery znaki w komórce A2, rozpoczynając od lewej.

    Formuła wyodrębniająca imię i nazwisko oraz inicjały drugiego i trzeciego imienia

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (4)

  2. Drugie imię

    Drugie imię zaczyna się na pozycji piątej (B) i kończy się na pozycji dziesiątej (trzeci odstęp). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pierwszego, drugiego i trzeciego wystąpienia odstępu na pozycjach czwartej, siódmej i dziesiątej.

    Formuła wyodrębnia pięć znaków, rozpoczynając od pozycji piątej.

    Formuła wyodrębniająca imię i nazwisko oraz inicjały drugiego i trzeciego imienia

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (4)

  3. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (B). Ta pozycja numeryczna jest pozycją początkową drugiego imienia. (4 + 1 = 5)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (4)

  4. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (B). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego wystąpienia odstępu. (4 + 1 = 5)

  5. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od piątej pozycji (B), która została znaleziona w kroku 4. (7)

  6. Dodaj 1, aby uzyskać pozycję znaku po drugim odstępie (G). Ten numer znaku jest pozycją początkową, od której chcesz rozpocząć wyszukiwanie trzeciego odstępu. (7 + 1 = 8)

  7. Wyszukaj trzeci odstęp w komórce A2, rozpoczynając od ósmej pozycji, która została znaleziona w kroku 6. (10)

  8. Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2. (4)

  9. Użyj numeru znaku trzeciego odstępu, który został znaleziony w kroku 7, i odejmij numer znaku pierwszego odstępu, który został znaleziony w kroku 6. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od piątej pozycji, która została znaleziona w kroku 2.

  10. Nazwisko

    Nazwisko zaczyna się dziesięć znaków od prawej (C) i kończy pierwszym znakiem od prawej (a). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pierwszego, drugiego i trzeciego wystąpienia odstępu.

    Formuła wyodrębnia dziesięć znaków w komórce A2, rozpoczynając od prawej pełnego nazwiska.

    Formuła wyodrębniająca imię i nazwisko oraz inicjały drugiego i trzeciego imienia

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (4)

  11. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (B). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego wystąpienia odstępu. (4 + 1 = 5)

  12. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od piątej pozycji (B), która została znaleziona w kroku 2. (7)

  13. Dodaj 1, aby uzyskać pozycję znaku po drugim odstępie (G). Ten numer znaku jest pozycją początkową, od której chcesz rozpocząć wyszukiwanie trzeciego odstępu. (7 + 1 = 8)

  14. Wyszukaj trzeci odstęp w komórce A2, rozpoczynając od ósmej pozycji (G), która została znaleziona w kroku 6. (10)

  15. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do trzeciego odstępu, który został znaleziony w kroku 5. Wynikiem jest liczba znaków pełnego nazwiska do wyodrębnienia od prawej. (20 - 10 = 10)

W tym przykładzie nazwisko występuje przed imieniem, a drugie imię jest na końcu. Przecinek oznacza koniec nazwiska i poszczególne składniki są oddzielone odstępem.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Olecka, Aneta Magda

Nazwisko na początku z przecinkiem

Formuła

Wynik (imię)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-SZUKAJ.TEKST(" ";A2;1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (drugie imię)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

Formuła

Wynik na żywo (nazwisko)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1)-2)

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1)-2)

  1. Imię

    Imię zaczyna się od dziewiątego znaku od lewej (A) i kończy czternastym znakiem (drugi odstęp). Ponieważ imię występuje w środku pełnego nazwiska, w celu wyodrębnienia imienia należy użyć funkcji FRAGMENT.TEKSTU.

    Formuła wyodrębnia sześć znaków, rozpoczynając od pozycji dziewiątej.

    Formuła wyodrębniająca nazwisko, po którym występuje imię i drugie imię

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (8)

  2. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (A). Ta pozycja numeryczna jest pozycją początkową imienia. (8 + 1 = 9)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (8)

  3. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (A). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (8 + 1 = 9)

    Wyszukaj drugi odstęp w komórce A2, rozpoczynając od dziewiątej pozycji (A), która została znaleziona w kroku 4. (14)

  4. Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (8)

  5. Użyj numeru znaku drugiego odstępu, który został znaleziony w kroku 5, i odejmij numer znaku pierwszego odstępu, który został znaleziony w kroku 6. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od dziewiątej pozycji, która została znaleziona w kroku 2. (14 - 8 = 6)

  6. Drugie imię

    Drugie imię zaczyna się pięć znaków od prawej (M) i kończy się pierwszym znakiem od prawej (a). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pierwszego i drugiego wystąpienia odstępu w ósmej i czternastej pozycji od lewej.

    Formuła wyodrębnia pięć znaków, rozpoczynając od prawej.

    Formuła wyodrębniająca nazwisko, po którym występuje imię i drugie imię

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (8)

  7. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (A). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (8 + 1 = 9)

  8. Wyszukaj drugie wystąpienie odstępu w komórce A2, rozpoczynając od dziewiątej pozycji (A), która została znaleziona w kroku 2. (14)

  9. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do drugiego odstępu, który został znaleziony w kroku 3. Wynikiem jest liczba znaków pełnego imienia i nazwiska do wyodrębnienia od prawej. (19 - 14 = 5)

  10. Nazwisko

    Nazwisko zaczyna się pierwszym znakiem od lewej (O) i kończy się szóstym znakiem (a). Formuła wyodrębnia cztery znaki, rozpoczynając od lewej.

    Formuła wyodrębniająca nazwisko, po którym występuje imię i drugie imię

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (8)

  11. Odejmij 2, aby uzyskać pozycję numeryczną końcowego znaku nazwiska (a). Wynikiem jest liczba znaków, która ma zostać wyodrębniona przez funkcję LEWY. (8 - 2 = 6)

W tym przykładzie są używane dwie części imienia: Joanna Maria. Składniki oddziela drugi i trzeci odstęp.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Joanna Maria D. Rybka

Imię dwuczęściowe

Formuła

Wynik (imię)

LEWY(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

Formuła

Wynik (inicjał drugiego imienia)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-(SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

Formuła

Wynik na żywo (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

  1. Imię

    Imię zaczyna się od pierwszego znaku od lewej i kończy się trzynastym znakiem (drugi odstęp). Ta formuła zawiera zagnieżdżoną funkcję SZUKAJ.TEKST, służącą do odnalezienia drugiego wystąpienia odstępu od lewej.

    Formuła wyodrębnia trzynaście znaków, rozpoczynając od lewej.

    Formuła wyodrębniająca imię, drugie imię, inicjał drugiego imienia i nazwisko

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (7).

  2. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (M). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego wystąpienia odstępu. (7 + 1 = 8)

  3. Wyszukaj drugie wystąpienie odstępu w komórce A2, rozpoczynając od ósmej pozycji (M), która została znaleziona w kroku 2. Wynikiem jest liczba znaków wyodrębniona przez funkcję LEWY z ciągu tekstowego. (13)

  4. Drugie imię

    Drugie imię zaczyna się na czternastej pozycji (D) i kończy się na szesnastej pozycji (trzeci odstęp). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pierwszego, drugiego i trzeciego wystąpienia odstępu.

    Formuła wyodrębnia dwa znaki ze środka, rozpoczynając od czternastej pozycji.

    Formuła wyodrębniająca imię, drugie imię, inicjał drugiego imienia i nazwisko

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (7).

  5. Dodaj 1, aby uzyskać znak po pierwszym odstępie (M). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (7 + 1 = 8)

  6. Wyszukaj pozycję drugiego wystąpienia odstępu w komórce A2, rozpoczynając od ósmej pozycji (M), która została znaleziona w kroku 2. Wynikiem jest liczba znaków wyodrębniana przez funkcję LEWY od lewej. (13)

  7. Dodaj 1, aby uzyskać znak po drugim odstępie (D). Wynikiem jest pozycja początkowa drugiego imienia. (13 + 1 = 14)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną znaku po drugim odstępie (D). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie trzeciego odstępu. (14)

  8. Wyszukaj pozycję numeryczną trzeciego odstępu w komórce A2, rozpoczynając od lewej. Wynikiem jest pozycja końcowa drugiego imienia. (16)

  9. Wyszukaj pozycję numeryczną znaku po drugim odstępie (D). Wynikiem jest pozycja początkowa drugiego imienia. (14)

  10. Użyj numeru znaku trzeciego odstępu, który został znaleziony w kroku 6, i odejmij numer znaku „D”, który został znaleziony w kroku 7. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od czternastej pozycji, która została znaleziona w kroku 4. (16 - 14 = 2)

  11. Nazwisko

    Nazwisko zaczyna się pięć znaków od prawej. Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pierwszego, drugiego i trzeciego wystąpienia odstępu na pozycjach siódmej, trzynastej i szesnastej.

    Formuła wyodrębnia pięć znaków od prawej.

    Formuła wyodrębniająca imię, drugie imię, inicjał drugiego imienia i nazwisko

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (7)

  12. Dodaj 1, aby uzyskać znak po pierwszym odstępie (M). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (7 + 1 = 8)

  13. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od ósmej pozycji (M), która została znaleziona w kroku 2. (13)

  14. Dodaj 1, aby uzyskać pozycję znaku po drugim odstępie (D). Wynikiem jest pozycja początkowa drugiego imienia. (13 + 1 = 14)

  15. Wyszukaj pozycję numeryczną trzeciego odstępu w komórce A2, rozpoczynając od lewej. Wynikiem jest pozycja końcowa drugiego imienia. (16)

  16. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do trzeciego odstępu, który został znaleziony w kroku 5. Wynikiem jest liczba znaków pełnego nazwiska do wyodrębnienia od prawej. (21 - 16 = 5)

W tym przykładzie są trzy części nazwiska: Sapieżyńska de Mattos. Pierwszy odstęp oznacza koniec imienia i początek nazwiska.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Beata Sapieżyńska de Mattos

Nazwisko trzyczęściowe

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (nazwisko)

PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

  1. Imię

    Imię zaczyna się od pierwszego znaku z lewej (B) i kończy się szóstym znakiem (pierwszy odstęp). Formuła wyodrębnia sześć znaków od lewej.

    Formuła wyodrębniająca imię i trzyczęściowe nazwisko

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (6)

  2. Nazwisko

    Nazwisko zaczyna się dwadzieścia jeden znaków od prawej (S) i kończy się pierwszym znakiem od prawej (s). Formuła wyodrębnia dwadzieścia jeden znaków od prawej.

    Formuła wyodrębniająca imię i trzyczęściowe nazwisko

    Użyj funkcji DŁ i SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (6)

  3. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do pierwszego odstępu, który został znaleziony w kroku 1. Wynikiem jest liczba znaków pełnego nazwiska do wyodrębnienia od prawej. (27 - 6 = 21)

W tym przykładzie są dwie części nazwiska: van Eaton. Pierwszy odstęp oznacza koniec imienia i początek nazwiska.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Michał van Eaton

Nazwisko dwuczęściowe

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

  1. Imię

    Imię zaczyna się od pierwszego znaku z lewej (M) i kończy się siódmym znakiem (pierwszy odstęp). Formuła wyodrębnia siedem znaków od lewej.

    Formuła wyodrębniająca imię i dwuczęściowe nazwisko

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (6)

  2. Nazwisko

    Nazwisko zaczyna się od dziewiątego znaku od prawej (v) i kończy się pierwszym znakiem od prawej (n). Formuła wyodrębnia dziewięć znaków pełnego nazwiska od prawej.

    Formuła wyodrębniająca imię i dwuczęściowe nazwisko

    Użyj funkcji DŁ i SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (7)

  3. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do pierwszego odstępu, który został znaleziony w kroku 1. Wynikiem jest liczba znaków pełnego nazwiska do wyodrębnienia od prawej. (16 - 7 = 9)

W tym przykładzie nazwisko jest na początku, a po nim występuje sufiks. Nazwisko i sufiks są oddzielone przecinkiem od imienia i inicjału drugiego imienia.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Czernek Jun., Paweł K.

Nazwisko i sufiks na początku z przecinkiem

Formuła

Wynik (imię)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

Formuła

Wynik (inicjał drugiego imienia)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)+1))

Formuła

Wynik (nazwisko)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (sufiks)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;(SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-2)-SZUKAJ.TEKST(" ";A2;1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;(SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-2)-SZUKAJ.TEKST(" ";A2;1))

  1. Imię

    Imię zaczyna się od piętnastego znaku (P) i kończy się dwudziestym znakiem (trzeci odstęp). Formuła wyodrębnia pięć znaków, rozpoczynając od piętnastej pozycji.

    Formuła wyodrębniająca nazwisko i sufiks na początku z przecinkiem

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (8)

  2. Dodaj 1, aby uzyskać znak po pierwszym odstępie (J). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (8 + 1 = 9)

  3. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od dziewiątej pozycji (J), która została znaleziona w kroku 2. (14)

  4. Dodaj 1, aby uzyskać znak po drugim odstępie (P). Wynikiem jest pozycja początkowa imienia. (14 + 1 = 15)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną znaku po drugim odstępie (P). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie trzeciego odstępu. (15)

  5. Wyszukaj pozycję numeryczną trzeciego odstępu w komórce A2, rozpoczynając od lewej. Wynikiem jest pozycja końcowa imienia. (20)

  6. Wyszukaj pozycję numeryczną znaku po drugim odstępie (P). Wynikiem jest pozycja początkowa imienia. (15)

  7. Użyj numeru znaku trzeciego odstępu, który został znaleziony w kroku 6, i odejmij numer znaku „P”, który został znaleziony w kroku 7. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od piętnastej pozycji, która została znaleziona w kroku 4. (20 - 15 = 5)

  8. Drugie imię

    Drugie imię zaczyna się od drugiego znaku od prawej (K). Formuła wyodrębnia dwa znaki od prawej.

    Formuła wyodrębniająca nazwisko i sufiks na początku z przecinkiem

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (8)

  9. Dodaj 1, aby uzyskać znak po pierwszym odstępie (J). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (8 + 1 = 9)

  10. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od dziewiątej pozycji (J), która została znaleziona w kroku 2. (14)

  11. Dodaj 1, aby uzyskać znak po drugim odstępie (P). Wynikiem jest pozycja początkowa imienia. (14 + 1 = 15)

  12. Wyszukaj pozycją numeryczną trzeciego odstępu w komórce A2, rozpoczynając od lewej. Wynikiem jest pozycja końcowa drugiego imienia. (20)

  13. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do trzeciego odstępu, który został znaleziony w kroku 5. Wynikiem jest liczba znaków pełnego nazwiska do wyodrębnienia od prawej. (22 - 20 = 2)

  14. Nazwisko

    Nazwisko zaczyna się pierwszym znakiem od lewej (C) i kończy się ósmym znakiem (pierwszy odstęp). Formuła zatem wyodrębnia osiem znaków od lewej.

    Formuła wyodrębniająca nazwisko i sufiks na początku z przecinkiem

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (8)

  15. Sufiks

    Sufiks zaczyna się dziewiątym znakiem od lewej (J) i kończy dwunastym znakiem od lewej (.). Formuła wyodrębnia cztery znaki, rozpoczynając od dziewiątego znaku.

    Formuła wyodrębniająca nazwisko i sufiks na początku z przecinkiem

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (8)

  16. Dodaj 1, aby uzyskać znak po pierwszym odstępie (J). Wynikiem jest pozycja początkowa sufiksu. (8 + 1 = 9)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (8)

  17. Dodaj 1, aby uzyskać pozycję numeryczną znaku po pierwszym odstępie (J). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (9)

  18. Wyszukaj pozycję numeryczną drugiego odstępu w komórce A2, rozpoczynając od dziewiątego znaku, który został znaleziony w kroku 4. (14)

  19. Odejmij 1 od numeru znaku drugiego odstępu, który został znaleziony w kroku 4, aby uzyskać numer znaku „,”. Wynikiem jest pozycja końcowa sufiksu. (14 - 1 = 13)

  20. Wyszukaj pozycję numeryczną pierwszego odstępu. (6)

  21. Po znalezieniu pierwszego odstępu dodaj do niego 1, aby znaleźć następny znak (J), która został też znaleziony w krokach 3 i 4. (9)

  22. Użyj numeru znaku „,”, który został znaleziony w kroku 6, i odejmij numer znaku „J” znaleziony w krokach 3 i 4. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od dziewiątej pozycji, która została znaleziona w kroku 2. (13 - 9 = 4)

W tym przykładzie imię jest na początku ciągu, a sufiks jest na końcu, dlatego można użyć formuł podobnych do tych z przykładu 2, czyli wyodrębnić imię za pomocą funkcji LEWY, nazwisko za pomocą funkcji FRAGMENT.TEKSTU i sufiks za pomocą funkcji PRAWY.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Wojciech Czupta III

Imię i nazwisko z sufiksem

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (nazwisko)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-(SZUKAJ.TEKST(" ";A2;1)+1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-(SZUKAJ.TEKST(" ";A2;1)+1))

Formuła

Wynik (sufiks)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

  1. Imię

    Imię zaczyna się pierwszym znakiem od lewej (W) i kończy się dziewiątym znakiem (pierwszy odstęp). Formuła zatem wyodrębnia dziewięć znaków pełnego imienia i nazwiska od lewej.

    Formuła wyodrębniająca imię i nazwisko, po których występuje sufiks

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (9)

  2. Nazwisko

    Nazwisko zaczyna się dziesiątym znakiem od lewej (C) i kończy się piętnastym znakiem (A). Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pozycji odstępów.

    Formuła wyodrębnia sześć znaków ze środka, rozpoczynając od dziesiątego znaku.

    Formuła wyodrębniająca imię i nazwisko, po których występuje sufiks

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (9)

  3. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (C). Wynikiem jest pozycja początkowa nazwiska. (9 + 1 = 10)

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (9)

  4. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (C). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (9 + 1 = 10)

  5. Wyszukaj pozycję numeryczną drugiego odstępu w komórce A2, rozpoczynając od dziesiątego znaku, który został znaleziony w kroku 4. Ten numer znaku jest pozycją końcową nazwiska. (16)

  6. Wyszukaj pozycję numeryczną pierwszego odstępu. (5)

  7. Dodaj 1, aby znaleźć pozycję numeryczną znaku po pierwszym odstępie (C), która została znaleziona również w krokach 3 i 4. (10)

  8. Użyj numeru znaku drugiego odstępu, który został znaleziony w kroku 5, a następnie odejmij numer znaku „A”, który został znaleziony w krokach 6 i 7. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od dziesiątej pozycji, która została znaleziona w kroku 2. (16 - 10 = 6)

  9. Sufiks

    Sufiks zaczyna się trzy znaki od prawej. Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pozycji odstępów.

    Formuła wyodrębniająca imię i nazwisko, po których występuje sufiks

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (9)

  10. Dodaj 1, aby uzyskać znak po pierwszym odstępie (C). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (9 + 1 = 10)

  11. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od dziesiątej pozycji (C), która została znaleziona w kroku 2. (16)

  12. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do drugiego odstępu, który został znaleziony w kroku 3. Wynikiem jest liczba znaków pełnego imienia i nazwiska do wyodrębnienia od prawej. (19 - 16 = 3)

W tym przykładzie pełne imię i nazwisko są poprzedzone prefiksem i można użyć formuł podobnych do tych z przykładu 2: imię można wyodrębnić za pomocą funkcji FRAGMENT.TEKSTU, a nazwisko za pomocą funkcji PRAWY.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

P. Maciej Czarnecki

Z prefiksem

Formuła

Wynik (imię)

'=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-(SZUKAJ.TEKST(" ";A2;1)+1))

=FRAGMENT.TEKSTU(A2;SZUKAJ.TEKST(" ";A2;1)+1;SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1)-(SZUKAJ.TEKST(" ";A2;1)+1))

Formuła

Wynik (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;SZUKAJ.TEKST(" ";A2;1)+1))

  1. Imię

    Imię zaczyna się czwartym znakiem od lewej (M) i kończy się dziesiątym znakiem (drugi odstęp). Formuła zagnieżdża funkcje SZUKAJ.TEKST, służące do odnalezienia pozycji odstępów. Wyodrębnia ona sześć znaków, rozpoczynając od czwartej pozycji.

    Formuła wyodrębniająca imię poprzedzone prefiksem

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu numer_początkowy:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (3)

  2. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (D). Wynikiem jest pozycja początkowa imienia. (3 + 1 = 4)

    Użyj zagnieżdżonej funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (3)

  3. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (D). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (3 + 1 = 4)

  4. Wyszukaj pozycję numeryczną drugiego odstępu w komórce A2, rozpoczynając od czwartego znaku, który został znaleziony w krokach 3 i 4. Ten numer znaku jest pozycją końcową imienia. (11)

  5. Wyszukaj pierwszy odstęp. (3)

  6. Dodaj 1, aby znaleźć pozycję numeryczną znaku po pierwszym odstępie (M), która została znaleziona również w krokach 3 i 4. (4)

  7. Użyj numeru znaku drugiego odstępu, który został znaleziony w kroku 5, a następnie odejmij numer znaku „D” znaleziony w krokach 6 i 7. Wynikiem jest liczba znaków wyodrębniona przez funkcję FRAGMENT.TEKSTU z ciągu tekstowego, rozpoczynając od czwartej pozycji, która została znaleziona w kroku 2. (11 - 4 = 7)

  8. Nazwisko

    Nazwisko zaczyna się dziesięć znaków od prawej. Ta formuła zawiera zagnieżdżone funkcje SZUKAJ.TEKST, służące do odnalezienia pozycji odstępów.

    Formuła wyodrębniająca imię poprzedzone prefiksem

    Użyj zagnieżdżonych funkcji SZUKAJ.TEKST i DŁ w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (3)

  9. Dodaj 1, aby uzyskać pozycję znaku po pierwszym odstępie (D). Wynikiem jest numer znaku, od którego chcesz rozpocząć wyszukiwanie drugiego odstępu. (3 + 1 = 4)

  10. Wyszukaj drugi odstęp w komórce A2, rozpoczynając od czwartej pozycji (D), która została znaleziona w kroku 2. (11)

  11. Oblicz całkowitą długość ciągu tekstowego w komórce A2, a następnie odejmij liczbę znaków od lewej do drugiego odstępu, który został znaleziony w kroku 3. Wynikiem jest liczba znaków pełnego imienia i nazwiska do wyodrębnienia od prawej. (18 - 11 = 7)

W tym przykładzie jest użyte nazwisko pisane z łącznikiem. Składniki nazwiska są oddzielone odstępem.

Skopiuj komórki w tabeli i wklej je do arkusza programu Excel w komórce A1. Formuła, którą zobaczysz po lewej stronie, będzie wyświetlana w celach referencyjnych, a program Excel automatycznie przekonwertuje formułę po prawej stronie na odpowiedni wynik.

Wskazówka    Zanim wkleisz dane do arkusza ustaw szerokość kolumny A i B na wartość 250.

Przykładowe imię i nazwisko

Opis

Aneta Wiśniewska-Szypuła

Nazwisko pisane z łącznikiem

Formuła

Wynik (imię)

'=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

=LEWY(A2;SZUKAJ.TEKST(" ";A2;1))

Formuła

Wynik (nazwisko)

'=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

=PRAWY(A2;DŁ(A2)-SZUKAJ.TEKST(" ";A2;1))

  1. Imię

    Imię zaczyna się pierwszym znakiem od lewej i kończy się szóstą pozycją (pierwszy odstęp). Formuła wyodrębnia sześć znaków od lewej.

    Formuła wyodrębniająca imię i nazwisko zawierające łącznik

    Użyj funkcji SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną pierwszego odstępu w komórce A2, rozpoczynając od lewej. (6)

  2. Nazwisko

    Całe nazwisko zaczyna się osiemnaście znaków od prawej (W) i kończy się pierwszym znakiem od prawej (a).

    Formuła wyodrębniająca imię i nazwisko zawierające łącznik

    Użyj funkcji DŁ i SZUKAJ.TEKST w celu znalezienia wartości argumentu liczba_znaków:

    Wyszukaj pozycję numeryczną odstępu w komórce A2, rozpoczynając od pierwszego znaku od lewej. (6)

  3. Oblicz całkowitą długość ciągu tekstowego do wyodrębnienia, a następnie odejmij liczbę znaków od lewej do pierwszego odstępu, który został znaleziony w kroku 1. (24 - 6 = 18)

Zobacz też

Dzielenie tekstu i umieszczanie go w różnych kolumnach przy użyciu Kreatora konwersji tekstu na kolumny

Rozwijaj swoje umiejętności
Poznaj szkolenia
Uzyskuj nowe funkcje w pierwszej kolejności
Dołącz do niejawnych testerów pakietu Office

Czy te informacje były pomocne?

Dziękujemy za opinię!

Dziękujemy za opinię! Wygląda na to, że połączenie Cię z jednym z naszych agentów pomocy technicznej pakietu Office może być pomocne.

×