Telle unike verdier blant duplikater

Telle unike verdier blant duplikater

La oss si at du vil finne ut hvor mange unike verdier det finnes i et område med flere like verdier. Hvis en kolonne for eksempel inneholder følgende:

  • Verdiene 5, 6, 7, 6, er resultatet tre unike verdier: 5 , 6 og 7.

  • Verdiene Berg, Larsen, Larsen, Larsen, er resultatet to unike verdier: Berg og Larsen.

Det finnes flere måter å telle unike verdier blant duplikater på.

Hva vil du gjøre?

Telle antallet unike verdier ved hjelp av et filter

Telle antallet unike verdier ved hjelp av funksjoner

Telle antallet unike verdier ved hjelp av et filter

Du kan bruke dialogboksen Avansert filter til å trekke ut de unike verdiene fra en kolonne med data og lime dem inn på et nytt sted. Deretter kan du bruke RADER-funksjonen til å telle antallet elementer i det nye området.

  1. Merk celleområdet, eller kontroller at den aktive cellen er i en tabell.

    Kontroller at celleområdet har en kolonneoverskrift.

  2. Klikk Avansert i gruppen Sorter og filtrer i kategorien Data.

    Dialogboksen Avansert filter vises.

  3. Klikk Kopier til et annet sted.

  4. Angi en cellereferanse i Kopier til-boksen.

    Du kan eventuelt klikke Skjul dialogboks Knappesymbol for å skjule dialogboksen midlertidig, merke cellen i regnearket, og deretter klikke Utvid dialogboks Knappesymbol .

  5. Merk av for Bare unike poster og klikk OK.

    De unike verdiene fra det merkede området kopieres til den nye plasseringen, og starter i cellen du angav i Kopier til-boksen.

  6. Skriv inn RADER-funksjonen i den tomme cellen under den siste cellen i området. Bruk området med de unike verdiene du nettopp kopierte, som argumentet, unntatt kolonneoverskriften. Hvis for eksempel området med unike verdier er B2:B45, skriver du inn =RADER(B2:B45).

Til toppen av siden

Telle antallet unike verdier ved hjelp av funksjoner

Du bruker en kombinasjon av funksjonene HVIS, SUMMER, FREKVENS, SAMMENLIGNE og LENGDE til å gjøre dette:

  • Tilordne en verdi på 1 til hvert vilkår som er sant, ved hjelp av HVIS-funksjonen.

  • Legge sammen totalsummen ved hjelp av SUMMER-funksjonen.

  • Telle antallet unike verdier ved hjelp av FREKVENS-funksjonen. FREKVENS-funksjonen ignorerer tekst- og nullverdier. For den første forekomsten av en bestemt verdi returnerer denne funksjonen et tall som er likt antallet forekomster av den verdien. For hver etterfølgende forekomst med samme verdi som den første returnerer funksjonen null.

  • Returnere plasseringen til en tekstverdi i et område ved hjelp av SAMMENLIGNE-funksjonen. Den returnerte verdien brukes deretter som et argument i FREKVENS-funksjonen slik at de tilsvarende tekstverdiene kan evalueres.

  • Finne tomme celler ved hjelp av LENGDE-funksjonen. Tomme celler har en lengde på 0.

Eksempel

Det kan være enklere å forstå dette eksemplet hvis du kopierer det til et tomt regneark.

Slik kopierer du et eksempel

  1. Opprett en tom arbeidsbok eller et tomt regneark.

  2. Merk eksemplet i hjelpeemnet.

    Merknad: Ikke merk rad- eller kolonneoverskriftene.

    Merke et eksempel fra Hjelp

    Merke et eksempel fra Hjelp

  3. Trykk CTRL+C.

  4. I regnearket merker du celle A1 og trykker CTRL+V.

  5. Hvis du vil veksle mellom å vise resultatene og vise formlene som returnerer resultatene, trykker du CTRL+J, eller velger FormelrevisjonVerktøy-menyen, og velger deretter Formelrevisjonsmodus.

1

2

3

4

5

6

7

8

9

10

A

B

Data

Data

986

Berg

Larsen

563

67

789

235

Berg

Larsen

689

789

Larsen

143

56

237

67

235

Formel

Beskrivelse (resultat)

=SUMMER(HVIS(FREKVENS(A2:A10;A2:A10)>0;1))

Teller antallet unike tallverdier i celleområdet A2:A10, men ikke tomme celler eller tekstverdier (4)

=SUMMER(HVIS(FREKVENS(SAMMENLIGNE(B2:B10;B2:B10;0);SAMMENLIGNE(B2:B10;B2:B10;0))>0;1))

Teller antallet unike tekst- og tallverdier i celleområdet B2:B10 (som ikke må inneholde tomme celler) (7)

=SUMMER(HVIS(FREKVENS(HVIS(LENGDE(A2:A10)>0;SAMMENLIGNE(A2:A10;A2:A10;0);""); HVIS(LENGDE(A2:A10)>0;SAMMENLIGNE(A2:A10;A2:A10;0);""))>0;1))

Teller antallet unike tekst- og tallverdier i celleområdet A2:A10, men ikke tomme celler eller tekstverdier (6)

Notater   

  • Formlene i dette eksemplet må legges inn som matriseformler. Merk hver celle som inneholder en formel, trykk F2, og trykk deretter CTRL+SKIFT+ENTER.

  • Hvis du vil evaluere en funksjon trinn for trinn, merker du cellen som inneholder formelen, og deretter klikker du Evaluer formel i Formelrevisjon-gruppen i kategorien Formler.

Funksjonsdetaljer

  • FREKVENS-funksjonen beregner hvor ofte verdier forekommer i et område med verdier, og returnerer en loddrett matrise med tall. Bruk for eksempel FREKVENS til å beregne testresultatene som faller innenfor et poengområde. Siden denne funksjonen returnerer en matrise, må den skrives inn som en matriseformel.

  • SAMMENLIGNE-funksjonen søker etter et bestemt element i et område med celler og returnerer den relative posisjonen til elementet i området. Hvis for eksempel området A1:A3 inneholder verdiene 5, 25 og 38, returnerer formelen =SAMMENLIGNE(25;A1:A3;0) tallet 2 fordi 25 er det andre elementet i området.

  • LENGDE-funksjonen returnerer antallet tegn i en tekststreng.

  • SUMMER-funksjonen legger sammen alle tallene du angir som argumenter. Hvert argument kan være et område, en cellereferanse, en matrise, en konstant, en formel eller resultatet av en annen funksjon. SUMMER(A1:A5) legger for eksempel sammen alle tallene i celle A1 til og med A5.

  • HVIS-funksjonen returnerer én verdi hvis et vilkår du angir, returnerer SANN, og en annen verdi hvis det returnerer USANN.

Til toppen av siden

Utvid ferdighetene dine
Utforsk opplæring
Vær først ute med de nye funksjonene
Bli med i Office Insiders

Var denne informasjonen nyttig?

Takk for tilbakemeldingen!

Takk for tilbakemeldingen! Det høres ut som det kan være lurt å sette deg i kontakt med én av våre Office-kundestøtteagenter.

×