Office
Aanmelden
Tekst splitsen in verschillende kolommen met functies

Tekst splitsen in verschillende kolommen met functies

U kunt de tekstfuncties LINKS, DEEL, RECHTS, VIND.SPEC en LENGTE gebruiken om tekenreeksen met tekst in uw gegevens te manipuleren. Zo kunt u bijvoorbeeld de voornaam, de middelste naam en de achternaam uit één cel in drie aparte kolommen plaatsen.

De sleutel tot het verdelen van naamcomponenten met behulp van tekstfuncties is de positie van elk teken in een teksttekenreeks. De posities van de spaties in de tekenreeks zijn ook belangrijk, want die geven het begin en het einde aan van de naamcomponenten in een tekenreeks.

In een cel die bijvoorbeeld alleen een voornaam en een achternaam bevat, begint de achternaam na de eerste spatie die erin voorkomt. Sommige namen in de lijst bevatten mogelijk een tweede voornaam. In dat geval begint de achternaam na de tweede spatie die in de tekenreeks voorkomt.

In dit artikel ziet u hoe u verschillende componenten kunt extraheren uit verschillend ingedeelde namen met behulp van deze handige functies. U kunt ook tekst verdelen over verschillende kolommen met de wizard Tekst naar kolommen

Voorbeeldnaam

Beschrijving

Voornaam

Tweede voornaam

Achternaam

Achtervoegsel

1

Ties Smits

Geen tweede voornaam

Ties

Smits

2

Nils S. Blaauboer

Eén middelste voorletter

Nils

S.

Blaauboer

3

Jeroen B. G. Cool

Twee middelste voorletters

Jeroen

B. G.

Cool

4

Geel, Maria Vera

Eerst de achternaam, met komma

Maria

Vera

Geel

5

Koos Jan D. Splinter

Tweedelige voornaam

Koos Jan

D.

Splinter

6

Paula Bartels van Vugt

Driedelige achternaam

Paula

Bartels van Vugt

7

Richard de Goederen

Tweedelige achternaam

Richard

de Goederen

8

Veninga Jr., Tjeerd K.

Achternaam en achtervoegsel eerst, met komma

Tjeerd

K.

Veninga

Jr.

9

Dick Beekman III

Met achtervoegsel

Dick

Beekman

III

10

Mr. Joop Zeger

Met voorvoegsel

Joop

Zeger

11

Julia Terp-Groen

Achternaam met koppelstreepje

Julia

Terp-Groen

Opmerking: In de afbeeldingen in de volgende voorbeelden geeft de markering in de volledige naam het teken aan waar de formule VIND.SPEC naar zoekt.

In dit voorbeeld worden twee componenten gescheiden: een voornaam en een achternaam. De twee naamcomponenten zijn van elkaar gescheiden door een spatie.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Ties Smits

Geen tweede voornaam

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

  1. Voornaam

    De voornaam begint met het eerste teken in de tekenreeks (T) en eindigt bij het vijfde teken (de spatie). De formule geeft als resultaat vijf tekens in cel A2, vanaf de linkerkant.

    Formule voor het ophalen van de voornaam

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de spatie in A2, vanaf de linkerkant.

  2. Achternaam

    De achternaam begint bij de spatie, vijf tekens vanaf de rechterkant, en eindigt bij het laatste teken aan de rechterkant (s). De formule extraheert vijf tekens in A2, vanaf de rechterkant.

    Formule voor het ophalen van de achternaam

    Met de functies VIND.SPEC en LENGTE vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de spatie in A2, vanaf de linkerkant. (5)

  3. De totale lengte van de teksttekenreeks tellen en vervolgens het aantal tekens links van de eerste spatie aftrekken, zoals gevonden in stap 1.

In dit voorbeeld wordt een voornaam, tweede voorletter en achternaam gebruikt. Een spatie vormt de scheiding tussen elk onderdeel van de naam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Nils S. Blaauboer

Eén middelste voorletter

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (middelste initiaal)

'=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1))

=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-VIND.SPEC(" ";A2;1))

Formule

