Met de ALS-functie kunt u een logische vergelijking maken tussen een waarde en wat u verwacht, door te testen op een voorwaarde en een resultaat te retourneren als die voorwaarde Waar of Onwaar is.
-
=ALS(iets waar is, doe dan iets, doe anders iets anders)
Maar wat moet u doen als u meerdere voorwaarden wilt testen, waarbij bijvoorbeeld alle voorwaarden waar of onwaar moeten zijn (EN), of waarbij maar één voorwaarde waar of onwaar hoeft te zijn (OF), of als u wilt controleren of een voorwaarde NIET aan uw criteria voldoet? Deze drie functies kunnen allemaal zelfstandig worden gebruikt, maar ze komen veel vaker gecombineerd met de ALS-functie voor.
Gebruik de functie ALS samen met EN, OF en NIET als u meerdere evaluaties wilt uitvoeren als voorwaarden waar of onwaar zijn.
Syntaxis
-
ALS(EN()) - ALS(END(logisch1, [logisch2], ...), waarde_als_waar, [waarde_als_onwaar]))
-
ALS(OF()) - ALS(OF(logisch1, [logisch2], ...), waarde_als_waar, [waarde_als_onwaar]))
-
ALS(NIET()) - ALS(NIET(logisch1), waarde_als_waar, [waarde_als_onwaar]))
|
Naam argument |
Beschrijving |
|
|
logische_test (vereist) |
De voorwaarde die u wilt testen. |
|
|
waarde_als_waar (vereist) |
De waarde die u als resultaat wilt hebben als het resultaat van logische_test WAAR is. |
|
|
waarde_als_onwaar (optioneel) |
De waarde die u als resultaat wilt hebben als het resultaat van logische_test ONWAAR is. |
|
Hier vindt u overzichten van hoe u EN-, OF- en NIET-functies afzonderlijk kunt structureren. Wanneer u elk van deze functies afzonderlijk met een ALS-instructie combineert, zien ze er als volgt uit:
-
EN – =ALS(EN(iets is waar, iets anders is waar), waarde indien waar, waarde indien onwaar)
-
OF – =ALS(OF(iets is waar, iets anders is waar), waarde indien waar, waarde indien onwaar)
-
NIET – =ALS(NIET(iets is waar), waarde indien waar, waarde indien onwaar)
Voorbeelden
Hieronder vindt u voorbeelden van enkele veelvoorkomende geneste ALS(EN())-, ALS(OF())- en ALS(NIET())-instructies. De EN- en OF-functies ondersteunen maximaal 255 afzonderlijke voorwaarden, maar het is niet raadzaam om te veel voorwaarden te gebruiken omdat het samenstellen, testen en onderhouden van complexe, geneste formules zeer lastig is. De functie NIET heeft maar één voorwaarde.
Hier worden de formules op basis van hun logica uitgeschreven:
|
Formule |
Beschrijving |
|---|---|
|
=ALS(EN(A2>0,B2<100),WAAR, ONWAAR) |
Als A2 (25) groter is dan 0 EN B2 (75) kleiner is dan 100, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval zijn beide voorwaarden waar en wordt dus WAAR geretourneerd. |
|
=ALS(EN(A3="rood",B3="groen"),WAAR,ONWAAR) |
Als A3 ('blauw') = 'rood' en B3 ('groen') is gelijk aan 'groen', retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is alleen de tweede voorwaarde waar, dus is het resultaat ONWAAR. |
|
=ALS(OF(A4>0,B4<50),WAAR, ONWAAR) |
Als A4 (25) groter is dan 0 OF B4 (75) kleiner is dan 50, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is alleen de eerste voorwaarde waar, maar aangezien bij een OF maar één argument waar hoeft te zijn, retourneert deze formule WAAR. |
|
=ALS(OF(A5="rood",B5="groen"),WAAR,ONWAAR) |
Als A5 ('blauw') is gelijk aan 'rood' OF B5 ('groen') is gelijk aan 'groen', retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is het tweede argument waar, dus de formule retourneert WAAR. |
|
=ALS(NIET(A6>50),WAAR,ONWAAR) |
Als A6 (25) NIET groter is dan 50, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is 25 niet groter dan 50, dus de formule retourneert WAAR. |
|
=ALS(NIET(A7="rood"),WAAR,ONWAAR) |
Als A7 ('blauw') NIET gelijk is aan 'rood', retourneer dan WAAR, retourneer anders ONWAAR. |
U ziet dat alle voorbeelden een haakje sluiten hebben nadat de desbetreffende voorwaarden zijn ingevoerd. De overige WAAR-/ONWAAR-argumenten behoren tot de buitenste ALS-instructie. U kunt de waarden voor de WAAR-/ONWAAR-argumenten in de voorbeelden vervangen door tekst of numerieke waarden.
Hier volgen enkele voorbeelden van het gebruik van EN, OF en NIET voor het evalueren van datums
Hier worden de formules op basis van hun logica uitgeschreven:
|
Formule |
Beschrijving |
|---|---|
|
=ALS(A2>B2,WAAR,ONWAAR) |
Als A2 groter is dan B2, retourneer dan WAAR, retourneer anders ONWAAR. 03/12/14 is groter dan 01/01/14, dus de formule retourneert WAAR. |
|
=ALS(EN(A3>B2,A3<C2),WAAR,ONWAAR) |
Als A3 groter is dan B2 EN A3 is kleiner dan C2, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval zijn beide argumenten waar, dus de formule retourneert WAAR. |
|
=ALS(OF(A4>B2,A4<B2+60),WAAR,ONWAAR) |
Als A4 groter is dan B2 OF A4 is kleiner dan B2 + 60, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is het eerste argument waar maar het tweede onwaar. Omdat er bij een OF-constructie maar een van de argumenten waar hoeft te zijn, retourneert de formule WAAR. Als u de Wizard Formule evalueren op het tabblad Formule gebruikt, ziet u hoe de formule in Excel wordt geëvalueerd. |
|
=ALS(NIET(A5>B2),WAAR,ONWAAR) |
Als A5 niet groter is dan B2, retourneer dan WAAR, retourneer anders ONWAAR. In dit geval is A5 groter dan B2, dus de formule retourneert ONWAAR. |
EN, OF en NIET gebruiken met voorwaardelijke opmaak
U kunt EN, OF en NIET ook gebruiken om criteria voor voorwaardelijke opmaak in te stellen met de formuleoptie. In dat geval kunt u de ALS-functie achterwege laten en EN, OF en NIET op zichzelf gebruiken.
Klik op het tabblad Start op Voorwaardelijke opmaak > Nieuwe regel. Selecteer vervolgens de optie Een formule gebruiken om te bepalen welke cellen worden opgemaakt, voer de formule in en pas de gewenste opmaak toe.
Op basis van het eerdere datumvoorbeeld ziet u hier hoe de formules zouden zijn.
|
Formule |
Beschrijving |
|---|---|
|
=A2>B2 |
Als A2 groter is dan B2, wordt de cel opgemaakt, anders gebeurt er niets. |
|
=EN(A3>B2,A3<C2) |
Als A3 groter is dan B2 EN A3 kleiner is dan C2, wordt de cel opgemaakt, anders gebeurt er niets. |
|
=OF(A4>B2,A4<B2+60) |
Als A4 groter is dan B2 OF A4 kleiner is dan B2 plus 60 (dagen), wordt de cel opgemaakt, anders gebeurt er niets. |
|
= NIET(A5>B2) |
Als A5 NIET groter is dan B2, wordt de cel opgemaakt, anders gebeurt er niets. In dit geval is A5 groter dan B2, dus het resultaat is ONWAAR. Als u de formule zou wijzigen in = NIET(B2>A5), zou het resultaat WAAR zijn en zou de cel worden opgemaakt. |
Opmerking: Een veelvoorkomende fout is het invoeren van de formule in Voorwaardelijke opmaak zonder het gelijkteken (=). Als u dit doet, ziet u dat in het dialoogvenster Voorwaardelijke opmaak het gelijkteken en de aanhalingstekens worden toegevoegd aan de formule ="OR(A4>B2,A4<B2+60)", dus u moet de aanhalingstekens verwijderen voordat de formule correct reageert.
Meer hulp nodig?
Zie ook
U kunt altijd uw vraag stellen aan een expert in de Excel Tech Community of ondersteuning vragen in de Communities.
Meer informatie over het gebruik van geneste functies in een formule
Overzicht van formules in Excel
