Bieži izmantoto formulu piemēri

Svarīgi!:  Šis raksts ir mašīntulkots, skatiet atrunu. Lūdzu, skatiet šī raksta versiju angļu valodā šeit jūsu informācijai.

Šos piemērus var izmantot aprēķinātās saraksta vai bibliotēkas kolonnās. Piemērus, kuros nav kolonnu references, var izmantot, lai norādītu kolonnas noklusēto vērtību.

Šajā rakstā

Nosacījuma formulu

Datuma un laika formulas

Matemātiskās formulas

Teksta formulas

Nosacījuma formulas

Šīs formulas var izmantot, lai pārbaudītu paziņojuma nosacījumu un saņemtu vērtību “Jā” vai “Nē”, lai pārbaudītu alternatīvu vērtību, piem., “Labi” vai “Nav labi”, vai lai saņemtu tukšumu vai domuzīmi, kas norāda nulles vērtību.

Pārbaude, vai skaitlis ir lielāks vai mazāks par citu skaitli

Lai veiktu šo salīdzināšanu, izmantojiet funkciju IF.

Kolonna1

Kolonna2

Formula

Apraksts (iespējamais rezultāts)

15000

9000

=[Kolonna1]>[Kolonna2]

Vai Kolonna1 ir lielāka par Kolonna2? (Jā)

15000

9000

=IF([Kolonna1]<=[Kolonna2], “Labi”, “Nav labi”)

Vai Kolonna1 ir mazāka vai vienāda ar Kolonna2? (Nav labi)

Atgriež loģisko vērtību pēc salīdzināšanas kolonnu saturs

Loģiskas vērtības rezultātam (Jā vai Nē) lietojiet funkcijas AND, OR un NOT.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (iespējamais rezultāts)

15

9

8

=AND([Kolonna1]>[Kolonna2], [Kolonna1]<[Kolonna3])

Vai 15 ir lielāks nekā 9 un mazāks nekā 8? (Nē)

15

9

8

=OR([Kolonna1]>[Kolonna2], [Kolonna1]<[Kolonna3])

Vai 15 ir liekāks nekā 9 vai mazāks nekā 8? (Jā)

15

9

8

=NOT([Kolonna1]+[Kolonna2]=24)

Vai 15 plus 9 nav vienāds ar 24? (Nē)

Cita aprēķina rezultātam vai jebkurai citai vērtībai, kas nav Jā vai Nē, lietojiet funkcijas IF, AND un OR.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (iespējamais rezultāts)

15

9

8

=IF([Kolonna1]=15, “Labi”, “Nav labi”)

Ja Kolonna1 vērtība ir vienāda ar 15, tiek atgriezts “Labi”. (Labi)

15

9

8

=IF(AND([Kolonna1]>[Kolonna2], [Kolonna1]<[Kolonna3]), “Labi”, “Nav labi”)

Ja 15 ir lielāks nekā 9 un mazāks nekā 8, tiek atgriezts “Labi”. (Nav labi)

15

9

8

=IF(OR([Kolonna1]>[Kolonna2], [Kolonna1]<[Kolonna3]), “Labi”, “Nav labi”)

Ja 15 ir liekāks nekā 9 vai mazāks nekā 8, tiek atgriezts “Labi”. (Labi)

Rādīt nulles kā tukšumus vai domuzīmes

Lai rādītu nulli, veiciet vienkāršu aprēķinu. Lai rādītu tukšumu vai domuzīmi, lietojiet funkciju IF.

C olumn1

Kolonna2

Formula

Apraksts (iespējamais rezultāts)

10

10

=[Kolonna1]-[Kolonna2]

Otrs skaitlis tiek atņemts no pirmā skaitļa (0)

15

9

=IF([Kolonna1]-[Kolonna2],“-”,[Kolonna1]-[Kolonna2])

Ja vērtība ir nulle, tiek atgriezta domuzīme (-)

Paslēpiet kļūdu vērtības kolonnās

