SEARCH, SEARCHB 함수

이 문서에서는 Microsoft Excel의 SEARCHSEARCHB 함수에 사용되는 수식 구문과 이 함수를 사용하는 방법을 설명합니다.

설명

SEARCHSEARCHB 함수는 두 번째 텍스트 문자열에서 지정된 텍스트 문자열을 검색하고, 두 번째 텍스트 문자열의 첫 문자를 기준으로 몇 번째 위치에서 첫 번째 텍스트 문자열이 시작하는지 나타내는 값을 반환합니다. 예를 들어 "printer"라는 단어에서 "n"자의 위치를 찾으려면 다음 함수를 사용하면 됩니다.

=SEARCH("n","printer")

"n"은 "printer"라는 단어의 네 번째 문자이므로 이 함수는 4를 반환합니다.

다른 단어 내에서 단어를 검색할 수도 있습니다.

=SEARCH("base","database")

예를 들어 위 함수는 "base"라는 단어가 "database"라는 단어의 다섯 번째 문자에서 시작하므로 5를 반환합니다. SEARCHSEARCHB 함수를 사용하여 다른 텍스트 문자열 내의 문자 또는 텍스트 문자열의 위치를 확인한 다음 MIDMIDB 함수를 사용하여 텍스트를 반환하거나 REPLACEREPLACEB 함수를 사용하여 텍스트를 변경할 수 있습니다. 이러한 함수에 대한 자세한 내용은 이 문서의 예제 1을 참조하세요.

중요: 

  • 일부 언어에서는 이러한 함수를 사용할 수 없습니다.

  • SEARCHB는 DBCS 언어를 기본 언어로 설정한 경우에만 문자당 2바이트를 계산합니다. 이러한 경우가 아니면 SEARCHB는 SEARCH와 동일하게 문자당 1바이트를 계산합니다.

DBCS를 지원하는 언어로는 한국어, 일본어, 중국어(간체) 및 중국어(번체)가 있습니다.

구문

SEARCH(find_text,within_text,[start_num])

SEARCHB(find_text,within_text,[start_num])

SEARCH 및 SEARCHB 함수 구문에는 다음과 같은 인수가 사용됩니다.

  • find_text    필수 요소입니다. 찾으려는 텍스트입니다.

  • within_text    필수 요소입니다. find_text 인수 값을 검색하려는 텍스트입니다.

  • start_num    선택 요소입니다. within_text 인수에서 찾기 시작하려는 위치까지의 문자 개수입니다.

주의

  • SEARCHSEARCHB는 대/소문자를 구분하지 않습니다. 대/소문자를 구분하여 검색하려면 FINDFINDB를 사용합니다.

  • find_text 인수에 와일드카드 문자인 물음표(?)와 별표(*)를 사용할 수 있습니다. 물음표는 한 문자에 해당하고 별표는 개수에 상관없는 임의의 문자열에 해당합니다. 실제 물음표나 별표를 찾으려면 해당 문자 앞에 물결표(~)를 입력합니다.

  • find_text 가 발견되지 않으면 #VALUE! 오류 값이 반환됩니다.

  • start_num 인수를 생략하면 1로 간주됩니다.

  • start_num 이 0보다 크지 않거나 within_text의 길이보다 크면 #VALUE! 오류 값이 반환됩니다.

  • start_num 을 사용하여 지정된 문자 수만큼 건너뛸 수 있습니다. 예를 들어 SEARCH 함수의 경우 텍스트 문자열 "AYF0093.YoungMensApparel"에서 텍스트 문자열의 설명 부분에 있는 첫 번째 "Y"의 위치를 찾으려면 텍스트의 일련 번호 부분(이 경우 "AYF0093")은 검색하지 않도록 start_num을 8로 설정합니다. 그러면 SEARCH 함수는 8번째 문자부터 검색 작업을 시작하여 그 뒷부분에서 find_text 인수에 지정된 문자를 찾아 번호 9를 반환합니다. SEARCH 함수는 start_num 인수가 1보다 큰 경우 건너뛴 문자 수도 계산하여 항상 within_text 인수의 시작 부분부터 센 문자 번호를 반환합니다.

예제

다음 표의 예제 데이터를 복사하여 새 Excel 워크시트의 A1 셀에 붙여 넣습니다. 수식의 결과를 표시하려면 수식을 선택하고 F2 키를 누른 다음 Enter 키를 누릅니다. 필요한 경우 열 너비를 조정하면 데이터를 모두 표시할 수 있습니다.

데이터

세금 명세서

판매 수익

여백

"철수"가 여기 있다.

수식

설명

결과

=SEARCH("세",A2,3)

A2 셀 문자열의 세 번째 위치에서 시작하여 첫 번째 "세"의 위치를 반환합니다.

7

=SEARCH(A4,A3)

"판매 수익"(찾을 셀은 A3)에서 "수익"(찾을 문자열은 A4 셀)의 위치를 반환합니다.

8

=REPLACE(A3,SEARCH(A4,A3),2,"금액")

A3 셀에서 "수익"의 위치를 검색한 후 해당 두 개 문자를 "금액"으로 바꿔서 "수익"을 "금액"으로 대체합니다.

판매 금액

=MID(A3,SEARCH(" ",A3)+1,2)

"판매 수익"(A3 셀)에서 첫 번째 공백 문자 바로 다음에 오는 문자 두 개를 반환합니다.

수익

=SEARCH("""",A5)

A5 셀에서 첫 번째 큰따옴표(")의 위치를 반환합니다.

5

=MID(A5,SEARCH("""",A5)+1,SEARCH("""",A5,SEARCH("""",A5)+1)-SEARCH("""",A5)-1)

A5 셀에서 큰따옴표로 묶인 텍스트만 반환합니다.

철수

Office 기술 확장
교육 살펴보기
새로운 기능 우선 가져오기
Office Insider 참여

이 정보가 유용한가요?

의견 주셔서 감사합니다!

피드백을 주셔서 감사합니다. Office 지원 에이전트와 연락하는 것이 도움이 될 것 같습니다.

×