Direct resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant (N) en eindigt bij het vijfde teken (de eerste spatie). De formule extraheert de eerste vijf tekens in A2, vanaf de linkerkant.

    Formule voor het scheiden van een voor- en achternaam, plus een initiaal in het midden

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de spatie in A2, vanaf de linkerkant. (5)

  2. Tweede voornaam

    De tweede voornaam begint bij de zesde tekenpositie (S) en eindigt bij de achtste positie (de tweede spatie). In deze formule worden VIND.SPEC-functies genest om de tweede instantie van een spatie te vinden.

    De formule extraheert drie tekens, vanaf de zesde positie.

    formule voor het extraheren van de tweede voornaam van voorbeeld 2: nils s. blaauboer

    Met de functie VIND.SPEC vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (5)

  3. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (S). Deze numerieke positie is de startpositie van de tweede voornaam. (5 + 1 = 6)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (5)

  4. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (S). Het resultaat is het tekennummer waarvandaan u naar de tweede instantie van een spatie moet zoeken. (5 + 1 = 6)

  5. Zoeken naar de tweede instantie van een spatie in A2, te beginnen vanaf de zesde positie (S) gevonden in stap 4. Dit tekennummer is de eindpositie van de tweede voornaam. (8)

  6. Zoeken naar de numerieke positie van de spatie in A2, vanaf het eerste teken links. (5)

  7. Neem het tekennummer van de tweede spatie gevonden in stap 5 en trek daar het tekennummer van de eerste spatie vanaf, gevonden in stap 6. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de zesde positie, gevonden in stap 2. (8 – 5 = 3)

  8. Achternaam

    De achternaam begint zes tekens vanaf de rechterkant (B) en eindigt met het eerste teken vanaf de rechterkant (r). In deze formule worden VIND.SPEC-functies genest om de tweede en derde instantie van een spatie te vinden (namelijk op de vijfde en achtste positie vanaf de linkerkant).

    De formule extraheert negen tekens in A2, vanaf de rechterkant.

    De tweede functie VIND.SPEC in een formule voor het scheiden van de voornaam, tweede naam en achternaam.
  9. Met de functie LENGTE en de geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de spatie in A2, vanaf het eerste teken links. (5)

  10. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (S). Het resultaat is het tekennummer waarvandaan u naar de tweede instantie van een spatie moet zoeken. (5 + 1 = 6)

  11. Zoeken naar de tweede instantie van een spatie in A2, te beginnen vanaf de zesde positie (S) gevonden in stap 4. Dit tekennummer is de eindpositie van de tweede voornaam. (8)

  12. De totale lengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de tweede spatie aftrekken, zoals gevonden in stap 3. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (14 – 8 = 6).

Hier volgt een voorbeeld om de tweede en derde voorletter op te halen. De eerste en derde spatie vormen de scheiding tussen de voor- en achternaam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Jeroen B. G. Cool

Twee middelste voorletters

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (middelste initialen)

'=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-VIND.SPEC(" ";A2;1))

=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-VIND.SPEC(" ";A2;1))

Formule

