Funkcija SUM

Funkcija SUM, viena iš matematikos ir trigonometrijos funkcijų, sudeda reikšmes. Galima sudėti atskiras reikšmes, langelių nuorodas, jų diapazonus arba naudoti visų trijų būdų derinį.

Pavyzdžiui:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Jūsų naršyklė nepalaiko vaizdo įrašo. Įdiekite „Microsoft Silverlight“, „Adobe Flash Player“ ar „Internet Explorer 9“.

Šis vaizdo įrašas yra mokymo kursų Skaičių įtraukimas „Excel 2013“ dalis.

SUM(skaičius1,[skaičius2],...)

Argumento pavadinimas

Aprašas

skaičius1    (būtina)

Pirmasis skaičius, kurį norite sudėti. Skaičius gali būti 4, a langelio nuoroda kaip B6 arba langelis diapazonas kaip B2:B8.

skaičius2-255    (pasirinktinai)

Tai antrasis skaičius, kurį norite sudėti. Taip galima nurodyti iki 255 skaičių.

Jei norite greitai gauti langelių diapazono sumą, tereikia pasirinkti diapazoną ir peržiūrėti apatiniame dešiniajame „Excel“ lango kampe pateiktą informaciją.

Ekrano kopija, rodanti langelių diapazono pasirinkimą, tada paiešką būsenos juostoje
Būsenos juosta


Tai būsenos juosta, kurioje rodoma informacija apie pasirinktą sritį. Tai gali būti vienas langelis arba keli langeliai. Dešiniuoju pelės mygtuku spustelėjus būsenos juostą rodomas funkcijų dialogo langas, kuriame pateikiamos visos parinktys, kurias galima pasirinkti. Atkreipkite dėmesį, kad taip pat rodomos pasirinkto diapazono reikšmės, jeigu pažymėjote šiuos atributus. Sužinokite daugiau apie būsenos juostą.

Paprasčiausias būdas įtraukti SUM formulę į darbalapį yra naudoti automatinės sudėties vediklį. Pažymėkite tuščią langelį tiesiai virš diapazono, kurį norite sumuoti, arba po juos, tada juostelės skirtuke Pagrindinis ar Formulė paspauskite Automatinė sudėtis > Suma. Automatinės sudėties vediklis automatiškai nustatys sudėties diapazoną ir sukurs formulę. Pasirinkus langelį sudedamo diapazono kairėje ar dešinėje, funkcija taip pat veikia horizontaliai. Atkreipkite dėmesį, kad funkcija neveiks ne gretimuose diapazonuose, tačiau tai apžvelgsime kitame skyriuje.

Automatinės sudėties vediklyje galite automatiškai sukurti formulę SUM.  Pasirinkite diapazoną aukščiau/žemiau arba į kairę/dešinę nuo diapazono, kurį norite sumuoti, ir eikite į juostelės skirtuką Formulė, tada pasirinkite Automatinė sudėtis ir SUM.
Automatinės sudėties vediklį naudokite norėdami greitai sudėti gretimus diapazonus


Dialogo lange Automatinė sudėtis taip pat galima pasirinkti kitas įprastas funkcijas, pvz.:

Automatinė sudėtis vertikaliai

Langelyje B6 rodoma automatinės sudėties formulė SUM: =SUM(B2:B5)

Automatinės sudėties vediklis automatiškai aptiko langelius B2: B5 kaip diapazoną, kurį reikia sudėti. Tereikia paspausti „Enter“, kad jį patvirtintumėte. Jei reikia įtraukti / pašalinti kelis langelius, laikykite nuspaudę klavišą „Shift“ > reikiamą rodyklės klavišą, kol pasirinksite reikiamus langelius, tada paspauskite „Enter“.

„IntelliSense“ funkcijos vadovas: SUM(skaičius1,[skaičius2],...) slankioji žymė po funkcija yra jos „IntelliSense“ vedlys. Spustelėjus SUM ar funkcijos pavadinimą, jis bus rodomas kaip mėlynos spalvos hipersaitas, kurį spustelėjus galima atidaryti tos funkcijos žinyno temą. Spustelėjus atskirus funkcijos elementus, bus paryškintos atitinkamos formulės dalys. Šiuo atveju bus paryškinta tik B2: B5, nes šioje formulėje yra tik viena skaičiaus nuoroda. „IntelliSense“ žymė rodoma visoms funkcijoms.

