AANTAL.ALS, functie

Gebruik AANTAL.ALS, een van de statistische functies, om het aantal cellen te tellen die voldoen aan een criterium, bijvoorbeeld om te tellen hoe vaak een bepaalde plaats voorkomt in een lijst met klanten.

Simpel gezegd betekent AANTAL.ALS:

  • =AANTAL.ALS(Waar wilt u zoeken? Wat wilt u zoeken?)

Bijvoorbeeld:

  • =AANTAL.ALS(A2:A5,"Londen")

  • =AANTAL.ALS(A2:A5;A4)

Uw browser biedt geen ondersteuning voor video. Installeer Microsoft Silverlight, Adobe Flash Player of Internet Explorer 9.

AANTAL.ALS(bereik;criteria)

Naam argument

Beschrijving

bereik    (vereist)

De groep cellen die u wilt tellen. Het argument bereik kan bestaan uit getallen, matrices, een benoemd bereik of verwijzingen die getallen bevatten. Lege waarden en tekstwaarden worden genegeerd.

Meer informatie over het selecteren van bereiken in een werkblad.

criterium    (vereist)

Een getal, expressie, celverwijzing of tekenreeks die bepaalt welke cellen worden geteld.

U kunt hier bijvoorbeeld een getal gebruiken zoals 32, een vergelijking zoals ">32", een cel zoals B4 of een woord zoals "appels".

AANTAL.ALS ondersteunt maar één criterium. Gebruik AANTALLEN.ALS als u meerdere criteria wilt gebruiken.

Voorbeelden

Kopieer de gegevens uit onderstaande tabel en plak deze in cel A1 van een nieuw werkblad, om deze voorbeelden te gebruiken in Excel.

Gegevens

Gegevens

appels

32

sinaasappels

54

perziken

75

appels

86

Formule

Beschrijving

=AANTAL.ALS(A2:A5;"appels")

Telt het aantal cellen met appels in de cellen A2 tot en met A5. Het resultaat is 2.

=AANTAL.ALS(A2:A5;A4)

Telt het aantal cellen met perziken (de waarde in A4) in de cellen A2 tot en met A5. Het resultaat is 1.

=AANTAL.ALS(A2:A5,A2)+AANTAL.ALS(A2:A5,A3)

Telt het aantal cellen met appels (de waarde in A2) en sinaasappels (de waarde in A3) in de cellen A2 tot en met A5. Het resultaat is 3. In deze formule wordt AANTAL.ALS twee keer gebruikt om meerdere criteria op te geven, met één criterium per expressie. U kunt ook de functie AANTALLEN.ALS gebruiken.

=AANTAL.ALS(B2:B5;">55")

Telt het aantal cellen met een waarde groter dan 55 in de cellen B2 tot en met B5. Het resultaat is 2.

=AANTAL.ALS(B2:B5;"<>"&B4)

Telt het aantal cellen met een waarde die niet gelijk is aan 75 in de cellen B2 tot en met B5. Met het teken & worden de vergelijkingsoperator voor niet gelijk aan (<>) en de waarde in B4 samengevoegd om te worden gelezen als =AANTAL.ALS(B2:B5;"<>75"). Het resultaat is 3.

=AANTAL.ALS(B2:B5;">=32")-AANTAL.ALS(B2:B5;">85")

Telt het aantal cellen met een waarde groter dan (>) of gelijk aan (=) 32 en kleiner dan (<) of gelijk aan (=) 85 in de cellen B2 tot en met B5. Het resultaat is 3.

=AANTAL.ALS(A2:A5;"*")

Telt het aantal cellen met tekst in de cellen A2 tot en met A5. Het sterretje (*) wordt gebruikt als jokerteken en geeft aan dat elk willekeurig teken is toegestaan. Het resultaat is 4.

=AANTAL.ALS(A2:A5;"?????es")

Telt het aantal cellen met een tekenreeks met 7 tekens die eindigt op "es" in de cellen A2 tot en met A5. Het vraagteken (?) wordt gebruikt als jokerteken en wordt gebruikt om de specifieke tekens op te geven die worden gezocht. Het resultaat is 2.

Algemene problemen

Probleem

Wat is er fout gegaan

Er wordt een verkeerde waarde geretourneerd voor lange tekenreeksen.

De functie AANTAL.ALS retourneert onjuiste resultaten als u deze gebruikt om tekenreeksen die meer dan 255 tekens lang zijn te vergelijken.

