Functie SOM

Met de functie SOM, een van de wiskundige en trigonometrische functies, kunnen waarden worden opgeteld. U kunt afzonderlijke waarden, celverwijzingen, celbereiken of een combinatie van deze drie optellen.

Bijvoorbeeld:

  • =SOM(A2:A10)

  • =SOM(A2:A10;C2:C10)

Uw browser biedt geen ondersteuning voor video. Installeer Microsoft Silverlight, Adobe Flash Player of Internet Explorer 9.

Deze video maakt deel uit van de trainingscursus Getallen optellen in Excel 2013.

SOM(getal1;[getal2];...)

Naam argument

Beschrijving

getal1    (vereist)

Het eerste getal dat u wilt optellen. Het getal kan een cijfer zijn zoals 4, een celverwijzing zoals B6 of een celbereik zoals B2:B8.

getal2-255    (optioneel)

Dit is het tweede getal dat u wilt optellen. U kunt op deze manier maximaal 255 getallen opgeven.

Als u snel de som van een bereik van cellen wilt weten, hoeft u alleen maar het bereik te selecteren en in de rechterbenedenhoek van het Excel-venster te kijken.

Schermafbeelding van het selecteren van een bereik van cellen, met daarna verschillende gegevens op de statusbalk
Statusbalk


Dit is de statusbalk en u ziet hier informatie over wat u hebt geselecteerd, ongeacht of de selectie bestaat uit één cel of meerdere cellen. Als u met de rechtermuisknop op de statusbalk klikt, ziet u een lijst met alle opties die u kunt kiezen. De statusbalk bevat ook waarden voor het geselecteerde bereik als u deze kenmerken hebt ingeschakeld. Meer informatie over de statusbalk.

De eenvoudigste manier om een formule met SOM toe te voegen aan het werkblad, is via de wizard AutoSom. Selecteer een lege cel direct boven of onder het bereik dat u wilt optellen en ga naar het tabblad Start of Formules. Klik op het lint op AutoSom > Som. De wizard AutoSom bepaalt automatisch welk bereik moet worden opgeteld en stelt de bijbehorende formule samen. U kunt de wizard ook gebruiken voor een horizontaal bereik door een cel te selecteren die links of rechts van het bereik staat dat moet worden opgeteld. Deze methode werkt niet voor een niet-aaneengesloten bereik, maar dit scenario zullen we in de volgende sectie bekijken.

U kunt de wizard AutoSom gebruiken om automatisch een formule met SOM te maken.  Selecteer een bereik boven/onder of links/rechts van het bereik dat u wilt optellen en ga naar het tabblad Formules op het lint en selecteer AutoSom > SOM.
De wizard AutoSom gebruiken om snel een aaneengesloten bereik op te tellen


In het dialoogvenster AutoSom kunt u ook andere veelgebruikte functies selecteren, zoals:

AutoSom voor een verticaal bereik

Cel B6 bevat de SOM-formule die is gemaakt met AutoSom: =SOM(B2:B5)

De wizard AutoSom heeft automatisch vastgesteld dat de cellen B2:B5 het bereik vormen dat moet worden opgeteld. U hoeft alleen nog maar op Enter te drukken om dit te bevestigen. Als u meer cellen wilt toevoegen of uitsluiten, houdt u Shift samen met de gewenste pijltoets ingedrukt om de selectie uit te breiden of kleiner te maken. Druk op Enter als u tevreden bent over het nieuwe bereik.

IntelliSense-functiebeschrijving: het zwevende label SOM(getal1;[getal2]; …) onder de functie is de bijbehorende IntelliSense-beschrijving. Als u op de som of de functienaam klikt, verandert deze in een blauwe hyperlink waarmee u naar het Help-onderwerp voor die functie gaat. Als u op de afzonderlijke functie-elementen klikt, worden de bijbehorende onderdelen in de formule gemarkeerd. In dit geval zou alleen B2:B5 worden gemarkeerd, aangezien er slechts één verwijzing naar een getal in deze formule staat. Het IntelliSense-label wordt weergegeven voor elke functie.

AutoSom voor een horizontaal bereik

Cel D2 bevat de SOM-formule die is gemaakt met AutoSom: =SOM(B2:C2)

