Microsoft로 로그인
로그인하거나 계정을 만듭니다.
안녕하세요.
다른 계정을 선택합니다.
계정이 여러 개 있음
로그인할 계정을 선택합니다.
함수를 사용하여 여러 셀로 텍스트 분할

LEFT, MID, RIGHT, SEARCH 및 LEN 텍스트 함수를 사용하여 데이터의 텍스트 문자열을 조작할 수 있습니다. 예를 들어 단일 셀의 첫 번째, 가운데 및 성을 세 개의 개별 열로 배포할 수 있습니다.

텍스트 함수를 사용하여 이름 구성 요소를 배포하는 키는 텍스트 문자열 내에서 각 문자의 위치입니다. 텍스트 문자열 내의 공백 위치도 문자열의 이름 구성 요소의 시작 또는 끝을 나타내기 때문에 중요합니다.

예를 들어 이름과 성만 포함된 셀에서 성이 공백의 첫 번째 instance 이후에 시작됩니다. 목록의 일부 이름에는 중간 이름이 포함될 수 있습니다. 이 경우 성이 공백의 두 번째 instance 이후에 시작됩니다.

이 문서에서는 이러한 편리한 함수를 사용하여 다양한 이름 형식에서 다양한 구성 요소를 추출하는 방법을 보여 줍니다. 텍스트를 열로 변환 마법사를 사용하여 텍스트를 다른 열로 분할할 수도 있습니다.

예제 이름

설명

이름

중간 이름

접미사

1

제프 스미스

중간 이름 없음

진식

Smith

2

Eric S. Kurjan

중간 이니셜 1개

Eric

S.

쿠르잔 (쿠르잔)

3

야나이나 비 G. 흠

두 개의 중간 이니셜

자나이나 주

B. G.

4

칸, 웬디 베스

성 첫 번째, 쉼표 사용

웬디

Beth

5

메리 케이 디 앤더슨

두 부분으로 된 이름

메리 케이

D.

6

폴라 바레토 드 마토스

3부로 구성된 성

폴라

바레토 데 마토스

7

제임스 반 이튼

2부로 구성된 성

제임스

반 이튼

8

베이컨 주니어, 댄 K.

성 및 접미사 먼저, 쉼표 사용

K.

베이컨

Jr.

9

게리 알트만 III

접미사

Gary

알트

III

10

라이언 이리그 씨

접두사

Ryan

이리그 주

11

줄리 Taft-Rider

하이픈 처리된 성

조미선

Taft-Rider

참고: 다음 예제의 그래픽에서 전체 이름의 강조 표시에는 일치하는 SEARCH 수식이 찾고 있는 문자가 표시됩니다.

다음은 이름과 성의 두 구성 요소를 구분하는 예제입니다. 단일 공간은 두 이름을 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

제프 스미스

중간 이름 없음

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름

    이름은 문자열에서 첫 번째 문자(J)로 시작하여 5번째 문자(공백)에서 끝납니다. 수식은 셀 A2에서 왼쪽부터 5개 문자를 반환합니다.

    이름을 추출하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 계산한 공백의 숫자 위치를 검색합니다.

  2. 성은 오른쪽 5개 문자이며 공백에서 시작하여 오른쪽의 마지막 문자(h)에서 끝납니다. 수식은 A2에서 오른쪽부터 5개 문자를 추출합니다.

    성을 추출하는 수식

    SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 계산한 공백의 숫자 위치를 검색합니다. (5)

  3. 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 1단계에서 찾은 첫 번째 공백까지의 문자 수를 뺍니다.

이 예제에서는 이름, 중간 이니셜 및 성을 사용합니다. 공백은 각 이름 구성 요소를 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

Eric S. Kurjan

중간 이니셜 1개

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(중간 이니셜)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

수식

