Funkcija TEXT

Bendraautoriai: Darius Smilgys Danas Barkus

Funkcija TEXT leidžia pakeisti skaičiaus rodymą, pritaikant formatavimą su formato kodais. Tai naudinga situacijose, kai norite rodyti skaičius geriau perskaitomu formatu arba norite juos derinti su tekstu ar simboliais.

Pastaba : Funkcija TEXT konvertuos skaičius į tekstą, todėl vėliau atliekant skaičiavimus gali būti sunku juos panaudoti. Geriausia viename langelyje palikti pradinę reikšmę, o funkciją TEXT naudoti kitame langelyje. Tada, jei reikės kurti kitas formules, visada nurodykite pradinę reikšmę, o ne funkcijos TEXT rezultatą.

Sintaksė

TEXT(value, format_text)

Funkcijos TEXT sintaksė turi tokius argumentus:

Argumento pavadinimas

Aprašas

value

Skaitinė reikšmė, kurį norite konvertuoti į tekstą.

format_text

Teksto eilutė, apibrėžianti formatavimą, kurį norite pritaikyti pateiktai reikšmei.

Apžvalga

Iš esmės funkcija TEXT nurodo:

  • =TEXT(reikšmė, kurią norite formatuoti, „Formato kodas, kurį norite taikyti“)

Toliau pateikiami keli populiarūs pavyzdžiai, kuriuos galite nukopijuoti tiesiai į „Excel“, kad galėtumėte išbandyti patys. Atkreipkite dėmesį į formato kodus tarp kabučių.

Formulė

Aprašas

=TEXT(1234.567,"$#,##0.00")

Valiuta su tūkstančių skyrikliu ir 2 dešimtainiais skaičiais, pvz., $1234.57. Atkreipkite dėmesį, kad „Excel“ suapvalina reikšmę iki 2 skaitmenų po kablelio.

=TEXT(TODAY(),"MM/DD/YY")

Šiandienos data MM/DD/YY formatu, pvz., 03/14/12

=TEXT(TODAY(),"DDDD")

Savaitės diena šiandien, pvz., pirmadienis

=TEXT(NOW(),"H:MM AM/PM")

Dabartinis laikas, pvz., 1:29 PM

=TEXT(0.285,"0.0%")

Procentas, pvz., 28.5%

=TEXT(4.34 ,"# ?/?")

Trupmena, pvz., 4 1/3

=TRIM(TEXT(0.34,"# ?/?"))

Trupmena, pvz., 1/3. Atkreipkite dėmesį, kad šis kodas naudoja funkciją TRIM, kad pašalintų pradžioje esantį tarpą su dešimtaine reikšme.

=TEXT(12200000,"0.00E+00")

Tiksli išraiška, pvz., 1.22E+07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

Specialusis formatavimas (telefono numeris), pvz., (123) 456-7898

=TEXT(1234,"0000000")

Įtraukti nulius (0) pradžioje, pvz., 0001234

=TEXT(123456,"##0° 00' 00''")

Pasirinktinis – platuma / ilguma

Pastaba : Nors formatavimui pakeisti galite naudoti funkciją TEXT, tai nėra vienintelis būdas. Formatą galite pakeisti be formulės, paspausdami CTRL + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“), tada dialogo lange Langelių formatavimas > Skaičius pasirinkite norimą formatą.

Atsisiųskite mūsų pavyzdžius

Jūs galite atsisiųsti darbaknygės pavyzdį su visais funkcijos TEXT pavyzdžiais, kuriuos rasite šiame straipsnyje, bei dar kelis papildomus pavyzdžius. Galite keisti formatavimą pagal šiuos pavyzdžius arba sukurti savo funkcijos TEXT formato kodus.

Atsisiųsti „Excel“ funkcijos TEXT pavyzdžius

Kiti galimi formato kodai

