Rekvizīts PrtDevMode

Attiecas uz

Objekts Form

Objekts Report

Varat izmantot rekvizītu PrtDevMode, lai iestatītu vai atgrieztu drukāšanas ierīces režīma informāciju, kas norādīta formai vai atskaitei dialoglodziņā Drukāšana. Lasāms/rakstāms Variant.

expression.PrtDevMode

expression Required. Izteiksme, kas atgriež vienu no objektiem sarakstā Attiecas uz.

Piezīmes

Ir stingri ieteicams skatīt Win32 programmatūras izstrādes komplektā pieejamo pilno dokumentāciju par rekvizītiem PrtDevMode, PrtDevNames un PrtMip.

Rekvizīta PrtDevMode iestatījums ir 94 baitu struktūra, kas atbilst Win32 programmatūras izstrādes komplektā definētajai struktūrai DEVMODE. Pilnu informāciju par rekvizīta PrtDevMode elementiem skatiet Win32 programmatūras izstrādes komplektā.

Rekvizīts PrtDevMode izmanto tālāk norādītos elementus.

Elements

Apraksts

DeviceName

Ne vairāk kā 32 baitus gara virkne, kas norāda tās ierīces nosaukumu, ko atbalsta draiveris. Piemērs, ja norādītais printeris ir Hewlett-Packard LaserJet IIISi: “HP LaserJet IIISi”. Katram printera draiverim ir unikāla virkne.

SpecVersion

Vesels skaitlis, kas norāda struktūras DEVMODE versijas numuru Win32 programmatūras izstrādes komplektā.

DriverVersion

Vesels skaitlis, kas norāda printera draivera izstrādātāja piešķirto printera draivera versijas numuru.

Size

Vesels skaitlis, kas norāda struktūras DEVMODE lielumu baitos. (Šī vērtība neietver neobligāto elementu dmDriverData konkrētas ierīces datiem, kas var būt norādīti pēc šīs struktūras.) Ja lietojumprogramma manipulē tikai ar to datu daļu, kas ir neatkarīga no draivera, varat izmantot šo elementu, lai uzzinātu šīs struktūras garumu, neņemot vērā dažādas versijas.

DriverExtra

Vesels skaitlis, kas norāda neobligātā elementa dmDriverData lielumu baitos konkrētas ierīces datiem, kas var būt norādīti pēc šīs struktūras. Ja lietojumprogramma neizmanto konkrētas ierīces informāciju, šis elements ir jāiestata pozīcijā 0.

Fields

Garā vērtība, kas norāda, kuri struktūras DEVMODE atlikušie elementi ir inicializēti.

Orientation

Vesels skaitlis, kas norāda papīra orientāciju. Tas var būt 1 (portrets) vai 2 (ainava).

PaperSize

Vesels skaitlis, kas norāda papīra lielumu. Ja šim elementam iestatīsit vērtību 0 vai 256, papīra garumu un platumu norādīs attiecīgi elementi PaperLength un PaperWidth. Varat arī iestatīt iepriekš definētu vērtību elementam PaperSize.

PaperLength

Vesels skaitlis, kas norāda papīra garumu milimetra desmitdaļās. Šis elements ignorē elementa PaperSize norādīto papīra garumu, ja izmantojat pielāgotu papīra izmēru vai tādas ierīces kā punktu matricas printerus, kas var drukāt uz dažāda izmēra papīra.

PaperWidth

Vesels skaitlis, kas norāda papīra platumu milimetra desmitdaļās. Šis elements ignorē elementa PaperSize norādīto papīra platumu.

Scale

Vesels skaitlis, kas norāda faktoru, pēc kura tiks mērogots izdrukātais materiāls. Redzamais papīra izmērs tiks mērogots no fiziskā papīra izmēra, izmantojot faktoru mērogs/100. Piemēram, papīra lapa ar izmēru 8,5x11 collas (vēstule) ar mēroga vērtību 50 ietvers tikpat daudz datu kā lapa ar izmēru 17x22 collas, jo izvades teksta un grafiku augstums un platums būs divreiz mazāks par sākotnējo.

Copies

Vesels skaitlis, kas norāda drukājamo kopiju skaitu, ja drukāšanas ierīce atbalsta vairāku lappušu kopijas.

DefaultSource