라이브 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름

    이름은 왼쪽(E)의 첫 번째 문자로 시작하고 다섯 번째 문자(첫 번째 공백)로 끝납니다. 수식은 왼쪽에서 시작하여 A2의 처음 5자를 추출합니다.

    이름과 성 및 중간 이니셜을 구분하기 위한 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 계산한 공백의 숫자 위치를 검색합니다. (5)

  2. 중간 이름

    가운데 이름은 여섯 번째 문자 위치(S)에서 시작하여 여덟 번째 위치(두 번째 공백)에서 끝납니다. 이 수식에는 공백의 두 번째 instance 찾기 위해 SEARCH 함수 중첩이 포함됩니다.

    수식은 여섯 번째 위치에서 시작하여 세 문자를 추출합니다.

    이름, 중간 이름, 성을 구분하는 수식의 세부 정보

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5).

  3. 1을 추가하여 첫 번째 공백(S) 뒤에 있는 문자의 위치를 가져옵니다. 이 숫자 위치는 중간 이름의 시작 위치입니다. (5 + 1 = 6)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  4. 1을 추가하여 첫 번째 공백(S) 뒤에 있는 문자의 위치를 가져옵니다. 그 결과 공간의 두 번째 instance 검색을 시작할 문자 번호가 생성됩니다. (5 + 1 = 6)

  5. 4단계에서 찾은 여섯 번째 위치(S)부터 A2의 두 번째 공간 instance 검색합니다. 이 문자 번호는 중간 이름의 끝 위치입니다. (8)

  6. 왼쪽의 첫 번째 문자부터 시작하여 A2에서 공백의 숫자 위치를 검색합니다. (5)

  7. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계에서 찾은 첫 번째 공백의 문자 번호를 뺍니다. 그 결과 2단계의 여섯 번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출한 문자 수가 생성됩니다. (8 – 5 = 3)

  8. 성은 오른쪽(K)에서 6자로 시작하고 오른쪽(n)의 첫 번째 문자로 끝납니다. 이 수식에는 공백의 두 번째 및 세 번째 인스턴스(왼쪽에서 다섯 번째 및 여덟 번째 위치에 있는)를 찾기 위해 SEARCH 함수 중첩이 포함됩니다.

    수식은 오른쪽부터 A2에서 6자를 추출합니다.

    첫 번째, 중간 및 성을 구분하기 위한 수식의 두 번째 SEARCH 함수
  9. LEN 및 중첩된 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽의 첫 번째 문자부터 시작하여 A2에서 공백의 숫자 위치를 검색합니다. (5)

  10. 1을 추가하여 첫 번째 공백(S) 뒤에 있는 문자의 위치를 가져옵니다. 그 결과 공간의 두 번째 instance 검색을 시작할 문자 번호가 생성됩니다. (5 + 1 = 6)

  11. 2단계에서 찾은 여섯 번째 위치(S)부터 A2의 두 번째 공간 instance 검색합니다. 이 문자 번호는 중간 이름의 끝 위치입니다. (8)

  12. A2에서 텍스트 문자열의 총 길이를 계산한 다음 왼쪽에서 3단계의 두 번째 instance 간격까지 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (14 – 8 = 6).

다음은 두 개의 중간 이니셜을 추출하는 방법의 예입니다. 공간의 첫 번째 인스턴스와 세 번째 인스턴스는 이름 구성 요소를 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

야나이나 비 G. 흠

두 개의 중간 이니셜

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(중간 이니셜)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

수식

