Overzicht van formules in Excel

Overzicht van formules in Excel

Als u Excel nog niet eerder hebt gebruikt, zult u snel merken dat het meer is dan alleen een raster waarin u getallen in kolommen en rijen kunt invullen. U kunt Excel gebruiken om de totalen voor een kolom of een rij getallen te berekenen, maar u kunt ook de hypotheekbetalingen berekenen, wiskundige of technische problemen oplossen of het beste alternatief vinden op basis van variabele getallen die u hebt opgegeven.

Excel doet dit met behulp van formules die in cellen staan. Een formule voert een berekening of andere acties uit op de gegevens in uw werkblad. Een formule begint altijd met een gelijkteken (=), dat kan worden gevolgd door getallen, wiskundige operatoren (zoals plus (+) en min (-)) en ingebouwde Excel-functies die de kracht van een formule echt doen toenemen.

In de volgende formule wordt bijvoorbeeld 2 vermenigvuldigd met 3 en wordt vervolgens 5 opgeteld bij het resultaat om zo op 11 uit te komen.

=2*3+5

Hier volgen enkele aanvullende voorbeelden van de soorten formules die u in een werkblad kunt invoeren.

  • =A1+A2+A3    Hiermee worden de waarden in de cellen A1, A2 en A3 bij elkaar opgeteld.

  • =SOM(A1:A10)    gebruikt de functie SOM met als resultaat de som van de waarden in A1 tot en met A10.

  • =VANDAAG()    Hiermee wordt de huidige datum geretourneerd.

  • =HOOFDLETTERS("hallo")     Hiermee converteert u de tekst 'hallo' naar 'HALLO' met de werkbladfunctie HOOFDLETTERS.

  • =ALS(A1>0)    Gebruikt de functie Als voor het testen van cel A1 om vast te stellen of deze een waarde hoger dan 0 bevat.

Een formule kan ook een of meer van de volgende items bevatten: functies, verwijzingen, operatoren en constanten.

Onderdelen van een formule   

onderdelen van een formule

1. Functies: de functie PI() berekent de waarde van pi: 3,142...

2. Verwijzingen: A2 geeft als resultaat de waarde in cel A2.

3. Constanten: cijfers of tekstwaarden die rechtstreeks worden ingevoerd in een formule, zoals 2.

4. Operatoren: de operator ^ (accent circonflexe) verheft een getal tot een bepaalde macht en de operator * (sterretje) vermenigvuldigt een getal.

Een constante is een waarde die niet wordt berekend, maar altijd hetzelfde blijft. De datum 10-9-2008, het getal 210 en de tekst 'Inkomsten per kwartaal' zijn constanten. Een expressie of een waarde die het resultaat is van een expressie, is geen constante. Als u in een formule constante waarden gebruikt in plaats van verwijzingen naar cellen (bijvoorbeeld =30+70+110), verandert de uitkomst van de formule alleen wanneer u de formule zelf aanpast. Over het algemeen is het het beste om constanten in individuele cellen te plaatsen waar ze, indien nodig, eenvoudig kunnen worden gewijzigd en vervolgens naar die cellen refereren in formules.

Operatoren geven het type berekening op dat u wilt uitvoeren op de elementen van een formule. Excel volgt rekenkundige standaardregels voor berekeningen in de volgorde: haakjes, exponenten, vermenigvuldigen en delen, en optellen en aftrekken. Met haakjes kunt u de volgorde van de berekeningen wijzigen.

