TEKST, functie

Met de functie TEKST kunt u de manier veranderen waarop een getal wordt weergegeven, door het op te maken met notatiecodes. Het is handig in situaties waarin u getallen wilt weergeven in een leesbaardere indeling of als u getallen wilt combineren met tekst of symbolen.

Opmerking: De functie TEKST converteert getallen naar tekst, waardoor het lastig wordt om ze later in berekeningen te gebruiken. Het is beter om de oorspronkelijke waarde in één cel te bewaren en de functie TEKST in een andere cel te gebruiken. Als u andere formules wilt maken, kunt u dan altijd verwijzen naar de oorspronkelijke waarde en niet naar het resultaat van de functie TEKST.

Syntaxis

TEKST(waarde;notatie_tekst)

De syntaxis van de functie TEKST heeft de volgende argumenten:

Naam argument

Beschrijving

waarde

Een numerieke waarde die u wilt converteren naar tekst.

notatie_tekst

Een teksttekenreeks die de opmaak bepaalt die u wilt toepassen op de opgegeven waarde.

Overzicht

In de meest eenvoudige vorm staat de functie TEKST voor het volgende:

  • =TEKST(Waarde die u wilt opmaken; "Notatiecode die u wilt toepassen")

Hier volgen enkele populaire voorbeelden. U kunt deze rechtstreeks kopiëren naar Excel om zelf te experimenteren. Let op de notatiecodes tussen aanhalingstekens.

Formule

Beschrijving

=TEKST(1234,567;"€ #.##0,00")

Valuta met een scheidingsteken voor duizendtallen en 2 decimalen, zoals € 1.234,57. Houd er rekening mee dat Excel de waarde afrondt op 2 decimalen.

=TEKST(VANDAAG();"DD-MM-JJ")

De datum van vandaag in de notatie DD-MM-JJ, zoals 14-03-12

=TEKST(VANDAAG(),"DDDD")

De huidige dag van de week, bijvoorbeeld maandag

=TEKST(NU();"U:MM AM/PM")

Huidige tijd, bijvoorbeeld 1:29 AM

=TEKST(0,285;"0,0%")

Percentage, bijvoorbeeld 28,5%

=TEKST(4,34 ,"# ?/?" )

Breuk, bijvoorbeeld 4 1/3

=SPATIES.WISSEN(TEKST(0,34;"# ?/?"))

Breuk, bijvoorbeeld 1/3. Hier wordt de functie SPATIES.WISSEN gebruikt om de voorloopspatie bij een decimale waarde te verwijderen.

=TEKST(12200000;"0,00E+00")

Wetenschappelijke notatie, bijvoorbeeld 1,22E+07

=TEKST(1234567898;"[<=9999999]###-####;(###) ###-####")

Speciaal (telefoonnummer), bijvoorbeeld (123) 456-7898

=TEKST(1234;"0000000")

Voorloopnullen (0) toevoegen, bijvoorbeeld 0001234

=TEKST(123456;"##0° 00' 00''")

Aangepast - breedtegraad/lengtegraad

Opmerking: Hoewel u de functie TEKST kunt gebruiken om de notatie te wijzigen, is het niet de enige manier. U kunt de notatie ook zonder formule wijzigen door te drukken op CTRL+1 (of Afbeelding van het pictogram voor de opdrachtknop MAC +1 op de Mac), en de gewenste indeling te kiezen in het dialoogvenster Celeigenschappen > Getal.

Voorbeelden downloaden

U kunt een voorbeeldwerkmap downloaden met alle voorbeelden van de functie TEKST die u in dit artikel vindt, plus enkele extra’s. U kunt deze volgen of uw eigen opmaakcodes voor de functie TEKST maken.

Voorbeelden van Excel-functie TEKST downloaden

Andere beschikbare notatiecodes