라이브 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 이름

    이름은 왼쪽(J)의 첫 번째 문자로 시작하고 여덟 번째 문자(첫 번째 공백)로 끝납니다. 수식은 왼쪽에서 시작하여 A2의 처음 8자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (8)

  2. 중간 이름

    중간 이름은 9번째 위치(B)에서 시작하여 14번째 위치(세 번째 공백)에서 끝납니다. 이 수식에는 검색을 중첩하여 8번째, 11번째 및 14번째 위치에서 공간의 첫 번째, 두 번째 및 세 번째 인스턴스를 찾습니다.

    수식은 아홉 번째 위치에서 시작하여 5자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  3. 1을 추가하여 첫 번째 공백(B) 뒤에 있는 문자의 위치를 가져옵니다. 이 숫자 위치는 중간 이름의 시작 위치입니다. (8 + 1 = 9)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  4. 1을 추가하여 첫 번째 공백(B) 뒤에 있는 문자의 위치를 가져옵니다. 그 결과 공간의 두 번째 instance 검색을 시작할 문자 번호가 생성됩니다. (8 + 1 = 9)

  5. 4단계에서 찾은 9번째 위치(B)부터 A2에서 두 번째 공간을 검색합니다. (11).

  6. 1을 추가하여 두 번째 공백(G) 뒤에 있는 문자의 위치를 가져옵니다. 이 문자 번호는 세 번째 공간 검색을 시작할 시작 위치입니다. (11 + 1 = 12)

  7. 6단계에서 찾은 열두 번째 위치에서 시작하여 A2에서 세 번째 공간을 검색합니다. (14)

  8. A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (8)

  9. 7단계에 있는 세 번째 공간의 문자 번호를 가져와서 6단계에서 찾은 첫 번째 공간의 문자 번호를 뺍니다. 그 결과 2단계의 9번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출한 문자 수가 생성됩니다.

  10. 성은 오른쪽(B)에서 5자로 시작하고 오른쪽(o)의 첫 번째 문자로 끝납니다. 이 수식에는 공간의 첫 번째, 두 번째 및 세 번째 인스턴스를 찾기 위해 SEARCH 중첩이 포함됩니다.

    수식은 전체 이름의 오른쪽에서 시작하여 A2에서 5자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    중첩된 SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  11. 1을 추가하여 첫 번째 공백(B) 뒤에 있는 문자의 위치를 가져옵니다. 그 결과 공간의 두 번째 instance 검색을 시작할 문자 번호가 생성됩니다. (8 + 1 = 9)

  12. 2단계에서 찾은 9번째 위치(B)부터 A2에서 두 번째 공간을 검색합니다. (11)

  13. 1을 추가하여 두 번째 공백(G) 뒤에 있는 문자의 위치를 가져옵니다. 이 문자 번호는 세 번째 공간 instance 검색을 시작할 시작 위치입니다. (11 + 1 = 12)

  14. 6단계에서 찾은 12번째 위치(G)부터 A2의 세 번째 공간을 검색합니다. (14)

  15. A2에서 텍스트 문자열의 총 길이를 계산한 다음 왼쪽에서 5단계의 세 번째 공백까지 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (19 - 14 = 5)

이 예제에서는 성이 이름 앞에 오고 중간 이름이 끝에 나타납니다. 쉼표는 성의 끝을 표시하고 공백은 각 이름 구성 요소를 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

칸, 웬디 베스

성 첫 번째, 쉼표 사용

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

수식

결과(중간 이름)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

수식

라이브 결과(성)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. 이름

    이름은 왼쪽의 7번째 문자(W)로 시작하여 12번째 문자(두 번째 공백)에서 끝납니다. 이름이 전체 이름의 중간에 표시되므로 MID 함수를 사용하여 이름을 추출해야 합니다.

    수식은 일곱 번째 위치에서 시작하여 6자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 이 숫자 위치는 이름의 시작 위치입니다. (6 + 1 = 7)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  3. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (6 + 1 = 7)

    4단계에서 찾은 7번째 위치(W)부터 A2의 두 번째 공백을 검색합니다. (12)

  4. A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  5. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계에서 찾은 첫 번째 공백의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 7번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (12 - 6 = 6)

  6. 중간 이름

    중간 이름은 오른쪽에서 4번째 문자(B)에서 시작하여 오른쪽에서 첫 번째 문자(h)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 왼쪽에서 6번째와 12번째 위치에서 첫 번째와 두 번째 공백을 찾습니다.

    수식은 오른쪽에서 시작하여 4자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  7. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (6 + 1 = 7)

  8. 2단계에서 찾은 7번째 위치(W)부터 A2의 두 번째 공백을 검색합니다. (12)

  9. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 3단계에서 찾은 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (16 - 12 = 4)

  10. 성은 왼쪽에서 첫 번째 문자(K)로 시작하여 네 번째 문자(n)에서 끝납니다. 수식은 왼쪽부터 4개 문자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  11. 2를 빼서 성(n)의 끝 문자의 숫자 위치를 가져옵니다. 결과는 LEFT 함수로 추출하는 문자 수입니다. (6 - 2 =4)

이 예제에서는 두 부분으로 구성된 이름인 Mary Kay를 사용합니다. 두 번째와 세 번째 공백은 각 이름 구성 요소를 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

메리 케이 디 앤더슨

두 부분으로 된 이름

수식

결과(이름)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

수식

결과(중간 이니셜)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,1)+1)+1)))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)+SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,1)+1)+1)+1))

수식