Norėdami rasti kitus galimus formato kodus, galite naudoti dialogo langą Langelių formatavimas.

  1. Paspauskite Ctrl + 1 ( MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“), kad būtų atidarytas dialogo langas Langelių formatavimas.

  2. Pasirinkite norimą formatą skirtuke Skaičius.

  3. Pasirinkite parinktį Pasirinktinis.

  4. Jūsų norimas formato kodas dabar rodomas lauke Tipas. Šiuo atveju pažymėkite viską, kas rodoma lauke Tipas, išskyrus kabliataškį (;) ir simbolį @. Toliau pateiktame pavyzdyje pažymėjome ir nukopijavome tik mm/dd/yy.

  5. Paspauskite Ctrl + C, kad nukopijuotumėte formato kodą, tada paspauskite Atšaukti, kad atsisakytumėte dialogo lango Langelių formatavimas.

  6. Dabar jums tik reikia paspausti Ctrl + V, kad įklijuotumėte formato kodą į savo formulę TEXT, pvz.: =TEXT(B2,"mm/dd/yy"). Įsitikinkite, ar įklijuojate formato kodą su kabutėmis ("formatavimo kodas"), nes priešingu atveju „Excel“ pateiks klaidos pranešimą.

Pavyzdys, kaip naudojant dialogo langą Formatas > Langeliai > Skaičius > Pasirinktinis „Excel“ gali už jus sukurti formato eilutes.

Formatavimo kodai pagal kategoriją

Toliau pateikiami keli pavyzdžiai, kaip savo reikšmėms galite pritaikyti skirtingus skaičių formatus, naudodami dialogo langą Langelių formatavimas, tada – kaip naudodami parinktį Pasirinktinis galite nukopijuoti tuos formatavimo kodus į savo funkciją TEXT.

Kodėl „Excel“ panaikina mano priekyje nurodytus nulius?

„Excel“ ieško langeliuose įvestų skaičių, o ne skaičių, kurie atrodo kaip tekstas, pvz., dalių numeriai ar SKU. Jei norite palikti pradžioje esančius nulius, prieš įklijuodami arba įvesdami reikšmes, suformatuokite įvesties diapazoną kaip tekstą. Pažymėkite stulpelį arba diapazoną, kur dėsite reikšmes, tada pasinaudodami CTRL + 1 iškvieskite dialogo langą Formatavimas > Langeliai ir skirtuke Skaičius pasirinkite Tekstas. Dabar „Excel“ paliks jūsų pradžioje rodomus nulius.

Jei jau įvedėte duomenis, ir „Excel“ pašalino pradžioje esančius nulius, galite juos vėl įtraukti naudodami funkciją TEXT. Galite nurodyti viršutinį langelį su reikšmėmis ir naudoti =TEXT(value,"00000"), kur nulių skaičius formulėje rodo bendrą pageidaujamą simbolių skaičių. Tada nukopijuokite ir įklijuokite į likusią diapazono dalį.

Pavyzdžiai, kaip naudojant TEXT formatuoti priekyje esančius nulius.  =TEXT(A2,"00000")

Jei dėl kokios nors priežasties jums reikia konvertuoti tekstines reikšmes atgal į skaičius, galite padauginti iš 1, pvz., =D4*1, arba naudoti dvivietį operatorių (--), pvz., =--D4.

