TEXT (funkcija TEXT)

Funkcija TEXT ļauj mainīt skaitļa izskatu, attiecinot uz to formatējumu ar formātu kodiem. Tas noder situācijās, kad vēlaties parādīt skaitļus vieglāk lasāmā formātā vai kombinēt skaitļus ar tekstu un simboliem.

Piezīme.: Funkcija TEXT pārvērš skaitļus tekstā, kas var apgrūtināt atsauces tālākos aprēķinos. Ieteicams saglabāt vienā šūnā saglabāt sākotnējo vērtību un tad citā šūnā izmantot funkciju TEXT. Tad, sastādot citas funkcijas, vienmēr veidojiet atsauces uz sākotnējo vērtību, nevis funkcijas TEXT rezultātu.

Sintakse

TEXT(vērtība, formāts_teksts)

Funkcijas TEXT sintaksei ir šādi argumenti:

Argumenta nosaukums

Apraksts

vērtība

Skaitliska vērtība, kuru vēlaties pārvērst tekstā.

formāts_teksts

Teksta virkne, kas definē uz norādīto vērtību attiecināmo formatējumu.

Pārskats

Funkcija TEXT vienkāršākajā formā izsaka:

  • =TEXT(vērtība, kuru vēlaties formatēt, "attiecināmais formātu kods")

Tālāk minēti daži populāri piemēri, kurus varat kopēt tieši programmā Excel, lai patstāvīgi ar tiem eksperimentētu. Pievērsiet uzmanību formāta kodiem pēdiņās.

Formula

Apraksts

=TEXT(1234.567,"$#,##0.00")

Valūta ar tūkstošu atdalītāju un 2 cipariem aiz komata, piemēram, $ 1,234.57. Ņemiet vērā, ka programma Excel vērtību noapaļo līdz 2 cipariem aiz komata.

=TEXT(TODAY(),"MM/DD/YY")

Šodienas datums formātā MM/DD/GG, piemēram, 03/14/12

=TEXT(TODAY(),"DDDD")

Pašreizējā nedēļas diena, piemēram, pirmdiena

=TEXT(NOW(),"H:MM AM/PM")

Pašreizējais laiks, piemēram, 1:29 PM

=TEXT(0.285,"0.0%")

Procentuālā vērtība, piemēram, 28,5 %

=TEXT(4.34 ,"# ?/?")

Daļskaitlis, piemēram, 4 1/3

=TRIM(TEXT(0.34,"# ?/?"))

Daļskaitlis, piemēram, 1/3. Ņemiet vērā, ka šeit izmantota funkcija TRIM, lai izņemtu sākuma atstarpi ar decimālskaitļa vērtību.

=TEXT(12200000,"0.00E+00")

Zinātniskais pieraksts, piemēram, 1.22E+07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

Īpašs (tālruņa numurs), piemēram, (123) 456-7898

=TEXT(1234,"0000000")

Pievienojiet sākuma nulles (0), piemēram, 0001234

=TEXT(123456,"##0° 00' 00''")

Pielāgotie — platums/garums

Piezīme.: Jūs varat mainīt formatējumu ar funkciju TEXT, taču tas nav vienīgais veids. Lai mainītu formātu bez formulas, nospiediet taustiņu kombināciju CTRL+1 (vai Attēls ar MAC komandpogas ikonu +1, strādājot ar Mac) un izvēlieties formātu dialoglodziņā Šūnu formatēšana > Skaitļi.

Lejupielādējiet mūsu piemērus

Varat lejupielādēt parauga darbgrāmatu ar visiem šajā rakstā izmantotajiem un citiem funkcijas TEXT piemēriem. Varat sekot darbgrāmatas piemēriem vai veidot savus funkcijas TEXT formāta kodus.

Lejupielādēt programmas Excel funkcijas TEXT piemērus

Citi pieejamie formāta kodi