Direct resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant (J) en eindigt bij het zevende teken (de eerste spatie). De formule extraheert de eerste zeven tekens in A2, vanaf de linkerkant.

    Formule voor het scheiden van een voor- en achternaam, plus twee initialen in het midden

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (7)

  2. Tweede voornaam

    De tweede voornaam begint bij de achtste positie (B) en eindigt op de dertiende positie (de derde spatie). In deze formule worden geneste VIND.SPEC-functies gebruikt om de eerste, tweede en derde instantie van een spatie te vinden op de zevende, tiende en dertiende plaats.

    De formule extraheert vijf tekens, vanaf de achtste positie.

    Formule voor het scheiden van een voor- en achternaam, plus twee initialen in het midden

    Met de functie VIND.SPEC vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (7)

  3. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (B). Deze numerieke positie is de startpositie van de tweede voornaam. (7 + 1 = 8)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (7)

  4. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (B). Het resultaat is het tekennummer waarvandaan u naar de tweede instantie van een spatie gaat zoeken. (7 + 1 = 8)

  5. Zoeken naar de tweede spatie in A2, te beginnen vanaf de achtste positie (B), gevonden in stap 4. (10)

  6. Er 1 bij optellen om de positie te krijgen van het teken na de tweede spatie (G). Dit tekennummer is de startpositie waarvandaan u naar de derde spatie moet zoeken. (10 + 1 = 11)

  7. Zoeken naar de derde spatie in A2, te beginnen bij de elfde positie, gevonden in stap 6. (13)

  8. Zoeken naar de numerieke positie van de eerste spatie in A2. (7)

  9. Neem het tekennummer van de derde spatie gevonden in stap 7 en trek daar het tekennummer van de eerste spatie vanaf, gevonden in stap 6. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de achtste positie, gevonden in stap 2.

  10. Achternaam

    De achternaam begint vier tekens vanaf de rechterkant (C) en eindigt met het eerste teken vanaf de rechterkant (l). Voor deze formule worden VIND.SPEC-functies genest om de eerste, tweede en derde instantie van een spatie te vinden.

    De formule extraheert vier tekens in A2, vanaf de rechterkant van de volledige naam.

    Formule voor het scheiden van een voor- en achternaam, plus twee initialen in het midden

    Met de geneste VIND.SPEC-functies en de functie LENGTE vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (7)

  11. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (B). Het resultaat is het tekennummer waarvandaan u naar de tweede instantie van een spatie gaat zoeken. (7 + 1 = 8)

  12. Zoeken naar de tweede spatie in A2, te beginnen vanaf de achtste positie (B), gevonden in stap 2. (10)

  13. Er 1 bij optellen om de positie te krijgen van het teken na de tweede spatie (G). Dit tekennummer is de startpositie waarvandaan u naar de derde instantie van een spatie moet zoeken. (10 + 1 = 11)

  14. Zoeken naar de derde spatie in A2, te beginnen bij de elfde positie (G), gevonden in stap 6. (13)

  15. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de derde spatie aftrekken, zoals gevonden in stap 5. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (17 - 13 = 4)

In dit voorbeeld komt de achternaam vóór de voornaam en staat de tweede voornaam achteraan. De komma markeert het einde van de achternaam en alle naamcomponenten zijn van elkaar gescheiden door een spatie.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Geel, Maria Vera

Eerst de achternaam, met komma

Formule

Resultaat (voornaam)

'=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1))

=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-VIND.SPEC(" ";A2;1))

Formule

Resultaat (middelste naam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

Formule

Direct resultaat (achternaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1)-2)

=LINKS(A2; VIND.SPEC(" ";A2;1)-2)

  1. Voornaam

    De eerste voornaam begint bij het zevende teken vanaf de linkerkant (M) en eindigt bij het twaalfde teken (de tweede spatie). Aangezien deze voornaam midden in de volledige naam staat, moet de voornaam worden geëxtraheerd met behulp van de functie DEEL.

    De formule extraheert zes tekens, vanaf de zevende positie.

    formule voor het extraheren van de achternaam van voorbeeld 4: geel, maria vera

    Met de functie VIND.SPEC vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  2. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (M). Deze numerieke positie is de startpositie van de middelste naam. (6 + 1 = 7)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  3. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (M). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (6 + 1 = 10)

    Zoeken naar de tweede spatie in A2, te beginnen vanaf de tiende positie (M), gevonden in stap 4. (12)

  4. Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  5. Neem het tekennummer van de tweede spatie gevonden in stap 5 en trek daar het tekennummer van de eerste spatie vanaf, gevonden in stap 6. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de tiende positie, gevonden in stap 2. (12 – 6 = 6)

  6. Tweede voornaam

    De tweede voornaam begint vier tekens vanaf de rechterkant (V) en eindigt met het eerste teken vanaf de rechterkant (a). In deze formule worden VIND.SPEC-functies genest om de eerste en tweede instantie van een spatie te vinden op de zesde en twaalfde positie vanaf de linkerkant.

    De formule extraheert vier tekens vanaf de rechterkant.

    formule voor het extraheren van de achternaam van voorbeeld 4: geel, maria vera

    Met de functie LENGTE en de geneste VIND.SPEC-functies vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  7. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (M). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (6 + 1 = 10)

  8. Zoeken naar de tweede spatie in A2, te beginnen vanaf de zevende positie (M), gevonden in stap 2. (12)

  9. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de tweede spatie aftrekken, zoals gevonden in stap 3. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (16 - 12 = 4)

  10. Achternaam

    De achternaam begint met het eerste teken vanaf de linkerkant (G) en eindigt bij het vierde teken (l). De formule extraheert vier tekens vanaf de linkerkant.

    formule voor het extraheren van de achternaam van voorbeeld 4: geel, maria vera

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  11. Hier 2 van aftrekken om de numerieke positie te verkrijgen van het eindteken van de achternaam (l). Het resultaat is het aantal tekens dat u met LINKS wilt extraheren. (6 - 2 = 4)

