Prisijunkite prie „Microsoft“
Prisijunkite arba sukurkite paskyrą.
Sveiki,
Pasirinkti kitą paskyrą.
Turite kelias paskyras
Pasirinkite paskyrą, kurią naudodami norite prisijungti.
Teksto skaidymas į atskirus stulpelius, naudojant funkcijas

Galite naudoti LEFT, MID, RIGHT, SEARCH ir LEN teksto funkcijas ir valdyti savo duomenų teksto eilutes. Pavyzdžiui, galite paskirstyti vardą, antrąjį vardą ir pavardę iš vieno langelio į tris atskirus stulpelius.

Vardo elementų paskirstymo teksto funkcijomis raktas yra kiekvieno simbolio padėtis teksto eilutėje. Tarpų padėtis teksto eilutėje yra taip pat svarbi, nes jie nurodo vardo elementų pradžią ir pabaigą eilutėje.

Pavyzdžiui, langelyje, kuriame yra tik vardas ir pavardė, pastaroji prasideda tik po pirmojo tarpo. Tuo atveju, jei kai kuriuose jūsų sąrašo varduose yra antras asmens vardas, pavardė pradedama po antro tarpo.

Šiame straipsnyje sužinosite, kaip išskleisti skirtingus įvairių vardo formatų elementus naudojantis šiomis naudingomis funkcijomis. Taip pat galite suskaidyti tekstą į skirtingus stulpelius naudodami teksto konvertavimo į stulpelius vediklį

Vardo pavyzdys

Aprašas

Vardas

Antras vardas

Pavardė

Indeksas

1

Jurgis Mikalauskas

Nėra antro vardo

Gediminas

Kubilius

2

Tadas Kenteris

Vienas antro vardo inicialas

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Du antro vardo inicialai

Janaina

B. G.

Bueno

4

Bertašiutė, Vida Ona

Pavardė pradžioje, su kableliu

Urtė

Beth

Kahn

5

Marija Ona Stankevičiūtė

Dviejų dalių pirmasis vardas

Marija Ona

D.

Stankevičiūtė

6

Paula Barreto de Mattos

Trijų dalių pavardė

Paula

Barreto de Mattos

7

James van Eaton

Dviejų dalių pavardė

James

van Eaton

8

Bacon Jr., Dan K.

Pavardė ir povardis, su kableliu

Dan

K.

Šoninė

Jr.

9

Gary Altman III

Su povardžiu

Garis

Altman

III

10

P. Ryan Ihrig

Su priešvardžiu

Ryan

Ihrig

11

Julie Taft-Rider

Pavardė su brūkšneliu

Julija

Taft-Rider

Pastaba: Šiuose pavyzdžiuose pateiktuose grafiniuose elementuose paryškinta vardo ir pavardės vieta rodo simbolį, kurio ieško sutampanti formulė SEARCH.

Šiame pavyzdyje atskiriami du komponentai: vardas ir pavardė. Šiuos du vardo komponentus skiria viengubas tarpas.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Jurgis Mikalauskas

Nėra antro vardo

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu eilutėje (J) ir baigiamas penktuoju (tarpas). Formulė grąžina penkis simbolius į A2 langelį, pradedant iš kairės.

    Vardo išskleidimo formulė

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos pradėdami iš kairės.

  2. Pavardė

    Pavardė prasideda tarpu, penki simboliai iš dešinės, o baigiasi paskutiniuoju simboliu dešinėje (h). Langelyje A2 formulė išskleidžia penkis simbolius pradedant iš dešinės.

    Pavardės išskleidimo formulė

    Naudokite funkcijas SEARCH ir LEN, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  3. Suskaičiuokite visą teksto eilutės ilgį, tada atimkite simbolių į kairę nuo pirmojo tarpo skaičių, kaip buvo 1 žingsnyje.

Šiame pavyzdyje naudojamas vardas, antrojo vardo pirmoji raidė ir pavardė. Kiekvienas vardo komponentas yra atskirtas tarpu.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Tadas Kenteris

Vienas antro vardo inicialas

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (antro vardo inicialas)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formulė

