IF (Fungsi IF)

Artikel ini memerihalkan sintaks formula dan penggunaan fungsiIF dalam Microsoft Excel.

Perihalan

Fungsi IF mengembalikan satu nilai jika syarat yang anda tentukan menilai kepada TRUE, dan satu nilai lain jika syarat itu menilai kepada FALSE. Contohnya, formula =IF(A1>10,"Melebihi 10","10 atau kurang") mengembalikan "Melebihi 10" jika A1 adalah lebih besar daripada 10, dan "10 atau kurang" jika A1 adalah lebih kecil daripada atau sama dengan 10.

Sintaks

IF(logical_test, [value_if_true], [value_if_false])

Sintaks fungsi IF mempunyai argumen berikut.

  • Logical_test    Diperlukan. Apa-apa nilai atau ungkapan yang boleh menilai kepada TRUE atau FALSE. Contohnya, A10=100 adalah satu ungkapan logik; jika nilai dalam sel A10 adalah sama dengan 100, ungkapan itu menilai kepada TRUE. Jika tidak, ungkapan itu menilai kepada FALSE. Argumen ini boleh menggunakan sebarang operator pengiraan perbandingan.

  • Value_if_true    Pilihan. Nilai yang anda ingin dikembalikan jika argumen logical_test menilai kepada TRUE. Contohnya, jika nilai argumen ini adalah rentetan teks "Dalam bajet" dan argumen logical_test menilai kepada TRUE, fungsi IF mengembalikan teks "Dalam bajet." Jika logical_test menilai kepada TRUE dan argumen value_if_true diabaikan (iaitu, hanya koma ditemui selepas argumen logical_test ), fungsi IF mengembalikan 0 (sifar). Untuk memaparkan perkataan TRUE, gunakan nilai logik TRUE untuk argumen value_if_true .

  • Value_if_false    Pilihan. Nilai yang anda ingin dikembalikan jika argumen logical_test menilai kepada FALSE. Contohnya, jika nilai argumen ini adalah rentetan teks "Luar bajet" dan argumen logical_test menilai kepada FALSE, fungsi IF mengembalikan teks "Luar bajet." Jika logical_test menilai kepada FALSE dan argumen value_if_true diabaikan (iaitu, hanya koma ditemui selepas argumen logical_test ), fungsi IF mengembalikan nilai logik FALSE. Jika logical_test menilai kepada FALSE dan nilai argumen value_if_false adalah kosong (iaitu, hanya terdapat satu koma selepas argumen value_if_true,) fungsi IF mengembalikan nilai 0 (sifar).

Catatan

  • Sehingga 64 fungsi IF boleh disarangkan sebagai argumen Value_if_true dan Value_if_false untuk menghasilkan ujian yang lebih terperinci. (Lihat Contoh 3 untuk sampel fungsi IF tersarang.) Atau, untuk menguji pelbagai syarat, pertimbangkan untuk menggunakan fungsi LOOKUP, VLOOKUP, HLOOKUP atau CHOOSE . (Lihat Contoh 4 untuk sampel fungsi LOOKUP .)

  • Jika mana-mana argumen kepada IF adalah tatasusunan, setiap unsur daripada tatasusunan tersebut akan dinilai apabila kenyataan IF dilaksanakan.

  • Excel menyediakan fungsi tambahan yang boleh digunakan untuk menganalisis data anda berdasarkan sesuatu syarat. Contohnya, untuk mengira bilangan kejadian rentetan teks atau nombor dalam julat sel, gunakan fungsi lembaran kerja COUNTIF atau COUNTIFS . Untuk mengira jumlah berdasarkan rentetan teks atau nombor dalam julat, gunakan fungsi lembaran kerja SUMIF atau SUMIFS .

Contoh

Buku kerja berikut menunjukkan contoh fungsi ini. Periksanya, ubah formula sedia ada atau masukkan formula anda sendiri untuk mengetahui cara fungsi ini berfungsi.