In dit voorbeeld wordt een voornaam die uit twee namen bestaat gebruikt, Koos Jan. De tweede en de derde spatie vormen de scheiding tussen de onderdelen van de naam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Koos Jan D. Splinter

Tweedelige voornaam

Formule

Resultaat (voornaam)

LINKS(A2; VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=LINKS(A2; VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

Formule

Resultaat (middelste initiaal)

'=DEEL(A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

=DEEL(A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-(VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

Formule

Direct resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant en eindigt met het negende teken (de tweede spatie). In deze formule wordt met behulp van geneste VIND.SPEC-functies de tweede instantie van een spatie vanaf de linkerkant gevonden.

    De formule extraheert negen tekens vanaf de linkerkant.

    Formule voor het scheiden van voornaam, middelste naam en -initiaal, en achternaam

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (5)

  2. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (5 + 1 = 6)

  3. Zoeken naar de tweede instantie van een spatie in A2, te beginnen vanaf de zesde positie (J) gevonden in stap 2. Het resultaat is het aantal tekens dat met LINKS wordt geëxtraheerd uit de teksttekenreeks. (9)

  4. Tweede voornaam

    Het middendeel van de naam begint in de tiende positie (D) en eindigt op de twaalfde positie (de derde spatie). Voor deze formule worden VIND.SPEC-functies genest om het eerste, tweede en derde voorkomen van een spatie te vinden.

    De formule extraheert twee tekens vanaf het midden, vanaf de tiende positie.

    Formule voor het scheiden van voornaam, middelste naam en -initiaal, en achternaam

    Met geneste VIND.SPEC-functies vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (5)

  5. Er 1 bij optellen om het teken te verkrijgen na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (5 + 1 = 6)

  6. Zoeken naar de positie van de tweede instantie van een spatie in A2, te beginnen vanaf de zesde positie (J) gevonden in stap 2. Het resultaat is het aantal tekens dat met LINKS wordt geëxtraheerd vanaf de linkerkant. (9)

  7. Er 1 bij optellen om het teken na de tweede spatie (D) te verkrijgen. Het resultaat is de beginpositie van het middendeel van de naam. (9 + 1 = 10)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van het teken na de tweede spatie (D). Het resultaat is het tekennummer vanaf waar u wilt gaat zoeken naar de derde spatie. (10)

  8. Zoeken naar de numerieke positie van de derde spatie in A2 vanaf de linkerkant. Het resultaat is de eindpositie van het middendeel van de naam. (12)

  9. Zoeken naar de numerieke positie van het teken na de tweede spatie (D). Het resultaat is de beginpositie van het middendeel van de naam. (10)

  10. Neem het tekennummer van de derde spatie gevonden in stap 6 en trek daar het tekennummer van 'D' vanaf, gevonden in stap 7. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de tiende positie, gevonden in stap 4. (12 – 10 = 2)

  11. Achternaam

    De achternaam begint acht tekens vanaf de rechterkant. In deze formule worden geneste VIND.SPEC-functies gebruikt om de eerste, tweede en derde voorkomende spatie te vinden in de vijfde, negende en twaalfde positie.

    De formule extraheert acht tekens, te beginnen bij de rechterkant.

    Formule voor het scheiden van voornaam, middelste naam en -initiaal, en achternaam

    Met de geneste VIND.SPEC-functie en de functie LENGTE vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (5)

  12. Er 1 bij optellen om het teken te verkrijgen na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de spatie moet zoeken. (5 + 1 = 6)

  13. Zoeken naar de tweede spatie in A2, te beginnen vanaf de zesde positie (J), gevonden in stap 2. (9)

  14. Er 1 bij optellen om de positie te verkrijgen van het teken na de tweede spatie (D). Het resultaat is de startpositie van het middendeel van de naam. (9 + 1 = 10)

  15. Zoeken naar de numerieke positie van de derde spatie in A2 vanaf de linkerkant. Het resultaat is de eindpositie van het middendeel van de naam. (12)

  16. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de derde spatie aftrekken, zoals gevonden in stap 5. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (20 - 12 = 8)

In dit voorbeeld bestaat de achternaam uit drie delen: Bartels van Vugt. De eerste spatie geeft het einde van de voornaam aan en het begin van de achternaam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Luc Bartels van Vugt

Driedelige achternaam

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achternaam)

RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant (L) en eindigt bij het vierde teken (de eerste spatie). De formule extraheert vier tekens vanaf de linkerkant.

    Formule voor het scheiden van een voornaam en een achternaam die uit drie delen bestaat

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  2. Achternaam

    De achternaam begint zestien tekens vanaf de rechterkant (B) en eindigt met het eerste teken vanaf de rechterkant (t). De formule extraheert zestien tekens vanaf de rechterkant.

    Formule voor het scheiden van een voornaam en een achternaam die uit drie delen bestaat

    Met de functies LENGTE en VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  3. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de eerste spatie aftrekken, zoals gevonden in stap 1. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (20 - 4 = 16)

In dit voorbeeld bestaat de achternaam uit twee delen: de Goederen. De eerste spatie geeft het einde van de voornaam aan en het begin van de achternaam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Richard de Goederen

Tweedelige achternaam

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant (R) en eindigt bij het achtste teken (de eerste spatie). De formule extraheert acht tekens vanaf de linkerkant.

    formule voor het extraheren van de achternaam van voorbeeld 7: richard de goederen

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  2. Achternaam

    De achternaam begint met het elfde teken vanaf de rechterkant (d) en eindigt bij het eerste teken vanaf de rechterkant (n). De formule extraheert elf tekens vanaf de rechterkant van de volledige naam.

    formule voor het extraheren van de achternaam van voorbeeld 7: richard de goederen

    Met de functies LENGTE en VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  3. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de eerste spatie aftrekken, zoals gevonden in stap 1. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (19 - 8 = 11)

In dit voorbeeld staat de achternaam vooraan, gevolgd door het achtervoegsel. De achternaam en het achtervoegsel zijn gescheiden van de voornaam en de middelste voorletter door middel van een komma.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Veninga Jr., Tjeerd K.

Achternaam en achtervoegsel eerst, met komma

Formule

Resultaat (voornaam)

'=DEEL(A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=DEEL(A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

Formule

Resultaat (middelste initiaal)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)+1))