라이브 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 이름

    첫 번째 이름은 왼쪽의 첫 번째 문자로 시작하고 아홉 번째 문자(두 번째 공백)로 끝납니다. 이 수식에는 왼쪽에서 두 번째 공간 instance 찾기 위해 SEARCH 중첩이 포함됩니다.

    수식은 왼쪽에서 시작하여 9자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  2. 1을 추가하여 첫 번째 공백(K) 뒤에 있는 문자의 위치를 가져옵니다. 그 결과 공간의 두 번째 instance 검색을 시작할 문자 번호가 생성됩니다. (5 + 1 = 6)

  3. 2단계에서 찾은 여섯 번째 위치(K)부터 A2의 두 번째 공간 instance 검색합니다. 그 결과 텍스트 문자열에서 LEFT 추출된 문자 수가 생성됩니다. (9)

  4. 중간 이름

    가운데 이름은 10번째 위치(D)에서 시작하여 열두 번째 위치(세 번째 공백)로 끝납니다. 이 수식에는 공간의 첫 번째, 두 번째 및 세 번째 인스턴스를 찾기 위해 SEARCH 중첩이 포함됩니다.

    수식은 10번째 위치에서 시작하여 가운데에서 두 문자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    중첩된 SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  5. 1을 추가하여 첫 번째 공백(K) 뒤에 있는 문자를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (5 + 1 = 6)

  6. 2단계에서 찾은 여섯 번째 위치(K)부터 A2의 두 번째 공간 instance 위치를 검색합니다. 그 결과 왼쪽에서 왼쪽에서 추출된 문자 수가 생성됩니다. (9)

  7. 1을 추가하여 두 번째 공간(D) 뒤에 있는 문자를 가져옵니다. 결과는 중간 이름의 시작 위치입니다. (9 + 1 = 10)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    두 번째 공간(D) 뒤에 있는 문자의 숫자 위치를 검색합니다. 그 결과 세 번째 공간 검색을 시작할 문자 번호가 생성됩니다. (10)

  8. 왼쪽부터 A2에서 세 번째 공간의 숫자 위치를 검색합니다. 결과는 중간 이름의 끝 위치입니다. (12)

  9. 두 번째 공간(D) 뒤에 있는 문자의 숫자 위치를 검색합니다. 결과는 중간 이름의 시작 위치입니다. (10)

  10. 6단계에서 찾은 세 번째 공백의 문자 번호를 가져와서 7단계에서 찾은 "D"의 문자 번호를 뺍니다. 그 결과 4단계에서 찾은 10번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출한 문자 수가 생성됩니다. (12 - 10 = 2)

  11. 성은 오른쪽에서 8자를 시작합니다. 이 수식에는 검색을 중첩하여 다섯 번째, 아홉 번째 및 열두 번째 위치에서 공간의 첫 번째, 두 번째 및 세 번째 인스턴스를 찾습니다.

    수식은 오른쪽에서 8자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    중첩된 SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  12. 1을 추가하여 첫 번째 공백(K) 뒤에 있는 문자를 가져옵니다. 그 결과 공간 검색을 시작할 문자 번호가 생성됩니다. (5 + 1 = 6)

  13. 2단계에서 찾은 여섯 번째 위치(K)부터 A2에서 두 번째 공간을 검색합니다. (9)

  14. 1을 추가하여 두 번째 공간(D) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 중간 이름의 시작 위치입니다. (9 + 1 = 10)

  15. 왼쪽부터 A2에서 세 번째 공간의 숫자 위치를 검색합니다. 결과는 중간 이름의 끝 위치입니다. (12)

  16. A2에서 텍스트 문자열의 총 길이를 계산한 다음 왼쪽에서 5단계의 세 번째 공백까지 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (20 - 12 = 8)

이 예제에서는 3부로 구성된 성 Barreto de Mattos를 사용합니다. 첫 번째 공백은 이름의 끝과 성의 시작을 표시합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

폴라 바레토 드 마토스

3부로 구성된 성

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름

    첫 번째 이름은 왼쪽(P)의 첫 번째 문자로 시작하고 여섯 번째 문자(첫 번째 공백)로 끝납니다. 수식은 왼쪽에서 6자를 추출합니다.

    이름과 세 부분으로 된 성을 구분하기 위한 수식

    Search 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  2. 성은 오른쪽(B)에서 17자로 시작하고 오른쪽의 첫 문자로 끝납니다. 수식은 오른쪽에서 17자를 추출합니다.

    이름과 세 부분으로 된 성을 구분하기 위한 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  3. A2에서 텍스트 문자열의 총 길이를 계산한 다음, 1단계에서 찾은 왼쪽에서 첫 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (23 - 6 = 17)