Salin data contoh dalam jadual berikut dan tampalkannya dalam sel A1 lembaran kerja Excel baru. Untuk memastikan formula menunjukkan hasil, pilihnya, tekan F2, kemudian tekan Enter. Jika perlu, anda boleh melaraskan lebar lajur untuk melihat semua data.

Data

50

23

33175

Formula

Perihalan

Hasil

=IF(A2<=100,"Dalam bajet","Terlampau bajet")

Jika nombor dalam sel A2 adalah kurang daripada atau sama dengan 100, formula mengembalikan "Dalam bajet." Jika tidak, fungsi memaparkan "Terlampau bajet."

Dalam bajet

=IF(A2=100,A2+B2,"")

Jika nombor dalam sel A2 sama dengan 100, A2 + B2 dikira dan dikembalikan. Jika tidak, teks kosong ("") dikembalikan.

0

=IF(3<1,"OK")

Jika hasil adalah False dan tiada argumen value_if_false disediakan untuk hasil False, FALSE dikembalikan.

FALSE

Jika hasil adalah False dan satu argumen value_if_false yang kosong disediakan untuk hasil False (koma diikuti argumen value_if_true), 0 dikembalikan.

0

Untuk bekerja secara lebih mendalam dengan data contoh dalam Excel, memuat turun buku kerja terbenam pada komputer anda kemudian membukanya dalam Excel.

Contoh 2

Perbelanjaan Sebenar

Perbelanjaan Jangkaan

$1,500

$900

$500

$900

$500

$925

Formula

Perihalan

Hasil

=IF(A2>B2,"Terlampau Bajet","OK")

Menyemak sama ada perbelanjaan sebenar dalam baris 2 adalah lebih besar daripada perbelanjaan jangkaan. Mengembalikan "Terlampau Bajet" kerana hasil ujian adalah True.

Terlampau Bajet

=IF(A3>B3,"Terlampau Bajet","OK")

Menyemak sama ada perbelanjaan sebenar dalam baris 3 adalah lebih besar daripada perbelanjaan jangkaan. Mengembalikan "OK" kerana hasil ujian adalah False.

OK

Contoh 3

Skor

45

90

78

Formula

Perihalan

Hasil

=IF(A2>89,"A",IF(A2>79,"B", IF(A2>69,"C",IF(A2>59,"D","F"))))

Menggunakan syarat IF tersarang untuk menguntukkan gred huruf bagi skor dalam sel A2.

F

=IF(A3>89,"A",IF(A3>79,"B", IF(A3>69,"C",IF(A3>59,"D","F"))))

Menggunakan syarat IF tersarang untuk menguntukkan gred huruf bagi skor dalam sel A3.

A

=IF(A4>89,"A",IF(A4>79,"B", IF(A4>69,"C",IF(A4>59,"D","F"))))

Menggunakan syarat IF tersarang untuk menguntukkan gred huruf bagi skor dalam sel A4.

C

Contoh 4

Skor

45

90

78

Formula

Perihalan

Hasil

=LOOKUP(A2,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Selain daripada menggunakan berbilang fungsi IF tersarang, formula tersebut menggunakan fungsi LOOKUP untuk mencari gred huruf yang sepadan dengan skor berangka yang disimpan dalam tatasusunan dalam formula.

F

=LOOKUP(A3,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Selain daripada menggunakan berbilang fungsi IF tersarang, formula tersebut menggunakan fungsi LOOKUP untuk mencari gred huruf yang sepadan dengan skor berangka yang disimpan dalam tatasusunan dalam formula.

A-

=LOOKUP(A4,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Selain daripada menggunakan berbilang fungsi IF tersarang, formula tersebut menggunakan fungsi LOOKUP untuk mencari gred huruf yang sepadan dengan skor berangka yang disimpan dalam tatasusunan dalam formula.

C+

Berkenaan Dengan: Excel 2013, Excel Online



Adakah maklumat ini membantu?

Ya Tidak

Bagaimana kami boleh menambah baiknya?

255 baki aksara

Untuk melindungi privasi anda, jangan masukkan maklumat hubungan dalam maklum balas anda. Semak semula dasar privasi.

Terima kasih atas maklum balas anda!

Sumber sokongan

Ubah bahasa