Formule

Resultaat (achternaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achtervoegsel)

'=DEEL(A2;VIND.SPEC(" "; A2;1)+1; VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-2)-(VIND.SPEC(" ";A2;1))

=DEEL(A2;VIND.SPEC(" "; A2;1)+1;(VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-2)-VIND.SPEC(" ";A2;1))

  1. Voornaam

    De voornaam begint met het veertiende teken (T) en eindigt met het eenentwintigste teken (de derde spatie). De formule extraheert zes tekens vanaf de twaalfde positie.

    Formule voor het scheiden van achternaam en achtervoegsel eerst, met komma

    Met geneste VIND.SPEC-functies vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  2. Er 1 bij optellen om het teken te verkrijgen na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (8 + 1 = 9)

  3. Zoeken naar de tweede spatie in A2, te beginnen vanaf de negende positie (J), gevonden in stap 2. (13)

  4. Er 1 bij optellen om het teken na de tweede spatie (T) te verkrijgen. Het resultaat is de beginpositie van de tweede voornaam. (13 + 1 = 14)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van het teken na de tweede spatie (D). Het resultaat is het tekennummer vanaf waar u wilt gaat zoeken naar de derde spatie. (14)

  5. Zoeken naar de numerieke positie van de derde spatie in A2 vanaf de linkerkant. Het resultaat is de eindpositie van de voornaam. (19)

  6. Zoeken naar de numerieke positie van het teken na de tweede spatie (T). Het resultaat is de beginpositie van de voornaam. (14)

  7. Neem het tekennummer van de derde spatie gevonden in stap 6 en trek daar het tekennummer van 'T' vanaf, gevonden in stap 7. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de veertiende positie, gevonden in stap 4. (17 – 14 = 3)

  8. Tweede voornaam

    De tweede voornaam begint met het tweede teken van rechts (K). De formule extraheert twee tekens vanaf de rechterkant.

    Formule voor het scheiden van achternaam en achtervoegsel eerst, met komma

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  9. Er 1 bij optellen om het teken te verkrijgen na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (8 + 1 = 9)

  10. Zoeken naar de tweede spatie in A2, te beginnen vanaf de negende positie (J), gevonden in stap 2. (13)

  11. Er 1 bij optellen om het teken na de tweede spatie (T) te verkrijgen. Het resultaat is de beginpositie van de voornaam. (13 + 1 = 14)

  12. Zoeken naar de numerieke positie van de derde spatie in A2 vanaf de linkerkant. Het resultaat is de eindpositie van de tweede voornaam. (19)

  13. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de derde spatie aftrekken, zoals gevonden in stap 5. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (21 - 19 = 2)

  14. Achternaam

    De achternaam begint met het eerste teken vanaf de linkerkant (V) en eindigt bij het achtste teken (de eerste spatie). De formule extraheert acht tekens vanaf de linkerkant.

    Formule voor het scheiden van achternaam en achtervoegsel eerst, met komma

    Met de functie VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  15. Achtervoegsel

    Het achtervoegsel begint bij het negende teken vanaf de linkerkant (J) en eindigt bij het elfde teken vanaf de linkerkant (.). De formule extraheert drie tekens, te beginnen bij het negende teken.

    Formule voor het scheiden van achternaam en achtervoegsel eerst, met komma

    Met de functie VIND.SPEC vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  16. Er 1 bij optellen om het teken na de eerste spatie (J) te verkrijgen. Het resultaat is de beginpositie van het achtervoegsel. (8 + 1 = 9)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  17. Er 1 bij optellen om de numerieke positie te verkrijgen van het teken na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (9)

  18. Zoeken naar de numerieke positie van de tweede spatie in A2, te beginnen vanaf de negende tekenpositie, gevonden in stap 4. (13)

  19. Er wordt 1 afgetrokken van het tekennummer van de tweede spatie, gevonden in stap 4, om te komen tot het tekennummer van de ','. Het resultaat is de eindpositie van het achtervoegsel. (13 - 1 = 12)

  20. Zoeken naar de numerieke positie van de eerste spatie. (6)

  21. Nadat de eerste spatie is gevonden, telt u 1 hierbij op om het volgende teken te vinden (J), dat ook al is gevonden in stappen 3 en 4. (7)

  22. Neem het tekennummer van ',' gevonden in stap 6 en trek daar het tekennummer van 'J' vanaf, gevonden in stap 3 en 4. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de negende positie, gevonden in stap 2. (12 – 9 = 3)