Tiesioginis rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu iš kairės (E) ir baigiamas penktuoju (pirmasis tarpas). Formulė langelyje A2 išskleidžia pirmus penkis simbolius pradedant iš kairės.

    Vardo ir pavardės atskyrimo formulė ir antro vardo inicialas

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  2. Antras vardas

    Antras vardas prasideda šeštoje simbolio pozicijoje (S), o baigiasi aštuntoje pozicijoje (antrasis tarpas). Šioje formulėje yra funkcijų SEARCH įdėjimo galimybė, kad būtų galima rasti antrąjį tarpą.

    Formulė išskleidžia tris simbolius pradedant šeštąja pozicija.

    Vardo, antrojo vardo ir pavardės atskyrimo formulės išsami informacija

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (5).

  3. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (S). Ši skaitinė pozicija yra antro vardo pradžios pozicija. (5 + 1 = 6)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (5).

  4. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (S). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  5. Ieškokite antrojo tarpo langelyje A2 pradėdami šeštąja pozicija(S), rasta atliekant 4 veiksmą. Šis simbolio numeris yra antro vardo pabaigos pozicija. (8)

  6. Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos, pradėdami pirmuoju simboliu iš kairės. (5)

  7. Pasirinkite antrojo tarpo simbolio numerį, rastą atliekant 5 veiksmą, ir atimkite pirmojo tarpo simbolio numerį, rastą atliekant 6 veiksmą. Gautasis rezultatas bus tų simbolių, kuriuos MID išskleidžia iš teksto eilutės pradedant šeštąja pozicija, skaičius, rastas atliekant 2 veiksmą. (8 – 5 = 3)

  8. Pavardė

    Pavardė prasideda šeši simboliai iš dešinės (K), o baigiasi pirmuoju simboliu iš dešinės (n). Šioje formulėje yra funkcijų SEARCH įdėjimo galimybė, kad būtų galima rasti antrąjį ir trečiąjį tarpus (esančius penktoje ir aštuntoje pozicijose iš kairės).

    Langelyje A2 formulė išskleidžia šešis simbolius pradedant iš dešinės.

    Antroji search funkcija vardo, antrojo vardo ir pavardės atskyrimo formulėje
  9. Naudokite LEN ir įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos, pradėdami pirmuoju simboliu iš kairės. (5)

  10. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (S). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  11. Ieškokite antrojo tarpo langelyje A2 pradėdami šeštąja pozicija(S), rasta atliekant 2 veiksmą. Šis simbolio numeris yra antro vardo pabaigos pozicija. (8)

  12. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairiausio simbolio iki pirmojo tarpo, rasto atliekant 3 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo pavardės dešinės. (14 – 8 = 6).

Šiame pavyzdyje parodyta, kaip išskleisti dviejų antrų vardų pirmąsias raides. Pirmasis ir trečiasis tarpas atskiria vardo elementus.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Janaina B. G. Bueno

Du antro vardo inicialai

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (antro vardo inicialai)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Formulė