Typen operatoren. Er zijn vier typen operatoren voor berekeningen: rekenkundige operatoren, vergelijkingsoperatoren, samenvoegingsoperatoren en verwijzingsoperatoren.

  • Rekenkundige operatoren

    Gebruik de volgende rekenkundige operatoren als u rekenkundige basisbewerkingen wilt uitvoeren, zoals optellen, aftrekken, vermenigvuldigen of delen, en als u getallen wilt combineren of numerieke resultaten wilt produceren.

    Rekenkundige operator

    Betekenis

    Voorbeeld

    + (plusteken)

    Optellen

    =3+3

    - (minteken)

    Aftrekken
    Negatief

    =3–3
    =-3

    * (sterretje)

    Vermenigvuldigen

    =3*3

    / (slash)

    Delen

    =3/3

    % (procentteken)

    Percentage

    30%

    ^ (accent circonflexe)

    Machtsverheffen

    =3^3

  • Vergelijkingsoperatoren

    Met de volgende operatoren kunt u twee waarden vergelijken. Het resultaat van een dergelijke vergelijking is een logische waarde: WAAR of ONWAAR. 

    Vergelijkingsoperator

    Betekenis

    Voorbeeld

    = (gelijkteken)

    Gelijk aan

    =A1=B1

    > (groter dan)

    Groter dan

    =A1>B1

    < (kleiner dan)

    Kleiner dan

    =A1<B1

    >= (groter dan of gelijk aan)

    Groter dan of gelijk aan

    =A1>=B1

    <= (kleiner dan of gelijk aan)

    Kleiner dan of gelijk aan

    =A1<=B1

    <> (niet gelijk aan)

    Niet gelijk aan

    =A1<>B1

  • Samenvoegingsoperatoren

    Met het en-teken (&) combineert u een of meer tekstreeksen tot één tekstfragment.

    Tekstoperator

    Betekenis

    Voorbeeld

    & (en-teken)

    Koppelt of verbindt twee waarden tot één tekstwaarde

    ="North"&"wind" resulteert in "Northwind".
    Als A1 "Achternaam" bevat en B1 "Voornaam", dan resulteert =A1&", "&B1 in "Achternaam, Voornaam".

  • Verwijzingsoperatoren

    Met de volgende verwijzingsoperatoren combineert u celbereiken voor berekeningen.

    Verwijzingsoperator

    Betekenis

    Voorbeeld

    : (dubbele punt)

    De bereikoperator, waarmee één celverwijzing naar alle cellen tussen twee verwijzingen wordt gemaakt, inclusief de twee verwijzingen.

    B5:B15

    ; (puntkomma)

    De verenigingsoperator, waarmee meerdere verwijzingen tot één verwijzing worden gecombineerd

    =SOM(B5:B15,D5:D15)

    (spatie)

    De doorsnede-operator, waarmee één verwijzing naar de gemeenschappelijke cellen van twee bereikwaarden wordt gemaakt

    B7:D7 C6:C8

Naar boven

In sommige gevallen kan de volgorde waarin een berekening wordt uitgevoerd gevolgen hebben voor het resultaat van een formule. Het is dus belangrijk dat u begrijpt welke volgorde wordt aangehouden en hoe u de volgorde kunt wijzigen om het gewenste resultaat te verkrijgen.

  • Volgorde van berekeningen

    Met formules worden waarden altijd in een bepaalde volgorde berekend. Een formule in Excel begint altijd met het gelijkteken (=). Het gelijkteken geeft aan dat de daaropvolgende tekens een formule vormen. Na het gelijkteken komen de elementen die moeten worden berekend (de operanden), zoals constanten of celverwijzingen. Deze worden gescheiden door berekeningsoperatoren. In Excel wordt een formule van links naar rechts berekend, op basis van een bepaalde volgorde voor elke operator in de formule.

  • Prioriteit van operatoren in Excel-formules

    Als u diverse operatoren in een formule combineert, worden de bewerkingen in Excel uitgevoerd in de volgorde van de volgende tabel. Als een formule operatoren met dezelfde prioriteit bevat (bijvoorbeeld een formule met zowel een vermenigvuldigingsoperator als een deeloperator), worden de operatoren van links naar rechts geëvalueerd.

    Operator

    Description

    : (dubbele punt)

    (één spatie)

    , (komma)

    Verwijzingsoperatoren

    -

    Negatief maken (bijvoorbeeld -1)

    %

    Percentage berekenen

    ^

    Machtsverheffen

    * en /

    Vermenigvuldigen en delen

    + en -

    Optellen en aftrekken

    &

    Twee tekenreeksen aan elkaar koppelen

    =
    < >
    <=
    >=
    <>

    Vergelijking

  • Haakjes gebruiken in Excel-formules

    Als u de evaluatievolgorde wilt wijzigen, plaatst u het deel van de formule dat u als eerste wilt berekenen tussen haakjes. Zo levert de volgende formule 11 op omdat in Excel vermenigvuldigen voor optellen gaat. In de formule wordt 2 vermenigvuldigd met 3 en wordt 5 bij het resultaat opgeteld.

    =5+2*3

    Als u daarentegen de syntaxis verandert door haakjes te gebruiken, wordt eerst 2 opgeteld bij 5 en wordt de som met 3 vermenigvuldigd, met 21 als resultaat.

    =(5+2)*3

    In het volgende voorbeeld zorgen de haakjes rond het eerste deel van de formule ervoor dat B4+25 eerst wordt berekend en dat het resultaat hiervan wordt gedeeld door de som van de waarden in de cellen D5, E5 en F5.

    =(B4+25)/SOM(D5:F5)

    Naar boven

Functies zijn vooraf gedefinieerde formules waarmee berekeningen worden uitgevoerd met specifieke waarden (argumenten) in een specifieke volgorde of structuur. U kunt functies gebruiken voor het uitvoeren van eenvoudige of complexe berekeningen. U kunt alle Excel-functies vinden op het tabblad Formules op het lint:

Het tabblad Formules op het lint in Excel
  • Excel-functiesyntaxis

    Het volgende voorbeeld van de functie AFRONDEN, waarmee het getal in cel A10 wordt afgerond, toont de syntaxis van een functie.

    Structuur van een functie

    1. Structuur. Een functie begint altijd met een gelijkteken (=), gevolgd door de functienaam, een haakje openen, de argumenten voor de functie gescheiden door puntkomma's, en een haakje sluiten.

    2. Functienaam. Klik op een cel en druk op Shift+F3 om het dialoogvenster Functie invoegen weer te geven, waarin u een lijst met beschikbare functies kunt vinden.

    Excel-formules - Dialoogvenster Functie invoegen

    3. Argumenten. Argumenten kunnen bestaan uit getallen, tekst, logische waarden zoals WAAR of ONWAAR, matrices, foutwaarden zoals #N/B of celverwijzingen. Het opgegeven argument moet een geldige waarde voor dit argument opleveren. U kunt ook constanten, formules of andere functies als argumenten gebruiken.

    4. Knopinfo voor argumenten. Een kader met de syntaxis en argumenten van de functie dat verschijnt tijdens het typen van de functie. Als u bijvoorbeeld =AFRONDEN( typt, verschijnt een kader met informatie over deze functie. De knopinfo wordt alleen weergegeven voor ingebouwde functies.

    Opmerking : U hoeft de functies niet volledig in hoofdletters te typen, zoals =AFRONDEN. De naam van de functie wordt in Excel automatisch in hoofdletters weergegeven wanneer u op enter drukt. Als u de naam van een functie verkeerd spelt, zoals =SIM(A1:A10) in plaats van =SOM(A1:A10) dan wordt in Excel de fout #NAAM? weergeven.

  • Excel-functies invoeren

    Wanneer u een formule met een functie maakt, kunt u het dialoogvenster Functie invoegen gebruiken bij het invoeren van werkbladfuncties. Als u een functie selecteert in het dialoogvenster Functie invoegen, wordt in Excel de wizard Functie gestart, waarin de naam van de functie, de verschillende argumenten, een beschrijving van de functie en de argumenten, het huidige resultaat van de functie en het huidige resultaat van de gehele formule worden weergegeven.

    Wizard Functie in Excel

    Gebruik de functie Formule automatisch aanvullen om het invoeren en bewerken van formules te vereenvoudigen en het aantal invoer- en syntaxisfouten tot een minimum te beperken. Nadat u een gelijkteken (=) en de beginletters van een functie hebt getypt, verschijnt er in Excel een dynamische vervolgkeuzelijst met geldige functies, argumenten en namen die met de letters overeenkomen. Vervolgens kunt u er een in de vervolgkeuzelijst selecteren, waarna Excel deze voor u invoert.

    Excel-formule automatisch aanvullen

  • Excel-functies nesten

    In bepaalde gevallen hebt u mogelijk een functie nodig als een van de argumenten van een andere functie. In de volgende formule wordt bijvoorbeeld een geneste functie GEMIDDELDE gebruikt en wordt het resultaat vergeleken met de waarde 50.

    geneste functies

    1. De functies GEMIDDELDE en SOM zijn genest in de functie ALS.

    Geldige resultaten    Wanneer een geneste functie als argument wordt gebruikt, moet de geneste functie resulteren in het waardetype van het argument. Als het argument bijvoorbeeld resulteert in de waarde WAAR of ONWAAR, moet de geneste functie eveneens de waarde WAAR of ONWAAR opleveren. Als dat niet het geval is, wordt de foutwaarde #WAARDE! weergegeven.

    Beperkingen bij het nesten van functies    Een formule kan maximaal zeven niveaus van geneste functies bevatten. Wanneer een functie (we noemen deze functie B) als argument wordt gebruikt in een andere functie (die we functie A noemen), is functie B een functie op het tweede niveau. Zo zijn GEMIDDELDE en SOM beide functies op het tweede niveau als ze worden gebruikt als argumenten van de functie ALS. Een geneste functie binnen de geneste functie GEMIDDELDE is dan een functie op het derde niveau, enzovoort.

    Naar boven

Een verwijzing wordt in Excel gebruikt om op een werkblad een cel of een celbereik aan te geven met de waarden of gegevens die u in een formule wilt gebruiken. U kunt verwijzingen gebruiken om gegevens in verschillende delen van een werkblad in een formule te gebruiken of de waarde uit één cel in verschillende formules te gebruiken. U kunt ook naar cellen in andere werkbladen van dezelfde werkmap en naar andere werkmappen verwijzen. Verwijzingen naar cellen in andere werkmappen worden koppelingen of externe verwijzingen genoemd.

  • Het verwijzingstype A1

    Standaard wordt in Microsoft Excel het verwijzingstype A1 gebruikt. Hierbij worden kolommen aangeduid met letters (A tot en met XFD voor in totaal 16.384 kolommen) en rijen met nummers (1 tot en met 1.048.576). Deze letters en cijfers worden rij- en kolomkoppen genoemd. Als u naar een cel wilt verwijzen, voert u de kolomletter in gevolgd door het rijnummer. B2 verwijst bijvoorbeeld naar de cel op het snijpunt van kolom B en rij 2.

    Gewenste verwijzing

    Gebruik

    De cel in kolom A en rij 10

    A10

    Het celbereik in kolom A en rij 10 tot en met 20

    A10:A20

    Het celbereik in rij 15 en kolom B tot en met E

    B15:E15

    Alle cellen in rij 5

    5:5

    Alle cellen in rij 5 tot en met 10

    5:10

    Alle cellen in kolom H

    H:H

    Alle cellen in kolom H tot en met J

    H:J

    Het celbereik in kolom A tot en met E en rij 10 tot en met 20

    A10:E20

  • Een verwijzing maken naar een cel of celbereik op een ander werkblad in dezelfde werkmap

    In het volgende voorbeeld wordt met de functie GEMIDDELDE de gemiddelde waarde van het bereik B1:B10 op het werkblad Marketing in dezelfde werkmap berekend.

    Voorbeeld van een bladverwijzing

    1. Verwijst naar het werkblad met de naam Marketing

    2. Verwijst naar het celbereik van B1 tot en met B10

    3. Het uitroepteken (!) scheidt de verwijzing naar het werkblad van de verwijzing naar het celbereik

    Opmerking : Als het werkblad waarnaar wordt verwezen spaties of getallen bevat, moet u apostroffen (') toevoegen vóór en na de naam van het werkblad, zoals ='123'!A1 of ='Inkomsten januari'!A1.

  • Het verschil tussen relatieve, absolute en gemengde verwijzingen

    1. Relatieve verwijzingen    Een relatieve celverwijzing in een formule, zoals A1, is gebaseerd op de relatieve positie van de cel met de formule en de cel waarnaar wordt verwezen. Als de positie van de cel met de formule verandert, wordt de verwijzing gewijzigd. Als u de formule kopieert of doorvoert in rijen of kolommen, wordt de verwijzing automatisch aangepast. In nieuwe formules worden standaard relatieve verwijzingen gebruikt. Als u een relatieve verwijzing in cel B2 bijvoorbeeld kopieert of doorvoert naar cel B3, wordt deze automatisch aangepast van =A1 naar =A2.

      Gekopieerde formule met relatieve verwijzing   

      Gekopieerde formule met relatieve verwijzing

    2. Absolute verwijzingen    Een absolute celverwijzing in een formule, zoals $A$1, verwijst altijd naar een cel op een specifieke locatie. Als de positie van de cel met de formule verandert, blijft de absolute verwijzing hetzelfde. Als u de formule kopieert of doorvoert in rijen of kolommen, wordt de absolute verwijzing niet aangepast. Voor nieuwe formules worden standaard relatieve verwijzingen gebruikt en deze zult u dus moeten omzetten in absolute verwijzingen. Als u een absolute verwijzing in cel B2 bijvoorbeeld kopieert of doorvoert in cel B3, blijft deze in beide cellen gelijk, namelijk =$A$1.

      Gekopieerde formule met absolute verwijzing   

      Gekopieerde formule met absolute verwijzing
    3. Gemengde verwijzingen    Een gemengde verwijzing heeft een absolute kolom en een relatieve rij, of een absolute rij en een relatieve kolom. Een absolute kolomverwijzing heeft de vorm $A1, $B1, enzovoort. Een absolute rijverwijzing heeft de vorm A$1, B$1, enzovoort. Als de positie van de cel met de formule verandert, wordt de relatieve verwijzing gewijzigd en de absolute verwijzing niet. Als u de formule kopieert of doorvoert in rijen of kolommen, wordt de relatieve verwijzing automatisch aangepast en de absolute verwijzing niet. Als u bijvoorbeeld een gemengde verwijzing van cel A2 kopieert of doorvoert in cel B3, wordt deze verwijzing aangepast van =A$1 naar =B$1.

      Gekopieerde formule met gemengde verwijzing   

      Gekopieerde formule met gemengde verwijzing

  • Het verwijzingstype 3D

    Snel verwijzingen maken naar meerdere werkbladen    Als u gegevens in dezelfde cel of hetzelfde celbereik in meerdere werkbladen van een werkmap wilt analyseren, gebruikt u een 3D-verwijzing. Een 3D-verwijzing bevat de cel of het celbereik, voorafgegaan door een bereik van werkbladnamen. In Excel worden alle werkbladnamen van de eerste tot en met de laatste naam in de verwijzing gebruikt. Zo telt u met =SOM(Blad2:Blad13!B5) alle waarden op in cel B5 van alle werkbladen van Blad2 tot en met Blad13.

    • Met 3D-verwijzingen kunt u verwijzen naar cellen van andere bladen, namen definiëren en formules maken met de volgende functies: SOM, GEMIDDELDE, GEMIDDELDEA, AANTAL, AANTALARG, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA, en VARPA.

    • 3D-verwijzingen kunnen niet worden gebruikt in matrixformules.

    • U kunt geen 3D-verwijzingen gebruiken in combinatie met de operator (een enkele spatie) of in formules met impliciet snijpunt.

    Wat gebeurt er als u werkbladen verplaatst, kopieert, invoegt of verwijdert    In de volgende voorbeelden wordt uitgelegd wat er gebeurt wanneer u werkbladen verplaatst, kopieert, invoegt of verwijdert die in een 3D-verwijzing voorkomen. In de voorbeelden worden met de formule =SOM(Blad2:Blad6!A2:A5) de waarden in cel A2 tot en met A5 op werkblad 2 tot en met 6 opgeteld.

    • Invoegen of kopiëren    Als u bladen tussen Blad2 en Blad6 (het begin- en eindpunt in dit voorbeeld) invoegt of kopieert, worden alle waarden in cel A2 tot en met A5 in de toegevoegde bladen in de berekening opgenomen.

    • Verwijderen     Als u bladen tussen Blad2 en Blad6 verwijdert, worden de waarden in die bladen niet meer in de berekening opgenomen.

    • Verplaatsen    Als u de bladen tussen Blad2 en Blad6 verplaatst naar een locatie buiten het bereik waarnaar wordt verwezen, worden de waarden niet meer in de berekening opgenomen.

    • Een eindpunt verplaatsen    Als u Blad2 of Blad6 naar een andere locatie in dezelfde werkmap verplaatst, wordt de berekening uitgevoerd op het nieuwe bereik.

    • Een eindpunt verwijderen    Als u Blad2 of Blad6 verwijdert, wordt de berekening uitgevoerd op het nieuwe bereik.

  • Het verwijzingstype R1K1

    U kunt ook een verwijzingstype hanteren waarbij zowel de rijen als de kolommen op het werkblad zijn genummerd. Het verwijzingstype R1K1 is handig voor het berekenen van rij- en kolomposities in macro's. Bij het verwijzingstype R1K1 wordt in Excel de locatie van een cel aangegeven met een R, gevolgd door het rijnummer en een K, gevolgd door het kolomnummer.

    Verwijzing

    Betekenis

    R[-2]K

    Een relatieve verwijzing naar de cel die zich twee rijen hoger in dezelfde kolom bevindt.

    R[2]K[2]

    Een relatieve verwijzing naar de cel die zich twee rijen lager en twee kolommen naar rechts bevindt.

    R2K2

    Een absolute verwijzing naar de cel in de tweede rij en de tweede kolom.

    R[-1]

    Een relatieve verwijzing naar de hele rij die zich boven de actieve cel bevindt.

    R

    Een absolute verwijzing naar de huidige rij.

    Wanneer u een macro opneemt, worden in Excel voor sommige opdrachten het verwijzingstype R1K1 gebruikt. Als u bijvoorbeeld een opdracht opneemt, zoals op de knop AutoSom klikken, om een formule in te voegen waarmee een celbereik wordt opgeteld, wordt de formule opgenomen met R1K1-verwijzingen en niet met A1-verwijzingen.

    U kunt het R1K1-verwijzingstype in- of uitschakelen met het selectievakje Verwijzingstype R1K1 in het gedeelte Werken met formules in de categorie Formules van het dialoogvenster Opties voor Excel. Klik op het tabblad Bestand om dit dialoogvenster weer te geven.

    Naar boven

U kunt gedefinieerde namen opgeven voor cellen, celbereiken, formules, constanten of Excel-tabellen. Een naam is een betekenisvolle afkorting waarmee het doel van een celverwijzing, constante, formule of tabel gemakkelijker te begrijpen is, terwijl deze in eerste instantie mogelijk moeilijk te begrijpen zijn. Hieronder ziet u gangbare voorbeelden van namen en de manier waarop u deze kunt gebruiken om formules begrijpelijker te maken.

Voorbeeld 1

Voorbeeldtype

Voorbeeld met bereiken in plaats van namen

Voorbeeld met namen

Verwijzing

=SOM(A16:A20)

=SOM(Verkoop)

Constante

=PRODUCT(A12;9,5%)

=PRODUCT(prijs,belastingpercentage)

Formule

=TEKST(VERT.ZOEKEN(MAX(A16;A20);A16:B20;2;ONWAAR);"m/dd/jjjj")

=TEKST(VERT.ZOEKEN(MAX(Verkoop),Verkoopinfo,2,ONWAAR),"m/dd/jjjj")

Tabel

A22:B25

=PRODUCT(Prijs;Tabel1[@Belastingtarief])

Voorbeeld 2

Kopieer de voorbeeldgegevens uit de volgende tabel en plak deze in cel A1 van een nieuw Excel-werkblad. U kunt de resultaten van formules weergeven door de formules te selecteren en op F2 en vervolgens op Enter te drukken. Desgewenst kunt u de kolombreedte wijzigen om alle gegevens te zien.

Opmerking :  In de formules in kolom C en D wordt de gedefinieerde naam Verkoop vervangen door de verwijzing naar (het bereik) A9:A13 en wordt de naam VerkoopInfo vervangen door het bereik A9:B13. Als u deze namen niet in uw testwerkmap maakt, retourneert de formule in D2:D3 de fout #NAAM?.

Type voorbeeld

Voorbeeld zonder naam

Voorbeeld met naam

Formule en resultaat met naam

Verwijzing

'=SOM(A9:A13)

'=SOM(Verkoop)

=SOM(Verkoop)

Formule

'=TEKST(VERT.ZOEKEN(MAX(A9:13),A9:B13,2,ONWAAR),"dd-mm-yyyy")

'=TEKST(VERT.ZOEKEN(MAX(Verkoop),VerkoopInfo,2,ONWAAR),"dd-mm-yyyy")

=TEKST(VERT.ZOEKEN(MAX(Verkoop),VerkoopInfo,2,ONWAAR),"dd-mm-yyyy")

Prijs

$995

Verkoop

Verkoopdatum

$249

17-03-2011

$399

02-04-2011

$643

23-04-2011

$275

30-04-2011

$447

04-05-2011

  • Typen namen

    Er zijn verschillende typen namen die u kunt maken en gebruiken.

    • Gedefinieerde naam    Een naam voor een cel, celbereik, formule, of constante waarde. U kunt een eigen gedefinieerde naam maken. Daarnaast wordt in Excel soms een gedefinieerde naam voor u gemaakt, bijvoorbeeld wanneer u een afdrukbereik instelt.

    • Tabelnaam    Een naam voor een Excel-tabel. Dit is een verzameling gegevens over een bepaald onderwerp die wordt opgeslagen in records (rijen) en velden (kolommen). In Excel wordt telkens een standaardtabelnaam Tabel1, Tabel2 enzovoort gemaakt wanneer u een Excel-tabel invoegt, maar u kunt deze namen wijzigen zodat ze betekenisvoller zijn.

      Zie Gestructureerde verwijzingen in combinatie met Excel-tabellen gebruiken voor meer informatie over Excel-tabellen.

  • Namen maken en invoeren

    U kunt als volgt een naam maken:

    • Via het vak Naam op de formulebalk     Deze methode wordt bij voorkeur gebruikt voor het maken van een naam op werkmapniveau voor een geselecteerd bereik.

    • Door een naam te maken op basis van een selectie     U kunt op handige wijze namen maken op basis van bestaande rij- en kolomlabels door een selectie cellen op het werkblad te gebruiken.

    • Via het dialoogvenster Nieuwe naam    Deze methode is het meest geschikt als u meer flexibiliteit nodig hebt bij het maken van namen, zoals het opgeven van een bereik op lokaal werkbladniveau of het maken van een opmerking bij een naam.

    Opmerking : Standaard worden voor namen absolute celverwijzingen gebruikt.

    U kunt op de volgende manieren een naam opgeven:

    • Typen    Typ de naam bijvoorbeeld als argument in een formule.

    • Met Formule automatisch aanvullen    Maak gebruik van de vervolgkeuzelijst Formule automatisch aanvullen, waarin geldige namen automatisch worden weergegeven.

    • Selecteren via de opdracht Gebruiken in formule    Selecteer een gedefinieerde naam in de lijst die u u kunt openen door naar het tabblad Formule te gaan en in de groep Gedefinieerde namen op Gebruiken in formule te klikken.

Zie Namen definiëren en gebruiken in formules voor meer informatie.

Naar boven

Met een matrixformule kunnen meerdere berekeningen worden uitgevoerd en vervolgens een of meer resultaten worden berekend. Matrixformules werken met twee of meer reeksen waarden, matrixargumenten genoemd. Elk matrixargument moet hetzelfde aantal rijen en kolommen bevatten. U maakt matrixformules op dezelfde wijze als andere formules, behalve dat u op Ctrl+Shift+Enter moet drukken om de formule in te voeren. Sommige ingebouwde functies zijn matrixformules. U moet deze als matrices invoeren om de juiste resultaten te krijgen.

U kunt matrixconstanten gebruiken in plaats van verwijzingen als u niet elke constante waarde in een aparte cel op het werkblad wilt invoeren.

Een matrixformule gebruiken om enkele of meerdere resultaten te berekenen

Opmerking : Wanneer u een matrixformule opgeeft, wordt de formule automatisch tussen { } (accolades) geplaatst. Als u die zelf probeert in te voeren, wordt de formule in Excel weergegeven als tekst.

  • Matrixformule met een enkel resultaat    Met dit type matrixformule kunt u een werkbladmodel vereenvoudigen door een aantal verschillende formules te vervangen door één matrixformule.

    Met de volgende matrixformule wordt bijvoorbeeld de waarde van een pakket aandelen berekend zonder dat u een rij cellen hoeft te gebruiken om de individuele waarden van elk aandeel te berekenen.

    matrixformule die één resultaat oplevert

    Wanneer u de formule ={SOM(B2:D2*B3:D3)} opgeeft als matrixformule, worden de waarden voor Aandelen en Prijs voor elk certificaat vermenigvuldigd en worden de resultaten van die berekeningen opgeteld.

  • Matrixformule met meerdere resultaten    Sommige werkbladfuncties geven waardematrices als resultaat of moeten een matrix van waarden als argument bevatten. Als u meerdere resultaten wilt berekenen met een matrixformule, moet u de matrix invoeren in een celbereik dat hetzelfde aantal rijen en kolommen heeft als de matrixargumenten.

    Bijvoorbeeld: bij een reeks van drie verkoopcijfers (in kolom B) voor een reeks van drie maanden (in kolom A) bepaalt de functie TREND de lineaire waarden voor de verkoopcijfers. De formule wordt ingevoerd in drie cellen in kolom C (C1:C3) om alle resultaten van de formule weer te geven.

    Matrixformule die meerdere resultaten oplevert

    Wanneer u de formule =TREND(B1:B3;A1:A3) opgeeft als matrixformule, levert deze drie afzonderlijke resultaten op (22196, 17079 en 11962) op basis van de drie verkoopcijfers en de drie maanden.

Matrixconstanten gebruiken

In een gewone formule kunt u een verwijzing invoeren naar een cel met een waarde of naar de waarde zelf (ook wel constante genoemd). Zo kunt u in een matrixformule een verwijzing invoeren naar een matrix, maar u kunt ook de matrix met waarden in de cellen invoeren (ook wel matrixconstante genoemd). In matrixformules worden constanten op dezelfde manier verwerkt als in gewone formules, maar u moet de matrixconstanten in een bepaalde notatie invoeren.

Matrixconstanten kunnen getallen, tekst, logische waarden (WAAR of ONWAAR) of foutwaarden (bijvoorbeeld #N/B) bevatten. Eén matrixconstante kan verschillende typen waarden bevatten, bijvoorbeeld {1,3,4;WAAR,ONWAAR,WAAR}. Getallen in matrixconstanten kunnen gehele getallen, decimale getallen of getallen in de wetenschappelijke notatie zijn. Tekst moet tussen dubbele aanhalingstekens worden geplaatst, bijvoorbeeld "dinsdag". 

Matrixconstanten mogen geen celverwijzingen, kolommen of rijen van ongelijke lengte, formules of de speciale tekens $ (dollarteken), () (ronde haken) of % (procentteken) bevatten.

Als u matrixconstanten wijzigt, moet u rekening houden met het volgende:

  • Plaats de matrixconstanten tussen accolades ({ }).

  • Plaats een komma (,) tussen de waarden in verschillende kolommen. Als u bijvoorbeeld de waarden 10, 20, 30 en 40 wilt weergeven, typt u {10,20,30,40}. Een dergelijke matrixconstante wordt een 1-bij-4-matrix genoemd en is hetzelfde als een verwijzing naar één rij met vier kolommen.

  • Plaats een puntkomma (;) tussen waarden in verschillende rijen. Als u de waarden 10, 20, 30, 40 in één rij wilt weergeven en de waarden 50, 60, 70, 80 in de rij eronder, voert u de 2-bij-4-matrixconstante {10,20,30,40;50,60,70,80} in.

Naar boven

Wanneer u een formule verwijdert, wordt de resulterende waarde van de formule ook verwijderd. U kunt echter ook alleen de formule verwijderen en de resulterende waarde van de formule in de cel laten.

  • Als u formules samen met de resulterende waarden wilt verwijderen, gaat u als volgt te werk:

    1. Selecteer de cel of het celbereik met de formule.

    2. Druk op Delete.

  • Als u formules zonder de resulterende waarden wilt verwijderen, gaat u als volgt te werk:

    1. Selecteer de cel of het celbereik met de formule.

      Selecteer het celbereik met de matrixformule als de formule een matrixformule is.

      Een celbereik met de matrixformule selecteren

      1. Klik op een cel in de matrixformule.

      2. Klik op het tabblad Start in de groep Bewerken achtereenvolgens op Zoeken en selecteren en Ga naar.

      3. Klik op Speciaal.

      4. Klik op Huidige matrix.

    2. Ga naar het tabblad Start en klik in de groep Klembord op Kopiëren Knopafbeelding .
      afbeelding van excel-lint

      Toetscombinatie    U kunt ook op Ctrl+C drukken.

    3. Ga naar het tabblad Start en klik in de groep Klembord achtereenvolgens op de pijl onder Plakken Knopafbeelding en op Waarden plakken.

Naar boven

In de volgende tabel vindt u een overzicht van enkele veelvoorkomende fouten die u tijdens het typen van een formule kunt maken en hoe u formulefouten kunt voorkomen:

Let op het volgende

Meer informatie

Zorg ervoor dat de haakjes openen en sluiten overeenkomen in de formule   

In een formule heeft elk haakje openen een bijbehorend haakje sluiten. Wanneer u een formule maakt, worden haakjes tijdens het typen in kleur weergegeven.

Gebruik een dubbele punt om een bereik aan te geven dat u in de formule invoert   

Dubbele punten (:) worden gebruikt om de verwijzing naar de eerste en laatste cel in het bereik te scheiden, bijvoorbeeld A1:A5.

Typ alle vereiste argumenten    

Functies kunnen verplichte en optionele argumenten hebben (die worden aangegeven met vierkante haken in de syntaxis). Alle vereiste argumenten moeten worden opgegeven. Controleer ook of u niet te veel argumenten hebt opgegeven.

Nest niet meer dan 64 functies in een formule   

Het nesten van functies in een formule is beperkt tot 64 niveaus.

Plaats namen van werkmappen of werkbladen tussen enkele aanhalingstekens    

Wanneer u verwijst naar waarden of cellen in andere werkbladen of werkmappen met niet-alfabetische tekens in de naam, moet u de namen tussen enkele aanhalingstekens plaatsen ( ' ).

Neem het pad naar externe werkmappen op    

Externe verwijzingen moeten de naam van een werkmap en het pad naar de werkmap bevatten.

Typ getallen zonder opmaak    

Voor getallen die u in een formule invoert, moet u geen decimaaltekens of dollartekens ($) in de notatie gebruiken omdat komma's al worden gebruikt als scheidingstekens voor argumenten in formules en dollartekens worden gebruikt om absolute verwijzingen te markeren. Typ bijvoorbeeld niet $1,00, maar 1 in de formule.

Naar boven

Belangrijk : De berekende resultaten van formules en van sommige Excel-werkbladfuncties kunnen enigszins verschillen tussen een Windows-pc met x86- of x86-64-architectuur en een Windows RT-pc met ARM-architectuur. Meer informatie over de verschillen.

Hebt u een vraag over een bepaalde functie?

Stel een vraag op het forum van de Excel-community

Help ons Excel verbeteren

Hebt u suggesties voor het verbeteren van de volgende versie van Excel? Als dat het geval is, kijk dan eens naar de onderwerpen op Excel User Voice (Engelstalig).

Zie ook

Overzicht van formules in Excel

Niet-werkende formules voorkomen

Fouten in formules zoeken en verbeteren

Excel-sneltoetsen en -functietoetsen

Excel-functies (alfabetisch)

Excel-functies (per categorie)

Uw vaardigheden uitbreiden
Training verkennen
Als eerste nieuwe functies krijgen
Deelnemen aan Office Insiders

Was deze informatie nuttig?

Bedankt voor uw feedback.

Hartelijk dank voor uw feedback! Het lijkt ons een goed idee om u in contact te brengen met een van onze Office-ondersteuningsagents.

×