In dit voorbeeld bevindt de voornaam zich aan het begin van de tekenreeks en staat het achtervoegsel op het einde, dus kunt u formules gebruiken die lijken op die van Voorbeeld 2: Gebruik de functie LINKS om de voornaam op te halen, de functie DEEL om de achternaam op te halen en de functie RECHTS om het achtervoegsel op te halen.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Dick Beekman III

Voor- en achternaam met achtervoegsel

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achternaam)

'=DEEL(A2;VIND.SPEC(" "; A2;1)+1; VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1)+1))

=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1)+1))

Formule

Resultaat (achtervoegsel)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

  1. Voornaam

    De voornaam begint met het eerste teken vanaf de linkerkant (D) en eindigt bij het vijfde teken (de eerste spatie). De formule extraheert vijf tekens vanaf de linkerkant van de volledige naam.

    Formule voor het scheiden van een voor- en achternaam gevolgd door een achtervoegsel

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (5)

  2. Achternaam

    De achternaam begint bij het zesde teken vanaf de linkerkant (B) en eindigt met het twaalfde teken (de tweede spatie). In deze formule worden met behulp van geneste VIND.SPEC-functies de positie van de spaties gevonden.

    De formule extraheert zeven tekens vanaf het midden, vanaf het zesde teken.

    Formule voor het scheiden van een voor- en achternaam gevolgd door een achtervoegsel

    Met de functie VIND.SPEC vindt u de waarde voor begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (5)

  3. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (B). Het resultaat is de startpositie van het middendeel van de naam. (5 + 1 = 6)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (5)

  4. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (B). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (5 + 1 = 6)

  5. Zoeken naar de numerieke positie van de tweede spatie in A2, te beginnen vanaf het zesde teken (B) gevonden in stap 4. Dit tekennummer is de eindpositie van de achternaam. (13)

  6. Zoeken naar de numerieke positie van de eerste spatie. (5)

  7. Voeg 1 toe om te zoeken naar de numerieke positie van het teken na de eerste spatie (B), ook gevonden in stap 1 en 3. (4)

  8. Neem het tekennummer van de tweede spatie gevonden in stap 5 en trek daar vervolgens het tekennummer van 'B' vanaf, gevonden in stap 6 en 7. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de zesde positie, gevonden in stap 2. (13 – 6 = 7)

  9. Achtervoegsel

    Het achtervoegsel begint drie tekens vanaf de rechterkant. In deze formule worden met behulp van geneste VIND.SPEC-functies de positie van de spaties gevonden.

    Formule voor het scheiden van een voor- en achternaam gevolgd door een achtervoegsel

    Met de geneste VIND.SPEC-functie en de functie LENGTE vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (5)

  10. Er 1 bij optellen om het teken te verkrijgen na de eerste spatie (B). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (5 + 1 = 6)

  11. Zoeken naar de tweede spatie in A2, te beginnen vanaf de zesde positie (B), gevonden in stap 2. (13)

  12. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de tweede spatie aftrekken, zoals gevonden in stap 3. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (16 - 13 = 3)