Automatinė sudėtis horizontaliai

Langelyje D2 rodoma automatinės sudėties formulė SUM: =SUM(B2:C2)

Funkcijos SUM naudojimas su ne gretimais diapazonais.  Langelyje C8 formulė yra =SUM(C2:C3,C5:C6). Taip pat gali naudoti pavadintus diapazonus, kad formulė būtų =SUM(Week1,Week2).

Automatinės sudėties vediklis paprastai veikia tik su gretimais diapazonais, todėl jei sudėties diapazone yra tuščių eilučių ar stulpelių, „Excel“ sustabdys skaičiavimą po pirmojo tarpo. Tokiu atveju reikia atlikti pasirinktos srities sudėtį SUM, kai sudedami atskiri diapazonai. Šiame pavyzdyje, jei turėjote duomenų langelyje B4, „Excel“ generuotų =SUM(C2:C6), nes programa atpažintų greta esantį diapazoną.

Kelis ne gretimus diapazonus galima greitai pasirinkti spustelėjant Ctrl + kairįjį pelės mygtuką. Iš pradžių įveskite „= SUM (“, tada pasirinkite skirtingus diapazonus ir „Excel“ automatiškai įtrauks kablelį tarp diapazonų. Baigę paspauskite „Enter“.

PATARIMAS. Jei norite greitai įtraukti į langelį SUM funkciją, naudokite ALT + =. Tada tereikia pasirinkti diapazoną (-us).

Pastaba. Galite pastebėti, kad „Excel“ paryškino funkcijos diapazonus skirtingomis spalvomis, kurios atitinka pačioje formulėje, todėl C2: C3 yra vienos spalvos, o C5:C6 – kitos. „Excel“ taip veikia su visomis funkcijomis, nebent nurodytas diapazonas yra kitame darbalapyje ar kitoje darbaknygėje. Kaip patobulintą pritaikymą neįgaliesiems su pagalbinėmis technologijomis galima naudoti Įvardintus diapazonus, pvz., „Savaitė1“, „Savaitė2“ ir t. t., tada nurodyti juos formulėje:

=SUM(savaitė1,savaitė2)

Galite lengvai atlikti matematines operacijas programoje „Excel“ kartu su „Excel“ funkcijomis, pvz., SUM. Šioje lentelėje išvardijami operatoriai, kuriuos galite naudoti, kartu su tam tikromis susijusiomis funkcijomis. Operatorius galite įvesti iš skaičių eilutės savo klaviatūroje arba 10 klavišų rinkiklio, jei tokį naudojate. Pavyzdžiui, Shift + 8 įves žvaigždutę (*) daugybai.

Operatorius

Operacija

Pavyzdžiai

+

Sudėtis

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Atimtis

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Daugyba

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) – funkcija PRODUCT

/

Dalyba

=1/1

= A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) – funkcija QUOTIENT

^

Kėlimas laipsniu

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) – funkcija POWER

Daugiau informacijos ieškokite Programos „Excel“ naudojimas skaičiavimams.

Kiti pavyzdžiai

  1. Tarkime, kad norite taikyti procentinę nuolaida langelių, kuriuose atlikote sudėtį, diapazonui.

    Operatorių naudojimas su SUM.  Formulė langelyje B16 yra =SUM(A2:A14)*-25%.  Formulė būtų sudaryta tinkamai, jei -25 % būrų langelio nuoroda, pvz., =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Bus pateikta 25 % sudėto diapazono reikšmė, tačiau formulėje bus užprogramuojami 25 %, todėl vėliau gali būti sudėtinga rasti šią reikšmę. Daug patogiau įvesti 25 % langelyje jį nurodyti, nes tokiu atveju jį lengva rasti ir pakeisti:

    • =SUM(A2:A14)*E2

    Jei norite dalyti, o ne dauginti, paprasčiausiai pakeiskite „*“ į „/“: = SUM(A2:A14)=SUM(A2:A14)/E2

  2. Pridėjimas prie SUM arba atėmimas

    i. Naudojant + arba - paprasta pridėti prie SUM arba atimti:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Šiame skyriuje aptariamos darbo su SUM funkcijomis geriausios praktikos. Daug informacijos tinka darbui su kitomis funkcijomis.