Gebruik hiervoor de functie TEKST.SAMENVOEGEN of de operator voor samenvoegen &. Gebruik bijvoorbeeld =AANTAL.ALS(A2:A5;"lange tekenreeks"&"een andere lange tekenreeks").

Er wordt geen waarde geretourneerd terwijl er wel een waarde wordt verwacht.

Plaats het argument criterium tussen aanhalingstekens.

De formule AANTAL.ALS resulteert in de fout #WAARDE! als er naar een ander werkblad wordt verwezen.

Deze fout treedt op wanneer de formule met de functie verwijst naar cellen of een bereik in een gesloten werkmap en de cellen in de berekening zijn opgenomen. Dit werkt alleen als de andere werkmap is geopend.

Aanbevolen procedures

Werkwijze

Waarom

De functie AANTAL.ALS maakt geen onderscheid tussen hoofdletters en kleine letters in tekenreeksen.

Het argument criterium is niet hoofdlettergevoelig. De tekenreeks "appels" en de tekenreeks "APPELS" leveren dus hetzelfde resultaat op.

Gebruik jokertekens.

U kunt jokertekens, een vraagteken (?) en een sterretje (*), gebruiken in het argument criterium. Een vraagteken staat voor elk willekeurig teken, een sterretje voor een willekeurige tekenreeks. Als u het vraagteken of sterretje zelf wilt zoeken, moet u een tilde (~) voor het teken typen.

Met =AANTAL.ALS(A2:A5;"appel?") telt u bijvoorbeeld alle cellen waarin "appel" voorkomt en de laatste letter een willekeurige letter is.

Zorg ervoor dat uw gegevens geen foutieve tekens bevatten.

Als u tekstwaarden wilt tellen, moet u ervoor zorgen dat de gegevens geen voorloop- of volgspaties bevatten en ook geen niet-afdrukbare tekens, of rechte en gekrulde aanhalingstekens door elkaar. Anders kan AANTAL.ALS een onverwacht resultaat opleveren.

Gebruik de functie WISSEN of TRIM.

Gebruik benoemde bereiken.

AANTAL.ALS ondersteunt benoemde bereiken in een formule (zoals =AANTAL.ALS(fruit;"> = 32")-AANTAL.ALS(fruit;"> 85'). Het benoemde bereik kan zich in het huidige werkblad bevinden, in een ander werkblad in dezelfde werkmap of in een andere werkmap. Als u wilt verwijzen naar een andere werkmap, moet die werkmap geopend zijn.

Opmerking : De functie AANTAL.ALS telt geen cellen op basis van celachtergrond of tekstkleur. Excel biedt echter wel ondersteuning voor door de gebruiker gedefinieerde functies (UDF's) die Microsoft Visual Basic for Applications (VBA)-bewerkingen gebruiken voor cellen die zijn gebaseerd op achtergrond of tekstkleur. Hier volgt een voorbeeld van hoe u het aantal cellen met een specifieke celkleur kunt tellen met behulp van VBA.

Meer hulp nodig?

U kunt altijd uw vraag stellen aan een expert in de Excel Tech Community, ondersteuning vragen in de Answer-community of een nieuwe functie of verbetering voorstellen in Excel User Voice.

Zie ook

Gebruik de functie AANTALARG om cellen te tellen die niet leeg zijn

Gebruik de functie AANTALLEN.ALS om cellen te tellen aan de hand van meerdere criteria

Bekijk een video over hoe u de functie AANTALLEN.ALS gebruikt

De functie SOM.ALS telt alleen de waarden die aan één criterium voldoen

De functie SOMMEN.ALS telt alleen de waarden die aan meerdere criteria voldoen

De functie IFS (Office 365, Excel 2016 en nieuwer)

Gebruik de functie TRIM om voorloop- of volgspaties uit cellen te verwijderen

Gebruik de functie WISSEN om niet-afdrukbare tekens uit cellen te verwijderen

Overzicht van formules in Excel

Niet-werkende formules voorkomen

Fouten opsporen in formules

Statistische functies

Functies in Excel (alfabetisch)

Functies in Excel (op categorie)

Using SUMIF, COUNTIF, and related functions for quick data analysis (free preview)

Uw vaardigheden uitbreiden
Training verkennen
Als eerste nieuwe functies krijgen
Deelnemen aan Office Insiders

Was deze informatie nuttig?

Bedankt voor uw feedback.

Hartelijk dank voor uw feedback! Het lijkt ons een goed idee om u in contact te brengen met een van onze Office-ondersteuningsagents.

×