Tiesioginis rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu iš kairės (J) ir baigiamas aštuntuoju (pirmasis tarpas). Formulė langelyje A2 išskleidžia pirmus aštuonis simbolius pradedant iš kairės.

    Vardo ir pavardės atskyrimo formulė ir du antrojo vardo inicialai

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (8)

  2. Antras vardas

    Antras vardas prasideda devintoje pozicijoje (B), o baigiasi keturioliktoje (trečiasis tarpas). Šioje formulėje yra funkcijų SEARCH įdėjimo galimybė, kad būtų galima rasti pirmąjį, antrąjį ir trečiąjį tarpus aštuntoje, vienuoliktoje ir keturioliktoje pozicijose.

    Formulė išskleidžia penkis simbolius pradedant devintąja pozicija.

    Vardo ir pavardės atskyrimo formulė ir du antrojo vardo inicialai

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (8).

  3. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (B). Ši skaitinė pozicija yra antro vardo pradžios pozicija. (8 + 1 = 9)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (8).

  4. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (B). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (8 + 1 = 9)

  5. Langelyje A2 ieškokite antrojo tarpo pradėdami devinta pozicija (B), rasta atliekant 4 veiksmą. (11).

  6. Pridėkite 1, kad gautumėte simbolio, esančio po antrojo tarpo, poziciją (G). Šis simbolio numeris yra pradinė pozicija, nuo kurios norite pradėti trečiojo tarpo paiešką. (11 + 1 = 12)

  7. Langelyje A2 ieškokite trečiojo tarpo pradėdami dvyliktąja pozicija, rasta atliekant 6 veiksmą. (14)

  8. Langelyje A2 ieškokite pirmojo tarpo skaitinės pozicijos. (8)

  9. Pasirinkite trečiojo tarpo simbolio numerį, rastą atliekant 7 veiksmą, ir atimkite pirmojo tarpo simbolio numerį, rastą atliekant 6 veiksmą. Gautasis rezultatas bus tų simbolių, kuriuos MID išskleidžia iš teksto eilutės pradedant devintąja pozicija, skaičius, rastas atliekant 2 veiksmą.

  10. Pavardė

    Pavardė prasideda penki simboliai iš dešinės (B), o baigiasi pirmuoju simboliu iš dešinės (o). Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti pirmąjį, antrąjį ir trečiąjį tarpus.

    Langelyje A2 formulė išskleidžia penkis simbolius pradėdama nuo vardo ir pavardės dešinės pusės.

    Vardo ir pavardės atskyrimo formulė ir du antrojo vardo inicialai

    Naudokite įdėtąsias funkcijas SEARCH ir LEN, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (8).

  11. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (B). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (8 + 1 = 9)

  12. Langelyje A2 ieškokite antrojo tarpo pradėdami devintąja pozicija (B), rasta atliekant 2 veiksmą. (11)

  13. Pridėkite 1, kad gautumėte simbolio, esančio po antrojo tarpo, poziciją (G). Šis simbolio numeris yra pradinė pozicija, nuo kurios norite pradėti trečiojo tarpo paiešką. (11 + 1 = 12)

  14. Langelyje A2 ieškokite trečiojo tarpo pradėdami dvyliktąja pozicija (G), rasta atliekant 6 veiksmą. (14)

  15. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki trečiojo tarpo, rasto atliekant 5 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (19 – 14 = 5)

Šiame pavyzdyje pavardė nurodyta prieš vardą, o antras vardas yra gale. Kablelis žymi kur baigiasi pavardė, o kiekvienas vardo ir pavardės komponentas yra atskirtas tarpu.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Bertašiutė, Vida Ona

Pavardė pradžioje, su kableliu

Formulė

Rezultatas (vardas)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formulė

Rezultatas (antras vardas)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formulė

Tiesioginis rezultatas (pavardė)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. Vardas

    Vardas pradedamas septintuoju simboliu iš kairės (W) ir baigiamas dvyliktuoju (antrasis tarpas). Turite naudoti MID funkciją, jei norite išskleisti vardą, nes jis yra vardo ir pavardės viduryje.

    Formulė išskleidžia šešis simbolius pradedant septintąja pozicija.

    Pavardės, po jos einančio vardo ir antrojo vardo atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (6).

  2. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (W). Ši skaitinė pozicija yra vardo pradžios pozicija. (6 + 1 = 7)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (6).

  3. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (W). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (6 + 1 = 7)

    Langelyje A2 ieškokite antrojo tarpo pradėdami septintąja pozicija (W), rasta atliekant 4 veiksmą. (12)

  4. Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (6).

  5. Pasirinkite antrojo tarpo simbolio numerį, rastą atliekant 5 veiksmą, ir atimkite pirmojo tarpo simbolio numerį, rastą atliekant 6 veiksmą. Gautasis rezultatas bus tų simbolių, kuriuos MID išskleidžia iš teksto eilutės pradedant septintąja pozicija, skaičius, rastas atliekant 2 veiksmą. (12 – 6 = 6)

  6. Antras vardas

    Antras vardas prasideda keturi simboliai iš dešinės (B), o baigiasi pirmuoju simboliu iš dešinės (h). Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti pirmąjį ir antrąjį tarpus šeštoje ir dvyliktoje pozicijose iš kairės.

    Formulė išskleidžia keturis simbolius pradedant iš dešinės.

    Pavardės, po jos einančio vardo ir antrojo vardo atskyrimo formulė

    Naudokite įdėtąsias funkcijas SEARCH ir LEN, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (6).

  7. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (W). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (6 + 1 = 7)

  8. Langelyje A2 ieškokite antrojo tarpo pradėdami septintąja pozicija (W), rasta atliekant 2 veiksmą. (12)

  9. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki antrojo tarpo, rasto atliekant 3 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (16 – 12 = 4)

  10. Pavardė

    Pavardė pradedama pirmuoju simboliu iš kairės (K) ir baigiama ketvirtuoju (n). Formulė išskleidžia keturis simbolius pradedant iš kairės.

    Pavardės, po jos einančio vardo ir antrojo vardo atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (6).

  11. Atimkite 2, kad gautumėte pavardės baigiamojo simbolio (n) skaitinę poziciją. Gautasis rezultatas yra simbolių, kuriuos norite išskleisti funkcija LEFT, skaičius. (6 – 2 = 4)