=1+2 ar =A+B metodas – nors galima įvesti =1+2+3 ar =A1+B1+C2 ir gauti visiškai tikslius atsakymus, naudojant šiuos metodus dėl kelių priežasčių gali įsivelti klaidų:

  1. Rašybos klaidos – įsivaizduokite, kad reikia įvesti daugiau ir daug ilgesnių reikšmių, pvz.:

    • =14598,93+65437,90+78496,23

    Tada reikia patikrinti, ar įvesti įrašai teisingi. Daug paprasčiau perkelti šias reikšmes į atskirus langelius ir naudoti formulę SUM. Be to, galima formatuoti langeliuose esančias reikšmes, kad jos būtų aiškiau suprantamos, kai bus formulėje.

    Naudokite funkciją SUM vietoj sudėtingai koduojamų reikšmių  formulėje.  Formulė langelyje D5 yra =SUM(D2:D4)
  2. #VALUE! klaidos nurodant tekstą vietoje skaičių

    Jei naudojate formulę, pvz:

    • =A1+B1+C1 ar =A1+A2+A3

    Netinkamo formulės sudarymo pavyzdys.  Formulė langelyje D2 yra =A2+B2+C2

    Formulė gali būti nutraukta, jeigu nurodytuose langeliuose atsiras bent viena ne skaitinė (teksto) reikšmė, todėl bus pateikta klaida #VALUE!. SUM nepaiso teksto reikšmių ir pateikia tik skaitinių reikšmių sumą.

    Tinkamos formulės kūrimas.  Vietoj =A2+B2+C2, langelio D2 formulė yra =SUM(A2:C2)
  3. #REF! klaida panaikinus eilutes arba stulpelius

    Panaikinus stulpelį, rodoma #REF! klaida.  Formulė pakeistas į =A2+#REF!+B2

    Panaikinus eilutę ar stulpelį formulė nebus atnaujinama, kad nebūtų įtraukiama panaikinta eilutė, ir bus rodoma klaida #REF!, o naudojant funkcija SUM formulė bus atnaujinta.

    Funkcija SUM automatiškai pakoreguos įterptas arba panaikintas eilutes ir stulpelius
  4. Formulės neatnaujins nuorodų įterpiant eilutes ar stulpelius

    = A+B+C formulės nebus naujinamos, jei įtrauksite eilutes

    Įterpus eilutę ar stulpelį formulė nebus atnaujinama, kad būtų įtraukta pridėta eilutė, o naudojant funkciją SUM ji bus automatiškai atnaujinama (tol, kol būsite formulėje nurodyto diapazono ribose). Tai ypač svarbu, kai manote, kad formulė bus atnaujinta, nors ji nėra atnaujinama, ir gaunate neišsamius rezultatus, kurie gali neatitikti.

    Pavyzdyje pavaizduota SUM formulė, automatiškai išplėsta nuo =SUM(A2:C2) iki =SUM(A2:D2) įterpus stulpelį
  5. SUM su atskirų langelių nuorodomis ir diapazonai

    Naudojant formulę:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Klaidingi rezultatai taip pat gali būti gauti įterpus ar panaikinus eilutes nurodytame diapazone. Daug tiksliau naudoti atskirus diapazonus, pvz.:

    • =SUM(A1:A3,B1:B3)

    Kurie įtraukus ar panaikinus eilutes bus atnaujinti.

  1. SUM galima naudoti su kitomis funkcijomis. Toliau pateiktas pavyzdys, kuriuo sukuriamas mėnesio vidurkio skaičiavimas:

    Funkcijos SUM naudojimas su kitomis funkcijomis.  Formulė langelyje M2 yra =SUM(A2:L2)/COUNTA(A2:L2).  Pastaba: gegužės–lapkričio stulpeliai slepiami informacija, kad būtų aiškiau.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. A2:L2 suma SUM padalijama iš ne tuščių langelių A2:L2 skaičiaus (langeliai nuo gegužės iki gruodžio yra tušti).

  1. Kartais reikia sudėti konkretų stulpelį, esantį keliuose darbalapiuose. Gali atrodyti patrauklu spustelėti kiekviena lapą ir langelį, tada paprasčiausiai naudoti „+“, kad būtų sudėtos reikšmės, tačiau taip ilgai užtruksite ir galima įvelti klaidų.

    • =Lapas1!A1+Lapas2!A1+Lapas3!A1

    Naudojant 3D arba 3 matmenų SUM funkciją šią užduotį galima atlikti daug lengviau:

    3D Sum – langelio D2 formulė yra =SUM(Sheet1:Sheet3! A2)
    • =SUM(Lapas1:Lapas3!A1)

    Bus sudėtos visų A1 langelių lapuose nuo 1 iki 3 reikšmės.

    Tai ypač naudinga, jeigu kiekvienam mėnesiui yra skirtas atskiras lapas (nuo sausio iki gruodžio) ir jums reikia gauto bendrą sumą suvestinės lape.

    3D SUM įvardytuose lapuose.  Formulė D2 langelyje yra =SUM(January:December!A2)
    • =SUM(Sausis:Gruodis!A2)

    Bus sudėtos visų lapų nuo Sausis iki Gruodis langelių A2 reikšmės.

    Pastabos : Jei darbalapių pavadinimai su tarpais, pvz., „Sausio pardavimai“, tada nurodant lapų pavadinimus formulėje būtina naudoti apostrofą. Atkreipkite dėmesį į apostrofą PRIEŠ pirmo darbalapio pavadinimą į dar vieną apostrofą paskutinio pavadinimo.

    • =SUM(‘Sausio pardavimai:Gruodžio pardavimai’!A2)

    3D metodas taip pat veiks su kitomis funkcijomis, pvz., AVERAGE, MIN, MAX, ir kt.

    • =AVERAGE(Lapas1:Lapas3!A1)

    • =MIN(Lapas1:Lapas3!A1)

    • =MAX(Lapas1:Lapas3!A1)