이 예제에서는 두 부분으로 구성된 성인 van Eaton을 사용합니다. 첫 번째 공백은 이름의 끝과 성의 시작을 표시합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

제임스 반 이튼

2부로 구성된 성

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름

    이름은 왼쪽(J)의 첫 번째 문자로 시작하고 여덟 번째 문자(첫 번째 공백)로 끝납니다. 수식은 왼쪽에서 6자를 추출합니다.

    이름, 성의 두 부분을 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  2. 성은 오른쪽(v)의 아홉 번째 문자로 시작하고 오른쪽(n)의 첫 번째 문자로 끝납니다. 수식은 전체 이름의 오른쪽에서 9자를 추출합니다.

    이름, 성의 두 부분을 구분하는 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  3. A2에서 텍스트 문자열의 총 길이를 계산한 다음, 1단계에서 찾은 왼쪽에서 첫 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (15 - 6 = 9)

이 예제에서는 성 뒤에 접미사가 붙습니다. 쉼표는 성 및 접미사를 이름과 중간 이니셜과 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

베이컨 주니어, 댄 K.

성 및 접미사 먼저, 쉼표 사용

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)+SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1)+1))

수식

결과(중간 이니셜)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

수식

결과(성)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(접미사)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. 이름

    첫 번째 이름은 12번째 문자(D)로 시작하고 15번째 문자(세 번째 공백)로 끝납니다. 수식은 열두 번째 위치에서 시작하여 세 문자를 추출합니다.

    쉼표로 성 및 접미사를 먼저 구분하는 수식

    중첩된 SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  2. 1을 추가하여 첫 번째 공백(J) 뒤에 있는 문자를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (6 + 1 = 7)

  3. 2단계에서 찾은 일곱 번째 위치(J)부터 A2에서 두 번째 공간을 검색합니다. (11)

  4. 1을 추가하여 두 번째 공간(D) 뒤에 있는 문자를 가져옵니다. 결과는 이름의 시작 위치입니다. (11 + 1 = 12)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    두 번째 공간(D) 뒤에 있는 문자의 숫자 위치를 검색합니다. 그 결과 세 번째 공간 검색을 시작할 문자 번호가 생성됩니다. (12)

  5. 왼쪽부터 A2에서 세 번째 공간의 숫자 위치를 검색합니다. 결과는 이름의 끝 위치입니다. (15)

  6. 두 번째 공간(D) 뒤에 있는 문자의 숫자 위치를 검색합니다. 결과는 이름의 시작 위치입니다. (12)

  7. 6단계에서 찾은 세 번째 공백의 문자 번호를 가져와서 7단계에서 찾은 "D"의 문자 번호를 뺍니다. 그 결과 4단계에서 찾은 12번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출한 문자 수가 생성됩니다. (15 - 12 = 3)

  8. 중간 이름

    가운데 이름은 오른쪽(K)의 두 번째 문자로 시작합니다. 수식은 오른쪽에서 두 문자를 추출합니다.

    쉼표로 성 및 접미사를 먼저 구분하는 수식

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  9. 1을 추가하여 첫 번째 공백(J) 뒤에 있는 문자를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (6 + 1 = 7)

  10. 2단계에서 찾은 일곱 번째 위치(J)부터 A2에서 두 번째 공간을 검색합니다. (11)

  11. 1을 추가하여 두 번째 공간(D) 뒤에 있는 문자를 가져옵니다. 결과는 이름의 시작 위치입니다. (11 + 1 = 12)

  12. 왼쪽부터 A2에서 세 번째 공간의 숫자 위치를 검색합니다. 결과는 중간 이름의 끝 위치입니다. (15)

  13. A2에서 텍스트 문자열의 총 길이를 계산한 다음, 5단계에서 찾은 왼쪽에서 세 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (17 - 15 = 2)

  14. 성은 왼쪽(B)의 첫 번째 문자에서 시작하여 여섯 번째 문자(첫 번째 공백)로 끝납니다. 따라서 수식은 왼쪽에서 6자를 추출합니다.

    쉼표로 성 및 접미사를 먼저 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  15. 접미사

    접미사는 왼쪽(J)의 일곱 번째 문자에서 시작하여 왼쪽(.)의 아홉 번째 문자로 끝납니다. 수식은 일곱 번째 문자부터 세 문자를 추출합니다.

    쉼표로 성 및 접미사를 먼저 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  16. 1을 추가하여 첫 번째 공백(J) 뒤에 있는 문자를 가져옵니다. 결과는 접미사의 시작 위치입니다. (6 + 1 = 7)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  17. 1을 추가하여 첫 번째 공백(J) 뒤에 있는 문자의 숫자 위치를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (7)

  18. 4단계에서 찾은 일곱 번째 문자부터 시작하여 A2에서 두 번째 공간의 숫자 위치를 검색합니다. (11)

  19. 4단계에 있는 두 번째 공백의 문자 번호에서 1을 빼 ""의 문자 번호를 가져옵니다. 결과는 접미사의 끝 위치입니다. (11 - 1 = 10)

  20. 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  21. 첫 번째 공간을 찾은 후 1을 추가하여 3단계와 4단계에서도 다음 문자(J)를 찾습니다. (7)

  22. 6단계에서 찾은 ""의 문자 번호를 가져와서 3단계와 4단계에서 찾은 "J"의 문자 번호를 뺍니다. 그 결과 2단계에서 찾은 7번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출한 문자 수가 생성됩니다. (10 - 7 = 3)

