Formulės ir funkcijos

Skirtumo tarp dviejų datų apskaičiavimas

Dviejų datų skirtumo skaičiavimas

Pastaba: Norėtume jums kuo greičiau pateikti naujausią žinyno turinį jūsų kalba. Šis puslapis išverstas automatiškai, todėl gali būti gramatikos klaidų ar netikslumų. Mūsų tikslas – padaryti, kad šis turinys būtų jums naudingas. Gal galite šio puslapio apačioje mums pranešti, ar informacija buvo naudinga? Čia yra straipsnis anglų kalba, kuriuo galite pasinaudoti kaip patogia nuoroda.

Norėdami apskaičiuoti dviejų datų skirtumą, naudokite funkciją DATEDIF. Pirmiausia viename langelyje įrašykite pradžios datą, o kitame langelyje – pabaigos datą. Tada įveskite formulę (pvz., vieną iš nurodytų toliau).

Įspėjimas: Aš f pradžios_data yra didesnė nei pabaigos_data, rezultatas bus #NUM!.

Skirtumas dienomis

=DATEDIF(D9,E9,"d") ir rezultatas 856

Šiame pavyzdyje pradžios data pateikiama D9 langelyje, o pabaigos data – E9 langelyje. Formulė įvesta F9 langelyje. „d“ pateikia pilnų dienų skaičių tarp dviejų datų.

Skirtumas savaitėmis

=(DATEDIF(D13,E13,"d")/7) ir rezultatas: 122.29

Šiame pavyzdyje pradžios data pateikiama D13 langelyje, o pabaigos data – E13 langelyje. „d“ pateikia dienų skaičių. Tačiau atkreipkite dėmesį į pabaigoje esantį ženklą /7. Tai padalina dienų skaičių iš 7, nes savaitėje yra 7 dienos. Atminkite, kad šį rezultatą taip pat reikia suformatuoti kaip skaičių. Paspauskite CTRL + 1. Tada spustelėkite Skaičius > Dešimtainio skyriklio vietų: 2.

Skirtumas mėnesiais

=DATEDIF(D5,E5,"m") ir rezultatas: 28

Šiame pavyzdyje pradžios data pateikiama D5 langelyje, o pabaigos data – E5 langelyje. Formulėje „m“ pateikia pilnų mėnesių skaičių tarp dviejų dienų.

Skirtumas metais

=DATEDIF(D2,E2,"y") ir rezultatas: 2

Šiame pavyzdyje pradžios data pateikiama D2 langelyje, o pabaigos data – E2 langelyje. „y“ pateikia pilnų metų skaičių tarp dviejų dienų.

Amžiaus apskaičiavimas metais, mėnesiais ir dienomis

Taip pat galite apskaičiuoti kokio nors asmens amžių ar tarnybos trukmę. Rezultatas galėtų būti, pvz., „2 m., 4 mėn., 5 d.“.

1. Norėdami sužinoti bendrą metų skaičių, naudokite DATEDIF.

=DATEDIF(D17,E17,"y") ir rezultatas: 2

Šiame pavyzdyje pradžios data pateikiama D17 langelyje, o pabaigos data – E17 langelyje. Formulėje „y“ pateikia pilnų metų skaičių tarp dviejų dienų.

2. Norėdami sužinoti mėnesių skaičių, dar kartą panaudokite DATEDIF su „ym“.

=DATEDIF(D17,E17,"ym") ir rezultatas: 4

Kitame langelyje panaudokite DATEDIF formulę su parametru „ym“. „ym“ pateikia likusių mėnesių skaičių po paskutinių pilnų metų.

3. Norėdami sužinoti dienų skaičių, naudokite kitą formulę.

=DATEDIF(D17,E17,"md") ir rezultatas: 5

Dabar turime sužinoti likusių dienų skaičių. Tai padarysime įrašydami kitokią formulę, kaip parodyta aukščiau. Ši formulė atima pirmą paskutinio mėnesio dieną (5/1/2016) iš pradinės pabaigos datos, nurodytos E17 langelyje (5/6/2016). Toliau aprašyta, kaip ji tai daro. Pirmiausia funkcija DATE sukuria datą: 5/1/2016. Ji ją sukuria naudodama E17 langelyje nurodytus metus ir mėnesį. Skaičius „1“ atitinka pirmą mėnesio dieną. Funkcijos DATE rezultatas yra 5/1/2016. Tada atimame tai iš pradinės pabaigos datos, nurodytos E17 langelyje, tai yra 5/6/2016. Iš 5/6/2016 atėmus 5/1/2016 gaunamos 5 dienos.

Įspėjimas: Nerekomenduojame naudoti DATEDIF argumento „md“, nes jis gali apskaičiuoti netikslius rezultatus.