Problema

Kas nutiko

SUM funkcija rodo #####, o ne rezultatą.

Patikrinkite stulpelių plotį. ##### paprastai reiškia, kad stulpelis per siauras, kad jame būtų galima rodyti formulės rezultatą.

SUM funkcija rodo pačią formulę kaip tekstą, o ne rezultatą.

Patikrinkite, ar langelis nėra suformatuotas kaip tekstas. Pasirinkite langelį arba jų diapazoną ir naudokite Ctrl+1, kad iškviestumėte dialogo langą Formatuoti langelius, tada spustelėkite Skaičių skirtuką ir pasirinkite norimą formatą. Jei langelis suformatuotas kaip tekstas ir nėra keičiamas pakeitus formatą, gali prireikti panaudoti F2 > Enter, kad formatas būtų pakeistas priverstinai.

SUM funkcija neatnaujinama.

Įsitikinkite, kad Skaičiavimas nustatytas į Automatinis. Skirtuke Formulė eikite į Skaičiavimo parinktys. Taip pat galima naudoti F9, kad būtų priverstinai atliktas skaičiavimas darbalapyje.

Įsitikinkite, kad nustatytas automatinis skaičiavimas.  Skirtuke Formulė eikite į Skaičiavimo parinktys.

Kai kurios reikšmės nėra sudedamos.

Galima sudėti tik skaitines reikšmes, esančias funkcijos nuorodoje ar diapazone. Tuščių langelių, loginių reikšmių, pvz., TRUE (teisinga), ar teksto nepaisoma.

Vietoj numatyto rezultato rodoma klaida #NAME?.

Paprastai tai reiškia, kad formulė yra įvesta neteisingai, pvz., =sume(A1:A10) vietoje =SUM(A1:A10).

Mano funkcija SUM rodo sveikąjį skaičių, nors ji turėtų rodyti dešimtaines skiltis.

