Divu datumu starpības aprēķināšana

Divu datumu starpības aprēķināšana

Ja vēlaties aprēķināt starpību starp diviem datumiem, izmantojiet funkciju DATEDIF. Vispirms šūnā ievadiet sākuma datumu un pēc tam citā beigu datumu. Pēc tam ierakstiet formulu, piemēram, kādu no tālāk norādītajām.

Starpība dienās

=DATEDIF(D9,E9,"d") ar rezultātu 856

Šajā piemērā sākuma datums ir šūnā D9 un beigu datums ir E9. Formula ir šūnā F9. “d” atgriež pilno dienu skaitu starp abiem datumiem.

Starpība nedēļās

=(DATEDIF(D13,E13,"d")/7) un rezultāts: 122.29

Šajā piemērā sākuma datums ir šūnā D13 un beigu datums ir E13. “d” atgriež dienu skaitu. Tomēr ievērojiet /7 beigās. Tas dienu skaitu dala ar 7, jo nedēļā ir 7 dienas. Ņemiet vērā, ka šis rezultāts ir arī jāformatē kā skaitlis. Nospiediet taustiņu kombināciju CTRL + 1. Pēc tam noklikšķiniet uz Skaitlis > Decimāldaļu vietas: 2.

Starpība mēnešos

=DATEDIF(D5,E5,"m") un rezultāts: 28

Šajā piemērā sākuma datums ir šūnā D5 un beigu datums ir E5. Formulā “m” atgriež pilno mēnešu skaitu starp abām dienām.

Starpība gados

=DATEDIF(D2,E2,"y") un rezultāts: 2

Šajā piemērā sākuma datums ir šūnā D2 un beigu datums ir E2. “y” atgriež pilno gadu skaitu starp abām dienām.

Vecuma aprēķināšana uzkrātajos gados, mēnešos un dienās

Var arī aprēķināt vecumu vai kādas personas stāžu. Rezultāts var būt, piemēram, “2 gadi, 4 mēneši, 5 dienas”.

1. Izmantojiet DATEDIF, lai atrastu gadu kopskaitu.

=DATEDIF(D17,E17,"y") un rezultāts: 2

Šajā piemērā sākuma datums ir šūnā D17 un beigu datums ir E17. Formulā “y” atgriež pilno gadu skaitu starp abām dienām.

2. Izmantojiet DATEDIF vēlreiz ar “ym”, lai atrastu mēnešus.

=DATEDIF(D17,E17,"ym") un rezultāts: 4

Citā šūnā izmantojiet formulu DATEDIF ar parametru “ym”. “ym” atgriež atlikušo mēnešu skaitu, kas pārsniedz pēdējo pilno gadu.

3. Izmantojiet citu formulu, lai atrastu dienas.

=DATEDIF(D17,E17,"md") un rezultāts: 5

Tagad mums ir jāatrod atlikušo dienu skaits. Mēs to izdarīsim, rakstot cita veida formulu, kas parādīta iepriekš. Šī formula atņem beigu mēneša pirmo dienu (5/1/2016) no sākotnējā beigu datuma šūnā E17 (5/6/2016). Lūk, kā tas tiek darīts: Vispirms funkcija DATE izveido datumu, 5/1/2016. Tā to izveido, izmantojot gadu šūnā E17 un mēnesi šūnā E17. Pēc tam 1 atspoguļo pirmo attiecīgā mēneša dienu. Funkcijas DATE rezultāts ir 5/1/2016. Pēc tam mēs to atņemam no sākotnējā beigu datuma šūnā E17, kas ir 5/6/2016. 5/6/2016 mīnus 5/1/2016 ir 5 dienas.

Piezīme : Neiesakām izmantot DATEDIF “md” argumentu, jo tas var aprēķināt neprecīzus rezultātus.

4. Neobligāti: Apvienojiet trīs formulas vienā.

=DATEDIF(D17,E17,"y")&" gadi, "&DATEDIF(D17,E17,"ym")&" mēneši, "&DATEDIF(D17,E17,"md")&" dienas" un rezultāts: 2 gadi, 4 mēneši, 5 dienas

Varat visus trīs aprēķinus ievietot vienā šūnā kā šajā piemērā. Izmantojiet & zīmes, pēdiņas un tekstu. Tāda formula ir garāka, bet vismaz viss ir vienuviet. Padoms. Nospiediet taustiņu kombināciju ALT + ENTER, lai formulā ievietotu rindiņu pārtraukumus. Tas atvieglo lasīšanu. Nospiediet arī taustiņu kombināciju CTRL+SHIFT+U, ja nav redzama visa formula.