4. Pasirinktinai: sujunkite tris formules į vieną.

=DATEDIF(D17,E17,"y")&" m., "&DATEDIF(D17,E17,"ym")&" mėn., "&DATEDIF(D17,E17,"md")&" d." ir rezultatas: 2 m., 4 mėn., 5 d.

Visus tris skaičiavimus galite įtraukti į vieną langelį, kaip šiame pavyzdyje. Naudokite ampersendus, kabutes ir tekstą. Tokia formulė yra ilgesnė, tačiau viskas yra vienoje vietoje. Patarimas: norėdami į formulę įtraukti eilučių lūžių, paspauskite ALT + ENTER. Taip ją lengviau perskaityti. Be to, jei nematote visos formulės, paspauskite CTRL + SHIFT + U.

Atsisiųskite mūsų pavyzdžius

Galite atsisiųsti "pavyzdys" darbaknygės su visais šio straipsnio pavyzdžiuose. Sekite kartu arba kurti savo formules.

Atsisiųsti datos skaičiavimo pavyzdžiai

Kiti datos ir laiko skaičiavimai

Kaip matėte ankščiau, DATEDIF funkcija apskaičiuoja skirtumą tarp pradžios ir pabaigos datų. Tačiau, kad nereiktų vesti konkrečių datų, formulėje taip pat galite naudoti funkciją TODAY(). Kai naudojate funkciją TODAY(), „Excel“ naudoja jūsų kompiuterio dabartinę datą. Turėkite omenyje, tai ji pasikeis, kai failas bus iš naujo atidarytas kitą dieną.

=DATEDIF(TODAY(),D28,"y") ir rezultatas: 984

Atkreipkite dėmesį, kad rašant šį straipsnį, buvo 2016 m. spalio 6 d.

Naudokite funkciją NETWORKDAYS.INTL, kai norite apskaičiuoti darbo dienų skaičių tarp dviejų datų. Taip pat gali nustatyti, kad formulė neįtrauktų savaitgalių ir šventinių dienų.

Prieš pradedant: nuspręskite, ar norite neįtraukti šventinių datų. Jei taip, atskiroje srityje arba lape įveskite šventinių datų sąrašą. Kiekvieną šventinę datą įveskite atskirame langelyje. Tada pažymėkite tuos langelius ir pasirinkite Formulės > Pavadinimo apibrėžimas. Pavadinkite diapazoną Mano šventės, tada spustelėkite Gerai. Tada sukurkite formulę, atlikdami toliau nurodytus veiksmus.

1. Įveskite pradžios ir pabaigos datas.

Pradžios data langelyje D53 yra 1/1/2016 pabaigos data langelyje E53 yra 12/31/2016

Šiame pavyzdyje pradžios data pateikiama D53 langelyje, o pabaigos data – E53 langelyje.

2. Kitame langelyje įveskite tokią formulę:

=NETWORKDAYS.INTL(D53,E53,1) ir rezultatas: 261

Įveskite formulę, kaip parodyta anksčiau pateiktame pavyzdyje. Skaičius „1“ formulėje nurodo šeštadienius ir sekmadienius kaip savaitgalio dienas, kurios į bendrą skaičių neįtraukiamos.

Pastaba. Programoje „Excel 2007“ funkcijos NETWORKDAYS.INTL nėra. Tačiau joje yra funkcija NETWORKDAYS. Anksčiau pateiktas pavyzdys „Excel 2007“ programoje atrodytų taip: =NETWORKDAYS(D53,E53). „1“ nenurodomas, nes NETWORKDAYS daro prielaidą, kad savaitgalis yra šeštadienį ir sekmadienį.

3. Jei reikia, pakeiskite „1“.

„IntelliSense“ sąrašas, kuriame 2 – sekmadienis, pirmadienis; 3 – pirmadienis, antradienis ir t. t.

Jei šeštadienis ir sekmadienis nėra jūsų savaitgalio dienos, pakeiskite „1“ kitu skaičiumi iš „IntelliSense“ sąrašo. Pavyzdžiui, skaičius „2“ kaip savaitgalio dienas nustato sekmadienius ir pirmadienius.

Jei naudojate „Excel 2007“, praleiskite šį veiksmą. „Excel 2007“ funkcija NETWORKDAYS visada daro prielaidą, kad savaitgalis yra šeštadienį ir sekmadienį.

4. Įveskite švenčių diapazono pavadinimą.

=NETWORKDAYS.INTL(D53,E53,1,MyHolidays) ir rezultatas: 252

Jei švenčių diapazono pavadinimą sukūrėte ankstesniame skyriuje „Prieš pradedant“, tada įveskite jį pabaigoje, kaip parodyta. Jei švenčių neturite, galite neįvesti kablelio ir „MyHolidays“. Jei naudojate „Excel 2007“, anksčiau pateiktas pavyzdys atrodytų taip: =NETWORKDAYS(D53,E53,MyHolidays).