Vesels skaitlis, kas norāda noklusējuma tvertni, no kuras tiek padots papīrs.

PrintQuality

Vesels skaitlis, kas norāda printera izšķirtspēju. Vērtības ir –4 (augsta), –3 (vidēja), –2 (zema) un –1 (melnraksts).

Color

Vesels skaitlis. Krāsu printerim norāda, vai ir jādrukā krāsains materiāls. Vērtības ir 1 (krāsains) un 2 (vienkrāsas).

Duplex

Vesels skaitlis. Printerim ar abpusējās drukāšanas funkciju norāda, vai izvade tiek drukāta uz abām papīra pusēm. Vērtības ir 1 (simplekss), 2 (horizontāli), un 3 (vertikāli).

YResolution

Vesels skaitlis, kas norāda printera y izšķirtspēju punktos collā (dots per inch — dpi). Ja printeris inicializē šo elementu, tad elements PrintQuality norāda printera x izšķirtspēju punktos collā.

TTOption

Vesels skaitlis, kas norāda, kā tiks izdrukāti TrueType fonti.

Collate

Vesels skaitlis, kas norāda, vai, drukājot vairākas kopijas, jāizmanto komplektēšana. Nekomplektētu kopiju izmantošana nodrošina ātrāku un efektīvāku izvadi, jo dati tiek nosūtīti printerim tikai vienreiz.

FormName

Ne vairāk kā 16 rakstzīmes gara virkne, kas norāda izmantojamā papīra izmēru, piemēram, “Vēstule” vai “Juridisks dokuments”.

Pad

Garā vērtība, kas tiek izmantota, lai paplašinātu atstarpes, rakstzīmes vai vērtības turpmākām versijām.

Bits

Garā vērtība, kas norāda displeja ierīces krāsu izšķirtspēju bitos uz vienu pikseli.

PW

Garā vērtība, kas norāda redzamās ierīces virsmas (ekrāna vai printera) platumu pikseļos.

PH

Garā vērtība, kas norāda redzamās ierīces virsmas (ekrāna vai printera) augstumu pikseļos.

DFI

Garā vērtība, kas norāda ierīces rādīšanas režīmu.

DFR

Garā vērtība, kas norāda displeja ierīces frekvenci hercos (ciklos sekundē) konkrētā režīmā.


Piezīme : Varat iestatīt rekvizītu PrtDevMode, izmantojot Visual Basic for Applications (VBA) kodu.

Šis rekvizīta iestatījums ir lasāms/rakstāms noformējuma skatā vai izkārtojuma skatā un tikai lasāms citos skatos.

Printeru draiveri var pievienot konkrētas ierīces datus uzreiz pēc struktūras DEVMODE 94 baitiem. Šī iemesla dēļ ir būtiski gādāt, lai iepriekš aprakstītie DEVMODE dati nepārsniegtu 94 baitus.

Struktūru DEVMODE izmanto tikai tie printeru draiveri, kas eksportē funkciju ExtDeviceMode.

Lietojumprogramma var izgūt printera atbalstītos papīra izmērus un nosaukumus, izmantojot vērtības DC_PAPERS, DC_PAPERSIZE un DC_PAPERNAMES, lai izsauktu funkciju DeviceCapabilities.

Pirms elementa TTOption vērtības iestatīšanas lietojumprogrammām ir jāuzzina, kā printera draiveris var izmantot TrueType fontus. Lai to paveiktu, jāizmanto vērtība DC_TRUETYPE un jāizsauc funkcija DeviceCapabilities.

Piemērs

Tālāk sniegtajā piemērā rekvizīts PrtDevMode tiek izmantots, lai pārbaudītu lietotāja definētu lappuses izmēru atskaitē.

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

Tālāk sniegtajā piemērā parādīts, kā mainīt atskaites orientāciju. Šajā piemērā orientācija tiks mainīta no portreta uz ainavu vai no ainavas uz portretu atkarībā no atskaites pašreizējās orientācijas.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
Paplašiniet savas prasmes
Iepazīties ar apmācību
Esiet pirmais, kas saņem jaunās iespējas
Pievienoties Office Insider programmai

Vai šī informācija bija noderīga?

Paldies par jūsu atsauksmēm!

Paldies par atsauksmēm! Šķiet, ka varētu būt noderīgi sazināties ar kādu no mūsu Office atbalsta aģentiem.

×