Lejupielādējiet mūsu piemērus

Varat lejupielādēt parauga darbgrāmatu ar visiem šajā rakstā sniegtajiem piemēriem. Varat sekot līdzi vai izveidot savas formulas.

Lejupielādēt datumu aprēķinu piemērus

Citi datuma un laika aprēķini

Kā redzējāt iepriekš, funkcija DATEDIF aprēķina sākuma un beigu datumu starpību. Tomēr tā vietā, lai ierakstītu konkrētus datumus, var arī lietot funkciju TODAY() formulā. Ja izmantojat funkciju TODAY(), Excel datumam izmanto datora pašreizējo datumu. Ņemiet vērā, ka tas mainīsies, kad fails tiks atvērts vēlreiz citā dienā nākotnē.

=DATEDIF(TODAY(),D28,"y") un rezultāts: 984

Lūdzu, ņemiet vērā, ka šīs informācijas rakstīšanas laikā datums bija 2016. gada 6. oktobris.

Ja vēlaties aprēķināt darbdienu skaitu starp diviem datumiem, izmantojiet funkciju NETWORKDAYS.INTL. Varat arī tai likt izslēgt brīvdienas un svētku dienas.

Pirms darba sākšanas: Izlemiet, vai vēlaties izslēgt brīvdienu datumus. Ja vēlaties, ierakstiet brīvdienu datumu sarakstu atsevišķā apgabalā vai lapā. Ievietojiet katru brīvdienu datumu atsevišķā šūnā. Pēc tam atlasiet šīs šūnas, atlasiet Formulas > Definēt nosaukumu. Piešķiriet diapazonam nosaukumu Manas_brīvdienas un noklikšķiniet uz Labi. Pēc tam izveidojiet formulu, izmantojot tālāk norādītās darbības.

1. Ierakstiet sākuma un beigu datumu.

Sākuma datums šūnā D53 ir 1/1/2016, beigu datums ir šūnā E53: 12/31/2016

Šajā piemērā sākuma datums ir šūnā D53 un beigu datums ir šūnā E53.

2. Citā šūnā ierakstiet šādu formulu:

=NETWORKDAYS.INTL(D53,E53,1) un rezultāts: 261

Ierakstiet formulu, kas līdzīga iepriekšējā piemērā esošajai. 1 formulā nosaka sestdienas un svētdienas kā brīvdienas un izslēdz tās no kopsummas.

Piezīme. Programmā Excel 2007 nav funkcijas NETWORKDAYS.INTL. Tomēr tajā ir NETWORKDAYS. Iepriekš esošais piemērs programmā Excel 2007 būtu šāds: =NETWORKDAYS(D53,E53). Jums nav jānorāda 1, jo NETWORKDAYS pieņem, ka nedēļas nogale ir sestdienā un svētdienā.

3. Ja nepieciešams, mainiet 1.

Intellisense saraksts, kur tiek rādīts 2 — svētdiena, pirmdiena; 3 — pirmdiena, otrdiena utt.

Ja jums sestdiena un svētdiena nav brīvdienas, mainiet 1 uz citu skaitli no IntelliSense saraksta. Piemēram, 2 nosaka svētdienas un pirmdienas kā brīvdienas.

Ja izmantojat Excel 2007, izlaidiet šo soli. Excel 2007 funkcija NETWORKDAYS vienmēr pieņem, ka nedēļas nogale ir sestdienā un svētdienā.

4. Ierakstiet brīvdienu diapazona nosaukumu.

=NETWORKDAYS.INTL(D53,E53,1,Manas_brīvdienas) un rezultāts: 252

Ja esat izveidojis brīvdienu diapazona nosaukumu iepriekš esošajā sadaļā “Pirms darba sākšanas”, ierakstiet to beigās šādi. Ja jums nav brīvdienu, varat neiekļaut komatu un Manas_brīvdienas. Ja izmantojat Excel 2007, iepriekš norādītais piemērs būtu šāds: =NETWORKDAYS(D53,E53,Manas_brīvdienas).

Padoms. Ja nevēlaties veidot atsauci uz brīvdienu diapazona nosaukumu, varat arī ierakstīt diapazonu, piemēram, D35:E:39. Varat arī ierakstīt katru brīvdienu formulā. Piemēram, ja jūsu brīvdienas bija 2016. gada 1. un 2. janvārī, ierakstiet tās šādi: =NETWORKDAYS.INTL(D53,E53,1,{"1/1/2016","1/2/2016"}). Programmā Excel 2007 tas izskatītos šādi: =NETWORKDAYS(D53,E53,{"1/1/2016","1/2/2016"})