Patarimas: Jei nenorite atostogų diapazono pavadinimo, taip pat galite įvesti diapazoną, pvz., D35:E:39. Arba galite įvesti atostogų viduje formulę. Pavyzdžiui, jei jūsų šventės sausio 1 ir 2 2016, įveskite jas taip: = NETWORKDAYS. Intl(D53,E53,1,{"1/1/2016","1/2/2016"}). Programoje "Excel 2007", jis turėtų atrodyti taip: =NETWORKDAYS(D53,E53,{"1/1/2016","1/2/2016"})

Praėjusį laiką galite apskaičiuoti atimdami vieną laiką iš kito. Pirmiausia viename langelyje įrašykite pradžios laiką, o kitame langelyje – pabaigos laiką. Nepamirškite įvesti viso laiko, įskaitant valandas, minutes, ir tarpą prieš AM arba PM. Toliau aprašoma, kaip tai padaryti.

1. Įveskite pradžios ir pabaigos laiką.

Pradžios data / laikas 7:15 AM, pabaigos data / laikas 4:30 PM

Šiame pavyzdyje pradžios laikas pateikiamas D80 langelyje, o pabaigos laikas – E80 langelyje. Nepamirškite įvesti valandų, minučių ir tarpo prieš AM arba PM.

2. Nustatykite formatą h:mm AM/PM.

Dialogo langas Langelių formatavimas, komanda Pasirinktinis, tipas h:mm AM/PM

Pasirinkite abi datas ir paspauskite CTRL + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“). Nepamirškite pasirinkti Pasirinktinis > h: mm AM/PM, jei dar nenustatyta.

3. Atimkite du laikus.

=E80-D80 ir rezultatas: 9:15 AM

Kitame langelyje atimkite pradžios laiko langelį iš pabaigos laiko langelio.

4. Nustatykite formatą h:mm.

Dialogo langas Langelių formatavimas, komanda Pasirinktinis, tipas h:mm

Paspauskite CTRL + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“). Pasirinkite Pasirinktinis > h:mm, kad rezultate nebūtų įtraukta AM ir PM.

Norėdami apskaičiuoti laiką tarp dviejų datų ir laikų, galite tiesiog atimti vieną iš kito. Tačiau kiekviename langelyje turite pritaikyti formatavimą, kad „Excel“ pateiktų norimą rezultatą.

1. Įveskite dvi pilnas datas ir laikus.

Pradžios data 1/1/16 1:00 PM; pabaigos data 1/2/16 2:00 PM

Viename langelyje įveskite visą pradžios datą / laiką. Kitame langelyje įveskite visą pabaigos datą / laiką. Kiekviename langelyje turėtų būti mėnuo, diena, metai, valanda, minutė ir tarpas prieš AM arba PM.

2. Nustatykite 3/14/12 1:30 PM formatą.

Dialogo langas Langelių formatavimas, komanda Data, tipas 3/14/12 1:30 PM

Pasirinkite abu langelius ir paspauskite CTRL + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“). Tada pasirinkite Data > 3/14/12 1:30 PM. Tai nėra data, kurią nustatysite, tai yra tik pavyzdys, kaip atrodys formatas. Atkreipkite dėmesį, kad ankstesnėse versijose (iki „Excel 2016“) šio formato pavyzdžio data gali būti kitokia, pvz., 3/14/01 1:30 PM.

3. Atimkite vieną iš kito.

=E84-D84 ir rezultatas 1.041666667

Kitame langelyje atimkite pradžios datą / laiką iš pabaigos datos / laiko. Rezultatas greičiausiai atrodys kaip skaičius su dešimtainio skyriklio vieta. Tai galėsite ištaisyti kitame veiksme.

4. Nustatykite formatą [h]:mm.

Dialogo langas Langelių formatavimas, komanda Pasirinktinis, tipas [h]:mm

Paspauskite CTRL + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“). Pasirinkite Pasirinktinis. Lauke Tipas įveskite [h]:mm.

Susijusios temos

Funkcija DATEDIF
NETWORKDAYS. Funkcija INTL
NETWORKDAYS
daugiau datos ir laiko funkcijos
apskaičiuoti skirtumą tarp dviejų laikų

Tobulinkite savo „Office“ įgūdžius
Ieškoti mokymo
Pirmiausia gaukite naujų funkcijų
Prisijunkite prie „Office Insider“ dalyvių

Ar ši informacija buvo naudinga?

Dėkojame už jūsų atsiliepimus!

Dėkojame už jūsų atsiliepimą! Panašu, kad gali būti naudinga jus sujungti su vienu iš mūsų „Office“ palaikymo agentų.

×