Saistītās tēmas
×
Formulas un funkcijas
Pierakstīties, izmantojot Microsoft
Pierakstīties vai izveidot kontu
Sveicināti!
Atlasīt citu kontu.
Jums ir vairāki konti
Izvēlieties kontu, ar kuru vēlaties pierakstīties.
Formulas un funkcijas

Funkcija COUNTIF

Izmantojiet statistikas funkciju COUNTIF, lai noteiktu kādam kritērijam atbilstošo šūnu skaitu, piemēram, lai saskaitītu, cik reizes konkrēta pilsēta parādās klientu sarakstā.

Vienkāršākajā formā funkcijas COUNTIF nozīme ir šāda:

  • =COUNTIF(Kur vēlaties meklēt?, Ko vēlaties meklēt?)

Piemērs.

  • =COUNTIF(A2:A5,"Londona")

  • =COUNTIF(A2:A5;A4)

Jūsu pārlūkprogramma neatbalsta video. Instalējiet Microsoft Silverlight, Adobe Flash Player vai Internet Explorer 9.

COUNTIF(diapazons, kritēriji)

Argumenta nosaukums

Apraksts

diapazons    (obligāts arguments)

Šūnu grupa, kuras vēlaties saskaitīt. Diapazonā var būt būt skaitļi, masīvi, nosaukts diapazons vai atsauces, kurās ir skaitļi. Tukšas vērtības un teksta vērtības tiek ignorētas.

Papildinformācija par to, kā atlasīt diapazonus darblapā.

kritēriji    (obligāts arguments)

Skaitlis, izteiksme, šūnas atsauce vai teksta virkne, kas nosaka, kuru šūnu skaits jānosaka.

Piemēram, varat izmantot skaitli 32, salīdzinājumu “>32”, šūnu B4 vai vārdu, piemēram, “āboli”.

Funkcija COUNTIF lieto tikai vienu kritēriju. Ja vēlaties lietot vairākus kritērijus, izmantojiet funkciju COUNTIFS.

Piemēri

Lai šos piemērus izmantotu programmā Excel, kopējiet tālāk redzamās tabulas datus un ielīmējiet tos jaunas darblapas šūnā A1.

Dati

Dati

āboli

32

apelsīni

54

persiki

75

āboli

86

Formula

Apraksts

=COUNTIF(A2:A5;"āboli")

Šūnu diapazonā A2–A5 nosaka to šūnu skaitu, kuras satur vārdu “āboli”. Rezultāts ir 2.

=COUNTIF(A2:A5;A4)

Šūnu diapazonā A2–A5 nosaka to šūnu skaitu, kuras satur vārdu “persiki” (izmantojot vērtību šūnā A4). Rezultāts ir 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Šūnu diapazonā A2–A5 nosaka vārdu “āboli” (vērtība šūnā A2) un vārdu “apelsīni” (vērtība šūnā A3) skaitu. Rezultāts ir 3. Šajā formulā funkcija COUNTIF izmantota divreiz, lai norādītu vairākus kritērijus (katram kritērijam atbilst viena izteiksme). Varat izmantot arī funkciju COUNTIFS.

=COUNTIF(B2:B5;">55")

Šūnu diapazonā B2–B5 nosaka to šūnu skaitu, kuru vērtība ir lielāka par 55. Rezultāts ir 2.

=COUNTIF(B2:B5;"<>"&B4)

Šūnu diapazonā B2–B5 nosaka to šūnu skaitu, kuru vērtība nav vienāda ar 75. Zīme “un” (&) sapludina salīdzināšanas operatoru “nav vienāds ar” (<>) un šūnas B4 vērtību, radot virkni =COUNTIF(B2:B5,"<>75"). Rezultāts ir 3.

=COUNTIF(B2:B5;">=32")-COUNTIF(B2:B5;"<=85")

Šūnu diapazonā B2–B5 nosaka to šūnu skaitu, kuru vērtība ir lielāka (>) vai vienāda (=) ar 32 un mazāka (<) vai vienāda (=) ar 85. Rezultāts ir 1.

=COUNTIF(A2:A5,"*")

Šūnu diapazonā A2–A5 nosaka to šūnu skaitu, kas satur jebkādu tekstu. Zvaigznīti (*) izmanto kā aizstājējzīmi jebkuras rakstzīmes aizstāšanai. Rezultāts ir 4.

=COUNTIF(A2:A5,"?????ki")

Šūnu diapazonā A2–A5 nosaka to šūnu skaitu, kurās ir tieši 7 rakstzīmes un kuras beidzas ar burtiem “ki”. Jautājuma zīmi (?) izmanto kā aizstājējzīmi jebkuras rakstzīmes aizstāšanai. Rezultāts ir 1.

Biežāk sastopamās problēmas