Pagājušo laiku var aprēķināt, atņemot vienu laiku no otra. Vispirms šūnā ievadiet sākuma laiku un pēc tam citā beigu laiku. Noteikti ierakstiet pilnu laiku, iekļaujot stundu, minūtes un atstarpi pirms AM vai PM. Lūk, kā:

1. Ierakstiet sākuma un beigu laiku.

Sākuma datums/laiks: 7:15 AM, beigu datums/laiks: 4:30 PM

Šajā piemērā sākuma laiks ir šūnā D80 un beigu laiks ir E80. Noteikti ierakstiet stundu, minūti un atstarpi pirms AM vai PM.

2. Iestatiet h:mm AM/PM formātu.

Dialoglodziņš Šūnu formatēšana, Komanda Pielāgots, h:mm AM/PM tips

Atlasiet abus datumus un nospiediet taustiņu kombināciju CTRL + 1 (vai Attēls ar MAC komandpogas ikonu + 1 Mac datorā). Noteikti atlasiet opciju Pielāgots > h:mm AM/PM, ja tā vēl nav iestatīta.

3. Atņemiet abus laikus.

=E80-D80 un rezultāts: 9:15 AM

Citā šūnā atņemiet sākuma laika šūnu no beigu laika šūnas.

4. Iestatiet h:mm formātu.

Dialogs Šūnu formatēšana, Komanda Pielāgots, h:mm tips

Nospiediet taustiņu kombināciju CTRL + 1 (vai Attēls ar MAC komandpogas ikonu + 1 Mac datorā). Izvēlieties Pielāgots > h:mm, lai rezultātā nebūtu AM un PM.

Lai aprēķinātu laiku starp diviem datumiem un laikiem, varat vienkārši atņemt vienu no otra. Tomēr jums ir jālieto formatējums katrai šūnai, lai nodrošinātu, ka programma Excel atgriež vēlamo rezultātu.

1. Ierakstiet divus pilnus datumus un laikus.

Sākuma datums: 1/1/16 1:00 PM; beigu datums: 1/2/16 2:00 PM

Vienā šūnā ierakstiet pilnu sākuma datumu/laiku. Un citā šūnā ierakstiet pilnu beigu datumu/laiku. Katrā šūnā ir jābūt mēnesim, dienai, gadam, stundai, minūtei un atstarpei pirms AM vai PM.

2. Iestatiet formātu 3/14/12 1:30 PM.

Dialogs Šūnu formatēšana, komanda Datums, 3/14/12 1:30 PM tips

Atlasiet abas šūnas un pēc tam nospiediet taustiņu kombināciju CTRL + 1 (vai Attēls ar MAC komandpogas ikonu + 1 Mac datorā). Pēc tam atlasiet Datums > 3/14/12 1:30 PM. Tas nav datums, kas jāiestata, vienkārši piemērs, kā formāts izskatīsies. Ņemiet vērā, ka versijās pirms Excel 2016 šim formātam var būt atšķirīgs parauga datums, piemēram, 3/14/01 1:30 PM.

3. Atņemiet abus.

=E84-D84 un rezultāts: 1.041666667

Citā šūnā atņemiet sākuma datumu/laiku no beigu datuma/laika. Rezultāts droši vien izskatīsies kā skaitlis un decimāldaļa. To labosit nākamajā darbībā.

4. Iestatiet [h]:mm formātu.

Dialogs Šūnu formatēšana, Komanda Pielāgots, [h]:mm tips

Nospiediet taustiņu kombināciju CTRL + 1 (vai Attēls ar MAC komandpogas ikonu + 1 Mac datorā). Atlasiet Pielāgots. Lodziņā Tips ierakstiet [h]:mm.

Skatiet arī

Funkcija DATEDIF

Funkcija NETWORKDAYS.INTL

NETWORKDAYS

Citas datuma un laika funkcijas

Starpības starp diviem laikiem aprēķināšana

Paplašiniet savas prasmes
Iepazīties ar apmācību
Esiet pirmais, kas saņem jaunās iespējas
Pievienoties Office Insider programmai

Vai šī informācija bija noderīga?

Paldies par jūsu atsauksmēm!

Paldies par atsauksmēm! Šķiet, ka varētu būt noderīgi sazināties ar kādu no mūsu Office atbalsta aģentiem.

×