Programa „Excel“ atskiria tūkstančius kableliais, jei formate yra kablelis (,), apsuptas skaičių ženklais (#) arba nuliais. Pavyzdžiui, jei formatavimo eilutė yra "#,###", „Excel“ skaičių 12200000 rodo taip: 12,200,000.

Po skaitmenų rezervavimo ženklo esantis kablelis padidina skaičių 1 000. Pavyzdžiui, jei formatavimo eilutė yra"#,###.0,", „Excel“ rodo skaičių 12200000 rodo taip: 12,200.0.

Funkcijos TEXT pavyzdžiai, naudojant tūkstančių skyriklį

Pastabos : 

  • Tūkstančių skyriklis priklauso nuo jūsų regiono parametrų. JAV tai yra kablelis, bet kitose lokalėse tai gali būti taškas (.).

  • Tūkstančių skyriklis gali būti naudojamas skaičių, valiutos ir apskaitos formatuose.

Toliau pateikiami standartinių skaičių (tik su tūkstančių ir dešimtainių skaičių skyrikliu), valiutos ir apskaitos formatų pavyzdžiai. Valiutos formatas leidžia įterpti pasirinktą valiutos simbolį ir sulygiuoja jį su jūsų reikšme, o apskaitos formatas sulygiuoja valiutos simbolį į kairę nuo langelio, o reikšmę – į dešinę. Atkreipkite dėmesį į valiutos ir apskaitos formato kodų skirtumus: apskaitos formate simboliui ir reikšmei atskirti naudojama žvaigždutė (*).

Funkcijos TEXT pavyzdžiai su skaičiaus, valiutos ir apskaitos formatais

Norėdami rasti valiutos simbolio formato kodą, pirmiausia paspauskite Ctrl + 1 (arba MAC komandos mygtuko piktogramos vaizdas + 1, jei naudojate „Mac“), pasirinkite norimą formatą, tada išplečiamajame sąraše Simbolis pasirinkite simbolį:

Valiutos simbolio pasirinkimas dialogo lange Langelių formatavimas

Dalies Kategorija kairėje spustelėkite Pasirinktinis ir nukopijuokite formato kodą, įskaitant valiutos simbolį.

Funkcija TEXT – pasirinktinė valiuta su simboliu

Pastaba : Funkcija TEXT nepalaiko spalvų formatavimo, todėl dialogo lange Langelių formatavimas nukopijavus skaičių formato kodą, pvz., $#,##0.00_);[Red]($#,##0.00), funkcija TEXT priims formato kodą, bet nerodys spalvos.

Naudodami raidžių derinį („M“ – mėnuo, „D“ – diena, „Y“ – metai) galite pakeisti datos rodymo būdą.

Mėnesio, dienos ir metų formato kodai

Funkcijos TEXT formato koduose neskiriamos didžiosios ir mažosios raidės, todėl galite naudoti „M“ arba „m“, „D“ arba „d“, „Y“ arba „y“.

„Excel“ MVP Mynda Treacy

Mynda rekomenduoja...

Jei bendrinate „Excel“ failus ir ataskaitas su vartotojais iš skirtingų šalių, galite pateikti jiems ataskaitą jų kalba. „Excel“ MVP Mynda Treacy šiame straipsnyje „Excel“ datos rodomos skirtingomis kalbomis pateikia puikų sprendimą. Jame taip pat pateikiamas darbaknygės pavyzdys, kurį galite atsisiųsti.

Naudodami raidžių derinį („H“ – valandos, „M“ – minutės, „S“ – sekundės ir „AM“ arba „PM“, kai naudojamas 12 valandų formatas) galite pakeisti laiko rodymo būdą.

Valandų, minučių ir sekundžių laiko formatai

Jei „AM“ / „PM“ arba „A“ / „P“ nenurodysite, laikas bus rodomas 24 valandų formatu.

Funkcijos TEXT formato koduose neskiriamos didžiosios ir mažosios raidės, todėl galite naudoti „H“ arba „h“, „M“ arba „m“, „S“ arba „S“, „AM/PM“ arba „am/pm“.

Naudodami procento (%) formatus, galite pakeisti dešimtainių reikšmių rodymo būdą.

Procentų formato kodai

Naudodami trupmenų (?/?) formatus, galite pakeisti dešimtainių reikšmių rodymo būdą.

Trupmenų formato kodai

Tiksli išraiška leidžia rodyti skaičius kaip dešimtainius nuo 1 iki 10, pakėlus 10-uoju laipsniu. Šis formatas dažnai naudojamas, norint sutrumpinti didelius skaičius.

Tikslios išraiškos formato kodai

„Excel“ pateikia 4 specialiuosius formatus:

  • Pašto indeksas – "00000"

  • Pašto indeksas + 4 – "00000-0000"

  • Telefono numeris – "[<=9999999]###-####;(###) ###-####"

  • Socialinio draudimo numeris – "000-00-0000"

Specialieji funkcijos TEXT formatai

Specialieji formatai skirsis, atsižvelgiant į lokalę, bet jei jūsų lokalėje nėra jokių specialiųjų formatų arba jei šie neatitinka jūsų reikmių, galite sukurti savo formatus dialogo lange Langelių formatavimas > Pasirinktinis.

Įprastas scenarijus

Funkcija TEXT retai naudojama atskirai, ir dažniausiai naudojama kartu su kažkuo kitu. Tarkime, kad norite derinti teksto ir skaičių reikšmę, pavyzdžiui „Ataskaita išspausdinta: 03/14/12“ arba „Savaitės pajamos: 66 348,72 USD“. Galite tai įvesti į „Excel“ rankiniu būdu, bet tai prieštarauja „Excel“ paskirčiai padaryti tai už jus. Deja, kai sujungiate tekstą ir formatuotus skaičius, pvz., datas, laiką, valiutą ir t. t., „Excel“ nežino, kaip norite juos rodyti, todėl nebetaiko skaičių formatavimo. Tai atvejis, kai labai praverčia funkcija TEXT, nes ji leidžia nurodyti programai „Excel“ formatuoti reikšmes, kaip pageidaujate, naudojant formato kodą, pvz., "MM/DD/YY", kaip datos formatą.

Toliau pateiktame pavyzdyje pamatysite, kas nutinka, kai bandote tai sujungti tekstą ir skaičių nenaudodami funkcijos TEXT. Šiuo atveju naudojame ampersando operatorių (&), kad sujungtume teksto eilutę, tarpą (" ") ir reikšmę su =A2&" "&B2.

Teksto jungimo be funkcijos TEXT pavyzdys

Kaip matote, „Excel“ pašalino datos formatavimą langelyje B2. Kitame pavyzdyje pamatysite, kaip funkcija TEXT leidžia pritaikyti norimą formatą.

Teksto jungimo su funkcija TEXT pavyzdys

Mūsų atnaujinta formulė yra:

  • Langelis C2:=A2&" "&TEXT(B2,"mm/dd/yy") – datos formatas

Dažniausiai užduodami klausimai

Deja, naudojant funkciją TEXT to padaryti negalima, reikia naudoti „Visual Basic for Applications“ (VBA) kodą. Toliau pateiktame saite aprašytas specialus metodas: Kaip skaitinę reikšmę konvertuoti į anglų kalbos žodžius naudojant programą „Excel“

Taip, galite naudoti funkcijas UPPER, LOWER ir PROPER. Pavyzdžiui, =UPPER("hello") pateiks rezultatą „HELLO“.

Taip, bet tam reikia atlikti kelis veiksmus. Pirmiausia pažymėkite langelį ar langelius, kur tai turėtų įvykti. Paspaudę Ctrl + 1 atidarykite dialogo langą Formatas > Langeliai ir dalyje Lygiuotė > Teksto tvarkymas pažymėkite parinktį Kelti teksto eilutę. Tada koreguokite savo užbaigtą TEXT funkciją, įtraukdami ASCII funkciją CHAR(10), kur norite įterpti eilutės lūžį. Gali tekti koreguoti stulpelio plotį, atsižvelgiant į tai, kaip lygiuojamas galutinis rezultatas.

TEXT naudojimo su CHAR(10) eilutės lūžiui įterpti pavyzdys. ="Šiandien yra: "&CHAR(10))&TEXT(TODAY(),"MM/DD/YY")