Šiame pavyzdyje naudojamas dviejų dalių vardas, Marija Ona. Antrasis ir trečiasis tarpai atskiria kiekvieną vardo elementą.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Marija Ona Stankevičiūtė

Dviejų dalių pirmasis vardas

Formulė

Rezultatas (vardas)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formulė

Rezultatas (antro vardo inicialas)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Formulė

Tiesioginis rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Vardas

    Vardas prasideda pirmuoju simboliu iš kairės, o baigiasi devintuoju simboliu (antrasis tarpas). Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti antrąjį tarpą iš kairės.

    Formulė išskleidžia devynis simbolius pradedant iš kairės.

    Vardo, antrojo vardo, antrojo vardo inicialo ir pavardės atskyrimo formulė

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (5).

  2. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (K). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  3. Ieškokite antrojo tarpo langelyje A2 pradėdami šeštąja pozicija (K), rasta atliekant 2 veiksmą. Gautasis rezultatas yra simbolių, kuriuos funkcija LEFT išskleidžia iš teksto eilutės, skaičius. (9).

  4. Antras vardas

    Antras vardas prasideda dešimtoje pozicijoje (D), o baigiasi dvyliktoje (trečiasis tarpas). Šioje formulėje yra funkcijų SEARCH įdėjimo galimybė, kad būtų galima rasti pirmą, antrą ir trečią tarpus.

    Formulė išskleidžia du simbolius iš antro vardo pradedant dešimtąja pozicija.

    Vardo, antrojo vardo, antrojo vardo inicialo ir pavardės atskyrimo formulė

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami pirmuoju simboliu iš kairės. (5).

  5. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (K). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  6. Ieškokite antrojo tarpo pozicijos langelyje A2 pradėdami šeštąja pozicija (K), rasta atliekant 2 veiksmą. Gautasis rezultatas yra simbolių, kuriuos funkcija LEFT išskleidžia iš kairės, skaičius. (9).

  7. Pridėkite 1, kad gautumėte simbolį, esantį po antrojo tarpo (D). Gautasis rezultatas yra pradinė antro vardo pozicija. (9 + 1 = 10)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite simbolio, esančio po antrojo tarpo, skaitinės padėties (D). Gautasis rezultatas yra simbolio skaičius, nuo kurio norite pradėti ieškoti trečiojo tarpo. (10).

  8. Ieškokite langelyje A2 esančio trečiojo tarpo skaitinės padėties pradėdami iš kairės. Gautasis rezultatas yra baigiamoji antro vardo pozicija. (12).

  9. Ieškokite simbolio, esančio po antrojo tarpo, padėties (D). Gautasis rezultatas yra pradinė antro vardo pozicija. (10).

  10. Pasirinkite trečiojo tarpo simbolio numerį, rastą atliekant 6 veiksmą, ir atimkite „D“ simbolio numerį, rastą atliekant 7 veiksmą. Gautasis rezultatas bus tų simbolių, kuriuos MID išskleidžia iš teksto eilutės pradedant dešimtąja pozicija, skaičius, rastas atliekant 4 veiksmą. (12 – 10 = 2)

  11. Pavardė

    Pavardė prasideda aštuntuoju simboliu iš dešinės. Šioje formulėje yra funkcijų SEARCH įdėjimo galimybė, kad būtų galima rasti pirmąjį, antrąjį ir trečiąjį tarpus penktoje, devintoje ir dvyliktoje pozicijose.

    Formulė išskleidžia aštuonis simbolius iš dešinės.

    Vardo, antrojo vardo, antrojo vardo inicialo ir pavardės atskyrimo formulė

    Naudokite įdėtąsias funkcijas SEARCH ir LEN, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  12. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (K). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti tarpo paiešką. (5 + 1 = 6)

  13. Langelyje A2 ieškokite antrojo tarpo pradėdami šeštąja pozicija (K), rasta atliekant 2 veiksmą. (9)

  14. Pridėkite 1, kad gautumėte simbolio, esančio po antrojo tarpo, poziciją (D). Šis rezultatas yra antro vardo pradžios pozicija. (9 + 1 = 10)

  15. Ieškokite langelyje A2 esančio trečiojo tarpo skaitinės padėties pradėdami iš kairės. Gautasis rezultatas yra baigiamoji antro vardo pozicija. (12).

  16. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki trečiojo tarpo, rasto atliekant 5 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (20 – 12 = 8)