이 예제에서 이름은 문자열의 시작 부분에 있고 접미사는 끝에 있으므로 예제 2와 유사한 수식을 사용할 수 있습니다. LEFT 함수를 사용하여 이름을 추출하고, MID 함수를 사용하여 성을 추출하고, RIGHT 함수를 사용하여 접미사를 추출할 수 있습니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

게리 알트만 III

접미사가 있는 이름과 성

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

수식

결과(접미사)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름

    이름은 왼쪽(G)의 첫 번째 문자에서 시작하여 다섯 번째 문자(첫 번째 공백)로 끝납니다. 따라서 수식은 전체 이름의 왼쪽에서 5자를 추출합니다.

    이름과 성을 구분한 다음 접미사를 구분하는 수식

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  2. 성은 왼쪽(A)의 여섯 번째 문자에서 시작하여 11번째 문자(두 번째 공백)로 끝납니다. 이 수식에는 공백의 위치를 찾기 위해 SEARCH 중첩이 포함됩니다.

    수식은 중간에서 여섯 번째 문자부터 시작하여 6자를 추출합니다.

    이름과 성을 구분한 다음 접미사를 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  3. 1을 추가하여 첫 번째 공백(A) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 성의 시작 위치입니다. (5 + 1 = 6)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  4. 1을 추가하여 첫 번째 공백(A) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (5 + 1 = 6)

  5. 4단계에서 찾은 여섯 번째 문자부터 시작하여 A2에서 두 번째 공간의 숫자 위치를 검색합니다. 이 문자 번호는 성의 끝 위치입니다. (12)

  6. 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  7. 1을 추가하여 3단계와 4단계에서도 첫 번째 공백(A) 뒤에 있는 문자의 숫자 위치를 찾습니다. (6)

  8. 5단계에서 찾은 두 번째 공간의 문자 번호를 가져와서 6단계와 7단계에서 찾은 "A"의 문자 번호를 뺍니다. 그 결과 2단계에서 찾은 6번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출하는 문자 수가 생성됩니다. (12 - 6 = 6)

  9. 접미사

    접미사는 오른쪽에서 세 문자를 시작합니다. 이 수식에는 공백의 위치를 찾기 위해 SEARCH 중첩이 포함됩니다.

    이름과 성을 구분한 다음 접미사를 구분하는 수식

    중첩된 SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (5)

  10. 1을 추가하여 첫 번째 공백(A) 뒤에 있는 문자를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (5 + 1 = 6)

  11. 2단계에서 찾은 여섯 번째 위치(A)부터 A2에서 두 번째 공간을 검색합니다. (12)

  12. A2에서 텍스트 문자열의 총 길이를 계산한 다음, 3단계에서 찾은 왼쪽에서 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (15 - 12 = 3)

이 예제에서는 전체 이름 앞에 접두사를 사용하고 예제 2: MID 함수와 유사한 수식을 사용하여 이름을 추출하고 성을 추출하는 RIGHT 함수를 사용합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

라이언 이리그 씨