Problēma

Kļūmes iemesls

Apstrādājot garas virknes, tiek atgriezta nepareiza vērtība.

Funkcija COUNTIF atgriež nepareizus rezultātus, ja to izmanto, lai saskaņotu virknes, kuru garums pārsniedz 255 rakstzīmes.

Lai saskaņotu virknes, kuru garums pārsniedz 255 rakstzīmes, izmantojiet funkciju CONCATENATE vai savienojumzīmi “un” (&). Piemēram, =COUNTIF(A2:A5,"gara virkne"&"vēl viena gara virkne").

Netiek atgriezta vērtība.

Pārbaudiet, vai arguments kritēriji ir norādīts pēdiņās.

Formula COUNTIF saņem #VALUE! kļūdu, atsaucoties uz citu darblapu.

Šī kļūda rodas tad, ja formulā, kurā ir funkcija, ir atsauce uz šūnām vai diapazonu aizvērtā darbgrāmatā un šīs šūnas ir aprēķinātas. Lai šis līdzeklis darbotos, otrai darbgrāmatai jābūt atvērtai.

Paraugprakse

Rīkojieties šādi

Kāpēc

Ņemiet vērā, ka funkcija COUNTIF ignorē lielos un mazos burtus teksta virknēs.

Kritēriji nav reģistrjutīgi. Citiem vārdiem sakot, virkne "āboli" un virkne "ĀBOLI" sakrīt ar vienām un tajā pašām šūnām.

Aizstājējzīmju izmantošana.

Kritērijos var izmantot aizstājējzīmes — jautājuma zīmi (?) un zvaigznīti (*). Jautājuma zīme aizvieto jebkuru atsevišķu rakstzīmi. Zvaigznīte aizvieto jebkuru rakstzīmju secību. Ja vēlaties atrast tieši jautājuma zīmi vai zvaigznīti, rakstzīmes priekšā ierakstiet tildi (~).

Piemēram, =COUNTIF(A2:A5,"ābol?") tiks skaitītas visas "ābol" instances, kurām pēdējais burts var atšķirties.

Pārbaudiet, vai datos nav kļūdainu rakstzīmju.

Nosakot teksta vērtību skaitu, pārbaudiet, vai dati nesākas un nebeidzas ar atstarpi, vai tajos netiek nepareizi izmantotas taisnās un ieapaļās pēdiņas vai nedrukājamas rakstzīmes. Šādos gadījumos COUNTIF var atgriezt negaidītu vērtību.

Mēģiniet izmantot funkciju CLEAN vai funkciju TRIM.

Ērtāk ir izmantot nosauktus diapazonus.

COUNTIF atbalsta nosauktu diapazonu darbību formulā (piemēram, =COUNTIF(augļi,">=32")-COUNTIF(augļi,">85"). Nosauktais diapazons var būt pašreizējā darblapā, citā darblapā tajā pašā darbgrāmatā vai citā darbgrāmatā. Lai veidotu atsauci uz citu darbgrāmatu, arī otrai darbgrāmatai jābūt atvērtai.

Piezīme.: Funkcija COUNTIF nesaskaitīs šūnas, pamatojoties uz šūnas fonu vai fonta krāsu. Tomēr programma Excel atbalsta lietotāja definētas funkcijas (UDF), izmantojot Microsoft Visual Basic for Applications (VBA) operācijas šūnām, pamatojoties uz fonu vai fonta krāsu. Lūk, piemērs, kā varat saskaitīt šūnas ar noteiktu šūnas krāsu, izmantojot VBA.

Vai nepieciešama papildu palīdzība?

Vienmēr varat pajautāt speciālistam Excel tech kopienā vai saņemt atbalstu kopienās.

Skatiet arī

Funkcija COUNTIFS

Funkcija IF

Funkcija COUNTA

Pārskats par formulām programmā Excel

IFS (funkcija IFS)

Funkcija SUMIF

Nepieciešama papildu palīdzība?

Vēlaties vairāk opciju?

Izpētiet abonementa priekšrocības, pārlūkojiet apmācības kursus, uzziniet, kā aizsargāt ierīci un veikt citas darbības.

Kopienas palīdz uzdot jautājumus un atbildēt uz tiem, sniegt atsauksmes, kā arī saņemt informāciju no ekspertiem ar bagātīgām zināšanām.

Vai šī informācija bija noderīga?

Cik lielā mērā esat apmierināts ar valodas kvalitāti?
Kas ietekmēja jūsu pieredzi?
Nospiežot Iesniegt, jūsu atsauksmes tiks izmantotas Microsoft produktu un pakalpojumu uzlabošanai. Jūsu IT administrators varēs vākt šos datus. Paziņojums par konfidencialitāti.

Paldies par jūsu atsauksmēm!

×