SOM gebruiken met niet-aaneengesloten bereiken.  De formule in cel C8 is =SOM(C2:C3;C5:C6). U kunt ook benoemde bereiken gebruiken. De formule wordt dan =SOM(Week1;Week2).

De wizard AutoSom werkt over het algemeen alleen voor aaneengesloten bereiken. Als het bereik dat u wilt optellen lege rijen of kolommen bevat, stopt de wizard bij de eerste lege rij of kolom. In een dergelijke situatie moet u SOM gebruiken per selectie en de afzonderlijke bereiken één voor één toevoegen. Als er in dit voorbeeld gegevens zouden hebben gestaan in cel B4, zou Excel de formule =SOM(C2:C6) hebben gegenereerd omdat dit als een aaneengesloten bereik wordt herkend.

U kunt snel meerdere, niet-aangrenzende bereiken selecteren met Ctrl+klikken met de linkermuisknop. Typ eerst =SOM( en selecteer daarna de verschillende bereiken. Er wordt automatisch een puntkomma als scheidingsteken ingevoerd tussen de bereiken. Druk op Enter als u klaar bent.

TIP: gebruik ALT+ = om de functie SOM snel toe te voegen aan een cel. Vervolgens hoeft u alleen nog maar een of meer bereiken te selecteren.

Opmerking: Het is u misschien opgevallen dat de verschillende functiebereiken met een eigen kleur zijn gemarkeerd, en dat die kleuren terugkomen in de formule zelf: C2:C3 heeft een kleur en C5:C6 heeft een andere kleur. Excel doet dit voor alle functies, tenzij het bereik waarnaar wordt verwezen zich in een ander werkblad of in een andere werkmap bevindt. U kunt de toegankelijkheid via ondersteunende technologie verbeteren door benoemde bereiken te gebruiken, zoals 'Week1', 'Week2', enzovoort, en hiernaar te verwijzen in de formule:

=SOM(Week1;Week2)

U kunt in Excel eenvoudig afzonderlijke wiskundige bewerkingen uitvoeren en in combinatie met Excel-functies zoals SOM. De volgende tabel bevat de operators die u kunt gebruiken en enkele gerelateerde functies. U kunt de operatoren invoeren via de cijfertoetsen op het toetsenbord of via het numerieke toetsenblok met tien toetsen, als u dit hebt. Met Shift + 8 voert u bijvoorbeeld het sterretje (*) in om te vermenigvuldigen.

Operator

Bewerking

Voorbeelden

+

Optellen

=1+1

=A1+B1

=SOM(A1:A10)+10

=SOM(A1:A10)+B1

-

Aftrekken

=1-1

=A1-B1

=SOM(A1:A10)-10

=SOM(A1:A10)-B1

*

Vermenigvuldigen

=1*1

=A1*B1

=SOM(A1:A10)*10

=SOM(A1:A10)*B1

=PRODUCT(1,1) - PRODUCT, functie

/

Delen

=1/1

=A1/B1

=SOM(A1:A10)/10

=SOM(A1:A10)/B1

=QUOTIENT(1,1) - QUOTIENT, functie

^

Machtsverheffen

=1^1

=A1^B1

=SOM(A1:A10)^10

=SOM(A1:A10)^B1

=MACHT(1,1) - MACHT, functie

Zie voor meer informatie Excel als rekenmachine.

Andere voorbeelden

  1. Stel dat u een procentuele korting wilt toepassen op een bereik met cellen die u hebt opgeteld.

    Operatoren gebruiken met SOM.  Formule in cel B16 is =SOM(A2:A14)*-25%.  De formule zou juist zijn samengesteld als -25% een celverwijzing was in plaats van een letterlijke waarde, zoals =SOM(A2:A14)*E2
    • =SOM(A2:A14)*-25%

    Het resultaat is weliswaar 25% van het opgetelde bereik, maar de korting van 25% wordt dan vastgelegd in de formule, waardoor het lastig kan zijn om deze later terug te vinden als er aanpassingen nodig zijn. Het is veel beter om de 25% in een cel te plaatsen en vervolgens naar die cel te verwijzen. De korting is dan veel makkelijker terug te vinden en te wijzigen. Doe dit als volgt:

    • =SOM(A2:A14)*E2

    Als u wilt delen in plaats van vermenigvuldigen, vervangt u het sterretje (*) door een schuine streep (/): =SOM(A2:A14)/E2

  2. Een berekende som aanpassen door een waarde op te tellen of af te trekken

    i. U kunt een som eenvoudig groter of kleiner maken met behulp van + of -, zoals hier:

    • =SOM(A1:A10)+E2

    • =SOM(A1:A10)-E2

In deze sectie worden enkele aanbevolen procedures behandeld voor het werken met de functie SOM. Veel van deze procedures gelden ook voor andere functies.

De methode =1+2 of =A+B. Hoewel =1+2+3 of =A1+B1+C2 in veel gevallen het juiste resultaat zal opleveren, zijn deze methoden om verschillende redenen foutgevoelig:

  1. Typfouten. Stel dat u meer en/of langere waarden moet invoeren zoals deze:

    • =14598,93+65437,90+78496,23

    Vervolgens moet u controleren of de invoer juist is. Het is veel gemakkelijker om deze waarden in afzonderlijke cellen te zetten en vervolgens SOM te gebruiken. Bovendien kunt u de waarden opmaken als ze in cellen staan, zodat ze veel beter leesbaar zijn dan in een formule.

    Gebruik de functie SOM in plaats van letterlijke waarden op te nemen in formules.  Formule in cel D5 is =SOM(D2:D4)
  2. De fout #WAARDE! omdat er wordt verwezen naar tekst in plaats van getallen

    Stel dat u deze formule gebruikt:

    • =A1+B1+C1 of =A1+A2+A3

    Voorbeeld van een slechte formule.  Formule in cel D2 is =A2+B2+C2

    De formule kan breken als er niet-numerieke waarden (tekst) in de cellen staan waarnaar wordt verwezen, met de fout #WAARDE! als gevolg. Met de functie SOM worden tekstwaarden gewoon genegeerd en krijgt u de som van alleen de numerieke waarden.

    Juiste samenstelling van formule.  In plaats van =A2+B2+C2, is de formule van cel D2 =SOM(A2:C2)
  3. De fout #VERW! door het verwijderen van rijen of kolommen

    #VERW!-fout veroorzaakt doordat er een kolom is verwijderd.  Formule is gewijzigd in =A2+#VERW!+B2

    Als u een rij of kolom verwijdert, wordt de formule niet automatisch bijgewerkt met als gevolg dat de fout #VERW! wordt geretourneerd. Als u de functie SOM gebruikt, wordt de functie wel automatisch aangepast.

    In de functie SOM wordt automatisch rekening gehouden met ingevoegde of verwijderde rijen en kolommen
  4. Verwijzingen in formules worden niet bijgewerkt als u rijen of kolommen invoegt

    Formules met =A+B+C worden niet bijgewerkt als u rijen toevoegt

    Als u een rij of kolom invoegt, wordt de formule niet automatisch aangepast. Dit gebeurt wel als u de functie SOM gebruikt (maar alleen als u zich binnen het bereik bevindt waarnaar wordt verwezen in de formule). Dit is vooral belangrijk als u verwacht dat de formule wordt bijgewerkt en dit niet het geval is. De kans bestaat dan namelijk dat u zonder dat u het weet met onvolledige resultaten werkt.

    In het voorbeeld ziet u een formule met SOM die automatisch wordt uitgebreid van =SOM(A2:C2) naar =SOM(A2:D2) als er een kolom wordt ingevoegd
  5. De functie SOM gebruiken met afzonderlijke celverwijzingen of bereiken

    Stel dat u deze formule gebruikt:

    • =SOM(A1;A2;A3;B1;B2;B3)

    De kans op fouten is dan om dezelfde redenen even groot wanneer u rijen invoegt of verwijdert in het bereik waarnaar wordt verwezen. Het is veel beter om afzonderlijke bereiken te gebruiken, zoals:

    • =SOM(A1:A3;B1:B3)

    Deze worden namelijk bijgewerkt als u rijen toevoegt of verwijdert.

  1. U kunt SOM gebruiken met andere functies. Hier ziet u een voorbeeld om per maand een gemiddelde te berekenen:

    SOM gebruiken met andere functies.  Formule in cel M2 is =SOM(A2:L2)/AANTALARG(A2:L2) .  Opmerking: de kolommen voor mei tot en met november zijn voor de duidelijkheid verborgen.
    • =SOM(A2:L2)/AANTALARG(A2:L2)

  2. Hiermee wordt de SOM berekend van A2:L2 gedeeld door het aantal niet-lege cellen in A2:L2 (mei tot en met december zijn leeg).

  1. Soms moet u de som van een bepaalde cel in verschillende werkbladen berekenen. Het kan dan verleidelijk zijn om in de verschillende bladen op de gewenste cel te klikken en het plusteken (+) te gebruiken om de celwaarden op te tellen, maar dat is nogal omslachtig en u maakt sneller fouten.

    • =Blad1!A1+Blad2!A1+Blad3!A1

    U kunt veel beter een 3D of driedimensionale SOM-functie gebruiken:

    3D SOM-bewerking - Formule in cel D2 is =SOM(Blad1:Blad3!A2)
    • =SOM(Blad1:Blad3!A1)

    Hiermee worden de waarden opgeteld van cel A1 op alle bladen van Blad 1 tot en met Blad 3.

    Dit is vooral handig in situaties waarin u één blad hebt voor elke maand (januari-december) en u een totaal nodig hebt op een overzichtsblad.

    3D SOM-bewerking voor benoemde bereiken.  Formule in D2 is =SOM(januari:december!A2)
    • =SOM(januari:december!A2)

    Hiermee wordt de som berekend van de waarde van elke cel A2 in de werkbladen van januari tot en met december.

    Notities : Als de namen van de werkbladen een spatie bevatten, zoals 'Verkopen januari', moet u een apostrof gebruiken om in een formule naar de namen te verwijzen. U ziet de apostrof vóór de naam van het eerste werkblad en na de naam van het laatste werkblad.

    • =SOM(‘Verkopen januari:Verkopen december’!A2)

    De 3D-methode werkt ook met andere functies, zoals GEMIDDELDE, MIN, MAX, enzovoort:

    • =GEMIDDELDE(Blad1;Blad3!A1)

    • =MIN(Blad1;Blad3!A1)

    • =MAX(Blad1;Blad3!A1)

Probleem

Wat is er fout gegaan

In mijn functie SOM wordt ##### weergegeven in plaats van het resultaat.

Controleer de kolombreedten. ##### betekent meestal dat de kolom te smal is om het resultaat van de formule weer te geven.

In mijn functie SOM wordt de formule zelf weergegeven als tekst in plaats van het resultaat.

Controleer of de cel niet is opgemaakt als tekst. Selecteer de cel of het celbereik en gebruik Ctrl+1 om het dialoogvenster Celeigenschappen weer te geven. Klik op het tabblad Getal en selecteer de gewenste notatie. Als de cel is opgemaakt als tekst en niet verandert als u de notatie wijzigt, moet u mogelijk F2 > Enter gebruiken om de wijziging van de notatie af te dwingen.

Mijn functie SOM wordt niet bijgewerkt.

Zorg ervoor dat Berekening is ingesteld op Automatisch. Ga op het tabblad Formule naar Berekeningsopties. U kunt ook F9 gebruiken om berekeningen in het werkblad af te dwingen.

Zorg ervoor dat Berekening is ingesteld op Automatisch.  Ga op het tabblad Formule naar Berekeningsopties.

Sommige waarden worden niet opgeteld.

Alleen numerieke waarden in de functieverwijzing of het functiebereik worden opgeteld. Lege cellen, logische waarden, zoals WAAR, of tekst worden genegeerd.

De foutwaarde #NAAM? wordt weergegeven in plaats van het verwachte resultaat.

Dit betekent meestal dat de formule verkeerd is gespeld, zoals =some(A1:A10) in plaats van =SOM(A1:A10).

In mijn functie SOM wordt een geheel getal weergegeven terwijl er decimalen moeten worden weergegeven

Controleer de celopmaak om na te gaan of er decimalen worden weergegeven. Selecteer de cel of het celbereik en gebruik Ctrl+1 om het dialoogvenster Celeigenschappen weer te geven. Klik op het tabblad Getal en selecteer de gewenste notatie.Geef het gewenste aantal decimalen op.

  1. Ik wil alleen getallen optellen/aftrekken/vermenigvuldigen/delen Bekijk deze videoreeks over het uitvoeren van basisberekeningen in Excel of gebruik van Excel als rekenmachine.

  2. Hoe kan ik meer/minder decimalen weergeven? U kunt de getalnotatie wijzigen. Selecteer de cel of het celbereik en gebruik Ctrl+1 om het dialoogvenster Celeigenschappen weer te geven. Klik op het tabblad Getal en selecteer de gewenste notatie.Geef het gewenste aantal decimalen op.

  3. Hoe kan ik tijden optellen of aftrekken? U kunt tijden op verschillende manieren optellen en aftrekken. Als u bijvoorbeeld voor de salarisadministratie het verschil tussen 8:00 uur en 24:00 uur wilt weergeven, gebruikt u: =("24:00"-"8:00")*24, de eindtijd minus de starttijd. Omdat tijden in Excel als dagdeel worden berekend, moet u de waarde vermenigvuldigen met 24 om het totaal aantal uren als resultaat weer te geven. In het eerste voorbeeld gebruiken we =((B2-A2)+(D2-C2))*24 om de som van het aantal uren van het begin tot het einde als resultaat weer te geven, minus de lunchpauze. (8,5 uur in totaal).

    Als u alleen uren en minuten wilt optellen en op die manier wilt weergeven, hoeft u niet met 24 te vermenigvuldigen. In het tweede voorbeeld gebruiken we daarom =SOM(A6:C6) omdat we alleen het totaal aantal uren en minuten willen voor toegewezen taken (5:36, ofwel 5 uren, 36 minuten).

    Tijden berekenen

    Zie voor meer informatie: Tijden optellen of aftrekken.

  4. Hoe kan ik het verschil tussen datums weergeven? U kunt net als bij tijden datums optellen en aftrekken. Hier volgt een zeer gangbaar voorbeeld van het tellen van het aantal dagen tussen twee datums. De functie is zeer eenvoudig: =B2-A2. Het belangrijkste voor het werken met datums en tijden is dat u begint met de einddatum/eindtijd en vervolgens de begindatum/begintijd hiervan aftrekt.

    Verschillen tussen datums berekenen

    Zie het volgende artikel voor meer informatie over het werken met datums: Het aantal dagen tussen twee datums berekenen

  5. Hoe ik alleen zichtbare cellen optellen? Soms wanneer u handmatig rijen verbergt of AutoFilter gebruikt om alleen bepaalde gegevens weer te geven, wilt u ook alleen de zichtbare cellen optellen. U kunt daarvoor de functie SUBTOTAAL gebruiken. Als u een rij met totalen in een Excel-tabel gebruikt, wordt een functie die u in de vervolgkeuzelijst Totalen selecteert automatisch ingevoerd als een subtotaal. Zie meer informatie over het optellen van gegevens in een Excel-tabel.

Meer hulp nodig?

U kunt altijd uw vraag stellen aan een expert in de Excel Tech Community, ondersteuning vragen in de Answer-community of een nieuwe functie of verbetering voorstellen in Excel User Voice.

Zie ook

Bekijk een video over het gebruik van de functie SOM

Met de functie SOM.ALS worden alleen de waarden opgeteld die voldoen aan één criterium

Met de functie SOMMEN.ALS worden alleen de waarden opgeteld die voldoen aan meerdere criteria

Met de functie AANTAL.ALS worden alleen de waarden opgeteld die voldoen aan één criterium

Met de functie AANTALLEN.ALS worden alleen de waarden opgeteld die voldoen aan meerdere criteria

Overzicht van formules in Excel

Niet-werkende formules voorkomen

Fouten in formules zoeken en verbeteren

Sneltoetsen in Excel voor Windows

Sneltoetsen in Excel voor Mac

Wiskundige en trigonometrische functies

Excel-functies (alfabetisch)

Excel-functies (per categorie)

Uw vaardigheden uitbreiden
Training verkennen
Als eerste nieuwe functies krijgen
Deelnemen aan Office Insiders

Was deze informatie nuttig?

Bedankt voor uw feedback.

Hartelijk dank voor uw feedback! Het lijkt ons een goed idee om u in contact te brengen met een van onze Office-ondersteuningsagents.

×