In het dialoogvenster Celeigenschappen vindt u andere beschikbare notatiecodes:

  1. Druk op Ctrl+1 ( Afbeelding van het pictogram voor de opdrachtknop MAC +1 op de Mac) om het dialoogvenster Celeigenschappen te openen.

  2. Selecteer de gewenste notatie op het tabblad Getal.

  3. Selecteer de optie Aangepast.

  4. Nu wordt de gewenste notatiecode weergegeven in het vak Type. In dit geval selecteert u alles in het vak Type behalve de puntkomma (;) en het @-teken. In onderstaand voorbeeld hebben we alleen dd-mm-jj geselecteerd en gekopieerd.

  5. Druk op Ctrl+C om de notatiecode te kopiëren en druk op Annuleren om het dialoogvenster Celeigenschappen te sluiten.

  6. Nu hoeft u alleen maar op Ctrl+V te drukken om de notatiecode in uw TEKST-formule te plakken, bijvoorbeeld =TEKST(B2;"dd-mm-jj'). Zorg dat u de notatiecode binnen de aanhalingstekens ("notatiecode") plakt. Anders wordt er een foutbericht weergegeven.

Voorbeeld van het gebruik van het dialoogvenster Opmaak > Cellen > Getal > Aangepast om Excel opmaakreeksen voor u te laten maken.

Opmaakcodes per categorie

Hier volgen enkele voorbeelden van hoe u met behulp van het dialoogvenster Celeigenschappen verschillende getalnotaties op de waarden kunt toepassen. Daarna gebruikt u de optie Aangepast om deze notatiecodes naar uw TEKST-functie te kopiëren.

Waarom worden voorloopnullen (0) in Excel verwijderd?

Excel is ingesteld om te zoeken naar getallen die in cellen worden ingevoerd, geen getallen die er uitzien als tekst, zoals onderdeelnummers of SKU's. Als u voorloopnullen wilt behouden, maakt u het invoerbereik op als tekst voordat u waarden plakt of invoert. Selecteer de kolom of het bereik waarin u de waarden wilt plaatsen en druk op CTRL+1 om het dialoogvenster Opmaak > Cellen te openen. Ga naar het tabblad Getal en selecteer Tekst. Nu blijven de voorloopnullen (0) in Excel staan.

Als u al gegevens hebt ingevoerd en Excel de voorloopnullen heeft verwijderd, kunt u ze met de functie TEKST opnieuw toevoegen. U kunt naar de cel met de waarden verwijzen en =TEKST(waarde;"00000") gebruiken, waarbij het aantal nullen in de formule staat voor het totale aantal tekens dat u wilt gebruiken. Daarna kopieert en plakt u naar de rest van het bereik.

Voorbeelden van het gebruik van TEKST om voorloopnullen op te maken. =TEKST(A2;"00000")

Als u tekstwaarden om welke reden dan ook weer wilt converteren naar getallen, dan kunt u met 1 vermenigvuldigen, bijvoorbeeld =D4*1 of de dubbel-unaire operator (--) gebruiken, bijvoorbeeld =--D4.

In Excel worden duizendtallen gescheiden door punten als de opmaak een punt (.) bevat die is omsloten door hekjes (#) of nullen. Als de notatiereeks bijvoorbeeld "#.###" is, wordt het getal 12.200.000 in Excel weergegeven als 12.200,000.

Als een tijdelijke aanduiding wordt gevolgd door een punt, wordt het getal geschaald met 1.000. Als de notatietekenreeks bijvoorbeeld "#.###,0." is, wordt het getal 12200000 weergegeven als 12.200,0.

Voorbeelden van de functie TEKST met het scheidingsteken voor duizendtallen

Notities: 

  • Het scheidingsteken voor duizendtallen is afhankelijk van uw landinstellingen. In Nederland is het een punt, maar voor andere landinstellingen kan het een komma (,) zijn.

  • Het scheidingsteken voor duizendtallen is beschikbaar voor de getal-, valuta en financiële notatie.

Hieronder vindt u voorbeelden van standaardgetal- (alleen scheidingstekens voor duizendtallen en decimalen), valuta- en financiële notaties. Met de valutanotatie kunt u het gewenste valutasymbool invoegen en naast de waarde uitlijnen. Met de financiële notatie wordt het valutasymbool uitgelijnd met de linkerkant van de cel en wordt de waarde rechts uitgelijnd. Let hieronder op het verschil tussen de valuta- en financiële notatie, waar in de financiële notatie een sterretje (*) wordt gebruikt om het symbool van de waarde te scheiden.

Voorbeelden van de functie TEKST met getal-, valuta- en financiële notaties

Als u de notatiecode voor een valutasymbool zoekt, drukt u eerst op Ctrl+1 (of Afbeelding van het pictogram voor de opdrachtknop MAC +1 op de Mac). Selecteer de gewenste notatie en kies vervolgens een symbool in de vervolgkeuzelijst Symbool:

Selectie van valutateken in het dialoogvenster Celeigenschappen

Klik vervolgens aan de linkerkant van de sectie Categorie op Aangepast en kopieer de notatiecode inclusief het valutasymbool.

Functie TEKST: aangepaste valuta met symbool

Opmerking: De functie TEKST biedt geen ondersteuning voor kleuropmaak, dus als u vanuit het dialoogvenster een numerieke notatiecode kopieert die een kleur bevat, bijvoorbeeld: € #.##0,00_);[rood](€ #.##0,00), zal de functie TEKST de notatiecode wel accepteren, maar wordt de kleur niet weergegeven.

U kunt de manier veranderen waarop een datum wordt weergegeven door een combinatie te gebruiken van 'M' voor maand, 'D' voor dag en 'J' voor jaar.

Notatiecodes voor maand, dag en jaar

Notatiecodes in de functie TEKST zijn niet hoofdlettergevoelig. U kunt dus 'M' of 'm', 'D' of 'd', 'J' of 'j' gebruiken.

Excel MVP Mynda Treacy

Mynda adviseert...

Als u Excel-bestanden en -rapporten deelt met gebruikers uit verschillende landen, kunt u ze een rapport in hun eigen taal geven. Mynda Treacy, Excel MVP beschrijft een geweldige oplossing in dit artikel: Excel Dates Displayed in Different Languages (Datums in Excel in verschillende talen weergegeven). Het bevat tevens een werkmap met voorbeelden die u kunt downloaden.

U kunt de manier wijzigen waarop de tijd wordt weergegeven door een combinatie te gebruiken van 'U' voor uren, 'M' voor minuten en 'S' voor seconden, en 'AM/PM' voor een 12-uurs tijdnotatie.

Tijdnotaties voor uren, minuten en seconden

Als u 'AM/PM' of 'A/P' weglaat, wordt de tijd weergegeven in een 24-uurs tijdnotatie.

Notatiecodes in de functie TEKST zijn niet hoofdlettergevoelig. U kunt dus 'U' of 'u', 'M' of 'm', 'S' of 's', 'AM/PM' of 'am/pm' gebruiken.

U kunt de manier wijzigen waarop decimale waarden met een percentagenotatie (%) worden weergegeven.

Notatiecodes voor procenten

U kunt de manier wijzigen waarop decimale waarden met een breuknotatie (?/?) worden weergegeven.

Notatiecodes voor breuken

De wetenschappelijke notatie is een manier om getallen weer te geven als een decimaal getal tussen 1 en 10, vermenigvuldigd met een macht van 10. Dit wordt vaak gebruikt om grote getallen korter weer te geven.

Notatiecodes voor wetenschappelijke notatie

Excel bevat 4 speciale indelingen:

  • Postcode: '00000'

  • Postcode + 4 - '00000-0000'

  • Telefoonnummer: '[<=9999999]###-####;(###) ###-####'

  • Sofi-nummer: '000-00-0000'

Speciale opmaak voor de functie TEKST

Speciale indelingen zijn afhankelijk van de landinstelling, maar als er geen speciale indelingen zijn voor uw landinstelling of als deze niet aan uw behoeften voldoen, kunt u een eigen indeling maken via het dialoogvenster Celeigenschappen > Aangepast.

Veelvoorkomend scenario

De functie TEKST wordt zelden op zichzelf gebruikt, meestal in combinatie met iets anders. Stel dat u tekst en een numerieke waarde wilt combineren, zoals "Rapport afgedrukt op: 14-03-12" of "Wekelijkse opbrengst: € 66.348,72". U kunt die gegevens natuurlijk handmatig in Excel invoeren, maar het voordeel van Excel is nu juist dat het programma dit voor u kan doen. Wanneer u tekst en opgemaakte getallen combineert, zoals datums, tijden, valuta, enzovoort, weet Excel echter niet hoe u ze wilt weergeven, en daarom wordt de getalnotatie genegeerd. Hier is de functie TEKST bijzonder handig omdat u ervoor kunt zorgen dat Excel de waarden opmaakt zoals u dat wilt. U gebruikt daarvoor een notatiecode zoals 'DD-MM-JJ' voor de datumnotatie.

In het volgende voorbeeld ziet u wat er gebeurt als u tekst en een getal probeert samen te voegen zonder de functie TEKST. In dit geval gebruiken we de Ampersand (&) om een teksttekenreeks, een spatie (" ") en een waarde samen te voegen met behulp van =A2&" "&B2.

Voorbeeld van het samenvoegen van tekst zonder de functie TEKST

Zoals u ziet, wordt de opmaak van de datum in cel B2 door Excel verwijderd. In het volgende voorbeeld ziet u hoe u met de functie TEKST de gewenste opmaak kunt toepassen.

Voorbeeld van het samenvoegen van tekst met de functie TEKST

De bijgewerkte formule ziet er als volgt uit:

  • Cel C2:=A2&" "&TEKST(B2;"dd-mm-jj") - Datumnotatie

Veelgestelde vragen

Dat is helaas niet mogelijk met de functie TEKST. Hiervoor moet u Visual Basic for Applications (VBA)-code gebruiken. Hier vindt u een mogelijke methode: How to convert a numeric value into English words in Excel(Een numerieke waarde omzetten in Engelse woorden in Excel)

Ja, u kunt de functies HOOFDLETTERS, KLEINE LETTERS en BEGINLETTERS gebruiken. Zo geeft =HOOFDLETTERS("Hallo") het resultaat 'HALLO'.

Ja, maar daar zijn een aantal stappen voor nodig. Selecteer eerst de cel of cellen waarin u dit wilt doen en druk op Ctrl+1 om het dialoogvenster Opmaak > Cellen te openen. Kies vervolgens Uitlijning > Tekstconfiguratie en schakel de optie Tekstterugloop in. Pas daarna uw voltooide functie TEKST aan door er de ASCII-functie TEKEN(10) in op te nemen op de positie waar u het regeleinde wilt plaatsen. Mogelijk moet u de kolombreedte aanpassen, afhankelijk van hoe het uiteindelijke resultaat wordt uitgelijnd.

Voorbeeld van tekst met TEKEN(10), om een regeleinde in te voegen. ="Vandaag is het: "&TEKEN(10))&TEKST(VANDAAG();"DD-MM-JJ")

Hier hebben we dit gebruikt: ="Vandaag is het: "&TEKEN(10)&TEKST(VANDAAG();"dd-mm-jj")

Dit heet de wetenschappelijke notatie. Als een of meer cellen de opmaak Algemeen hebben, worden getallen met meer dan 12 cijfers geconverteerd, en als een of meer cellen de opmaak Getal hebben, worden cellen met meer dan 15 cijfers geconverteerd. Als u lange numerieke tekenreeksen moet invoeren en niet wilt dat ze worden geconverteerd, dient u de cellen in kwestie op te maken als Tekst voordat u de waarden in Excel invoert of plakt.

Excel MVP Mynda Treacy

Mynda adviseert...

Als u Excel-bestanden en -rapporten deelt met gebruikers uit verschillende landen, kunt u ze een rapport in hun eigen taal geven. Mynda Treacy, Excel MVP beschrijft een geweldige oplossing in dit artikel: Excel Dates Displayed in Different Languages (Datums in Excel in verschillende talen weergegeven). Het bevat tevens een werkmap met voorbeelden die u kunt downloaden.

Zie ook

Aangepaste getalnotaties maken of verwijderen

Tekst omzetten in getallen

Excel-functies (per categorie)

Uw Office-vaardigheden uitbreiden
Training verkennen
Als eerste nieuwe functies krijgen
Deelnemen aan Office Insiders

Was deze informatie nuttig?

Bedankt voor uw feedback.

Hartelijk dank voor uw feedback! Het lijkt ons een goed idee om u in contact te brengen met een van onze Office-ondersteuningsagents.

×