SUMMER, funksjon

SUMMER-funksjonen, én av funksjonene for matematikk og trigonometri, legger sammen verdier. Du kan legge til enkeltverdier, cellereferanser eller celleområder, eller en blanding av alle tre.

Eksempel:

  • =SUMMER(A2:A10)

  • =SUMMER(A2:A10, C2:C10)

Nettleseren støtter ikke video. Installer Microsoft Silverlight, Adobe Flash Player eller Internet Explorer 9.

Denne videoen er en del av et opplæringskurs som heter Legge sammen tall i Excel 2013.

SUMMER(tall1;[tall2]; ...)

Argumentnavn

Beskrivelse

tall1    (obligatorisk)

Det første tallet du vil legge til. Nummeret kan være 4, en cellereferanse som B6, eller en celle område som B2:B8.

tall2-255    (valgfritt)

Dette er det andre tallet du legger til. Du kan angi opptil 255 tall på denne måten.

Hvis du raskt vil summere et celleområde, trenger du bare å merke området og se nederst til høyre i Excel-vinduet.

Skjermbilde av merking av et celleområdet, og deretter visning av statuslinjen.
Statuslinje


Dette er statuslinjen, som viser informasjon om det du har merket, enten det er en enkelt celle eller flere celler. Hvis du høyreklikker statuslinjen, spretter det opp en dialogboks som viser alle alternativene du kan velge. Vær oppmerksom på at den også viser verdier for det merkede området hvis du har disse attributtene merket av. Finn ut mer om statuslinjen.

Den enkleste måten å legge til en SUMMER-formel i regnearket på, er å bruke Autosummer-veiviseren. Velg en tom celle direkte ovenfor eller nedenfor området du vil summere, og på Hjem- eller Formel-fanen i båndet trykker du Autosummer > Summer. Autosummer-veiviseren registrerer automatisk hvilket område som skal summeres, og bygger formelen for deg. Den kan også fungere vannrett hvis du velger en celle til venstre eller høyre for området som skal summeres. Vær oppmerksom på at dette ikke fungerer på et celleområde som ikke er sammenhengende, men vi skal gå gjennom det i neste seksjon.

Du kan bruke veiviseren for automatisk summering for automatisk å bygge en Summer-formel.  Merk et område rett ovenfor/nedenfor eller til venstre/høyre for området som skal summeres, og gå til Formel-fanen på båndet, og velg deretter Autosummer og SUMMER.
Bruk Autosummer-veiviseren for raskt å summere tilstøtende områder


Autosummer-dialogboksen har valgmuligheter for andre vanlige funksjoner som:

Autosummer loddrett

Celle B6 viser Autosummer summer-formelen: =SUMMER(B2:B5)

Autosummer-veiviseren registrerte automatisk celle B2:B5 som området som skal summeres. Alt du trenger å gjøre, er å trykke Enter for å bekrefte det. Hvis du trenger å legge til/utelukke flere celler, holder du nede Skift-tasten > Pilstast (valgfritt) inntil du har merket det relevante området, og trykker Enter når du er ferdig.

Veiledning for Intellisense-funksjonen: Den flytende koden nedenfor funksjonen SUMMER(tall1; [tall2];...) er Intellisense-veiledningen. Hvis du klikker SUMMER eller funksjonsnavnet, blir det en blå hyperkobling, som tar deg direkte til Hjelp-emnet for den funksjonen. Hvis du klikker de individuelle funksjonselementene, utheves deres representerende elementer i formelen. I dette tilfellet utheves bare B2:B5, da det bare er én tallreferanse i denne formelen. Intellisense-koden vises for alle funksjoner.

Autosummer vannrett

Celle D2 viser formelen Autosummer summer: =SUM(B2:C2)

Bruke SUMMER med områder som ikke er sammenhengende.  Celle C8-formelen er = SUM(C2:C3,C5:C6). Du kan også bruke navngitte områder, og formelen ville da vært =SUMMER(Uke1,Uke2).