Lai kļūdainas vērtības vietā parādītu domuzīmi, #N/A vai NA, lietojiet funkciju ISERROR.

Kolonna1

Kolonna2

Formula

Apraksts (iespējamais rezultāts)

10

0

=[Kolonna1]/[Kolonna2]

Rezultātā ir radusies kļūda (#DIV/0)

10

0

=IF(ISERROR([Kolonna1]/[Kolonna2]),“NA”,[Kolonna1]/[Kolonna2])

Ja vērtība ir kļūdaina, tiek atgriezta vērtība NA

10

0

=IF(ISERROR([Kolonna1]/[Kolonna2]),“-”,[Kolonna1]/[Kolonna2])

Ja vērtība ir kļūdaina, tiek atgriezta vērtība NA

Uz lapas sākumu

Datuma un laika formulas

Šīs formulas var izmantot, lai veiktu ar datumu un laiku saistītus aprēķinus, piem., pievienotu dienu, mēnešu vai gadu skaitu datumam, aprēķinātu atšķirību starp diviem datumiem un konvertētu datumu par decimālskaitļa vērtību.

Datumu pieskaitīšanas

Lai datumam pievienotu dienu skaitu, lietojiet papildu operatoru (+).

Piezīme.: Ja veicat darbības ar datumiem, aprēķinātās kolonnas atgriešanas tipam ir jābūt iestatītam uz Datums un laiks.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

9.6.2007.

3

=[Kolonna1]+[Kolonna2]

Pievieno 3 dienas datumam 6/9/2007 (6/12/2007)

12/10/2008

54

=[Kolonna1]+[Kolonna2]

Pievieno 54 dienas datumam 12/10/2008 (2/2/2009)

Lai datumam pievienotu mēnešu skaitu, lietojiet funkcijas DATE, YEAR, MONTH un DAY.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

9.6.2007.

3

=DATE(YEAR([Kolonna1]),MONTH([Kolonna1])+[Kolonna2],DAY([Kolonna1]))

Pievieno 3 mēnešus datumam 6/9/2007 (9/9/2007)

12/10/2008

25

=DATE(YEAR([Kolonna1]),MONTH([Kolonna1])+[Kolonna2],DAY([Kolonna1]))

Pievieno 25 mēnešus datumam 12/10/2008 (1/10/2011)

Lai datumam pievienotu gadu skaitu, lietojiet funkcijas DATE, YEAR, MONTH un DAY.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

9.6.2007.

3

=DATE(YEAR([Kolonna1])+[Kolonna2],MONTH([Kolonna1]),DAY([Kolonna1]))

Pievieno 3 gadus datumam 6/9/2007 (6/9/2010)

12/10/2008

25

=DATE(YEAR([Kolonna1])+[Kolonna2],MONTH([Kolonna1]),DAY([Kolonna1]))

Pievieno 25 gadus datumam 12/10/2008 (12/10/2033)

Lai datumam pievienotu dienu, mēnešu un gadu kombināciju, lietojiet funkcijas DATE, YEAR, MONTH un DAY.

Kolonna1

Formula

Apraksts (rezultāts)

6/9/2007

=DATE(YEAR([Kolonna1])+3,MONTH([Kolonna1])+1,DAY([Kolonna1])+5)

Pievieno 3 gadus, 1 mēnesi un 5 dienas datumam 6/9/2007 (7/14/2010)

12/10/2008

=DATE(YEAR([Kolonna1])+1,MONTH([Kolonna1])+7,DAY([Kolonna1])+5)

Pievieno 1 gadu, 7 mēnešus un 5 dienas datumam 12/10/2008 (7/15/2010)

Divu datumu starpības aprēķināšana

Lai veiktu šo aprēķinu, izmantojiet funkciju DATEDIF.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

01-Jan-1995

15-Jun-1999

=DATEDIF([Kolonna1], [Kolonna2],“d”)

Atgriež dienu skaitu starp abiem datumiem (1626)

01-Jan-1995

15-Jun-1999

=DATEDIF([Kolonna1], [Kolonna2],“ym”)

Atgriež mēnešu skaitu starp abiem datumiem, ignorējot gadus (5)

01-Jan-1995

15-Jun-1999

=DATEDIF([Kolonna1], [Kolonna2],“yd”)

Atgriež dienu skaitu starp datumiem, ignorējot gadus (165)

Divas reizes starpības aprēķināšana

Lai rezultātu rādītu standarta laika formātā (stundas:minūtes:sekundes), lietojiet atņemšanas operatoru (-) un funkciju TEXT. Lai šī metode darbotos, stundas nedrīkst pārsniegt 24 un minūtes un sekundes nedrīkst pārsniegt 60.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

06/09/2007 10:35 AM

06/09/2007 3:30 PM

=TEXT([Kolonna2]-[Kolonna1],“h”)

Stundas starp diviem laikiem (4)

06/09/2007 10:35 AM

06/09/2007 3:30 PM

=TEXT([Kolonna2]-[Kolonna1],“h:mm”)

Stundas un minūtes starp diviem laikiem (4:55)

06/09/2007 10:35 AM

06/09/2007 3:30 PM

=TEXT([Kolonna2]-[Kolonna1],“h:mm:ss”)

Stundas, minūtes un sekundes starp diviem laikiem (4:55:00)

Lai rādītu kopējo rezultātu, kas ir balstīts uz vienu laika vienību, lietojiet funkciju INT vai funkcijas HOUR, MINUTE vai SECOND.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=INT(([Kolonna2]-[Kolonna1])*24)

Kopējais stundu skaits starp diviem laikiem (28)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=INT(([Kolonna2]-[Kolonna1])*1440)

Kopējais minūšu skaits starp diviem laikiem (1735)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=INT(([Kolonna2]-[Kolonna1])*86400)

Kopējais sekunžu skaits starp diviem laikiem (104100)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=HOUR([Kolonna2]-[Kolonna1])

Stundu skaits starp diviem laikiem, ja atšķirība nepārsniedz 24 (4)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=MINUTE([Kolonna2]-[Kolonna1])

Minūšu skaits starp diviem laikiem, ja atšķirība nepārsniedz 60 (55)

06/09/2007 10:35 AM

06/10/2007 3:30 PM

=SECOND([Kolonna2]-[Kolonna1])

Sekunžu skaits starp diviem laikiem, ja atšķirība nepārsniedz 60 (0)

Konvertēt laikus

Lai stundas no standarta laika formāta konvertētu decimālskaitlī, lietojiet funkciju INT.

Kolonna1

Formula

Apraksts (rezultāts)

10:35 AM

=([Kolonna1]-INT([Kolonna1]))*24

Stundu skaits kopš 12:00 AM (10,583333)

12:15 PM

=([Kolonna1]-INT([Kolonna1]))*24

Stundu skaits kopš 12:00 AM (12,25)

Lai stundas no decimālskaitļa konvertētu standarta laika formātā (stundās:minūtēs:sekundēs), lietojiet dalīšanas operatoru un funkciju TEXT.

Kolonna1

Formula

Apraksts (rezultāts)

23:58

=TEXT(Kolonna1/24, “hh:mm:ss”)

Stundas, minūtes un sekundes kopš 12:00 AM (00:59:55)

2:06

=TEXT(Kolonna1/24, “h:mm”)

Stundas un minūtes kopš 12:00 AM (0:05)

Ievietot Jūlija kalendāra datumus

Juliāna datumi ir datumu formāts, kas sastāv no pašreizējā gada un dienu skaita no gada sākuma. Piem., 2007. gada 1. janvāris tiek attēlots kā 2007001 un 2007. gada 31. decembris kā 2007365. Šī formāta pamatā nav Jūlija kalendārs.

Lai datumu konvertētu par Juliāna datumu, lietojiet funkcijas TEXT un DATEVALUE.

Kolonna1

Formula

Apraksts (rezultāts)

6/23/2007

=TEXT([Kolonna1],“yy”)&TEXT(([Kolonna1]-DATEVALUE(“1/1/”& TEXT([Kolonna1],“yy”))+1),“000”)

Datums Juliāna formātā ar gadskaitli, kurā ir divi cipari (07174)

6/23/2007

=TEXT([Kolonna1],“yyyy”)&TEXT(([Kolonna1]-DATEVALUE(“1/1/”&TEXT([Kolonna1],“yy”))+1),“000”)

Datums Juliāna formātā ar gadskaitli, kurā ir četri cipari (2007174)

Lai datumu konvertētu astronomijā izmantotajā Juliāna formātā, lietojiet konstanti 2415018,50. Šī formula darbojas tikai tiem datumiem, kas ir pēc 3/1/1901, un ja lietojat 1900 datumu sistēmu.

Kolonna1

Formula

Apraksts (rezultāts)

6/23/2007

=[Kolonna1]+2415018,50

Astronomijā izmantotais datums Juliāna formātā (2454274,50)

Rādītu datumus kā nedēļas dienu

Lai datumus konvertētu tekstā, kas atbilst nedēļas dienai, lietojiet funkcijas TEXT un WEEKDAY.

Kolonna1

Formula

Apraksts (iespējamais rezultāts)

19-Feb-2007

=TEXT(WEEKDAY([Kolonna1]), “dddd”)

Aprēķina datuma nedēļas dienu un atgriež pilnu dienas nosaukumu (pirmdiena)

3-Jan-2008

=TEXT(WEEKDAY([Kolonna1]), “ddd”)

Aprēķina datuma nedēļas dienu un atgriež saīsinātu dienas nosaukumu (ce)

Uz lapas sākumu

Matemātiskās formulas

Šīs formulas var izmantot, lai veiktu dažādus matemātiskos aprēķinus, piem., skaitļu saskaitīšanu, atņemšanu, reizināšanu un dalīšanu, skaitļu vidējās vērtības vai mediānas aprēķināšanu, skaitļu noapaļošanu un vērtību saskaitīšanu.

Skaitļu saskaitīšana

Lai saskaitītu skaitļus divās vai vairākās kolonnās pēc kārtas, lietojiet saskaitīšanas operatoru (+) vai funkciju SUM.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

6

5

4

=[Kolonna1]+[Kolonna2]+[Kolonna3]

Saskaita pirmo trīs kolonnu vērtības (15)

6

5

4

=SUM([Kolonna1],[Kolonna2],[Kolonna3])

Saskaita pirmo trīs kolonnu vērtības (15)

6

5

4

=SUM(IF([Kolonna1]>[Kolonna2], [Kolonna1]-[Kolonna2], 10), [Kolonna3])

Ja Kolonna1 ir lielāka nekā Kolonna2, tiek saskaitīta to starpība un Kolonna3. Pretējā gadījumā tiek saskaitīti 10 un Kolonna3 (5)

Skaitļu atņemšana

Lai atņemtu skaitļus divās vai vairākās kolonnās pēc kārtas, lietojiet atņemšanas operatoru (-) vai funkciju SUM ar negatīviem skaitļiem.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

15000

9000

-8000

=[Kolonna1]-[Kolonna2]

No 9000 tiek atņemts 15000 (6000)

15000

9000

-8000

=SUM([Kolonna1], [Kolonna2], [Kolonna3])

Saskaita skaitļus pirmajās trijās kolonnās, ieskaitot negatīvās vērtības (16000)

Divu skaitļu kā procentu starpības aprēķināšana

Lietojiet atņemšanas (-) un dalīšanas (/) operatorus un funkciju ABS.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

2342

2500

=([Kolonna2]-[Kolonna1])/ABS([Kolonna1])

Procentu izmaiņas (6,75% vai 0,06746)

Skaitļu reizināšana

Lai reizinātu skaitļus divās vai vairākās kolonnās pēc kārtas, lietojiet reizināšanas operatoru (*) vai funkciju PRODUCT.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

5

2.

=[Kolonna1]*[Kolonna2]

Reizina skaitļus pirmajās divās kolonnās (10)

5

2.

=PRODUCT([Kolonna1], [Kolonna2])

Reizina skaitļus pirmajās divās kolonnās (10)

5

2.

=PRODUCT([Kolonna1],[Kolonna2],2)

Reizina skaitļus pirmajās divās kolonnās un skaitli 2 (20)

Skaitļu dalīšana

Lai dalītu skaitļus divās vai vairākās kolonnās pēc kārtas, lietojiet dalīšanas operatoru (/).

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

15000

12

=[Kolonna1]/[Kolonna2]

Dala 15000 ar 12 (1250)

15000

12

=([Kolonna1]+10000)/[Kolonna2]

Saskaita 15000 un 10000 un pēc tam dala rezultātu ar 12 (2083)

Skaitļu vidējās vērtības aprēķināšana

Vidējo vērtību sauc arī par vidējo. Lai aprēķinātu skaitļu vidējo vērtību divās vai vairākās kolonnās pēc kārtas, lietojiet funkciju AVERAGE.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

6

5

4

=AVERAGE([Kolonna1], [Kolonna2],[Kolonna3])

Skaitļu vidējā vērtība pirmajās trīs kolonnās (5)

6

5

4

=AVERAGE(IF([Kolonna1]>[Kolonna2], [Kolonna1]-[Kolonna2], 10), [Kolonna3])

Ja Kolonna1 ir lielāka nekā Kolonna2, tiek aprēķināta to starpība un Kolonna3 vidējā vērtība. Pretējā gadījumā gadījumā tiek aprēķināta skaitļa 10 un Kolonna3 vidējā vērtība (2,5)

Aprēķinātu skaitļu mediānu

Mediāna ir secīga skaitļu diapazona centrālā vērtība. Lai aprēķinātu skaitļu grupas mediānu, lietojiet funkciju MEDIAN.

A

B

C

D

E

F

Formula

Apraksts (rezultāts)

10

7

9

27

0

4

=MEDIAN(A, B, C, D, E, F)

Pirmo 6 kolonnu skaitļu mediāna (8)

Aprēķinātu mazāko vai lielāko skaitli diapazonā

Lai aprēķinātu lielāko vai mazāko skaitli divās vai vairākās kolonnās pēc kārtas, lietojiet funkcijas MIN un MAX.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

10

7

9

=MIN([Kolonna1], [Kolonna2], [Kolonna3])

Mazākais skaitlis (7)

10

7

9

=MAX([Kolonna1], [Kolonna2], [Kolonna3])

Lielākais skaitlis (10)

Vērtību skaitīšana

Lai saskaitītu skaitliskas vērtības, lietojiet funkciju COUNT.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

Ābols

12/12/2007

=COUNT([Kolonna1], [Kolonna2], [Kolonna3])

Saskaita kolonnu skaitu, kurās ir skaitliskas vērtības. Neiekļauj datumu un laiku, tekstu un nulles vērtības (0)

$12

#DIV/0!

1,01

=COUNT([Kolonna1], [Kolonna2], [Kolonna3])

Saskaita kolonnu skaitu, kurās ir skaitliskas vērtības, bet neiekļauj kļūdas un loģiskās vērtības (2)

Palielinātu vai samazinātu skaitli ar procentiem

Lai veiktu šo aprēķinu, lietojiet procentu (%) operatoru.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

23

3%

=[Kolonna1]*(1+5%)

Kolonna1 skaitlis tiek palielināts par 5% (24,15)

23

3%

=[Kolonna1]*(1+[Kolonna2])

Kolonna1 skaitlis tiek palielināts par Kolonna2 procentuālo vērtību: 3% (23,69)

23

3%

=[Kolonna1]*(1-[Kolonna2])

Kolonna1 skaitlis tiek samazināts par Kolonna2 procentuālo vērtību: 3% (22,31)

Skaitļa pakāpē

Lai veiktu šo aprēķinu, lietojiet kāpināšanas operatoru (^) vai funkciju POWER.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

5

2.

=[Kolonna1]^[Kolonna2]

Aprēķina pieci kvadrātā (25)

5

3

=POWER([Kolonna1], [Kolonna2])

Aprēķina pieci kubā (125)

Skaitļa noapaļošana

Lai noapaļotu skaitli uz augšu, lietojiet funkcijas ROUNDUP, ODD vai EVEN.

Kolonna1

Formula

Apraksts (rezultāts)

20,3

=ROUNDUP([Kolonna1],0)

Noapaļo 20,3 uz augšu līdz tuvākajam veselajam skaitlim (21)

-5,9

=ROUNDUP([Kolonna1],0)

Noapaļo -5,9 uz augšu līdz tuvākajam veselajam skaitlim (-5)

12,5493

=ROUNDUP([Kolonna1],2)

Noapaļo 12,5493 uz augšu līdz tuvākajai simtdaļai, divām decimāldaļas vietām (12,55)

20,3

=EVEN([Kolonna1])

Noapaļo 20,3 uz augšu līdz tuvākajam pārskaitlim (22)

20,3

=ODD([Kolonna1])

Noapaļo 20,3 uz augšu līdz tuvākajam nepārskaitlim (21)

Lai noapaļotu skaitli uz leju, lietojiet funkciju ROUNDDOWN.

Kolonna1

Formula

Apraksts (rezultāts)

20,3

=ROUNDDOWN([Kolonna1],0)

Noapaļo 20,3 uz leju līdz tuvākajam veselajam skaitlim (20)

-5,9

=ROUNDDOWN([Kolonna1],0)

Noapaļo -5,9 uz leju līdz tuvākajam veselajam skaitlim (-6)

12,5493

=ROUNDDOWN([Kolonna1],2)

Noapaļo 12,5493 uz leju līdz tuvākajai simtdaļai, divām decimāldaļas vietām (12,54)

Lai noapaļotu skaitli līdz tuvākajam skaitlim vai daļskaitlim, lietojiet funkciju ROUND.

Kolonna1

Formula

Apraksts (rezultāts)

20,3

=ROUND([Kolonna1],0)

Noapaļo 20,3 uz leju, daļskaitļa daļa ir mazāka nekā ,5 (20)

5,9

=ROUND([Kolonna1],0)

Noapaļo 5,9 uz augšu, jo daļskaitļa daļa ir lielāka nekā ,5 (6)

-5,9

=ROUND([Kolonna1],0)

Noapaļo -5,9 uz leju, jo daļskaitļa daļa ir mazāka nekā -,5 (-6)

1,25

=ROUND([Kolonna1], 1)

Noapaļo skaitli līdz tuvākajai desmitdaļai (vienai decimāldaļas vietai). Skaitlis tiek noapaļots uz augšu, jo noapaļojamā vienība ir 0,05 vai lielāka (rezultāts: 1,3)

30,452

=ROUND([Kolonna1], 2)

Noapaļo skaitli līdz tuvākajai simtdaļai (divām decimāldaļas vietām). Skaitlis tiek noapaļots uz leju, jo noapaļojamā vienība, 0,002, ir mazāka nekā 0,005 (rezultāts: 30,45)

Lai noapaļotu skaitli līdz nozīmīgam ciparam virs 0, lietojiet funkcijas ROUND, ROUNDUP, ROUNDDOWN, INT un LEN.

Kolonna1

Formula

Apraksts (rezultāts)

5492820

=ROUND([Kolonna1],3-LEN(INT([Kolonna1])))

Noapaļo skaitli līdz 3 nozīmīgiem cipariem (5490000)

22230

=ROUNDDOWN([Kolonna1],3-LEN(INT([Kolonna1])))

Noapaļo skaitli uz leju līdz 3 nozīmīgiem cipariem (22200)

5492820

=ROUNDUP([Kolonna1], 5-LEN(INT([Kolonna1])))

Noapaļo skaitli uz augšu līdz 5 nozīmīgiem cipariem (5492900)

Uz lapas sākumu

Teksta formulas

Šīs formulas var izmantot, lai veiktu darbības ar tekstu, piem., kombinētu vai savienotu vērtības no vairākām kolonnām, salīdzinātu kolonnu saturu, noņemtu rakstzīmes vai atstarpes vai atkārtotu rakstzīmes.

Teksta burtu reģistra maiņa

Lai mainītu burtu reģistru, lietojiet funkcijas UPPER, LOWER vai PROPER.

Kolonna1

Formula

Apraksts (rezultāts)

līna Ābola

=UPPER([Kolonna1])

Maina tekstu uz lielajiem burtiem (LĪNA ĀBOLA)

līna Ābola

=LOWER([Kolonna1])

Maina tekstu uz mazajiem burtiem (līna ābola)

līna Ābola

=PROPER([Kolonna1])

Maina tekstu uz virsraksta burtu reģistru (Līna Ābola)

Apvienotu vārdu un uzvārdu

Lai kombinētu vārdu un uzvārdu, lietojiet zīmes operatoru (&) vai funkciju CONCATENATE.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

Kaspars

Ginters

=[Kolonna1]&[Kolonna2]

Kombinē abas virknes (KasparsGinters)

Kaspars

Ginters

=[Kolonna1]&“ ”&[Kolonna2]

Kombinē abas virknes, atdalot ar atstarpi (Kaspars Ginters)

Kaspars

Ginters

=[Kolonna2]&“, ”&[Kolonna1]

Kombinē abas virknes, atdalot ar komatu un atstarpi (Ginters, Kaspars)

Kaspars

Ginters

=CONCATENATE([Kolonna2], “,”, [Kolonna1])

Kombinē abas virknes, atdalot ar komatu (Ginters,Kaspars)

Teksta un skaitļu apvienošana no dažādām kolonnām

Lai kombinētu tekstu un skaitļus, lietojiet funkciju CONCATENATE, zīmes operatoru (&), vai funkciju TEXT un zīmes operatoru.

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

Jensens

28

=[Kolonna1]&“ pārdeva ”&[Kolonna2]&“ vienības.”

Kombinē kolonnu saturu, izveidojot frāzi (Jensens pārdeva 28 vienības.)

Višņevska

40%

=[Kolonna1]&“ pārdeva ”&TEXT([Kolonna2],“0%”)&“ no kopējiem ieņēmumiem.”

Kombinē kolonnu saturu, izveidojot frāzi (Višņevska pārdeva 40% no kopējiem ieņēmumiem.)

Piezīme.: Funkcija TEXT lieto Kolonna2 formatēto vērtību, nevis pamatā esošo vērtību — ,4.

Jensens

28

=CONCATENATE([Kolonna1],“ pārdeva ”,[Kolonna2],“ vienības.”)

Kombinē kolonnu saturu, izveidojot frāzi (Jensens pārdeva 28 vienības.)

Kombinētu tekstu ar datumu vai laiku

Lai kombinētu tekstu ar datumu vai laiku, lietojiet funkciju TEXT un zīmes operatoru (&).

Kolonna1

Kolonna2

Formula

Apraksts (rezultāts)

Rēķina izrakstīšanas datums

5-Jun-2007

=“Ieraksta datums: ”&TEXT([Kolonna2], “d-mmm-yyyy”)

Kombinē tekstu ar datumu (Ieraksta datums: 5-Jun-2007)

Rēķina datums

5-Jun-2007

=[Kolonna1]&“ ”&TEXT([Kolonna2], “mmm-dd-yyyy”)

Kombinē tekstu un datumu no dažādām kolonnām vienā kolonnā (Rēķina numurs Jun-05-2007)

Kolonnu satura salīdzināšana

Lai vienu kolonnu salīdzinātu ar citu kolonnu vai ar vērtību sarakstu, lietojiet funkcijas EXACT un OR.

Kolonna1

Kolonna2

Formula

Apraksts (iespējamais rezultāts)

BD122

BD123

=EXACT([Kolonna1],[Kolonna2])

Salīdzina pirmo divu kolonnu saturu (Nē)

BD122

BD123

=EXACT([Kolonna1], “BD122”)

Salīdzina Kolonna1 saturu ar virkni “BD122” (Jā)

Pārbaude, vai kolonnas vērtība vai tās daļa atbilst noteiktam tekstam

Lai pārbaudītu, vai kolonnas vērtība vai tās daļa sakrīt ar ar noteiktu tekstu, lietojiet funkcijas IF, FIND, SEARCH un ISNUMBER.

Kolonna1

Formula

Apraksts (iespējamais rezultāts)

Ābola

=IF([Kolonna1]=“Ābola”, “Labi”, “Nav labi”)

Pārbauda, vai Kolonna1 ir Ābola (Labi)

Ābola

=IF(ISNUMBER(FIND(“v”,[Kolonna1])), “Labi”, “Nav labi”)

Pārbauda vai kolonnā Kolonna1 ir burts “v” (Labi)

BD123

=ISNUMBER(FIND(“BD”,[Kolonna1]))

Pārbauda, vai Kolonna1 satur BD (Jā)

Count nav tukšas kolonnas

Lai saskaitītu aizpildītās šūnas, lietojiet funkciju COUNTA.

Kolonna1

Kolonna2

Kolonna3

Formula

Apraksts (rezultāts)

Realizācija

19

=COUNTA([Kolonna1], [Kolonna2])

Saskaita aizpildīto kolonnu skaitu (2)

Realizācija

19

=COUNTA([Kolonna1], [Kolonna2], [Kolonna3])

Saskaita aizpildīto kolonnu skaitu (2)

Noņemt rakstzīmes no teksta

Lai tekstā noņemtu rakstzīmes, lietojiet funkcijas LEN, LEFT un RIGHT.

Kolonna1

Formula

Apraksts (rezultāts)

Vitamīns A

=LEFT([Kolonna1],LEN([Kolonna1])-2)

Atgriež 8 (10-2) rakstzīmes, sākot no kreisās puses (Vitamīns)

Vitamīns B1

=RIGHT([Kolonna1], LEN([Kolonna1])-9)

Atgriež 2 (11-9) rakstzīmes, sākot no labās puses (B1)

No kolonnas sākuma un beigu noņemtu atstarpes

Lai no kolonnas noņemtu atstarpes, lietojiet funkciju TRIM.

Kolonna1

Formula

Apraksts (rezultāts)

Sveiki!

=TRIM([Kolonna1])

Noņem atstarpes sākumā un beigās ( Sveiki!)

Kolonnā atkārtotu rakstzīmi

Lai kolonnā atkārtotu rakstzīmi, lietojiet funkciju REPT.

Formula

Apraksts (rezultāts)

=REPT(“.”,3)

Atkārto punktu 3 reizes (...)

=REPT("-",10)

Atkārto domuzīmi 10 reizes (----------)

Uz lapas sākumu

Piezīme.: Mašīntulkošanas atruna. Šo rakstu ir tulkojusi datorsistēma bez cilvēka iejaukšanās. Microsoft piedāvā šos mašīntulkojumus, lai palīdzētu angliski nerunājošajiem lietotājiem izmanot saturu par Microsoft produktiem, pakalpojumiem un tehnoloģijām. Tā kā šis raksts ir mašīntulkots, tajā var būt leksikas, sintakses un gramatikas kļūdas.

Paplašiniet savas prasmes
Iepazīties ar apmācību
Esiet pirmais, kas saņem jaunās iespējas
Pievienoties Office Insider programmai

Vai šī informācija bija noderīga?

Paldies par jūsu atsauksmēm!

Paldies par atsauksmēm! Šķiet, ka varētu būt noderīgi sazināties ar kādu no mūsu Office atbalsta aģentiem.

×