Varat izmantot dialoglodziņu Šūnu formatēšana, lai atrastu citus pieejamos formāta kodus:

  1. Nospiediet taustiņu kombināciju Ctrl+1 ( Attēls ar MAC komandpogas ikonu +1, strādājot ar Mac), lai atvērtu dialoglodziņu Šūnu formatēšana.

  2. Atlasiet vajadzīgo formātu no cilnes Skaitļi.

  3. Atlasiet opciju Pielāgotie,

  4. Tagad vajadzīgais formāta kods ir redzams lodziņā Tips. Šajā gadījumā jums lodziņā Tips jāatlasa viss, izņemot semikolu (;) un simbolu @. Zemāk redzamajā piemērā mēs atlasījām un kopējām tikai mm/dd/gg.

  5. Nospiediet taustiņu kombināciju Ctrl+C, lai kopētu formāta kodu, tad nospiediet Atcelt, lai aizvērtu dialoglodziņu Šūnu formatēšana.

  6. Visbeidzot nospiediet taustiņu kombināciju Ctrl+V, lai ielīmētu formāta kodu savā TEXT formulā, piemēram: =TEXT (B2,"mm/dd/yy"). Noteikti ielīmējiet formāta kodu pēdiņās ("formāta kods"), pretējā gadījumā programma Excel parādīs kļūdas ziņojumu.

Piemērs dialoga Formāts > Šūnas > Numurs > Pielāgots lietošanai, lai programma Excel jums izveidotu formāta virknes.

Formāta kodi pēc kategorijas

Lūk, daži piemēri, kā varat uz vērtībām attiecināt dažādus skaitļu formātus, izmantojot dialoglodziņu Šūnu formatēšana, un pēc tam izmantot opciju Pielāgotie, lai šos formāta kodus kopētu uz savu TEXT</c3> funkciju.

Kāpēc Excel dzēš manas sākuma nulles?

Programma Excel tiecas atrast šūnās ievadītus skaitļus, nevis skaitļus, kas izskatās pēc teksta, piemēram, detaļu numurus vai SKU kodus. Lai paturētu sākuma nulles, pirms vērtību ielīmēšanas vai ievadīšanas formatējiet ievades diapazonu kā tekstu. Atlasiet kolonnu vai diapazonu, kur plānojat ievietot vērtības, tad ar taustiņu kombināciju CTRL+1 atveriet dialoglodziņu Formāts > Šūnas un Skaitļu cilnē atlasiet opciju Teksts. Tagad Excel paturēs jūsu sākuma nulles.

Ja jau esat ievadījis datus un programma Excel ir noņēmusi jūsu sākuma nulles, varat izmantot funkciju TEXT, lai tās atgrieztu. Varat izveidot atsauci uz augšējo šūnu ar vērtībām un izmantot funkciju =TEXT(value,"00000"), kur nuļļu skaits formulā atbilst vajadzīgajam kopējam rakstzīmju skaitam, tad nokopēt un ielīmēt atlikušo diapazonu.

TEXT lietošanas piemēri sākuma nuļļu formatēšanai.  =TEXT(A2;"00000")

Ja kāda iemesla dēļ vēlaties pārvērst teksta vērtības atpakaļ par skaitļiem, varat tās reizināt ar 1, piemēram, =D4*1, vai izmantot dubultunāro operatoru (--), piemēram =--D4.

Programma Excel atdala tūkstošus ar atstarpi, ja formātā ir komats, kas ir iekļauts starp numura zīmēm (,) vai nullēm. Piemēram, ja formāta virkne ir "#,###", Excel skaitli 12200000 parāda kā 12,200,000.

Atstarpe, kas ir aiz cipara viettura, mērogo skaitli pēc 1000. Piemēram, ja formāta virkne ir "#,###.0", Excel skaitli 12200000 parāda kā 12,200.0.

Funkcijas TEXT piemēri, izmantojot tūkstošu atdalītāju

Piezīmes.: 

  • Tūkstošu atdalītājs ir atkarīgs no jūsu reģionālajiem iestatījumiem. ASV tas ir komats, taču citās lokalizācijās tas var būt punkts (.).

  • Tūkstošu atdalītājs ir pieejams skaitļa, valūtas un grāmatvedības formātos.

Tālāk sniegti standarta skaitļa (tikai tūkstošu atdalītāju un ciparu aiz komata), valūtas un grāmatvedības formātu piemēri. Valūtas formāts ļauj ievietot valūtas simbolu pēc jūsu izvēles un līdzina to blakus vērtībai, taču grāmatvedības formāts līdzina valūtas simbolu šūnas kreisajā pusē un vērtību — labajā. Pievērsiet uzmanību valūtas un grāmatvedības formāta kodu atšķirībai zemāk, kur grāmatvedības formātā simbols un vērtība ir atdalīti ar zvaigznīti (*).

