SUM funkcija

Funkcija SUM, viena no matemātikas un trigonometrijas funkcijām, pievieno vērtības. Varat pievienot atsevišķas vērtības, šūnu atsauces vai diapazonus, kā arī visu šo trīs vienumu kombināciju.

Piemērs.

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Jauns uzdevums

Šis video ir daļa no apmācības kursa Skaitļu saskaitīšana programmā Excel 2013.

SUM(skaitlis1,[skaitlis2],...)

Argumenta nosaukums

Apraksts

skaitlis1    (obligāts)

Pirmais skaitlis, ko vēlaties pievienot. Skaitlis var būt, piemēram, 4, šūnas atsauce, piemēram, B6, vai šūna diapazons, piemēram, B2:B8.

skaitlis2-255    (neobligāts)

Tas ir otrs skaitlis, ko vēlaties pievienot. Šādi varat norādīt līdz pat 255 skaitļus.

Ja vēlaties ātri iegūt šūnu diapazona summu, vienkārši atlasiet diapazonu un pievērsiet uzmanību Excel loga apakšējai labajai pusei.

Ekrānuzņēmums ar atlasītu šūnu diapazonu, kur pēc tam tiek meklēts statusa joslā
Statusa josla


Tā ir statusa josla, kurā tiek parādīta informācija par visiem atlasītajiem vienumiem — gan vienu, gan vairākām šūnām. Ja ar peles labo pogu noklikšķināsit uz statusa joslas, tiks parādīts uznirstošais dialoglodziņš, kura atlasei tiks piedāvātas visas opcijas. Ņemiet vērā: dialoglodziņā tiks parādītas arī jūsu atlasītā diapazona vērtības, ja būsit atzīmējis šos atribūtus. Uzziniet vairāk par statusa joslu.

Automātiskās summēšanas vednis ir vieglākais veids, kā darblapai pievienot formulu SUM. Atlasiet tukšu šūnu tieši zem vai virs tā diapazona, ko vēlaties summēt, un lentes sākuma vai formulas cilnēs nospiediet Automātiskā summēšana > Summēt. Automātiskās summēšanas vednis automātiski noteiks summējamo diapazonu un izveidos jums formulu. Tas var darboties arī horizontāli, ja atlasīsit šūnu pa kreisi vai pa labi no summējamā diapazona. Ņemiet vērā, ka šī iespēja nedarbosies attiecībā uz blakus nenovietotiem diapazoniem, bet par to aplūkosim nākamajā sadaļā.

Lai automātiski izveidotu formulu SUM, varat izmantot automātiskās summēšanas vedni.  Atlasiet diapazonu virs/zem vai pa labi/pa kreisi no summējamā diapazona un lentē atveriet formulu cilni, pēc tam atlasiet Automātiskā summēšana un SUM.
Automātiskās summēšanas vedņa izmantošana, lai ātri summētu blakus novietotus diapazonus


Automātiskās summēšanas dialoglodziņā varat arī atlasīt šādas bieži izmantotas funkcijas:

Automātiskā summēšana vertikāli

Šūnā B6 tiek rādīta automātiskās summēšanas formula Sum: =SUM(B2:B5)

Automātiskās summēšanas vednis ir automātiski noteicis šūnas B2:B5 kā summējamo diapazonu. Lai to apstiprinātu, jums ir tikai jānospiež taustiņš Enter. Ja vēlaties pievienot/izslēgt vairāk šūnu, pēc izvēles varat turēt taustiņu Shift > bultiņa, līdz atlase atbilst vēlamajai. Kad tas ir paveikts, nospiediet taustiņu Enter.

IntelliSense funkcijas ceļvedis: SUM(skaitlis1,[skaitlis2], …) peldošais tags zem funkcijas ir IntelliSense ceļvedis. Ja noklikšķinājāt uz SUM vai funkcijas nosaukuma, tā tiks pārveidota par zilu hipersaiti, kas novirzīs uz attiecīgās funkcijas palīdzības tēmu. Ja noklikšķināsit uz atsevišķiem funkcijas elementiem, formulā tiks izceltas attiecīgās daļas. Šajā gadījumā tiks izceltas tikai B2:B5, jo šajā formulā ir tikai viena skaitļa atsauce. IntelliSense tags tiks rādīts ikvienai funkcijai.

Automātiskā summēšana horizontāli

Šūnā D2 tiek rādīta automātiskās summēšanas formula Sum: =SUM(B2:C2)