Šiame pavyzdyje naudojama trijų dalių pavardė: Barreto de Mattos. Pirmasis tarpas žymi vardo pabaigą ir pavardės pradžią.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Paula Barreto de Mattos

Trijų dalių pavardė

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (pavardė)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu iš kairės (P) ir baigiamas šeštuoju (pirmasis tarpas). Formulė išskleidžia šešis simbolius iš kairės.

    Vardo ir pavardės iš trijų dalių atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  2. Pavardė

    Pavardė prasideda septynioliktuoju simboliu iš dešinės (B), o baigiasi pirmuoju simboliu iš dešinės (s). Formulė išskleidžia septyniolika simbolių iš dešinės.

    Vardo ir pavardės iš trijų dalių atskyrimo formulė

    Naudokite funkcijas LEN ir SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  3. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki pirmojo tarpo, rasto atliekant 1 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (23 – 6 = 17)

Šiame pavyzdyje naudojama dviejų dalių pavardė: van Eaton. Pirmasis tarpas žymi vardo pabaigą ir pavardės pradžią.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

James van Eaton

Dviejų dalių pavardė

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu iš kairės (J) ir baigiamas aštuntuoju (pirmasis tarpas). Formulė išskleidžia šešis simbolius iš kairės.

    Vardo ir pavardės iš dviejų dalių atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  2. Pavardė

    Pavardė pradedama devintuoju simboliu iš dešinės (v) ir baigiama pirmuoju iš dešinės (n). Formulė išskleidžia devynis simbolius pradedant iš dešinės vardo ir pavardės pusės.

    Vardo ir pavardės iš dviejų dalių atskyrimo formulė

    Naudokite funkcijas LEN ir SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  3. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki pirmojo tarpo, rasto atliekant 1 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (15 – 6 = 9)

Šiame pavyzdyje pradžioje yra pavardė, po kurios seka povardis. Kablelis skiria pavardę ir povardį nuo vardo ir antro vardo inicialo.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Bacon Jr., Dan K.

Pavardė ir povardis, su kableliu

Formulė

Rezultatas (vardas)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formulė

Rezultatas (antro vardo inicialas)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Formulė