Autosummer-veiviseren fungerer vanligvis bare for tilstøtende områder, så hvis du har tomme rader eller kolonner i summeringsområdet, stopper Excel ved det første åpne området. I dette tilfellet må du summere utvalg, hvor du legger sammen ett enkelt område om gangen. I dette eksemplet ville Excel genert =SUMMER(C2:C6) hvis det var data i B4, fordi programmet ville registrert et sammenhengende område.

Du kan raskt merke flere, usammenhengende områder med CTRL+VENSTREKLIKK. Angi først «=SUMMER(», velg så de forskjellige områdene, og Excel legger automatisk til kommaseparatoren mellom områdene for deg. Trykk ENTER når du er ferdig.

TIPS: Du kan bruke ALT + = for raskt å legge SUMMER-funksjonen til i en celle. Deretter trenger du bare å velge området/områdene.

Obs! Kanskje du legger merke til at Excel har uthevet de forskjellige funksjonsområdene med forskjellige farger, og disse samsvarer i selve formelen, slik at C2:C3 er én farge og C5:C6 er en annen. Excel gjør dette for alle funksjoner, med mindre det refererte området er på et annet regneark eller i en annen arbeidsbok. Du kan bruke Navngitte områder, for eksempel Uke1, Uke2 osv. og deretter referere til dem i formelen for å oppnå forbedret tilgjengelighet med hjelpeteknologi:

=SUMMER(Uke1,Uke2)

Du kan enkelt utføre matematiske operasjoner med Excel for seg selv, og i forbindelse med Excel-funksjoner som SUMMER. Tabellen nedenfor viser operatorer du kan bruke, sammen med noen relaterte funksjoner. Du kan angi operatorene fra tallraden på tastaturet, eller fra det numeriske tastaturet hvis du har et. SKIFT + 8 vil for eksempel angi en stjerne (*) for multiplikasjon.

Operator

Operasjon

Eksempler

+

Addisjon

=1+1

= A1+B1

= SUMMER(A1:A10)+10

= SUMMER(A1:A10)+B1

-

Subtraksjon

=1-1

= A1-B1

= SUMMER(A1:A10)-10

= SUMMER(A1:A10)-B1

*

MULTIPLIKASJONSTEGN

=1*1

=A1*B1

= SUMMER(A1:A10)*10

= SUMMER(A1:A10)*B1

=PRODUKT(1,1) - PRODUKT (funksjon)

/

Divisjon

=1/1

= A1/B1

= SUMMER(A1:A10)/10

= SUMMER(A1:A10)/B1

=KVOTIENT(1,1) - KVOTIENT (funksjon)

^

Eksponentiering

=1^1

= A1^B1

= SUMMER(A1:A10)^10

= SUMMER(A1:A10)^B1

=OPPHØYD.I(1,1) - OPPHØYD.I (funksjon)

Hvis du vil ha mer informasjon, se bruke Excel som kalkulator.

Andre eksempler

  1. La oss si at du vil bruke en prosentvis rabatt på et celleområde som du har summert.

    Bruk av operatorer med SUMMER.  Formelen i celle B16 er =SUMMER(A2:A14)*-25%.  Formelen ville vært bygget opp korrekt hvis -25% i stedet var en cellereferanse, for eksempel =SUMMER(A2:A14)*E2
    • =SUMMER(A2:A14)*-25%

    Dette ville gitt deg 25 % av det summerte området, uansett hardkodene i 25%-delen av formelen, og kan være vanskelig å finne senere hvis du må endre det. Det er mye bedre å plassere 25% i en celle og referere til den i stedet, der dette er åpent og enkelt kan endres, som dette:

    • =SUMMER(A2:A14)*E2

    For å dividere i stedet for å multiplisere skifter du ganske enkelt ut «*» med «/»: =SUMMER(A2:A14)/E2

  2. Legge til eller trekke fra en SUM

    i. Du kan enkelt legge til eller trekke fra en Sum ved bruk av + eller - som følger:

    • =SUMMER(A1:A10)+E2

    • =SUMMER(A1:A10)-E2

Denne delen drøfter noen anbefalte fremgangsmåter for arbeid med SUMMER-funksjoner. Mye av dette kan også anvendes på arbeid med andre funksjoner.

Metoden =1+2 eller =A+B – Selv om du kan legge inn =1+2+3 eller =A1+B1+C2 og få nøyaktige resultater, er disse metodene av forskjellige årsaker tilbøyelige til feil:

  1. Skrivefeil – Tenk deg at du skal skrive inn flere og/eller mye større verdier, som dette:

    • =14598,93+65437,90+78496,23

    Prøv deretter å validere at oppføringene er riktige. Det er mye enklere å plassere disse verdiene i individuelle celler og bruke en SUMMER-formel. I tillegg kan du formatere verdiene når de er i celler, slik at det blir mye enklere å lese dem når de er i en formel.

    Bruk SUMMER-funksjonen i stedet for hardkodede verdier i formler.  Formelen i celle D5 er =SUMMER(D2:D4)
  2. #VERDI!-feil som følge av tekstreferanse i stedet for tallreferanse

    Hvis du bruker en formel som:

    • =A1+B1+C1 eller =A1+A2+A3

    Eksempel på dårlig formelbygging.  Formelen i celle D2 er =A2+B2+C2

    Formelen kan brytes hvis det finnes ikke-numeriske (tekst)verdier i de refererte cellene, hvilket returnerer en #VERDI!-feil. SUMMER ignorerer tekstverdier og gir deg bare summen av tallverdiene.

    Riktig formelbygging.  I stedet for =A2+B2+C2, er formelen i D2 =SUMMER(A2:C2)
  3. #REF!-feil som følge av sletting av rader eller kolonner

    #REF!-feil forårsakes ved sletting av en kolonne.  Formelen er endret til =A2+#REF!+B2

    Hvis du sletter en rad eller kolonne, oppdateres ikke formelen for å utelukke den slettede raden, og den returnerer en #REF!-feil der en SUMMER-funksjon ville blitt oppdatert automatisk.

    SUMMER-funksjonen justerer automatisk for innsatte eller slettede rader og kolonner
  4. Formler oppdaterer ikke referanser ved innsetting av rader eller kolonner

    = A+B+C-formler oppdateres ikke om du legger til rader

    Hvis du setter inn en rad eller kolonne, oppdateres ikke formelen for inkludering av raden som legges til der en SUMMER-funksjon ville blitt oppdatert automatisk (så lenge du ikke er utenfor området referert til i formelen). Dette er spesielt viktig hvis du forventer at formelen oppdateres og dette ikke skjer, da det vil gi deg ufullstendige resultater som du kanskje ikke fanger opp.

    Eksemplet viser en SUMMER-formel som automatisk utvides fra =SUMMER(A2:C2) til =SUMMMER(A2:D2) når det settes inn en kolonne
  5. SUMMER med enkeltvise cellereferanser kontra områder

    Bruk av en formel som:

    • =SUMMER(A1,A2,A3,B1,B2,B3)

    er like tilbøyelig til feil ved innsetting eller sletting av rader innenfor det refererte området, av samme årsaker. Det er mye bedre å bruke individuelle områder, som:

    • =SUMMER(A1:A3,B1:B3),

    som oppdateres når du legger til eller sletter rader.

  1. Du kan definitivt bruke SUMMER med andre funksjoner Her er et eksempel som oppretter en månedlig gjennomsnittsberegning:

    Bruk SUMMER med andre funksjoner.  Formelen i celle M2 er =SUMMER(A2:L2)/ANTALLA(A2:L2) .  Obs! Av hensyn til tydeligheten er kolonnene for mai–november skjult.
    • =SUMMER(A2:L2)/ANTALLA(A2:L2)

  2. Hvilket tar summen av A2:L2 dividert med antallet ikke-tomme celler i A2:L2 (mai til og med desember er tomme).

  1. Noen ganger trenger du å summere en bestemt celle i flere regneark. Det kan være nærliggende å klikke på hvert ark og cellen du vil bruke, og bruke «+» for å legge til celleverdier, men dette er langtekkelig og det er lett å gjøre feil.

    • =Ark1!A1+Ark2!A1+Ark3!A1

    Du kan oppnå dette mye enklere med en 3D- eller 3-dimensjonal summering:

    3D summer – formelen i celle D2 er =SUMMER(Ark1:Ark3!A2)
    • =SUMMER(Ark1:Ark3!A1)

    Hvilket summerer celle A1 i alle arkene fra Ark1 til Ark3.

    Dette er spesielt nyttig i situasjoner der du har ett enkelt ark for hver måned (januar til desember), og du trenger til å summere dem i et sammenfattende regneark.

    3D summerer over navngitte ark.  Formelen i D2 er =SUMMER(januar: desember! A2)
    • = SUMMER(januar:desember!A2)

    Hvilket summerer celle A2 i hvert regneark fra januar til og med desember.

    Kommentarer: Hvis regnearkene har mellomrom i navnet, for eksempel «Salg i januar», må du bruke en apostrof når du refererer til arknavnene i en formel. Legg merke til apostrofen FØR det første regnearknavnet, og igjen ETTER det siste.

    • = SUMMER('Salg januar:Salg desember'!A2)

    3D-metoden fungerer også med andre funksjoner som GJENNOMSNITT, MIN, MAKS osv.:

    • =GJENNOMSNITT(Ark1:Ark3!A1)

    • =MIN(Ark1:Ark3!A1)

    • =MAKS(Ark1:Ark3!A1)

Problem

Hva gikk galt

SUMMER-funksjonen min viser ##### i stedet for resultatet.

Kontroller kolonnebreddene. ##### betyr vanligvis at kolonnen er for smal til å vise resultatet av formelen.

SUMMER-funksjonen viser selve formelen som tekst, ikke resultatet.

Kontroller at cellen ikke er formatert som tekst. Merk den aktuelle cellen eller det aktuelle celleområdet, og bruk CTRL+1 for å åpne dialogboksen Formater celler og klikk deretter Tall-fanen og velg ønsket format. Hvis cellen er formatert som tekst og ikke endres etter at du har forandret formatet, kan det være du må bruke F2 > Enter for å tvinge endringen av formatet.

SUMMER-funksjonen min oppdateres ikke.

Kontroller at Beregning er satt til Automatisk. På Formel-fanen går du til Beregningsalternativer. Du kan også bruke F9 for å tvinge beregning av regnearket.

Kontroller at beregning er satt til Automatisk.  På Formel-fanen går du til Beregningsalternativer.

Enkelte verdier legges ikke til.

Bare tallverdier i funksjonsreferansen eller -området kan legges til. Tomme celler, logiske verdier som SANN eller tekst ignoreres.

Feilen #NAVN? vises i stedet for det forventede resultatet.

Dette betyr vanligvis at formelen er feilstavet, for eksempel =sume(A1:A10) i stedet for =SUMMER(A1:A10).

Min SUMMER-funksjon viser et helt tall, men det skal vise desimaler

Kontroller formateringen av cellen for å kontrollere at du viser desimaler. Merk den aktuelle cellen eller det aktuelle celleområdet, og bruk CTRL+1 for å åpne dialogboksen Formater celler. Klikk deretter Tall-fanen og velg ønsket format. Pass på å angi ønsket antall desimaler.

  1. Jeg vil bare legge til / trekke fra / multiplisere / dividere tall – Se denne videoserien om Enkle matematiske beregninger i Excel, eller Bruk Excel som kalkulator.

  2. Hvordan viser jeg flere/færre desimaler? – Du kan endre tallformatet. Merk den aktuelle cellen eller det aktuelle celleområdet, og bruk CTRL+1 for å åpne dialogboksen Formater celler. Klikk deretter Tall-fanen og velg ønsket format. Pass på å angi ønsket antall desimaler.

  3. Hvordan legge til eller trekke fra tid? Du kan legge til og trekke fra tid på et par forskjellige måter. For eksempel kan du finne forskjellen mellom 08:00 – 12:00 for lønnsformål ved på bruke =(«12:00»-«08:00»)*24, som tar sluttidspunktet minus starttidspunktet. Legg merke til at Excel beregner tidsrom som brøker av et døgn, så du må multiplisere med 24 å få totalt antall timer. I det første eksemplet bruker vi =((B2-A2)+(D2-C2))*24 for å få summen av timer fra start til slutt, minus en lunsjpause (8,50 timer totalt).

    Hvis du bare vil legge til timer og minutter og vil vise på denne måten, kan du summere og trenger ikke å multiplisere med 24, slik at vi i det andre eksemplet bruker =SUMMER(A6:C6) fordi vi trenger bare det totale antallet timer og minutter for tildelte aktiviteter (5:36 eller 5 timer, 36 minutter).

    Beregn tidsrom

    Hvis du vil ha mer informasjon, kan du se: Legge til eller trekke fra tid.

  4. Hvordan beregner jeg forskjellen mellom datoer? I likhet med tidspunkt kan du addere og subtrahere datoer. Her er et svært vanlig eksempel på hvordan å telle antall dager mellom to datoer. Det er så enkelt som =B2-A2. Nøkkelen til å arbeide med både datoer og klokkeslett er at du starter med sluttdato/sluttid og trekker fra startdato/starttid.

    Beregn forskjeller mellom datoer

    Du finner flere måter å arbeide med datoer på i: Beregne antall dager mellom to datoer.

  5. Hvordan summerer jeg bare synlige celler? Noen ganger når du manuelt skjuler radene eller bruker AutoFilter for å vise bare bestemte data, vil du også bare summere de synlige cellene. Du kan bruke TOTALSUM-funksjonen. Hvis du bruker en totalrad i en Excel-tabell, legges funksjoner du velger fra Total-rullegardinlisten automatisk inn som en totalsum. Se mer informasjon om hvordan du summerer dataene i en Excel-tabell.

Trenger du mer hjelp?

Du kan alltid spørre en ekspert i Excel tekniske fellesskap, få støtte i Svar-fellesskapet eller foreslå en ny funksjon eller forbedring på Excel User Voice.

Se også

Se en video om hvordan du bruker SUMMER-funksjonen

SUMMERHVIS-funksjonen legger bare sammen verdiene som oppfyller ett enkelt vilkår

SUMMER.HVIS.SETT-funksjonen legger bare sammen verdiene som oppfyller flere vilkår

ANTALL.HVIS-funksjonen teller bare verdiene som oppfyller ett enkelt vilkår

ANTALL.HVIS.SETT -funksjonen teller bare verdiene som oppfyller flere vilkår

Oversikt over formler i Excel

Unngå formler med feil

Finne og rette feil i formler

Hurtigtaster i Excel for Windows

Hurtigtaster i Excel for Mac

Matematikk- og trigonometri-funksjoner

Funksjoner i Excel (alfabetisk)

Excel-funksjoner (etter kategori)

Utvid ferdighetene dine
Utforsk opplæring
Vær først ute med de nye funksjonene
Bli med i Office Insiders

Var denne informasjonen nyttig?

Takk for tilbakemeldingen!

Takk for tilbakemeldingen! Det høres ut som det kan være lurt å sette deg i kontakt med én av våre Office-kundestøtteagenter.

×