Filtrer-funksjon

Med FILTRER-funksjonen kan du filtrere et dataområde basert på vilkår du angir.

Nettleseren støtter ikke video. Installer Microsoft Silverlight, Adobe Flash Player eller Internet Explorer 9.

I eksemplet nedenfor brukte vi formelen =FILTRER(A5:D20,C5:C20=H2,"") til å returnere alle poster for eple, som valgt i celle H2, og hvis det ikke finnes noen epler, til å returnere en tom streng ("").

FILTRER-funksjon – Filtrer område etter produkt (eple)

FILTRER-funksjonen filtrerer en matrise som er basert på en boolsk (sann/usann) matrise.

=FILTRER(matrise,inkluder,[hvis_tom])

Argument	Beskrivelse
matrise Obligatorisk	Matrisen eller området som skal filtreres
inkluder Obligatorisk	En boolsk matrise hvis høyde eller bredde er lik matrisen
[hvis_tom] Valgfritt	Verdien som skal returneres hvis alle verdiene i den inkluderte matrisen er tomme (filteret returnerer ikke noe)

Obs!:

En matrise kan ses på som en rad med verdier, en kolonne med verdier eller en kombinasjon av rader og kolonner med verdier. I eksemplet ovenfor er kildematrisen for FILTRER-formelen området A5:D20.
FILTRER-funksjonen returnerer en matrise som flyter over hvis det er det endelige resultatet av en formel. Dette betyr at Excel dynamisk oppretter riktig tilpasset matriseområde når du trykker på ENTER. Hvis støttedataene er i en Excel-tabell, vil matrisen automatisk endre størrelse når du legger til eller fjerner data fra matriseområdet, hvis du bruker strukturerte referanser. Hvis du vil ha mer informasjon, kan du se denne artikkelen om overflytende matriser.
Hvis det er en mulighet for at datasettet returnerer en tom verdi, kan du bruke det tredje argumentet ([hvis_tom]). Hvis ikke vil det føre til en #BEREGN!-feil siden tomme matriser ikke støttes i Excel for øyeblikket.
Hvis en verdi i inkluder-argumentet er en feil (#N/A, #VERDI osv.) eller ikke kan konverteres til en boolsk verdi, returnerer FILTRER-funksjonen en feil.
Excel har begrenset støtte for dynamiske matriser mellom arbeidsbøker, og dette scenarioet støttes bare når begge arbeidsbøkene er åpne. Hvis du lukker kildearbeidsboken, vil eventuelle koblede, dynamiske matriseformler returnere en #REF! feil når de er oppdaterte.

Eksempler

FILTRER brukt til å returnere flere vilkår

I dette tilfellet bruker vi multiplikasjonsoperatoren (*) til å returnere alle verdiene i matriseområdet (A5:D20) som har epler OG er i området øst: =FILTRER(A5:D20,(C5:C20=H1)*(A5:A20=H2),"").

Bruk av FILTRER med multiplikasjonsoperatoren (*) til å returnere alle verdiene i matriseområdet (A5:D20) som har epler OG er i området øst.

FILTRER brukt til å returnere flere vilkår og sortere

I dette tilfellet bruker vi den forrige FILTRER-funksjonen med SORTER-funksjonen til å returnere alle verdiene i matriseområdet (A5:D20) som har epler OG er i området øst, og deretter sortere enheter i synkende rekkefølge: =SORTER(FILTRER(A5:D20,(C5:C20=H1)*(A5:A20=H2),""),4,-1)

Bruk av FILTRER med SORTER-funksjonen til å returnere alle verdiene i matriseområdet (A5:D20) som har epler OG er i området øst, og deretter sortering av enheter i synkende rekkefølge.

I dette tilfellet bruker vi FILTRER-funksjonen med addisjonsoperatoren (+) til å returnere alle verdiene i matriseområdet (A5:D20) som har epler ELLER er i området øst, og deretter sortere enheter i synkende rekkefølge: =SORTER(FILTRER(A5:D20,(C5:C20=H1)+(A5:A20=H2),""),4,-1).

FILTRER og SORTER sammen – filtrer etter produkt (eple) ELLER etter område (øst)

Legg merke til at ingen av funksjonene krever absolutte referanser, fordi de bare finnes i én celle og flyter over resultatene til nærliggende celler.