Funkcijas SUM izmantošana ar blakus nenovietotiem diapazoniem.  Šūnas C8 formula ir =SUM(C2:C3,C5:C6). Varat arī izmantot diapazonus ar nosaukumiem, lai formula būtu =SUM(Nedēļa1,Nedēļa2).

Automātiskās summēšanas vednis darbosies tikai blakus novietotos diapazonos, tāpēc, ja jūsu summas diapazonā ir tukšas rindas vai kolonnas, Excel pārtrauks darbu pie pirmās atstarpes. Šādā gadījumā funkcija SUM ir jāizpilda pēc atlases, kurā pēc kārtas pievienojat atsevišķus diapazonus. Ja šajā piemērā jums būtu dati šūnā B4, Excel ģenerētu =SUM(C2:C6), jo programma būtu atpazinusi blakus novietotu diapazonu.

Varat ātri atlasīt vairākus, blakus nenovietotus diapazonus, izmantojot Ctrl+klikšķis ar peles kreiso pogu. Vispirms ievadiet “=SUM(“, pēc tam atlasiet dažādus diapazonus, un Excel jūsu vietā automātiski starp diapazoniem pievienos komatu atdalītāju. Kad esat pabeidzis, nospiediet taustiņu Enter.

PADOMS. Lai šūnai ātri pievienotu funkciju SUM, varat izmantot taustiņu kombināciju ALT+=. Pēc tam vienkārši atlasiet diapazonu(s).

Piezīme. Iespējams, esat pamanījis, jā programmā Excel dažādi funkciju diapazoni tiek izcelti pēc krāsas, un tie atbilst pašai formulai, tāpēc C2:C3 ir vienā krāsā, bet C5:C6 — citā. Tā Excel rīkosies attiecībā uz visām funkcijām, ja vien atsauces diapazons nebūs citā darblapā vai citā darbgrāmatā. Lai uzlabotai pieejamībai izmantotu palīgtehnoloģiju, varat izmantot Diapazonus ar nosaukumiem, piemēram, “Nedēļa1”, “Nedēļa2” utt. un pēc tam savā formulā izveidot uz tiem atsauci:

=SUM(Week1,Week2)

Varat ērti veikt matemātiskas darbības programmā Excel patstāvīgi un kopā ar tādām Excel funkcijām kā SUM. Tālāk esošajā tabulā norādīti operatori, ko varat izmantot, kā arī dažas saistītas funkcijas. Varat ievadīt operatorus, izmantojot tastatūras skaitļu rindu vai 10 ciparu tastatūru, ja jums tāda pieejama. Piemēram, izmantojot taustiņu kombināciju Shift+8, varat ievadīt zvaigznīti (*) reizināšanai.

Operators

Darbība

Piemēri

+

Saskaitīšana

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Atņemšana

=1-1

= A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Reizināšana

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - Funkcija PRODUCT

/

Dalīšana

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - Funkcija QUOTIENT

^

Kāpināšana

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - Funkcija POWER

Lai iegūtu papildinformāciju, skatiet tēmu Excel kā kalkulatora izmantošana.

Citi piemēri

  1. Pieņemsim, ka summētam šūnu diapazonam vēlaties lietot procentuālu atlaidi.

    Operatoru izmantošana ar SUM.  Formula šūnā B16 ir =SUM(A2:A14)*-25%.  Formula būtu veidota pareizi, ja -25% būtu šūnas atsauce, piemēram, =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Jūs iegūsit 25% no summētā diapazona, tomēr šie 25% tiks iekodēti formulā, bet vēlāk, kad vēlēsities to mainīt, šos 25% varētu būt grūti atrast. Tā vietā labāk ievietojiet 25% šūnā un izveidojiet uz to atsauci: tā šis ieraksts būs vieglāk atrodams un arī maināms:

    • =SUM(A2:A14)*E2

    Ja vēlaties nevis reizināt, bet dalīt, vienkārši aizstājiet “*” ar “/”: =SUM(A2:A14)/E2

  2. Pieskaitīšana funkcijai SUM vai atņemšana no tās

    i. Varat viegli pieskaitīt funkcijai SUM vai atņemt no tās, izmantojot + vai -. Tas notiek šādi:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Šajā sadaļā aplūkosim dažas labākās prakses darbam ar funkciju SUM. Daudz no šīs informācijas var arī izmantot, strādājot ar citām funkcijām.

Metode =1+2 vai =A+B: kaut gan varat ievadīt =1+2+3 vai =A1+B1+C2 un saņemt pilnībā precīzus rezultātus, šajās metodēs bieži tiek konstatētas kļūdas vairāku iemeslu dēļ.

  1. Pārrakstīšanās kļūdas — iedomājieties, ka mēģināt ievadīt vairāk vērtību un/vai lielāku vērtību par šo:

    • =14598.93+65437.90+78496.23

    Pēc tam mēģināt pārbaudīt, vai ievades ir pareizas. Daudz vieglāk ir šīs vērtības ievietot atsevišķās šūnās un izmantot formulu SUM. Papildus varat formatēt vērtības, kad tās ir šūnās, lai pēc ievietošanas formulā tās būtu vieglāk lasāmas.

    Formulās iekodētu vērtību vietā izmantojiet funkciju SUM.  Formula šūnā D5 ir =SUM(D2:D4)
  2. Kļūdas #VALUE! no atsauces teksta (nevis skaitļiem)

    Ja izmantojat šādu formulu:

    • =A1+B1+C1 vai =A1+A2+A3

    Piemērs ar neatbilstoši izveidotu formulu.  Formula šūnā D2 ir =A2+B2+C2

    Formula var pārtraukt darboties, ja atsauces šūnās būs tādas vērtības, kas nav skaitliskas (teksts), tā atgriežot kļūdu #VALUE!. Funkcija SUM ignorēs teksta vērtības un parādīs tikai skaitlisko vērtību summu.

    Pareizu formulu veidošana.  Šūnas D2 formula ir nevis =A2+B2+C2, bet =SUM(A2:C2)
  3. Kļūda #REF!, dzēšot rindas vai kolonnas

    Kļūda #REF!, ko izraisīja kolonnas dzēšana.  Formula ir mainīta uz =A2+#REF!+B2

    Ja izdzēsīsit rindu vai kolonnu, formula netiks atjaunināta, lai izslēgtu izdzēsto rindu, un atgriezīs kļūdu #REF!, kurā automātiski tiks atjaunināta funkcija SUM.

    Funkcija SUM tiks automātiski pielāgota attiecībā uz ievietotajām vai izdzēstajām rindām un kolonnām
  4. Ievietojot rindas vai kolonnas, formulas neatjauninās atsauces

    =A+B+C formulas netiks atjauninātas, ja tiks pievienotas rindas

    Ja ievietosit rindu vai kolonnu, formula netiks atjaunināta, lai iekļautu pievienoto rindu, bet funkcija SUM tiks automātiski atjaunināta (ja vien nebūsit ārpus formulā ar atsauci norādītā diapazona). Tas ir īpaši svarīgi, ja paredzat, ka formula tiks atjaunināta, bet tā nenotiek: šādi varat iegūt nepilnīgus rezultātus, iespējams, to pat nepamanot.

    Piemērā ir parādīta SUM formula, kas automātiski tiek izvērsta no =SUM(A2:C2) uz =SUM(A2:D2), kad tiek ievietota kolonna
  5. SUM ar atsevišķām šūnu atsaucēm salīdzinājumā ar diapazoniem

    Tiek izmantota šāda formula:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Arī šajā formulā tā paša iemesla dēļ bieži tiek konstatētas kļūdas, ievietojot vai dzēšot rindas atsauces diapazonā. Daudz noderīgāk ir izmantot atsevišķus diapazonus, piemēram:

    • =SUM(A1:A3,B1:B3)

    Šajā gadījumā, pievienojot vai dzēšot rindas, notiks atjaunināšana.

  1. SUM varat pilnībā izmantot ar citām funkcijām. Tālāk ir sniegts piemērs, kurā ir izveidots vidējais mēneša aprēķins:

    Funkcijas SUM izmantošana ar citām funkcijām.  Formula šūnā M2 ir =SUM(A2:L2)/COUNTA(A2:L2) .  Piezīme. Lai skats būtu pārskatāmāks, kolonnas Maijs-Novembris ir paslēptas.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Šeit A2:L2 funkcija SUM tiek dalīta ar to A2:L2 esošo šūnu skaitu, kas nav tukšas (laiks no maija līdz decembrim ir tukšs).

  1. Dažreiz var būt nepieciešams summēt kādu konkrētu šūnu vairākās darblapās. Var rasties kārdinājums noklikšķināt katrā vajadzīgajā lapā un šūnā un vienkārši izmantot “+”, lai pievienotu šūnu vērtības, bet tas ir lieks darbs, turklāt var rasties kļūdas.

    • =Lapa1!A1+Lapa2!A1+Lapa3!A1

    Šo darbu var paveikt daudz vieglāk, izmantojot 3D vai 3 dimensiju SUM:

    3D summēšana: formula šūnā D2 ir =SUM(Lapa1:Lapa3!A2)
    • =SUM(Lapa1:Lapa3!A1)

    Ar šo darbību tiek summēta šūna A1 visās lapās no 1. lapas līdz 3. lapai.

    Tas ir īpaši noderīgi gadījumos, kad katram mēnesim ir izveidota atsevišķa lapa (no janvāra līdz decembrim), bet jums dati ir jāsaskaita vienā kopsavilkuma lapā.

    Summēšana ar 3d SUM visās lapās ar nosaukumiem.  Formula šūnā D2 ir =SUM(Janvāris:Decembris!A2)
    • =SUM(Janvāris:Decembris!A2)

    Ar šo darbību katrā lapā tiks summēta šūna A2 no janvāra līdz decembrim.

    Piezīmes : Ja darblapu nosaukumos ir atstarpes, piemēram, “Janvāra apgrozījums”, lapu nosaukumu atsauces veidošanai formulās izmantojiet apostrofu. Ievietojiet apostrofu PIRMS pirmās darblapas nosaukuma un vēlreiz AIZ pēdējā nosaukuma.

    • =SUM(‘Janvāra apgrozījums:Decembra apgrozījums’!A2)

    3D metode darbosies arī ar citām funkcijām, piemēram, AVERAGE, MIN, MAX utt.:

    • =AVERAGE(Lapa1:Lapa3!A1)

    • =MIN(Lapa1:Lapa3!A1)

    • =MAX(Lapa1:Lapa3!A1)

Problēma

Kļūmes iemesls

Mana funkcija SUM rāda #####, bet nerāda rezultātu.

Pārbaudiet kolonnu platumu. ##### parasti nozīmē, ka kolonna ir pārāk šaura un nevar parādīt formulas rezultātu.

Mana funkcija SUM parāda formulu kā tekstu, bet nerāda rezultātu.

Pārbaudiet, vai šūna nav formatēta kā teksts. Atlasiet attiecīgo šūnu vai diapazonu un izmantojiet taustiņu kombināciju Ctrl+1, lai atvērtu šūnu formatēšanas dialoglodziņu, pēc tam noklikšķiniet uz skaitļu cilnes un atlasiet vajadzīgo formulu. Ja šūna tika formatēta kā teksts un pēc formāta maiņas nemainās, iespējams, būs jāizmanto F2 > Enter, lai uzspiestu formāta maiņu.

Mana funkcija SUM netiek atjaunināta.

Pārbaudiet, vai aprēķināšanai ir iestatīta vērtība Automātiski. Formulas cilnē dodieties uz Aprēķina opcijas. Lai darblapā uzspiestu aprēķināšanu, varat arī izmantot taustiņu F9.

Pārbaudiet, vai aprēķināšanai ir iestatīta vērtība Automātiski.  Formulas cilnē dodieties uz Aprēķina opcijas.

Dažas vērtības netiek pieskaitītas.

Funkcijas atsaucē vai diapazonā var saskaitīt tikai skaitliskas vērtības. Tukšās šūnas, loģiskās vērtības, piemēram, TRUE, un teksts tiek ignorēti.

Gaidāmā rezultāta vietā tiek rādīta kļūda #NAME?.

Tas parasti nozīmē nepareizi uzrakstītu formulu, piemēram, =sume(A1:A10) nevis =SUM(A1:A10).

Funkcija SUM rāda veselu skaitli, bet tai jārāda decimālskaitļi

Pārbaudiet šūnu formatējumu, vai tiek attēloti decimālskaitļi. Atlasiet attiecīgo šūnu vai diapazonu un izmantojiet taustiņu kombināciju Ctrl+1, lai atvērtu šūnu formatēšanas dialoglodziņu, pēc tam noklikšķiniet uz skaitļu cilnes un atlasiet vajadzīgo formātu, lai norādītu nepieciešamo decimāldaļu skaitu.

  1. Vienkārši vēlos pieskaitīt/atņemt/reizināt/dalīt skaitļus: noskatieties šos videoklipus Vienkāršas matemātiskas darbības programmā Excel vai Excel kā kalkulatora izmantošana.

  2. Kā parādīt vairāk/mazāk zīmju aiz komata?: varat mainīt skaitļa formātu. Atlasiet attiecīgo šūnu vai diapazonu un izmantojiet taustiņu kombināciju Ctrl+1, lai atvērtu šūnu formatēšanas dialoglodziņu, pēc tam noklikšķiniet uz skaitļu cilnes un atlasiet vajadzīgo formātu, lai norādītu nepieciešamo decimāldaļu skaitu.

  3. Kā pievienot vai atņemt laiku? Varat pievienot un atņemt laiku dažādos veidos. Piemēram, lai iegūtu starpību starp 8:00 - 12:00 algu aprēķināšanas vajadzībām, varat izmantot: = ("12:00"-"8:00")*24, atņemot sākuma laiku no beigu laika. Ņemiet vērā, ka programma Excel aprēķina laiku kā dienas daļu, tāpēc ir jāreizina ar 24, lai iegūtu kopējo stundu skaitu. Pirmajā piemērā mēs izmantojam =((B2-A2)+(D2-C2))*24, lai iegūtu stundu skaitu no sākuma līdz beigām, nevis pusdienu pārtraukumu (kopā 8,5 stundas).

    Ja vienkārši pievienojat stundas un minūtes un vēlaties šādu attēlojumu, varat saskaitīt, nereizinot ar 24, tāpēc otrajā piemērā izmantojam =SUM(A6:C6), tā kā nepieciešams kopējais stundu un minūšu skaits piešķirtajiem uzdevumiem (5:36 vai 5 stundas, 36 minūtes).

    Laiku aprēķināšana

    Papildinformāciju skatiet rakstā: Laika saskaitīšana un atņemšana.

  4. Kā iegūt starpību starp datumiem? Tāpat kā ar laiku, varat arī pieskaitīt un atņemt datumus. Lūk, bieži sastopams piemērs par to, kā saskaitīt dienu skaitu starp diviem datumiem. Tas ir vienkārši: =B2-A2. Noslēpums darbā ar datumiem un laikiem ir šāds: jūs sākat ar beigu datumu/laiku un atņemat sākuma datumu/laiku.

    Datumu starpību aprēķināšana

    Lai uzzinātu citus veidus darbam ar datumiem, skatiet rakstu Dienu skaita aprēķināšana starp diviem datumiem.

  5. Kā saskaitīt tikai redzamās šūnas? Reizēm, kad manuāli paslēpjat rindas vai izmantojat automātisko filtru, lai attēlotu tikai konkrētus datus, vēlaties arī saskaitīt redzamās šūnas. Varat izmantot funkciju SUBTOTAL. Ja izmantojat kopsummas rindu Excel tabulā, jebkura funkcija, ko atlasāt kopsummas nolaižamajā lodziņā, tiks automātiski ievadīta kā starpsumma. Skatiet papildinformāciju par to, kā iegūt Excel tabulas datu kopsummu.

Vai nepieciešama papildu palīdzība?

Vienmēr varat pajautāt speciālistiem Excel Tech kopienā, saņemt atbalstu Answers kopienā vai ieteikt jaunu līdzekli vai uzlabojumu vietnē Excel User Voice.

Skatiet arī

Noskatieties video, lai uzzinātu, kā izmantot funkciju SUM

Funkcija SUMIF pievieno tikai tās vērtības, kas atbilst vienam kritērijam

Funkcija SUMIFS pievieno tikai tās vērtības, kas atbilst vairākiem kritērijiem

Funkcija COUNTIF saskaita tikai tās vērtības, kas atbilst vienam kritērijam

Funkcija COUNTIFS saskaita tikai tās vērtības, kas atbilst vairākiem kritērijiem

Pārskats par formulām programmā Excel

Kā nepieļaut kļūdainas formulas

Kļūdu atrašana un izlabošana formulās

Īsinājumtaustiņi programmā Excel darbam ar Windows

Īsinājumtaustiņi programmā Excel darbam ar Mac

Matemātikas un trigonometrijas funkcijas

Excel funkciju saraksts (pēc alfabēta)

Excel funkciju saraksts (pēc kategorijas)

Paplašiniet savas prasmes
Iepazīties ar apmācību
Esiet pirmais, kas saņem jaunās iespējas
Pievienoties Office Insider programmai

Vai šī informācija bija noderīga?

Paldies par jūsu atsauksmēm!

Paldies par atsauksmēm! Šķiet, ka varētu būt noderīgi sazināties ar kādu no mūsu Office atbalsta aģentiem.

×