Patikrinkite savo langelio formatavimą, kad įsitikintumėte, jog rodomos dešimtainės skiltys. Pasirinkite langelį arba jų diapazoną ir naudokite Ctrl + 1, kad iškviestumėte dialogo langą Formatuoti langelius, tada spustelėkite Skaičių skirtuką ir pasirinkite norimą formatą, nurodydami norimą dešimtainių skilčių skaičių.

  1. Tiesiog noriu sudėti / atimti / dauginti / dalyti skaičius – žr. šią vaizdo įrašų seriją apie Pagrindinius matematinius veiksmus „Excel“ ar Programos „Excel“ naudojimas skaičiavimams.

  2. Kaip Rodyti daugiau/mažiau dešimtainio skyriklio skaičių? – Galima keisti skaičių formatą. Pasirinkite langelį arba jų diapazoną ir naudokite Ctrl + 1, kad iškviestumėte dialogo langą Formatuoti langelius, tada spustelėkite Skaičių skirtuką ir pasirinkite norimą formatą, nurodydami pageidaujamą dešimtainių skilčių skaičių.

  3. Kaip pridėti ar atimti laiką? Galite pridėti ir atimti laiką keliais skirtingais būdais. Pvz., norėdami gauti skirtumą tarp 8:00 ir 12:00 atlyginimo skaičiavimo tikslais, galite naudoti: = ("12:00"-"8:00")*24, iš pabaigos laiko atimdami pradžios laiką. Atkreipkite dėmesį, kad „Excel“ skaičiuoja laiko reikšmes kaip dienos dalis, todėl būtina dauginti iš 24, kad gautumėte bendrą valandų skaičių. Pirmame pavyzdyje naudojame =((B2-A2)+(D2-C2))*24, kad gautume valandų sumą nuo pradžios iki pabaigos, atėmus pietų pertrauką (iš viso 8,50 val.).

    Jei tiesiog sudedate valandas ir minutes ir norite, kad taip ir būtų rodoma, tada galite tiesiog sumuoti ir nedauginti iš 24, taigi antrame pavyzdyje naudojame =SUM(A6:C6), kadangi mums reikia tiktai bendro paskirtų užduočių valandų ir minučių skaičiaus (5:36, arba 5 val. 36 min.).

    Laiko skaičiavimas

    Daugiau informacijos ieškokite: Laiko pridėjimas arba atėmimas.

  4. Kaip gauti skirtumą tarp datų? Kaip ir su laiko reikšmėmis, datų reikšmes galima sudėti ir atimti. Toliau pateiktas bendras dienų skaičiavimo tarp dviejų datų pavyzdys. Tai paprasta kaip naudoti =B2-A2. Darbo su datų ir laikų reikšmėmis pagrindas yra tas, kad iš pabaigos datos / laiko būtina atimti pradžios datą / laiką.

    Skirtumo tarp datų skaičiavimas

    Daugiau darbo su datų reikšmėmis būdų žr.: Dienų skaičiaus tarp dviejų datų skaičiavimas.

  5. Kaip galima sumuoti tik matomus langelius? Kartais, kai rankiniu būdu paslepiate eilutes arba naudojate automatinio filtravimo funkciją, kad būtų rodomi tik tam tikri duomenys, galite norėti sumuoti tik matomus langelius. Galite naudoti funkciją SUBTOTAL. Jei naudojate sumos eilutę „Excel“ lentelėje, bet kuri funkcija, kurią pasirenkate iš sumos išplečiamojo sąrašo, bus automatiškai įrašyta kaip tarpinė suma. Žr. daugiau informacijos apie Duomenų sumavimą „Excel“ lentelėje.

Reikia daugiau pagalbos?

Visada galite paprašyti specialisto iš „Excel“ technologijų bendruomenės, gauti pagalbos iš Atsakymų bendruomenės arba siūlyti naują funkciją ar patobulinimą „Excel“ vartotojo balse.

Taip pat žr.

Peržiūrėkite vaizdo įrašą, kaip naudoti funkciją SUM

Funkcija SUMIF sudeda tik reikšmes, kurios atitinka vieną kriterijų.

Funkcija SUMIFS sudeda tik reikšmes, kurios atitinka kelis kriterijus

Funkcija COUNTIF sudeda tik reikšmes, kurios atitinka vieną kriterijų

Funkcija COUNTIFS sudeda tik reikšmes, kurios atitinka kelis kriterijus

„Excel“ formulių apžvalga

Kaip išvengti sugadintų formulių

Klaidų formulėse radimas ir taisymas

„Excel“, skirtos „Windows“, spartieji klavišai

„Excel“, skirtos „Mac“, spartieji klavišai

Matematinės ir trigonometrinės funkcijos

„Excel“ funkcijos (pagal abėcėlę)

„Excel“ funkcijos (pagal kategoriją)

Tobulinkite savo įgūdžius
Ieškoti mokymo
Pirmiausia gaukite naujų funkcijų
Prisijunkite prie „Office Insider“ dalyvių

Ar ši informacija buvo naudinga?

Dėkojame už jūsų atsiliepimus!

Dėkojame už jūsų atsiliepimą! Panašu, kad gali būti naudinga jus sujungti su vienu iš mūsų „Office“ palaikymo agentų.

×