Formulės ir funkcijos

Funkcija COUNTIF

COUNTIF (funkcija COUNTIF)

Naudokite COUNTIF (vieną iš statistinių funkcijų), norėdami suskaičiuoti, kiek stulpelių atitinka kriterijų; pvz., suskaičiuoti, kiek kartų konkretus miestas yra klientų sąraše.

Paprasčiausia forma COUNTIF praneša:

  • =COUNTIF(kur norite ieškoti?, ko norite ieškoti?)

Pavyzdžiui:

  • =COUNTIF(A2:A5,"Londonas")

  • =COUNTIF(A2:A5;A4)

Jūsų naršyklė nepalaiko vaizdo įrašo. Įdiekite „Microsoft Silverlight“, „Adobe Flash Player“ ar „Internet Explorer 9“.

COUNTIF(diapazonas, kriterijai)

Argumento pavadinimas

Aprašas

diapazonas    (būtina)

Langelių, kuriuos norite skaičiuoti, grupė. Diapazonas gali apimti skaičius, masyvus, pavadintą diapazoną arba nuorodas, kuriose yra skaičiai. Tuščių ir tekstinių reikšmių nepaisoma.

Sužinokite, kaip pasirinkti darbalapio diapazonus.

kriterijai    (būtina)

Skaičius, išraiška, langelio nuoroda arba teksto eilutė, nurodanti, kurie langeliai bus skaičiuojami.

Pvz., galite naudoti skaičių 32, palyginimą ">32", langelį B4 arba žodį "obuoliai".

COUNTIF naudoja tik vieną kriterijų. Naudokite COUNTIFS, jei norite naudoti kelis kriterijus.

Pavyzdžiai

Norėdami šiuos pavyzdžius naudoti programoje „Excel“, nukopijuokite šios lentelės duomenis ir įklijuokite į naujo darbalapio A1 langelį.

Duomenys

Duomenys

obuoliai

32

apelsinai

54

persikai

75

obuoliai

86

Formulė

Aprašas

=COUNTIF(A2:A5;"obuoliai")

Apskaičiuoja, kiek langelių su obuoliais langeliuose nuo A2 iki A5. Rezultatas – 2.

=COUNTIF(A2:A5;A4)

Apskaičiuoja, kiek langelių su persikais (A4 reikšmė) langeliuose nuo A2 iki A5. Rezultatas – 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Apskaičiuoja obuolių (A2 reikšmė) ir apelsinų (A3 reikšmė) skaičių langeliuose nuo A2 iki A5. Rezultatas – 3. Šioje formulėje dukart naudojama COUNTIF, kad būtų galima nurodyti kelis kriterijus, vienas kriterijus yra reiškinys. Taip pat galima naudoti funkciją COUNTIFS.

=COUNTIF(B2:B5;"> 55")

Apskaičiuoja, kiek yra langelių, kurių reikšmė didesnė už 55, langeliuose nuo B2 iki B5. Rezultatas yra 2.

=COUNTIF(B2:B5;"<>"&B4)

Apskaičiuoja, kiek yra langelių, kurių reikšmė nelygi 75, langeliuose nuo B2 iki B5. Ženklas & sulieja palyginimo nelygybės operatorių (<>) ir reikšmę iš langelio B4, kad gautų =COUNTIF(B2:B5,"<>75"). Rezultatas – 3.

=COUNTIF(B2:B5;">=32")-COUNTIF(B2:B5;"> 85")

Skaičiuoja, kiek yra langelių su reikšme, didesne (>) arba lygia (=) 32 ir mažesne (<) arba lygia (=) 85, skaičius B2–B5 langelių diapazone. Rezultatas yra 3.

=COUNTIF(A2:A5,"*")

Skaičiuoja langelius, kuriuose yra bet kokio teksto, A2–A5 langelių diapazone. Žvaigždutė (*) naudojama kaip pakaitos simbolis, atitinkantis bet kokį simbolį. Rezultatas – 4.

=COUNTIF(A2:A5,"?????es")

Skaičiuoja langelius, kuriuose yra lygiai 7 simboliai ir kurie baigiasi raidėmis „es“, langeliuose nuo A2 iki A5. Klaustukas (?) naudojamas kaip pakaitos simbolis, atitinkantis atskirus simbolius. Rezultatas – 2.

Dažniausiai pasitaikančios problemos

Problema

Kas nutiko

Grąžinta klaidinga ilgų eilučių reikšmė.

Funkcija COUNTIF grąžina neteisingus rezultatus, jei ją naudojate su ilgesnėmis nei 255 simboliai eilutėmis.

Su ilgesnėmis nei 255 simboliai eilutėmis naudokite funkciją CONCATENATE arba sujungimo operatorių &. Pavyzdžiui, =COUNTIF(A2:A5,"ilga eilutė"&"kita ilga eilutė").