Rezultatas (pavardė)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (povardis)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. Vardas

    Vardas pradedamas dvyliktuoju simboliu (D) ir baigiamas penkioliktuoju (trečiasis tarpas). Formulė išskleidžia tris simbolius pradedant dvyliktąja pozicija.

    Pavardės ir povardžio atskyrimo formulė su kableliu

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  2. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (J). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (6 + 1 = 7)

  3. Langelyje A2 ieškokite antrojo tarpo pradėdami septintąja pozicija (J), rasta atliekant 2 veiksmą. (11)

  4. Pridėkite 1, kad gautumėte simbolį, esantį po antrojo tarpo (D). Gautasis rezultatas yra pradinė vardo pozicija. (11 + 1 = 12)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite simbolio, esančio po antrojo tarpo, skaitinės padėties (D). Gautasis rezultatas yra simbolio skaičius, nuo kurio norite pradėti ieškoti trečiojo tarpo. (12).

  5. Ieškokite langelyje A2 esančio trečiojo tarpo skaitinės padėties pradėdami iš kairės. Gautasis rezultatas yra baigiamoji vardo pozicija. (15).

  6. Ieškokite simbolio, esančio po antrojo tarpo, skaitinės padėties (D). Gautasis rezultatas yra pradinė vardo pozicija. (12).

  7. Pasirinkite trečiojo tarpo simbolio numerį, rastą atliekant 6 veiksmą, ir atimkite „D“ simbolio numerį, rastą atliekant 7 veiksmą. Gautasis rezultatas bus tų simbolių skaičius, kuriuos MID išskleidžia iš teksto eilutės pradedant dvyliktąja pozicija, rasta atliekant 4 veiksmą. (15 – 12 = 3)

  8. Antras vardas

    Antras vardas prasideda antruoju simboliu iš dešinės (K). Formulė išskleidžia du simbolius iš dešinės.

    Pavardės ir povardžio atskyrimo formulė su kableliu

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  9. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (J). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (6 + 1 = 7)

  10. Langelyje A2 ieškokite antrojo tarpo pradėdami septintąja pozicija (J), rasta atliekant 2 veiksmą. (11)

  11. Pridėkite 1, kad gautumėte simbolį, esantį po antrojo tarpo (D). Gautasis rezultatas yra pradinė vardo pozicija. (11 + 1 = 12)

  12. Ieškokite langelyje A2 esančio trečiojo tarpo skaitinės padėties pradėdami iš kairės. Gautasis rezultatas yra baigiamoji antro vardo pozicija. (15).

  13. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki trečiojo tarpo, rasto atliekant 5 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (17 – 15 = 2)

  14. Pavardė

    Pavardė pradedama pirmuoju simboliu iš kairės (B) ir baigiama šeštuoju (pirmasis tarpas). Formulė išskleidžia šešis simbolius iš kairės.

    Pavardės ir povardžio atskyrimo formulė su kableliu

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  15. Povardis

    Povardis pradedamas septintuoju simboliu iš kairės (J) ir baigiamas devintuoju simboliu iš kairės (.). Formulė išskleidžia tris simbolius pradedant septintuoju simboliu.

    Pavardės ir povardžio atskyrimo formulė su kableliu

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  16. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (J). Gautasis rezultatas yra pradinė povardžio pozicija. (6 + 1 = 7)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  17. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (J). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (7)

  18. Langelyje A2 ieškokite skaitinės antrojo tarpo pozicijos pradėdami septintuoju simboliu, rastu atliekant 4 veiksmą. (11)

  19. Atimkite 1 iš antrojo tarpo simbolio numerio, rasto atliekant 4 veiksmą, kad gautumėte „,“ simbolio numerį. Gautasis rezultatas yra baigiamoji povardžio pozicija. (11 – 1 = 10)

  20. Ieškokite pirmojo tarpo skaitinės pozicijos. (6)

  21. Radę pirmąjį tarpą, pridėkite 1, kad rastumėte kitą simbolį (J), taip pat rastą atliekant veiksmus 3 ir 4. (7)

  22. Pasirinkite „,“ simbolio numerį, rastą atliekant 6 veiksmą, ir atimkite „J“ simbolio numerį, rastą atliekant 3 ir 4 veiksmą. Gautasis rezultatas yra tų simbolių skaičius, kuriuos MID išskleidžia iš teksto eilutės pradedant septintąja pozicija, rasta atliekant 2 veiksmą. (10 – 7 = 3)

Šiame pavyzdyje vardas yra eilutės pradžioje, o povardis yra gale, todėl galima naudoti formules, panašias į 2 pavyzdį: naudokite funkciją LEFT, kad išskleistumėte vardą, funkciją MID, kad išskleistumėte pavardę, ir funkciją RIGHT, kad išskleistumėte povardį.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Gary Altman III

