Format, funksjon

Eksempler

Bruke Format-funksjonen i et uttrykk    Du kan bruke Format der du kan bruke uttrykk. Du kan for eksempel bruke den i en spørring som en del av et feltalias, eller i kontrollkildeegenskapen for en tekstboks i et skjema eller en rapport. Eksemplene nedenfor viser et uttrykk du kan bruke i filteregenskapen for en rapport for å begrense utdataene til poster fra forrige uke.

Format([Date],"ww")=Format(Now(),"ww")-1

I dette eksemplet har rapportens postkilde et felt kalt Dato, som inneholder datoen hver bestemt post ble endret, og som brukes i rapporten. Når du kjører rapporten, filtreres resultatene slik at de bare viser postene der uken for verdien i Dato-feltet (Format([Date],"ww")) er lik forrige uke (Format(Now(),"ww")-1).

Bruke Format-funksjonen i VBA-kode    

Dette eksemplet viser ulike bruksområder for Format-funksjonen til å formatere verdier ved hjelp av både navngitte formater og brukerdefinerte formater. For datoskilletegnet (/), tidsskilletegnet (:) og AM/PM-litteralen avhenger de faktiske formaterte utdataene som vises av systemet, av de nasjonale innstillingene for datamaskinen som koden kjører på. Når klokkeslett og datoer vises i utviklingsmiljøet, brukes det korte klokkeslettformatet og det korte datoformatet for kodeinnstillingen. Når den vises ved å kjøre kode, brukes det korte klokkeslettformatet og det korte datoformatet for de nasjonale innstillingene for systemet, noe som kan være forskjellig fra de nasjonale kodeinnstillingene. I dette eksemplet antas nasjonal innstilling for amerikansk engelsk.

MyTime og MyDate vises i utviklingsmiljøet ved hjelp av gjeldende systeminnstilling for kort tid og kort datoinnstilling.

Dim MyTime, MyDate, MyStr
MyTime = #17:04:23#
MyDate = #January 27, 1993#
' Returns current system time in the system-defined long time format.
MyStr = Format(Time, "Long Time")
' Returns current system date in the system-defined long date format.
MyStr = Format(Date, "Long Date")
MyStr = Format(MyTime, "h:m:s")    ' Returns "17:4:23".
MyStr = Format(MyTime, "hh:mm:ss AMPM")    ' Returns "05:04:23 PM".
MyStr = Format(MyDate, "dddd, mmm d yyyy")    ' Returns "Wednesday,
    ' Jan 27 1993".
' If format is not supplied, a string is returned.
MyStr = Format(23)    ' Returns "23".
' User-defined formats.
MyStr = Format(5459.4, "##,##0.00")    ' Returns "5,459.40".
MyStr = Format(334.9, "###0.00")    ' Returns "334.90".
MyStr = Format(5, "0.00%")    ' Returns "500.00%".
MyStr = Format("HELLO", "<")    ' Returns "hello".
MyStr = Format("This is it", ">")    ' Returns "THIS IS IT".

Bruke Format med tomme strenger

I Microsoft Access versjon 2.0 og tidligere kan du bruke Format-funksjonen til å returnere én verdi for en nullengdestreng og en annen for en verdi. Du kan for eksempel bruke et formatuttrykk som følgende med Format-funksjonen for å returnere den riktige strengverdien fra koden:

Dim varX As Variant
Dim varStrX As Variant
' Assign some value to varStrX and pass to Format function.
varX = Format(varStrX, "@;ZLS;Null")

I Microsoft Access versjon 97 og nyere må du teste separat for Null-saken , og deretter returnere den riktige verdien basert på resultatet. Du kan for eksempel bruke IIf-funksjonen i et uttrykk med Format-funksjonen , for eksempel følgende:

varX = IIf(IsNull(varStrX),"Null", Format(varStrX, "@;ZLS"))

Denne endringen gjelder bare når du bruker Format-funksjonen til å formatere en streng som er avhengig av om det er en tom streng eller en nullverdi. Andre formatuttrykk som brukes med Format-funksjonen , fortsetter å fungere som de gjorde i tidligere versjoner.

Hvis du konverterer en database fra Microsoft Access versjon 2.0 og tidligere til Microsoft Access 2002 eller nyere, må du endre kode for å teste separat for nulltilfellet.