Negrąžinama jokia reikšmė, kai tikitės reikšmės.

Kriterijų argumentą rašykite kabutėse.

Formulė COUNTIF pateikia #VALUE! klaidą, kai nurodoma į kitą darbalapį.

Ši klaida įvyksta, kai formulė, kurioje yra funkcija, nurodo langelius arba diapazoną uždarytoje darbaknygėje, ir langeliai suskaičiuojami. Kad ši funkcija veiktų, reikia atidaryti tą darbaknygę.

Geriausios praktikos

Atlikite tai

Kodėl

Atminkite, kad COUNTIF nepaiso didžiųjų ir mažųjų raidžių teksto eilutėse.

Kriterijuose neskiriamos didžiosios ir mažosios raidės. Kitaip tariant, eilutė „obuoliai“ ir eilutė „OBUOLIAI“ atitiks tuos pačius langelius.

Naudokite pakaitos simbolius.

Pakaitos simbolius – klaustuką (?) ir žvaigždutę (*) – galima naudoti kriterijuose. Klaustukas atitinka bet kokį vieną simbolį. Žvaigždutė atitinka bet kokią simbolių seką. Jei norite rasti tikrą klaustuką ar žvaigždutę, prieš simbolį įveskite tildės ženklą (~).

Pavyzdžiui, =COUNTIF(A2:A5,"obuoli?") suskaičiuos visus „obuoli“ egzempliorius, kur paskutinioji raidė gali skirtis.

Įsitikinkite, kad jūsų duomenyse nėra klaidingų simbolių.

Skaičiuodami teksto reikšmes, įsitikinkite, kad duomenų pradžioje ir pabaigoje nėra tarpų, nenaudojamos tiesios ir lenktos kabutės ir nėra nespausdinamų simbolių. Tokiais atvejais funkcija COUNTIF gali grąžinti nenumatytą reikšmę.

Pabandykite naudoti funkciją CLEAN arba funkciją TRIM.

Kad būtų patogiau, naudokite pavadintus diapazonus

COUNTIF palaiko pavadintus diapazonus formulėje (pvz., =COUNTIF(fruit,">=32")-COUNTIF(fruit,">85"). Pavadintas diapazonas gali būti dabartiniame darbalapyje, kitame tos pačios darbaknygėje darbalapyje arba iš skirtingos darbaknygės. Norint nurodyti iš kitos darbaknygės, antroji darbaknygė taip pat turi būti atidaryta.

Pastaba: Funkcija COUNTIF neskaičiuos langelių pagal langelio foną arba šrifto spalvą. Tačiau „Excel“ palaiko vartotojo nustatytas funkcijas (UDF), naudodama „Microsoft Visual Basic for Applications“ (VBA) langelių operacijas, pagrįstas fonu arba šrifto spalva. Štai pavyzdys, kaip galite suskaičiuoti konkrečios spalvos langelius, naudodami VBA.

Reikia daugiau pagalbos?

Visada galite paprašyti specialisto iš „Excel“ technologijų bendruomenės, gauti pagalbos iš Atsakymų bendruomenės arba siūlyti naują funkciją ar patobulinimą „Excel“ vartotojo balse.

Taip pat žr.

Norėdami skaičiuoti langelius, kurie nėra tušti, naudokite funkciją COUNTA

Norėdami skaičiuoti langelius pagal kelis kriterijus, naudokite funkciją COUNTIFS

Peržiūrėkite vaizdo įrašą apie tai, kaip naudoti funkciją COUNTIFS

Funkcija SUMIF sudeda tik reikšmes, kurios atitinka vieną kriterijų

Funkcija SUMIFS sudeda tik reikšmes, kurios atitinka kelis kriterijus

Funkcija IFS („Office 365“, „Excel 2016“ ir naujesnės versijos)

Naudokite funkciją TRIM norėdami pašalinti iš langelių pradžios ir pabaigos tarpus

Naudokite funkciją CLEAN norėdami pašalinti iš langelių nespausdinamus simbolius

„Excel“ formulių apžvalga

Kaip išvengti sugadintų formulių

Formulių klaidų aptikimas

Statistinės funkcijos

„Excel“ funkcijos (pagal abėcėlę)

„Excel“ funkcijos (pagal kategoriją)

Tobulinkite savo „Office“ įgūdžius
Ieškoti mokymo
Pirmiausia gaukite naujų funkcijų
Prisijunkite prie „Office Insider“ dalyvių

Ar ši informacija buvo naudinga?

Dėkojame už jūsų atsiliepimus!

Dėkojame už jūsų atsiliepimą! Panašu, kad gali būti naudinga jus sujungti su vienu iš mūsų „Office“ palaikymo agentų.

×