Funkcijas TEXT piemēri ar skaitļa, valūtas un grāmatvedības formātiem

Lai atrastu valūtas simbola formāta kodu, vispirms nospiediet taustiņu kombināciju Ctrl+1 (vai Attēls ar MAC komandpogas ikonu +1, strādājot ar Mac), atlasiet vajadzīgo formātu un tad izvēlieties simbolu no nolaižamās izvēlnes Simbols:

Valūtas simbola atlase dialogā Šūnu formatēšana

Tad noklikšķiniet uz Pielāgotie pa kreisi no sadaļas Kategorija un nokopējiet formāta kodu, ieskaitot valūtas simbolu.

Funkcija TEXT — pielāgota valūta ar simbolu

Piezīme.: Funkcija TEXT neatbalsta krāsu formatējumu, tāpēc, no Šūnu formatēšanas dialoglodziņa kopējot skaitļa formāta kodu, kas ietver krāsu, piemēram: $#,##0.00_);[Red]($#,##0.00), funkcija TEXT pieņems formāta kodu, taču nerādīs krāsu.

Jūs varat mainīt to, kā tiek rādīti datumi, izmantojot "M" mēnešu, "D" dienu un "Y" gadu apzīmēšanai.

Mēneša, dienas un gada formātu kodi

Funkcijas TEXT formāta kodi nav reģistrjutīgi, tāpēc varat izmantot "M" vai "m", "D" vai "d", "Y" vai "y".

Excel MVP Mynda Treacy

Minda iesaka...

Ja koplietojat Excel failus un atskaites ar lietotājiem no dažādām valstīm, iespējams, vēlaties sniegt viņiem atskaiti viņu valodā. Excel MVP balvas ieguvēja Minda Trīsija piedāvā lielisku risinājumu šajā rakstā Excel datumu rādīšana dažādās valodās. Tajā ir iekļauts arī darbgrāmatas paraugs, kuru varat lejupielādēt.

Jūs varat mainīt to, kā tiek rādīts laiks, izmantojot "H" stundu, "M" minūšu, "S" sekunžu un "AM/PM" 12 stundu formāta apzīmēšanai.

Stundu, minūšu un sekunžu laika formāti

Ja izlaidīsiet "AM/PM" vai "A/P", laiks tiks rādīts 24 stundu formātā.

Funkcijas TEXT formāta kodi nav reģistrjutīgi, tāpēc varat izmantot "H" vai "h", "M" vai "m", "S" vai "s", "AM/PM" vai "am/pm".

Jūs varat mainīt to, kā tiek rādītas decimālskaitļu vērtības, ar procentu (%) formātiem.

Procentu formātu kodi

Jūs varat mainīt to, kā tiek rādītas decimālskaitļu vērtības, ar daļskaitļu (?/?) formātiem.

Daļskaitļu formātu kodi

Zinātniskajā pierakstā skaitļi tiek attēloti kā decimālskaitļi no 1 līdz 10, kas reizināti ar 10 kādā pakāpē. To bieži izmanto, lai saīsinātu lielus skaitļus.

Zinātniskā pieraksta formātu kodi

Programmā Excel pieejami 4 īpaši formāti:

  • Pasta indekss — "00000"

  • Pasta indekss + 4 — "00000-0000"

  • Tālruņa numurs — "[<=9999999]###-####;(###) ###-####"

  • Sociālās apdrošināšanas numurs — "000-00-0000"

Funkcijas TEXT speciālie formāti

Īpašie formāti atšķirsies atkarībā no lokalizācijas, taču, ja jūsu lokalizācijā nav īpašu formātu vai arī tie neatbilst jūsu vajadzībām, jūs varat izveidot savus formātus dialoglodziņā Šūnu formatēšana > Pielāgotie.

Bieži sastopams gadījums

Funkciju TEXT reti izmanto atsevišķi, un daudz biežāk — kopā ar ko citu. Pieņemsim, ka vēlaties apvienot tekstu un skaitlisku vērtību, piemēram: “Atskaite drukāta: 03/14/12” vai “Nedēļas ieņēmumi: 66 348,72 EUR”. Jūs varētu šo informāciju ierakstīt programmā Excel manuāli, taču mūsu mērķis ir panākt, ka Excel to paveic jūsu vietā. Diemžēl, apvienojot tekstu un formatētus skaitļus, piemēram, datumu, laiku, valūtu u.tml., Excel nezina, kā vēlaties tos parādīt, un attiecīgi atmet skaitļu formatējumu. Šeit funkcija TEXT ir neatsverama, jo tā jums ļauj likt programmai Excel formatēt vērtības vajadzīgajā veidā, izmantojot formāta kodu, piemēram, "MM/DD/YY" datuma formātam.