In dit voorbeeld wordt de volledige naam voorafgegaan door een voorvoegsel en kunt u formules gebruiken die lijken op die uit Voorbeeld 2: gebruik de functie DEEL om de voornaam op te halen en de functie RECHTS om de achternaam op te halen.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Mr. Joop Zeger

Met voorvoegsel

Formule

Resultaat (voornaam)

'=DEEL(A2;VIND.SPEC(" "; A2;1)+1; VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1)+1))

=DEEL(A2;VIND.SPEC(" ";A2;1)+1;VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1)-(VIND.SPEC(" ";A2;1)+1))

Formule

Resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;VIND.SPEC(" ";A2;1)+1))

  1. Voornaam

    De voornaam begint bij het vijfde teken vanaf de linkerkant (J) en eindigt met het negende teken (de tweede spatie). In deze formule worden met behulp van geneste VIND.SPEC-functies de positie van de spaties gevonden. De formule extraheert vier tekens, te beginnen bij de vijfde positie.

    Formule voor het scheiden van een voornaam voorafgegaan door een voorvoegsel

    Met de functie VIND.SPEC vindt u de waarde voor het begin_getal:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (4)

  2. Tel hierbij 1 op om de positie te vinden van het teken na de eerste spatie (R). Het resultaat is de beginpositie van de voornaam. (4 + 1 = 5)

    Met geneste VIND.SPEC-functies vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (4)

  3. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (4 + 1 = 5)

  4. Zoeken naar de numerieke positie van de tweede spatie in A2, te beginnen vanaf het vijfde teken (B) gevonden in stap 3 en 4. Dit tekennummer is de eindpositie van de voornaam. (9)

  5. Zoek naar de eerste spatie. (4)

  6. Er 1 bij optellen om te zoeken naar de numerieke positie van het teken na de eerste spatie (J), ook gevonden in stap 1 en 3. (4)

  7. Neem het tekennummer van de tweede spatie gevonden in stap 5 en trek daar vervolgens het tekennummer van 'J' vanaf, gevonden in stap 6 en 7. Het resultaat is het aantal tekens dat door DEEL wordt geëxtraheerd uit de teksttekenreeks, te beginnen bij de vijfde positie, gevonden in stap 2. (9 – 5 = 4)

  8. Achternaam

    De achternaam begint vijf tekens vanaf de rechterkant. In deze formule worden met behulp van geneste VIND.SPEC-functies de positie van de spaties gevonden.

    Formule voor het scheiden van een voornaam voorafgegaan door een voorvoegsel

    Met de geneste VIND.SPEC-functie en de functie LENGTE vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (4)

  9. Er 1 bij optellen om de positie te verkrijgen van het teken na de eerste spatie (J). Het resultaat is het tekennummer waarvandaan u naar de tweede spatie moet zoeken. (4 + 1 = 5)

  10. Zoeken naar de tweede spatie in A2, te beginnen vanaf de vijfde positie (J), gevonden in stap 2. (9)

  11. De totaallengte van de teksttekenreeks in A2 tellen en vervolgens het aantal tekens vanaf de linkerkant tot de tweede spatie aftrekken, zoals gevonden in stap 3. Het resultaat is het aantal tekens dat moet worden geëxtraheerd vanaf de rechterkant van de volledige naam. (14 - 9 = 5)