Šiuo atveju naudojome: ="Šiandien yra: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy")

Tai vadinama tikslia išraiška. „Excel“ automatiškai konvertuos ilgesnius nei 12 skaitmenų skaičius, jei langelis (-iai) suformatuotas (-i) kaip Bendra. Ilgesni nei 15 skaitmenų skaičiai bus konvertuojami, jei langelis (-iai) suformatuotas (-i) kaip Skaičius. Jei jums reikia įvesti ilgas skaitinės eilutes, bet nenorite, kad jos būtų konvertuojamos, prieš įvesdami arba įklijuodami reikšmes programoje „Excel“, formatuokite reikiamus langelius kaip Tekstas.

„Excel“ MVP Mynda Treacy

Mynda rekomenduoja...

Jei bendrinate „Excel“ failus ir ataskaitas su vartotojais iš skirtingų šalių, galite pateikti jiems ataskaitą jų kalba. „Excel“ MVP Mynda Treacy šiame straipsnyje „Excel“ datos rodomos skirtingomis kalbomis pateikia puikų sprendimą. Jame taip pat pateikiamas darbaknygės pavyzdys, kurį galite atsisiųsti.

Taip pat žr.

Pasirinktinio skaičių formato kūrimas arba naikinimas

Teksto konvertavimas į skaičius

Visos „Excel“ funkcijos (pagal kategoriją)

Tobulinkite savo įgūdžius
Ieškoti mokymo
Pirmiausia gaukite naujų funkcijų
Prisijunkite prie „Office Insider“ dalyvių

Ar ši informacija buvo naudinga?

Dėkojame už jūsų atsiliepimus!

Dėkojame už jūsų atsiliepimą! Panašu, kad gali būti naudinga jus sujungti su vienu iš mūsų „Office“ palaikymo agentų.

×