Šajā piemērā jūs redzēsit, kas notiek, mēģinot apvienot tekstu un skaitli bez funkcijas TEXT. Šajā gadījumā mēs izmantojam zīmi&, lai savienotu teksta virkni, atstarpi (" ") un vērtību ar =A2&" "&B2.

Teksta apvienošanas piemērs bez funkcijas TEXT

Kā redzams, Excel ir noņēmis šūnā B2 esošā datuma formatējumu. Nākamajā piemērā redzēsit, kā funkcija TEXT ļauj jums attiecināt vajadzīgo formatējumu.

Teksta apvienošanas piemērs, izmantojot funkciju TEXT

Mūsu jaunā formula ir:

  • Šūna C2:=A2&" "&TEXT(B2,"mm/dd/yy") — datuma formāts

Bieži uzdotie jautājumi

Diemžēl to ar funkciju TEXT nevar paveikt; jums jāizmanto Visual Basic for Applications (VBA) kods. Viena metode aprakstīta šeit: Skaitliskas vērtības pārvēršana angļu valodas vārdos ar Excel

Jā, varat izmantot funkcijas UPPER, LOWER un PROPER. Piemēram, funkcijas =UPPER("sveiki") rezultāts būs "SVEIKI".

Jā, bet tad jāveic vairākas darbības. Vispirms atlasiet šūnu vai šūnas, kurās vēlaties to paveikt, un izmantojiet taustiņu kombināciju Ctrl+1, lai atvērtu dialoglodziņu Formāts > Šūnas, tad atveriet sadaļu Līdzinājums > Teksta vadīkla > atzīmējiet opciju Teksta aplaušana. Pēc tam rediģējiet savu pabeigto TEXT funkciju, iekļaujot tajā ASCII funkciju CHAR(10) vietā, kur jābūt rindiņas pārtraukumam. Atkarībā no gala rezultāta līdzinājuma jums, iespējams, būs jāpielāgo kolonnu platums.

Funkcijas TEXT izmantošanas ar CHAR(10) piemērs rindiņas pārtraukuma ievietošanai. ="Šodien ir: "&CHAR(10)&TEXT(TODAY();"dd.mm.yyyy.")

Šajā gadījumā izmantojām: ="Šodien ir: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy")

To sauc par zinātnisko pierakstu, un programma Excel automātiski pārvērš par 12 cipariem garākus skaitļus šūnās, kuru formatējums ir Vispārīgi, un par 15 cipariem garākus skaitļus šūnās, kuru formatējums ir Skaitlis. Ja jums jāievada garas skaitļu virknes, taču nevēlaties, lai tās tiktu pārvērstas, pirms vērtību ievadīšanas vai ielīmēšanas programmā Excel formatējiet attiecīgās šūnas kā Tekstu.

Excel MVP Mynda Treacy

Minda iesaka...

Ja koplietojat Excel failus un atskaites ar lietotājiem no dažādām valstīm, iespējams, vēlaties sniegt viņiem atskaiti viņu valodā. Excel MVP balvas ieguvēja Minda Trīsija piedāvā lielisku risinājumu šajā rakstā Excel datumu rādīšana dažādās valodās. Tajā ir iekļauts arī darbgrāmatas paraugs, kuru varat lejupielādēt.

Skatiet arī

Pielāgota skaitļu formāta izveide vai dzēšana

Skaitļu, kas saglabāti kā teksts, pārvēršana par skaitļiem

Visas Excel funkcijas (pēc kategorijas)

Paplašiniet savas Office prasmes
Iepazīties ar apmācību
Esiet pirmais, kas saņem jaunās iespējas
Pievienoties Office Insider programmai

Vai šī informācija bija noderīga?

Paldies par jūsu atsauksmēm!

Paldies par atsauksmēm! Šķiet, ka varētu būt noderīgi sazināties ar kādu no mūsu Office atbalsta aģentiem.

×