In dit voorbeeld wordt een achternaam met een koppelteken gebruikt. Een spatie vormt de scheiding tussen elk onderdeel van de naam.

Kopieer de cellen in de tabel en plak ze in een Excel-werkblad bij cel A1. De formule aan de linkerkant wordt ter referentie weergegeven. De formule aan de rechterkant wordt automatisch geconverteerd naar het juiste resultaat.

Tip    Stel de kolombreedte van de kolommen A en B in op 205 voordat u de gegevens in het werkblad plakt.

Voorbeeldnaam

Beschrijving

Julia Terp-Groen

Achternaam met koppelstreepje

Formule

Resultaat (voornaam)

'=LINKS(A2; VIND.SPEC(" ";A2;1))

=LINKS(A2; VIND.SPEC(" ";A2;1))

Formule

Resultaat (achternaam)

'=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

=RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2;1))

  1. Voornaam

    De voornaam begint bij het eerste teken vanaf de linkerkant en eindigt bij de zesde positie (de eerste spatie). De formule extraheert zes tekens vanaf de linkerkant.

    Formule voor het scheiden van een voornaam en een achternaam met koppelstreepje

    Met de functie VIND.SPEC vindt u de waarde van aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf de linkerkant. (6)

  2. Achternaam

    De volledige achternaam begint tien tekens vanaf de rechterkant (T) en eindigt met het eerste teken vanaf de rechterkant (n).

    Formule voor het scheiden van een voornaam en een achternaam met koppelstreepje

    Met de functies LENGTE en VIND.SPEC vindt u de waarde voor aantal_tekens:

    Zoeken naar de numerieke positie van de eerste spatie in A2, vanaf het eerste teken links. (6)

  3. De totaallengte van de te extraheren teksttekenreeks tellen en vervolgens het aantal tekens vanaf de linkerkant tot de eerste spatie aftrekken, gevonden in stap 1. (16 - 6 = 10)

Zie ook

Tekst verdelen over verschillende kolommen met de wizard Tekst naar kolommen

Uw Office-vaardigheden uitbreiden
Training verkennen
Als eerste nieuwe functies krijgen
Deelnemen aan Office Insiders

Was deze informatie nuttig?

Bedankt voor uw feedback.

Hartelijk dank voor uw feedback! Het lijkt ons een goed idee om u in contact te brengen met een van onze Office-ondersteuningsagents.

×