Vardas ir pavardė su povardžiu

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (pavardė)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formulė

Rezultatas (povardis)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Vardas

    Vardas ir pavardė pradedami pirmuoju simboliu iš kairės (G) ir baigiamas penktuoju (pirmasis tarpas). Formulė išskleidžia penkis vardo ir pavardės simbolius iš kairės.

    Vardo ir pavardės atskyrimo formulė su povardžiu

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  2. Pavardė

    Pavardė prasideda šeštuoju simboliu iš kairės (A), o baigiasi vienuoliktuoju simboliu (antrasis tarpas). Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti tarpų pozicijas.

    Formulė išskleidžia šešis simbolius iš antro vardo pradedant šeštuoju simboliu.

    Vardo ir pavardės atskyrimo formulė su povardžiu

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  3. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (A). Gautasis rezultatas yra pradinė pavardės pozicija. (5 + 1 = 6)

    Naudokite įdėtąsias funkcijas SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  4. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (A). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  5. Langelyje A2 ieškokite skaitinės antrojo tarpo pozicijos pradėdami šeštuoju simboliu, rastu atliekant 4 veiksmą. Šis simbolio skaičius yra baigiamoji pavardės pozicija. (12)

  6. Ieškokite pirmojo tarpo skaitinės pozicijos. (5)

  7. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (A), taip pat gautą atliekant veiksmus 3 ir 4. (6)

  8. Pasirinkite antrojo tarpo simbolio numerį, rastą atliekant 5 veiksmą, ir atimkite „A“ simbolio numerį, rastą atliekant 6 ir 7 veiksmus. Gautasis rezultatas bus tų simbolių skaičius, kuriuos MID išskleidžia iš teksto eilutės pradedant šeštąja pozicija, rasta atliekant 2 veiksmą. (12 – 6 = 6)

  9. Povardis

    Povardis prasideda trečiu simboliu iš dešinės. Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti tarpų pozicijas.

    Vardo ir pavardės atskyrimo formulė su povardžiu

    Naudokite įdėtąsias funkcijas SEARCH ir LEN, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (5)

  10. Pridėkite 1, kad gautumėte simbolį, esantį po pirmojo tarpo (A). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (5 + 1 = 6)

  11. Langelyje A2 ieškokite antrojo tarpo pradėdami šeštąja pozicija (A), rasta atliekant 2 veiksmą. (12)

  12. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki antrojo tarpo, rasto atliekant 3 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (15 – 12 = 3)

Šiame pavyzdyje povardis yra prieš vardą ir pavardę, todėl naudokite formules, panašias į 2 pvz.: funkcija MID vardui išskleisti, funkcija RIGHT pavardei išskleisti.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

P. Ryan Ihrig

Su priešvardžiu

Formulė

Rezultatas (vardas)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formulė

Rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Vardas

    Vardas prasideda penktuoju simboliu iš kairės (R), o baigiasi devintuoju simboliu (antrasis tarpas). Formulė įdeda SEARCH, kad rastų tarpų padėtį. Išskleidžiami keturi simboliai, pradedant penktąją pozicija.

    Vardo, prieš kurį yra priešdėlis, atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte pradžios_nr reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (4)

  2. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (R). Gautasis rezultatas yra pradinė vardo pozicija. (4 + 1 = 5)

    Naudokite įdėtąją funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (4)

  3. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (R). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (4 + 1 = 5)

  4. Langelyje A2 ieškokite skaitinės antrojo tarpo pozicijos pradėdami penktuoju simboliu, rastą atliekant 3 ir 4 veiksmuose. Šis simbolio skaičius yra baigiamoji vardo pozicija. (9)

  5. Ieškokite pirmojo tarpo. (4)

  6. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (R), taip pat gautą atliekant veiksmus 3 ir 4. (5)

  7. Pasirinkite antrojo tarpo simbolio numerį, rastą atliekant 5 veiksmą, ir atimkite „R“ simbolio numerį, rastą atliekant 6 ir 7 veiksmus. Gautasis rezultatas bus tų simbolių skaičius, kuriuos MID išskleidžia iš teksto eilutės pradedant penktąja pozicija, rasta atliekant 2 veiksmą. (9 – 5 = 4)

  8. Pavardė

    Pavardė prasideda penktuoju simboliu iš dešinės. Šioje formulėje yra SEARCH įdėjimo galimybė, kad būtų galima rasti tarpų pozicijas.

    Vardo, prieš kurį yra priešdėlis, atskyrimo formulė

    Naudokite įdėtąsias funkcijas SEARCH ir LEN, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (4)

  9. Pridėkite 1, kad gautumėte simbolio, esančio po pirmojo tarpo, poziciją (R). Šis rezultatas yra simbolio numeris nuo kurio norite pradėti antrojo tarpo paiešką. (4 + 1 = 5)

  10. Langelyje A2 ieškokite antrojo tarpo pradėdami penktąja pozicija (R), rasta atliekant 2 veiksmą. (9)

  11. Apskaičiuokite bendrą teksto eilutės ilgį langelyje A2, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki antrojo tarpo, rasto atliekant 3 veiksmą. Gautasis rezultatas bus išskleistinų simbolių skaičius nuo vardo ir pavardės dešinės. (14 – 9 = 5)

Šiame pavyzdyje naudojama brūkšneliu sujungta pavardė. Kiekvienas vardo komponentas yra atskirtas tarpu.

Nukopijuokite langelius į lentelę ir įklijuokite juos į „Excel“ darbalapio A1 langelį. Kairėje rodoma formulė bus rodoma kaip nuoroda, o "Excel" automatiškai konvertuos formulę dešinėje į atitinkamą rezultatą.

Užuomina    Prieš įklijuodami duomenis į darbalapį, nustatykite A ir B stulpelių pločius iki 250.

Vardo pavyzdys

Aprašas

Julie Taft-Rider

Pavardė su brūkšneliu

Formulė

Rezultatas (vardas)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formulė

Rezultatas (pavardė)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Vardas

    Vardas pradedamas pirmuoju simboliu iš kairės ir baigiamas šeštoje pozicijoje (pirmasis tarpas). Formulė išskleidžia šešis simbolius iš kairės.

    Vardo ir pavardės su brūkšneliu atskyrimo formulė

    Naudokite funkciją SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio pirmojo tarpo skaitinės pozicijos pradėdami iš kairės. (6)

  2. Pavardė

    Visa pavardė prasideda dešimtuoju simboliu iš dešinės (T), o baigiasi pirmuoju simboliu iš dešinės (r).

    Vardo ir pavardės su brūkšneliu atskyrimo formulė

    Naudokite funkcijas LEN ir SEARCH, kad rastumėte simbolių_skaičiaus reikšmę:

    Ieškokite langelyje A2 esančio tarpo skaitinės pozicijos, pradėdami pirmuoju simboliu iš kairės. (6)

  3. Apskaičiuokite bendrą išskleistinos teksto eilutės ilgį, tada atimkite simbolių skaičių nuo kairėje esančio simbolio iki pirmojo tarpo, rasto atliekant 1 veiksmą. (16 – 6 = 10)

Teksto skaidymas į atskirus stulpelius naudojant teksto konvertavimo į stulpelius vediklį

Reikia daugiau pagalbos?

Norite daugiau parinkčių?

Sužinokite apie prenumeratos pranašumus, peržiūrėkite mokymo kursus, sužinokite, kaip apsaugoti savo įrenginį ir kt.

Bendruomenės padeda užduoti klausimus ir į juos atsakyti, pateikti atsiliepimų ir išgirsti iš ekspertų, turinčių daug žinių.

Ar ši informacija buvo naudinga?

Ar esate patenkinti kalbos kokybe?
Kas turėjo įtakos jūsų įspūdžiams?
Paspaudus mygtuką Pateikti, jūsų atsiliepimai bus naudojami tobulinant „Microsoft“ produktus ir paslaugas. Jūsų IT administratorius galės rinkti šiuos duomenis. Privatumo patvirtinimas.

Dėkojame už jūsų atsiliepimą!

×