TEXT 함수를 사용하면 서식 코드를 사용하여 숫자에 서식을 적용하는 방식으로 숫자 표시 방법을 변경할 수 있습니다. 이 함수는 숫자를 더 읽기 좋은 형식으로 표시하거나 숫자를 텍스트 또는 기호와 결합하려는 상황에서 유용합니다.
참고: TEXT 함수는 숫자를 텍스트로 변환하므로 이후 계산에서 참조하기가 어려울 수 있습니다. 원래 값을 한 셀에 유지한 다음, 다른 셀에서 TEXT 함수를 사용하는 것이 가장 좋습니다. 그런 다음 다른 수식을 작성해야 할 경우에는 항상 TEXT 함수 결과가 아닌 원래 값을 참조합니다.
구문
TEXT(값, format_text)
TEXT 함수 구문에는 다음과 같은 인수가 사용됩니다.
|
인수 이름 |
Description(설명) |
|
값 |
텍스트로 변환할 숫자 값입니다. |
|
format_text |
제공된 값에 적용할 서식을 정의하는 텍스트 문자열입니다. |
개요
가장 간단한 형식의 TEXT 함수는 다음과 같은 의미입니다.
-
=TEXT(서식을 지정할 값, "적용할 서식 코드")
다음은 많이 사용하는 예제로, 혼자서 연습할 때 Excel에 직접 복사할 수 있습니다. 따옴표 안의 서식 코드에 주목하세요.
|
수식 |
설명 |
|---|---|
|
=TEXT(1234.567,"$#,##0.00") |
1000 단위 구분 기호 및 소수점 두 자리가 있는 통화(예: $1,234.57). Excel에서 값을 두 개의 소수 자릿수로 반올림함을 알 수 있습니다. |
|
=TEXT(TODAY(),"MM/DD/YY") |
MM/DD/YY 형식의 오늘 날짜(예: 03/14/12) |
|
=TEXT(TODAY(),"DDDD") |
오늘 요일(예: 월요일) |
|
=TEXT(NOW(),"H:MM AM/PM") |
현재 시간(예: 1:29 PM) |
|
=TEXT(0.285,"0.0%") |
백분율(예: 28.5%) |
|
=TEXT(4.34 ,"# ?/?") |
분수(예: 4 1/3) |
|
=TRIM(TEXT(0.34,"# ?/?")) |
분수(예: 1/3). 이 예제는 TRIM 함수를 사용하여 소수 값에서 선행 공백을 제거합니다. |
|
=TEXT(12200000,"0.00E+00") |
과학적 표기법(예: 1.22E+07) |
|
=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####") |
특수(전화 번호)(예: (123) 456-7898) |
|
=TEXT(1234,"0000000") |
앞에 오는 0을 추가합니다(예: 0001234). |
|
=TEXT(123456,"##0° 00' 00''") |
사용자 지정 - 위도/경도 |
참고: TEXT 함수를 사용하여 서식을 변경할 수 있지만 유일한 방법은 아닙니다. Ctrl+1(또는 Mac의 경우 
예제 다운로드
이 문서에서 찾을 수 있는 모든 데이터 TEXT 함수 예제가 포함된 예제 통합 문서 등을 다운로드할 수 있습니다. 자신만의 TEXT 함수 서식 코드를 따르거나 만들 수 있습니다.
Download Excel TEXT function examples(Excel TEXT 함수 예제 다운로드)
사용할 수 있는 기타 서식 코드
셀 서식 대화 상자를 사용하여 사용 가능한 다른 서식 코드를 찾을 수 있습니다.
-
Ctrl+1(Mac에서는
-
표시 형식 탭에서 원하는 서식을 선택합니다.
-
사용자 지정 옵션을 선택합니다.
-
원하는 서식 코드가 형식 상자에 표시됩니다. 이 경우 형식 상자에서 세미콜론(;) 및 @ 기호를 제외하고 모든 것을 선택합니다. 아래 예제에서는 mm/dd/yy를 선택하고 복사했습니다.
-
Ctrl+C를 눌러 서식 코드를 복사한 다음 취소를 눌러 셀 서식 대화 상자를 해제합니다.
-
이제 Ctrl+V를 눌러 서식 코드를 TEXT 수식에 붙여넣으면 됩니다(예: =TEXT(B2,"mm/dd/yy")). 따옴표("서식 코드")에 서식 코드를 붙여넣었는지 확인합니다. 그렇지 않으면 Excel에서 오류 메시지를 표시합니다.
범주별 서식 코드
다음은 셀 서식 대화 상자를 사용하여 값에 다른 숫자 서식을 적용한 다음 사용자 지정 옵션을 사용하여 해당 서식 코드를TEXT 함수에 복사하는 방법의 몇 가지 예입니다.
- 표시 형식 선택
- 앞에 오는 0
- 1000 단위 구분 기호 표시
- 숫자, 통화 및 회계 서식
- 날짜
- 시간
- 백분율
- 분수
- 과학적 표기법
- 특수 서식
Excel에서 선행 0을 삭제하는 이유는 무엇인가요?
Excel은 부품 번호나 SKU 같이 텍스트처럼 보이는 숫자가 아니라 셀에 입력되는 숫자를 검색하도록 학습됩니다. 앞에 오는 0을 유지하려면 값을 붙여넣거나 입력하기 전에 입력 범위의 서식을 텍스트로 지정합니다. 값을 넣을 열 또는 범위를 선택하고, CTRL+1을 사용하여 서식 > 셀 대화 상자를 표시하고, 표시 형식 탭에서 텍스트를 선택합니다. 이제 Excel에서 선행 0이 유지됩니다.
데이터를 이미 입력했는데 Excel에서 앞에 오는 0을 삭제한 경우 TEXT 함수를 사용하여 0을 다시 추가할 수 있습니다. 값이 있는 맨 위의 셀을 참조하고 =TEXT(값,"00000")를 사용한 다음 나머지 범위에 복사하여 붙여넣을 수 있습니다. 여기에서 수식에 있는 0의 수는 원하는 전체 문자 수를 나타냅니다.
어떤 이유로 텍스트 값을 다시 숫자로 변환해야 하는 경우에는 1을 곱하거나(예: =D4*1) 이항 연산자(--)를 사용합니다(예: =--D4).
Excel에서는 서식에 숫자 기호(#) 또는 0으로 둘러싸인 쉼표(,)가 포함된 경우 쉼표로 1000 단위를 구분합니다. 예를 들어 서식 문자열이 "#,###"이면 Excel에서는 숫자 12200000을 12,200,000으로 표시합니다.
숫자 자리 표시자 뒤에 있는 쉼표는 1,000 단위로 숫자를 구분합니다. 예를 들어 서식 문자열이 "#,###.0"인 경우 Excel은 12200000을 12,200.0으로 표시합니다.
참고 사항:
-
1000 단위 구분 기호는 국가별 설정에 따라 다릅니다. 미국에서는 쉼표를 사용하지만 다른 로캘에서는 마침표(.)를 사용할 수 있습니다.
-
1000 단위 구분 기호는 숫자, 통화 및 회계 서식에 사용할 수 있습니다.
다음은 표준 숫자(1000 단위 구분 기호 및 소수만), 통화 및 회계 서식의 예제입니다. 통화 서식을 사용하여 선택한 통화 기호를 삽입할 수 있고 값 옆에 통화를 정렬하지만 회계 서식은 통화 기호를 셀 왼쪽에 정렬하고 값을 오른쪽에 정렬합니다. 아래 통화 및 회계 서식 코드의 차이점을 확인하세요. 이 서식 코드에서 회계는 별표(*)를 사용하여 기호와 값 사이에 구분을 만듭니다.
통화 기호에 대한 서식 코드를 찾으려면 먼저 Ctrl+1(또는 Mac의 경우
그런 다음 범주 섹션의 왼쪽에서 사용자 지정을 클릭하고 통화 기호를 포함한 서식 코드를 복사합니다.
참고: TEXT 함수는 색 서식을 지원하지 않으므로 셀 서식 대화 상자에서 색이 포함된 숫자 서식 코드를 복사하면(예: $#,##0.00_);[Red]($#,##0.00)) TEXT 함수는 서식 코드를 허용하지만 색을 표시하지 않습니다.
"M"(월), "D"(일) 및 "Y"(연도)를 혼합하여 날짜 표시 방법을 변경할 수 있습니다.
TEXT 함수의 서식 코드는 대/소문자를 구분하지 않으므로 "M" 또는 "m", "D" 또는 "d", "Y" 또는 "y"를 사용할 수 있습니다.
|
|
Mynda의 권장 사항... Excel 파일과 보고서를 다른 국가의 사용자와 공유할 경우 사용자에게 해당 언어로 보고서를 제공해야 할 수 있습니다. Excel MVP, Mynda Treacy에게는 이 Excel Dates Displayed in Different Languages(다양한 언어로 표시된 Excel 날짜) 문서에 좋은 해결 방법이 있습니다. 또한 다운로드할 수 있는 샘플 통합 문서가 포함되어 있습니다. |
"H"(시간), "M"(월) 또는 "S"(초)와 "AM/PM"(12시간 시계)을 혼합하여 시간 표시 방법을 변경할 수 있습니다.
"AM/PM" 또는 "A/P"를 제외하면 24시간 시계를 기준으로 시간이 표시됩니다.
TEXT 함수의 서식 코드는 대/소문자를 구분하지 않으므로 "H" 또는 "h", "M" 또는 "m", "S" 또는 "s", "AM/PM" 또는 "am/pm"을 사용할 수 있습니다.
백분율(%) 서식으로 소수 값 표시 방법을 변경할 수 있습니다.
분수(?/?) 서식으로 소수 값 표시 방법을 변경할 수 있습니다. 양식.
과학적 표기법은 1~10 사이의 10진수를 10의 거듭제곱을 곱한 숫자로 표시하는 방법입니다. 종종 큰 수를 표시하는 방법을 줄이는 데 사용됩니다.
Excel에서는 4개의 특수 서식을 제공합니다.
-
우편 번호 - "00000"
-
우편 번호 + 4 - "00000-0000"
-
전화 번호 - "[<=9999999]###-####;(###) ###-####"
-
사회 보장 번호 - "000-00-0000"
특수 서식은 로캘에 따라 달라지지만, 해당 로캘에 대한 특수 서식이 없거나 이러한 특수 서식이 필요에 맞지 않으면 셀 서식 > 사용자 지정 대화 상자를 통해 직접 만들 수 있습니다.
일반적인 시나리오
TEXT 함수는 단독으로는 거의 사용되지 않고 대부분 다른 것과 함께 사용됩니다. 텍스트와 숫자 값을 결합하려고 합니다. 예를 들면 “보고서 인쇄 날짜: 03/14/12" 또는 "주간 수익: $66,348.72"입니다. 해당 정보를 Excel에 수동으로 입력할 수 있지만 그러면 Excel을 사용하는 의미가 없습니다. 아쉽게도 텍스트와 서식 지정된 숫자(예: 날짜, 시간, 통화 등)를 결합하면 Excel이 표시하려는 방법을 이해하지 못하므로 숫자 서식이 삭제됩니다. 이 경우 TEXT 함수를 사용하면 Excel에서 서식 코드(날짜 서식의 경우 "MM/DD/YY")를 사용하여 사용자가 원하는 대로 값에 서식을 적용할 수 있으므로 이 함수가 아주 유용합니다.
다음 예제에서는 TEXT 함수를 사용하지 않고 텍스트와 숫자를 결합하려는 경우 어떻게 되는지 살펴봅니다. 이 경우 앰퍼샌드(&)를 사용하여 텍스트 문자열, 공백(" ") 및 =A2&" "&B2 값을 연결합니다.
Excel이 셀 B2의 날짜에서 서식을 제거했음을 알 수 있습니다. 다음 예제에서는 TEXT 함수를 통해 원하는 서식을 적용하는 방법을 살펴봅니다.
업데이트된 수식은 다음과 같습니다.
-
셀 C2:=A2&" "&TEXT(B2,"mm/dd/yy") - 날짜 형식
질문과 대답
아쉽게도 TEXT 함수에서는 이 작업을 수행할 수 없습니다. VBA(Visual Basic for Applications) 코드를 사용해야 합니다. 다음 링크에는 Excel에서 숫자 값을 영어 단어로 변환하는 방법이 있습니다.
예, 하지만 몇 가지 단계를 수행해야 합니다. 먼저 이 작업을 수행할 셀 또는 셀을 선택하고 Ctrl+1을 사용하여 > 셀 서식 대화 상자를 표시한 다음 텍스트 줄 바꿈 옵션을 > 검사 맞춤 > 텍스트 컨트롤을 표시합니다. 다음으로 완성된 TEXT 함수를 조정하여 줄을 바꾸려는 곳에 ASCII 함수 CHAR(10)를 포함합니다. 최종 결과 정렬 방법에 따라 열 너비를 조정해야 할 수 있습니다.
이 경우 ="Today is: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy")를 사용했습니다.
이를 공학용 표기법이라고 하며 셀의 서식이 일반인 경우 12자리보다 긴 숫자를 자동으로 변환하고 셀의 서식이 숫자인 경우 15자리를 자동으로 변환합니다. 긴 숫자 문자열을 입력해야 하지만 변환하지 않으려면 값을 입력하거나 Excel에 붙여넣기 전에 해당 셀의 서식을 텍스트 로 지정합니다.
|
|
Mynda의 권장 사항... Excel 파일과 보고서를 다른 국가의 사용자와 공유할 경우 사용자에게 해당 언어로 보고서를 제공해야 할 수 있습니다. Excel MVP, Mynda Treacy에게는 이 Excel Dates Displayed in Different Languages(다양한 언어로 표시된 Excel 날짜) 문서에 좋은 해결 방법이 있습니다. 또한 다운로드할 수 있는 샘플 통합 문서가 포함되어 있습니다. |