접두사

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름

    첫 번째 이름은 왼쪽(R)의 다섯 번째 문자에서 시작하여 아홉 번째 문자(두 번째 공백)로 끝납니다. 수식은 SEARCH를 중첩하여 공백의 위치를 찾습니다. 다섯 번째 위치에서 시작하여 4자를 추출합니다.

    접두사 앞의 이름을 구분하기 위한 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (4)

  2. 1을 추가하여 첫 번째 공백(R) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 이름의 시작 위치입니다. (4 + 1 = 5)

    중첩된 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (4)

  3. 1을 추가하여 첫 번째 공백(R) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (4 + 1 = 5)

  4. 3단계와 4단계에서 찾은 다섯 번째 문자부터 시작하여 A2에서 두 번째 공간의 숫자 위치를 검색합니다. 이 문자 번호는 이름의 끝 위치입니다. (9)

  5. 첫 번째 공간을 검색합니다. (4)

  6. 1을 추가하여 3단계와 4단계에서도 첫 번째 공백(R) 뒤에 있는 문자의 숫자 위치를 찾습니다. (5)

  7. 5단계에서 찾은 두 번째 공간의 문자 번호를 가져와서 6단계와 7단계에서 찾은 "R"의 문자 번호를 뺍니다. 그 결과 2단계의 다섯 번째 위치에서 시작하여 텍스트 문자열에서 MID가 추출하는 문자 수가 생성됩니다. (9 - 5 = 4)

  8. 성은 오른쪽에서 5자를 시작합니다. 이 수식에는 공백의 위치를 찾기 위해 SEARCH 중첩이 포함됩니다.

    접두사 앞의 이름을 구분하기 위한 수식

    중첩된 SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (4)

  9. 1을 추가하여 첫 번째 공백(R) 뒤에 있는 문자의 위치를 가져옵니다. 결과는 두 번째 공백을 검색하기 시작할 문자 번호입니다. (4 + 1 = 5)

  10. 2단계에서 찾은 다섯 번째 위치(R)부터 A2에서 두 번째 공간을 검색합니다. (9)

  11. A2에서 텍스트 문자열의 총 길이를 계산한 다음, 3단계에서 찾은 왼쪽에서 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (14 - 9 = 5)

이 예제에서는 하이픈을 넣은 성을 사용합니다. 공백은 각 이름 구성 요소를 구분합니다.

표의 셀을 복사하여 셀 A1의 Excel 워크시트에 붙여넣습니다. 왼쪽에 표시되는 수식은 참조용으로 표시되고 Excel은 자동으로 오른쪽의 수식을 적절한 결과로 변환합니다.

힌트    워크시트에 데이터를 붙여넣기 전에 A 열과 B 열의 열 너비를 250으로 설정합니다.

예제 이름

설명

줄리 Taft-Rider

하이픈 처리된 성

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름

    첫 번째 이름은 왼쪽의 첫 번째 문자에서 시작하여 여섯 번째 위치(첫 번째 공백)에서 끝납니다. 수식은 왼쪽에서 6자를 추출합니다.

    첫 번째 이름과 하이픈을 넣은 성을 구분하기 위한 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽부터 A2에서 첫 번째 공간의 숫자 위치를 검색합니다. (6)

  2. 전체 성은 오른쪽(T)에서 10자를 시작하고 오른쪽(r)의 첫 번째 문자로 끝납니다.

    첫 번째 이름과 하이픈을 넣은 성을 구분하기 위한 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽의 첫 번째 문자부터 시작하여 A2에서 공간의 숫자 위치를 검색합니다. (6)

  3. 추출할 텍스트 문자열의 총 길이를 계산한 다음, 1단계에서 찾은 왼쪽에서 첫 번째 공백까지의 문자 수를 뺍니다. (16 - 6 = 10)

텍스트 나누기 마법사로 텍스트를 여러 열로 나누기

도움이 더 필요하세요?

더 많은 옵션을 원하세요?

구독 혜택을 살펴보고, 교육 과정을 찾아보고, 디바이스를 보호하는 방법 등을 알아봅니다.

커뮤니티를 통해 질문하고 답변하고, 피드백을 제공하고, 풍부한 지식을 갖춘 전문가의 의견을 들을 수 있습니다.

이 정보가 유용한가요?

언어 품질에 얼마나 만족하시나요?
사용 경험에 어떠한 영향을 주었나요?
제출을 누르면 피드백이 Microsoft 제품과 서비스를 개선하는 데 사용됩니다. IT 관리자는 이 데이터를 수집할 수 있습니다. 개인정보처리방침

의견 주셔서 감사합니다!

×